sysdeps/powerpc/powerpc32/fpu/s_truncf.S

   1 /* truncf function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align 2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27 /* float [fp1] truncf (float x [fp1])
  28    IEEE 1003.1 trunc function.  IEEE specifies "trunc to the integer
  29    value, in floating format, nearest to but no larger in magnitude
  30    then the argument."
  31    We set "round toward Zero" mode and trunc by adding +-2**23 then
  32    subtracting +-2**23.  */
  33
  34         .section        ".text"
  35 ENTRY (__truncf)
  36         mffs    fp11            /* Save current FPU rounding mode.  */
  37 #ifdef SHARED
  38         mflr    r11
  39         bl      _GLOBAL_OFFSET_TABLE_@local-4
  40         mflr    r10
  41         lwz     r9,.LC0@got(10)
  42         mtlr    r11
  43         lfs     fp13,0(r9)
  44 #else
  45         lis     r9,.LC0@ha
  46         lfs     fp13,.LC0@l(r9)
  47 #endif
  48         fabs    fp0,fp1
  49         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  50         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  51         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  52         bnllr-  cr7
  53         mtfsfi  7,1             /* Set rounding toward 0 mode.  */
  54         ble-    cr6,.L4
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  57         fabs    fp1,fp1         /* if (x == 0.0)  */
  58                                 /* x = 0.0; */
  59         mtfsf   0x01,fp11       /* restore previous truncing mode.  */
  60         blr
  61 .L4:
  62         bge-    cr6,.L9         /* if (x < 0.0)  */
  63         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  64         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  65         fnabs   fp1,fp1         /* if (x == 0.0)  */
  66                                 /* x = -0.0; */
  67 .L9:
  68         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  69         blr
  70         END (__truncf)
  71
  72 weak_alias (__truncf, truncf)
  73