sysdeps/sparc/sparc64/rshift.S

   1 /* SPARC v9 __mpn_rshift --
   2
   3    Copyright (C) 1996, 1999 Free Software Foundation, Inc.
   4
   5    This file is part of the GNU MP Library.
   6
   7    The GNU MP Library is free software; you can redistribute it and/or modify
   8    it under the terms of the GNU Lesser General Public License as published by
   9    the Free Software Foundation; either version 2.1 of the License, or (at your
  10    option) any later version.
  11
  12    The GNU MP Library is distributed in the hope that it will be useful, but
  13    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15    License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public License
  18    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20    MA 02111-1307, USA.  */
  21
  22 #include <sysdep.h>
  23
  24 /* INPUT PARAMETERS
  25    res_ptr      %o0
  26    src_ptr      %o1
  27    size         %o2
  28    cnt          %o3  */
  29
  30         .register       %g2, #scratch
  31         .register       %g3, #scratch
  32
  33 ENTRY(__mpn_rshift)
  34         ldx     [%o1],%g2       ! load first limb
  35         sub     %g0,%o3,%o5     ! negate shift count
  36         add     %o2,-1,%o2
  37         andcc   %o2,4-1,%g4     ! number of limbs in first loop
  38         sllx    %g2,%o5,%g1     ! compute function result
  39         be,pn   %xcc,.L0        ! if multiple of 4 limbs, skip first loop
  40          mov    %g1,%g5
  41
  42         sub     %o2,%g4,%o2     ! adjust count for main loop
  43
  44 .Loop0: ldx     [%o1+8],%g3
  45         add     %o0,8,%o0
  46         add     %o1,8,%o1
  47         srlx    %g2,%o3,%o4
  48         addcc   %g4,-1,%g4
  49         sllx    %g3,%o5,%g1
  50         mov     %g3,%g2
  51         or      %o4,%g1,%o4
  52         bne,pt  %xcc,.Loop0
  53          stx    %o4,[%o0-8]
  54
  55 .L0:    brz,pn  %o2,.Lend
  56          nop
  57
  58 .Loop:  ldx     [%o1+8],%g3
  59         add     %o0,32,%o0
  60         srlx    %g2,%o3,%o4
  61         addcc   %o2,-4,%o2
  62         sllx    %g3,%o5,%g1
  63
  64         ldx     [%o1+16],%g2
  65         srlx    %g3,%o3,%g4
  66         or      %o4,%g1,%o4
  67         stx     %o4,[%o0-32]
  68         sllx    %g2,%o5,%g1
  69
  70         ldx     [%o1+24],%g3
  71         srlx    %g2,%o3,%o4
  72         or      %g4,%g1,%g4
  73         stx     %g4,[%o0-24]
  74         sllx    %g3,%o5,%g1
  75
  76         ldx     [%o1+32],%g2
  77         srlx    %g3,%o3,%g4
  78         or      %o4,%g1,%o4
  79         stx     %o4,[%o0-16]
  80         sllx    %g2,%o5,%g1
  81
  82         add     %o1,32,%o1
  83         or      %g4,%g1,%g4
  84         bne,pt  %xcc,.Loop
  85          stx    %g4,[%o0-8]
  86
  87 .Lend:  srlx    %g2,%o3,%g2
  88         stx     %g2,[%o0-0]
  89
  90         jmpl    %o7+8,%g0
  91          mov    %g5,%o0
  92
  93 END(__mpn_rshift)