configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10.2)dnl            dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # We need a variable with the absolute path to the toplevel build directory.
  11 top_absdir=`cd $srcdir; pwd`
  12 AC_SUBST(top_absdir)
  13
  14 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  15 AC_ARG_WITH(gmp, dnl
  16   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  17             [dnl
  18 case "$with_gmp" in
  19 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  20 ''|no) ;;
  21 *) config_vars="$config_vars
  22 gmp-srcdir = $withval" ;;
  23 esac
  24 ])
  25 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  26 AC_ARG_WITH(gettext, dnl
  27   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  28             [dnl
  29 case "$with_gettext" in
  30 yes)
  31   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  32 ''|no) ;;
  33 *)
  34   config_vars="$config_vars
  35 gettext-srcdir = $withval" ;;
  36 esac
  37 ])
  38
  39 dnl Arguments to specify presence of other packages/features.
  40 AC_ARG_WITH(fp, dnl
  41   --with-fp               if using floating-point hardware [default=yes],
  42             with_fp=$withval, with_fp=yes)
  43 AC_ARG_WITH(gnu-binutils, dnl
  44   --with-gnu-binutils     if using GNU binutils (as and ld),
  45             gnu_binutils=$withval, gnu_binutils=no)
  46 AC_ARG_WITH(gnu-ld, dnl
  47   --with-gnu-ld           if using GNU ld (in the binutils package),
  48             gnu_ld=$withval, gnu_ld=no)
  49 AC_ARG_WITH(gnu-as, dnl
  50   --with-gnu-as           if using GNU as (in the binutils package),
  51             gnu_as=$withval, gnu_as=no)
  52 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  53 AC_ARG_WITH(elf, dnl
  54   --with-elf              if using the ELF object format,
  55             elf=$withval, elf=no)
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 dnl Arguments to enable or disable building the shared, profiled, and
  67 dnl -fomit-frame-pointer libraries.
  68 AC_ARG_ENABLE(shared, dnl
  69 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  70               shared=$enableval, shared=default)
  71 AC_ARG_ENABLE(profile, dnl
  72 [  --enable-profile        build profiled library [default=yes]],
  73               profile=$enableval, profile=yes)
  74 AC_ARG_ENABLE(omitfp, dnl
  75 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  76               omitfp=$enableval, omitfp=no)
  77
  78 dnl Generic infrastructure for drop-in additions to libc.
  79 AC_ARG_ENABLE(add-ons, dnl
  80 [  --enable-add-ons=DIR... configure and build named extra directories],
  81               [add_ons=`echo "$enableval" | sed 's/,/ /g'`],
  82               [add_ons=])
  83 AC_CONFIG_SUBDIRS($add_ons)
  84 add_ons_pfx=
  85 if test x"$add_ons" != x; then
  86   for f in $add_ons; do
  87     add_ons_pfx="$add_ons_pfx $f/"
  88   done
  89 fi
  90
  91 AC_CANONICAL_HOST
  92 # We keep the original values in `$config_*' and never modify them, so we
  93 # can write them unchanged into config.make.  Everything else uses
  94 # $machine, $vendor, and $os, and changes them whenever convenient.
  95 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  96
  97 # Some configurations imply other options.
  98 case "$host_os" in
  99 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 100   # These systems always use GNU tools.
 101   gnu_ld=yes gnu_as=yes ;;
 102 esac
 103 case "$host_os" in
 104 linux*ecoff*)
 105   ;;
 106 gnu* | linux* | sysv4* | solaris2*)
 107   # These systems (almost) always use the ELF format.
 108   elf=yes
 109   ;;
 110 esac
 111
 112 machine=$config_machine
 113 vendor=$config_vendor
 114 os=$config_os
 115
 116 dnl We need to use [ and ] for other purposes for a while now.
 117 changequote(,)dnl
 118 # Expand the configuration machine name into a subdirectory by architecture
 119 # type and particular chip.
 120 case "$machine" in
 121 a29k | am29000) base_machine=a29k machine=a29k ;;
 122 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 123 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 124 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 125 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 126 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 127 m88???)         base_machine=m88k machine=m88k/$machine ;;
 128 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 129 mips*)          base_machine=mips machine=mips/$machine ;;
 130 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 131 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 132 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 133 esac
 134 changequote([,])dnl
 135 AC_SUBST(base_machine)
 136
 137 # Compute the list of sysdep directories for this configuration.
 138 # This can take a while to compute.
 139 sysdep_dir=$srcdir/sysdeps
 140 AC_MSG_CHECKING(sysdep dirs)
 141 dnl We need to use [ and ] for other purposes for a while now.
 142 changequote(,)dnl
 143 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 144 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 145
 146 case "$os" in
 147 gnu*)
 148   base_os=mach/hurd ;;
 149 netbsd* | 386bsd* | freebsd* | bsdi*)
 150   base_os=unix/bsd/bsd4.4 ;;
 151 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 152   base_os=unix/bsd ;;
 153 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 154   base_os=unix/sysv ;;
 155 solaris[2-9]*)
 156   base_os=unix/sysv/sysv4 ;;
 157 none)
 158   base_os=standalone ;;
 159 *)
 160   base_os='' ;;
 161 esac
 162
 163 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 164 tail=$os
 165 ostry=$os
 166 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 167   ostry="$ostry /$o"
 168   tail=$o
 169 done
 170 o=`echo $tail | sed 's/[0-9]*$//'`
 171 if test $o != $tail; then
 172   ostry="$ostry /$o"
 173 fi
 174 # For linux-gnu, try linux-gnu, then linux.
 175 o=`echo $tail | sed 's/-.*$//'`
 176 if test $o != $tail; then
 177   ostry="$ostry /$o"
 178 fi
 179
 180 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 181 base=
 182 tail=$base_os
 183 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 184   set $b
 185   base="$base /$1"
 186   tail="$2"
 187 done
 188
 189 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 190 mach=
 191 tail=$machine
 192 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 193   set $m
 194   # Prepend the machine's FPU directory unless --without-fp.
 195   if test "$with_fp" = yes; then
 196     mach="$mach /$1/fpu"
 197   fi
 198   mach="$mach /$1"
 199   tail="$2"
 200 done
 201
 202 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 203 changequote([,])dnl
 204
 205 # Find what sysdep directories exist.
 206 sysnames=
 207 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 208 for d in $add_ons_pfx ''; do
 209   for b in $base ''; do
 210     for m0 in $mach ''; do
 211       for v in /$vendor ''; do
 212         for o in /$ostry ''; do
 213           for m in $mach ''; do
 214             if test "$m0$b$v$o$m"; then
 215               try="${d}sysdeps$m0$b$v$o$m"
 216               test -n "$enable_debug_configure" &&
 217               echo "$0 [DEBUG]: try $try" >&2
 218               case $try in
 219                 /*) dest=$try ;;
 220                 *)  dest=$srcdir/$try ;;
 221               esac
 222               if test -d $dest; then
 223                 sysnames="$sysnames $try"
 224                 { test -n "$o" || test -n "$b"; } && os_used=t
 225                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 226               fi
 227             fi
 228           done
 229         done
 230       done
 231     done
 232   done
 233 done
 234 IFS="$ac_save_ifs"
 235
 236 if test -z "$os_used" && test "$os" != none; then
 237   AC_MSG_ERROR(Operating system $os is not supported.)
 238 fi
 239 if test -z "$machine_used" && test "$machine" != none; then
 240   AC_MSG_ERROR(The $machine is not supported.)
 241 fi
 242
 243 # We have now validated the configuration.
 244
 245
 246 # If using ELF, look for an `elf' subdirectory of each machine directory.
 247 # We prepend these rather than inserting them whereever the machine appears
 248 # because things specified by the machine's ELF ABI should override
 249 # OS-specific things, and should always be the same for any OS on the
 250 # machine (otherwise what's the point of an ABI?).
 251 if test "$elf" = yes; then
 252   elf_dirs=
 253   for d in $add_ons_pfx ''; do
 254     case $d in
 255       /*) xsrcdir= ;;
 256       *)  xsrcdir=$srcdir/ ;;
 257     esac
 258     for m in $mach; do
 259       if test -d $xsrcdir${d}sysdeps$m/elf; then
 260         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 261       fi
 262     done
 263   done
 264   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 265 fi
 266
 267
 268 # Expand the list of system names into a full list of directories
 269 # from each element's parent name and Implies file (if present).
 270 set $sysnames
 271 names=
 272 while test $# -gt 0; do
 273   name=$1
 274   shift
 275
 276   case " $names " in *" $name "*)
 277     # Already in the list.
 278     continue
 279   esac
 280
 281   # Report each name as we discover it, so there is no long pause in output.
 282   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 283
 284   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 285
 286   case $name in
 287     /*) xsrcdir= ;;
 288     *)  xsrcdir=$srcdir/ ;;
 289   esac
 290   test -n "$enable_debug_configure" &&
 291   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 292
 293   if test -f $xsrcdir$name/Implies; then
 294     # Collect more names from the `Implies' file (removing comments).
 295     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 296     implied=
 297     for x in $implied_candidate; do
 298       if test -d $xsrcdir$name_base/$x; then
 299         implied="$implied $name_base/$x";
 300       else
 301         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 302       fi
 303     done
 304   else
 305     implied=
 306   fi
 307
 308   # Add NAME to the list of names.
 309   names="$names $name"
 310
 311   # Find the parent of NAME, using the empty string if it has none.
 312 changequote(,)dnl
 313   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 314 changequote([,])dnl
 315
 316   # Add the names implied by NAME, and NAME's parent (if it has one), to
 317   # the list of names to be processed (the argument list).  We prepend the
 318   # implied names to the list and append the parent.  We want implied
 319   # directories to come before further directories inferred from the
 320   # configuration components; this ensures that for sysv4, unix/common
 321   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 322   # after sysv4).
 323   sysnames="`echo $implied $* $parent`"
 324   test -n "$sysnames" && set $sysnames
 325 done
 326
 327 # Add the default directories.
 328 sysnames="$names sysdeps/generic sysdeps/stub"
 329 AC_SUBST(sysnames)
 330 # The other names were emitted during the scan.
 331 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 332
 333
 334 ### Locate tools.
 335
 336 AC_PROG_INSTALL
 337 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 338   # The makefiles need to use a different form to find it in $srcdir.
 339   INSTALL="$top_absdir/install-sh -c"
 340 fi
 341 AC_PROG_LN_S
 342 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 343
 344 AC_CHECK_TOOL(CC, gcc)
 345 if test $host != $build; then
 346   AC_CHECK_PROG(BUILD_CC, gcc cc)
 347 fi
 348 AC_PROG_CPP
 349 AC_CHECK_TOOL(AR, ar)
 350 AC_CHECK_TOOL(RANLIB, ranlib, :)
 351
 352 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 353 echo '#include <stddef.h>
 354 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 355 if eval "$ac_cpp conftest.c 2>/dev/null" \
 356 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 357   libc_cv_signed_size_t=no
 358 else
 359   libc_cv_signed_size_t=yes
 360 fi
 361 rm -f conftest*])
 362 if test $libc_cv_signed_size_t = yes; then
 363   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 364   cat >> confdefs.h <<\EOF
 365 #undef __SIZE_TYPE__
 366 #define __SIZE_TYPE__ unsigned
 367 EOF
 368 fi
 369
 370 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 371 AC_TRY_COMPILE(dnl
 372 [#define __need_size_t
 373 #define __need_wchar_t
 374 #include <stddef.h>
 375 #define __need_NULL
 376 #include <stddef.h>], [size_t size; wchar_t wchar;
 377 #ifdef offsetof
 378 #error stddef.h ignored __need_*
 379 #endif
 380 if (&size == NULL || &wchar == NULL) abort ();],
 381                libc_cv_friendly_stddef=yes,
 382                libc_cv_friendly_stddef=no)])
 383 if test $libc_cv_friendly_stddef = yes; then
 384   config_vars="$config_vars
 385 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 386 fi
 387
 388 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 389                libc_cv_need_minus_P, [dnl
 390 cat > conftest.S <<EOF
 391 #include "confdefs.h"
 392 /* Nothing whatsoever.  */
 393 EOF
 394 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 395   libc_cv_need_minus_P=no
 396 else
 397   libc_cv_need_minus_P=yes
 398 fi
 399 rm -f conftest*])
 400 if test $libc_cv_need_minus_P = yes; then
 401   config_vars="$config_vars
 402 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 403 fi
 404
 405 AC_CACHE_CHECK(for assembler global-symbol directive,
 406                libc_cv_asm_global_directive, [dnl
 407 libc_cv_asm_global_directive=UNKNOWN
 408 for ac_globl in .globl .global; do
 409   cat > conftest.s <<EOF
 410 .text
 411 ${ac_globl} foo
 412 foo: .long 0
 413 EOF
 414   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 415     libc_cv_asm_global_directive=${ac_globl}
 416   fi
 417   rm -f conftest*
 418   test $libc_cv_asm_global_directive != UNKNOWN && break
 419 done])
 420 if test $libc_cv_asm_global_directive = UNKNOWN; then
 421   AC_MSG_ERROR(cannot determine asm global directive)
 422 else
 423   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 424 fi
 425
 426 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 427 cat > conftest.s <<EOF
 428 .text
 429 foo: .long 0
 430 .set glibc_conftest_frobozz,foo
 431 $libc_cv_asm_global_directive glibc_conftest_frobozz
 432 EOF
 433 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 434 # (but it doesn't work), so we must do a linking check to be sure.
 435 cat > conftest1.c <<\EOF
 436 extern int glibc_conftest_frobozz;
 437 main () { printf ("%d\n", glibc_conftest_frobozz); }
 438 EOF
 439 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 440             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 441   libc_cv_asm_set_directive=yes
 442 else
 443   libc_cv_asm_set_directive=no
 444 fi
 445 rm -f conftest*])
 446 if test $libc_cv_asm_set_directive = yes; then
 447   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 448 fi
 449
 450 if test $elf != yes; then
 451   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 452                  [AC_TRY_COMPILE(, [asm (".section .init");
 453                                     asm (".section .fini");
 454                                     asm (".text");],
 455                                  libc_cv_have_initfini=yes,
 456                                  libc_cv_have_initfini=no)])
 457   AC_SUBST(libc_cv_have_initfini)dnl
 458   if test $libc_cv_have_initfini = yes; then
 459     AC_DEFINE(HAVE_INITFINI)
 460   fi
 461 fi
 462
 463 if test $elf = yes; then
 464   libc_cv_asm_underscores=no
 465 else
 466   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 467                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 468                               libc_cv_asm_underscores=yes,
 469                               libc_cv_asm_underscores=no)])
 470 fi
 471 if test $libc_cv_asm_underscores = no; then
 472   AC_DEFINE(NO_UNDERSCORES)
 473 fi
 474
 475 if test $elf = yes; then
 476   libc_cv_weak_symbols=yes
 477   libc_cv_asm_weak_directive=yes
 478   libc_cv_asm_weakext_directive=no
 479 else
 480   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 481                  [dnl
 482 cat > conftest.s <<EOF
 483 .text
 484 ${libc_cv_asm_global_directive} foo
 485 foo: .long 0
 486 .weak foo
 487 .weak bar; bar = foo
 488 EOF
 489   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 490     libc_cv_asm_weak_directive=yes
 491   else
 492     libc_cv_asm_weak_directive=no
 493   fi
 494   rm -f conftest*])
 495
 496 if test $libc_cv_asm_weak_directive = no; then
 497   AC_CACHE_CHECK(for assembler .weakext directive,
 498                  libc_cv_asm_weakext_directive,
 499                  [dnl
 500 cat > conftest.s <<EOF
 501 .text
 502 ${libc_cv_asm_global_directive} foo
 503 foo: .long 0
 504 .weakext foo
 505 .weakext foo, bar
 506 EOF
 507   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 508     libc_cv_asm_weakext_directive=yes
 509   else
 510     libc_cv_asm_weakext_directive=no
 511   fi
 512   rm -f conftest*])
 513
 514   fi # no .weak
 515 fi # not ELF
 516
 517 if test $libc_cv_asm_weak_directive = yes; then
 518   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 519 elif test $libc_cv_asm_weakext_directive = yes; then
 520   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 521 fi
 522
 523 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 524 cat > conftest.c <<\EOF
 525 _start () {}
 526 int __eh_pc;
 527 __throw () {}
 528 EOF
 529 dnl No \ in command here because it ends up inside ''.
 530 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 531                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 532                             -o conftest conftest.c]); then
 533   libc_cv_ld_no_whole_archive=yes
 534 else
 535   libc_cv_ld_no_whole_archive=no
 536 fi
 537 rm -f conftest*])
 538 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 539
 540 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 541 cat > conftest.c <<\EOF
 542 _start () {}
 543 int __eh_pc;
 544 __throw () {}
 545 EOF
 546 dnl No \ in command here because it ends up inside ''.
 547 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 548                             -nostdlib -nostartfiles -fno-exceptions
 549                             -o conftest conftest.c]); then
 550   libc_cv_gcc_no_exceptions=yes
 551 else
 552   libc_cv_gcc_no_exceptions=no
 553 fi
 554 rm -f conftest*])
 555 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 556
 557 ### End of automated tests.
 558 ### Now run sysdeps configure fragments.
 559
 560 # sysdeps configure fragments may set these with files to be linked below.
 561 libc_link_dests=
 562 libc_link_sources=
 563
 564 # Iterate over all the sysdep directories we will use, running their
 565 # configure fragments, and looking for a uname implementation.
 566 uname=
 567 for dir in $sysnames; do
 568   case $dir in
 569     /*) dest=$dir ;;
 570     *)  dest=$srcdir/$dir ;;
 571   esac
 572   if test -r $dest/configure; then
 573     AC_MSG_RESULT(running configure fragment for $dest)
 574     . $dest/configure
 575   fi
 576 [
 577   if test -z "$uname"; then
 578     if test -r $sysdep_dir/$dir/uname.c ||
 579        test -r $sysdep_dir/$dir/uname.S ||
 580        { test -r $sysdep_dir/$dir/syscalls.list &&
 581          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 582       uname=$dir
 583     fi
 584   fi
 585 ]dnl
 586 done
 587
 588 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 589
 590 # If we will use the generic uname implementation, we must figure out what
 591 # it will say by examining the system, and write the results in config-name.h.
 592 if test "$uname" = generic; then
 593
 594 changequote(,)dnl
 595   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 596 changequote([,])dnl
 597   if test $uname_sysname != $config_os; then
 598     config_release=`echo $config_os | sed s/$uname_sysname//`
 599   fi
 600 dnl
 601 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 602     if test -r /vmunix; then
 603       kernel_id=`strings /vmunix | grep UNIX`
 604     elif test -r /dynix; then
 605       kernel_id=`strings /dynix | grep DYNIX`
 606     else
 607       kernel_id=
 608     fi
 609 ])dnl
 610
 611   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 612 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 613 changequote(,)dnl
 614   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 615 changequote([,])dnl
 616   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 617          != x$config_release; then
 618     # The configuration release is a substring of the kernel release.
 619     libc_cv_uname_release=$kernel_release
 620   elif test x$config_release != x; then
 621     libc_cv_uname_release=$config_release
 622   elif test x$kernel_release != x; then
 623     libc_cv_uname_release=$kernel_release
 624   else
 625     libc_cv_uname_release=unknown
 626   fi])
 627   uname_release="$libc_cv_uname_release"
 628
 629   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 630 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 631 changequote(,)dnl
 632   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 633 changequote([,])dnl
 634   if test -n "$kernel_version"; then
 635     libc_cv_uname_version="$kernel_version"
 636   else
 637     libc_cv_uname_version=unknown
 638   fi])
 639   uname_version="$libc_cv_uname_version"
 640
 641 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 642   config_uname=config-name.h:config-name.in
 643 else
 644   # For non-generic uname, we don't need to create config-name.h at all.
 645   config_uname=
 646 fi
 647
 648 AC_MSG_CHECKING(stdio selection)
 649 AC_SUBST(stdio)
 650 case $stdio in
 651 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 652 default) stdio=stdio ;;
 653 esac
 654 AC_MSG_RESULT($stdio)
 655
 656 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 657 if test $gnu_ld = yes; then
 658   AC_DEFINE(HAVE_GNU_LD)
 659 fi
 660 if test $gnu_as = yes; then
 661   AC_DEFINE(HAVE_GNU_AS)
 662 fi
 663 if test $elf = yes; then
 664   AC_DEFINE(HAVE_ELF)
 665 fi
 666
 667 AC_SUBST(shared)
 668 if test $shared = default; then
 669   if test $gnu_ld = yes; then
 670     shared=$elf
 671   fi
 672 fi
 673 AC_SUBST(profile)
 674 AC_SUBST(omitfp)
 675
 676 AC_SUBST(DEFINES)
 677
 678 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 679   config_makefile=
 680 else
 681   config_makefile=Makefile
 682 fi
 683
 684 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 685           [echo '$config_vars' >> config.make])