sysdeps/i386/fpu/e_log10l.S

   1 /*
   2  * Written by J.T. Conklin <jtc@netbsd.org>.
   3  * Public domain.
   4  *
   5  * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
   6  *
   7  * Changed to use fyl2xp1 for values near 1, <drepper@cygnus.com>.
   8  */
   9
  10 #include <machine/asm.h>
  11
  12 RCSID("$NetBSD: $")
  13
  14 #ifdef __ELF__
  15         .section .rodata
  16 #else
  17         .text
  18 #endif
  19         .align ALIGNARG(4)
  20         ASM_TYPE_DIRECTIVE(one,@object)
  21 one:    .double 1.0
  22         ASM_SIZE_DIRECTIVE(one)
  23         /* It is not important that this constant is precise.  It is only
  24            a value which is known to be on the safe side for using the
  25            fyl2xp1 instruction.  */
  26         ASM_TYPE_DIRECTIVE(limit,@object)
  27 limit:  .double 0.29
  28         ASM_SIZE_DIRECTIVE(limit)
  29
  30
  31 #ifdef PIC
  32 #define MO(op) op##@GOTOFF(%edx)
  33 #else
  34 #define MO(op) op
  35 #endif
  36
  37         .text
  38 ENTRY(__ieee754_log10l)
  39         fldlg2                  // log10(2)
  40         fldt    4(%esp)         // x : log10(2)
  41 #ifdef PIC
  42         LOAD_PIC_REG (dx)
  43 #endif
  44         fxam
  45         fnstsw
  46         fld     %st             // x : x : log10(2)
  47         sahf
  48         jc      3f              // in case x is NaN or ±Inf
  49 4:      fsubl   MO(one)         // x-1 : x : log10(2)
  50         fld     %st             // x-1 : x-1 : x : log10(2)
  51         fabs                    // |x-1| : x-1 : x : log10(2)
  52         fcompl  MO(limit)       // x-1 : x : log10(2)
  53         fnstsw                  // x-1 : x : log10(2)
  54         andb    $0x45, %ah
  55         jz      2f
  56         fstp    %st(1)          // x-1 : log10(2)
  57         fyl2xp1                 // log10(x)
  58         ret
  59
  60 2:      fstp    %st(0)          // x : log10(2)
  61         fyl2x                   // log10(x)
  62         ret
  63
  64 3:      jp      4b              // in case x is ±Inf
  65         fstp    %st(1)
  66         fstp    %st(1)
  67         ret
  68 END(__ieee754_log10l)