configure.ac

   1 # configure.ac - for GnuPG 2.0
   2 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005,
   3 #               2006, 2007, 2008 Free Software Foundation, Inc.
   4 #
   5 # This file is part of GnuPG.
   6 #
   7 # GnuPG is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GnuPG is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  19
  20 # Process this file with autoconf to produce a configure script.
  21 AC_PREREQ(2.61)
  22 min_automake_version="1.10"
  23
  24 # Remember to change the version number immediately *after* a release.
  25 # Set my_issvn to "yes" for non-released code.  Remember to run an
  26 # "svn up" and "autogen.sh" right before creating a distribution.
  27 m4_define([my_version], [2.0.13])
  28 m4_define([my_issvn], [no])
  29
  30 m4_define([svn_revision], m4_esyscmd([printf "%d" $(svn info 2>/dev/null \
  31           | sed -n '/^Revision:/ s/[^0-9]//gp'|head -1)]))
  32 AC_INIT([gnupg],
  33         [my_version[]m4_if(my_issvn,[yes],[-svn[]svn_revision])],
  34         [http://bugs.gnupg.org])
  35 # Set development_version to yes if the minor number is odd or you
  36 # feel that the default check for a development version is not
  37 # sufficient.
  38 development_version=no
  39
  40 NEED_GPG_ERROR_VERSION=1.4
  41
  42 NEED_LIBGCRYPT_API=1
  43 NEED_LIBGCRYPT_VERSION=1.4.0
  44
  45 NEED_LIBASSUAN_API=1
  46 NEED_LIBASSUAN_VERSION=1.0.4
  47
  48 NEED_KSBA_API=1
  49 NEED_KSBA_VERSION=1.0.2
  50
  51
  52 PACKAGE=$PACKAGE_NAME
  53 PACKAGE_GT=${PACKAGE_NAME}2
  54 VERSION=$PACKAGE_VERSION
  55
  56 AC_CONFIG_AUX_DIR(scripts)
  57 AC_CONFIG_SRCDIR(sm/gpgsm.c)
  58 AM_CONFIG_HEADER(config.h)
  59 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  60 AC_CANONICAL_HOST
  61 AB_INIT
  62
  63 AC_GNU_SOURCE
  64
  65 # Some status variables.
  66 have_gpg_error=no
  67 have_libgcrypt=no
  68 have_libassuan=no
  69 have_ksba=no
  70 have_pth=no
  71 have_libusb=no
  72 have_adns=no
  73
  74 use_bzip2=yes
  75 use_exec=yes
  76 disable_keyserver_path=no
  77
  78
  79 GNUPG_BUILD_PROGRAM(gpg, yes)
  80 GNUPG_BUILD_PROGRAM(gpgsm, yes)
  81 GNUPG_BUILD_PROGRAM(agent, yes)
  82 GNUPG_BUILD_PROGRAM(scdaemon, yes)
  83 GNUPG_BUILD_PROGRAM(tools, yes)
  84 GNUPG_BUILD_PROGRAM(doc, yes)
  85 GNUPG_BUILD_PROGRAM(symcryptrun, no)
  86
  87 AC_SUBST(PACKAGE)
  88 AC_SUBST(PACKAGE_GT)
  89 AC_SUBST(VERSION)
  90 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
  91 AC_DEFINE_UNQUOTED(PACKAGE_GT, "$PACKAGE_GT",
  92                                 [Name of this package for gettext])
  93 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
  94 AC_DEFINE_UNQUOTED(PACKAGE_BUGREPORT, "$PACKAGE_BUGREPORT",
  95                                         [Bug report address])
  96 AC_DEFINE_UNQUOTED(NEED_LIBGCRYPT_VERSION, "$NEED_LIBGCRYPT_VERSION",
  97                                        [Required version of Libgcrypt])
  98 AC_DEFINE_UNQUOTED(NEED_KSBA_VERSION, "$NEED_KSBA_VERSION",
  99                                        [Required version of Libksba])
 100
 101
 102
 103 # The default is to use the modules from this package and the few
 104 # other packages in a standard place; i.e where this package gets
 105 # installed.  With these options it is possible to override these
 106 # ${prefix} depended values with fixed paths, which can't be replaced
 107 # at make time.  See also am/cmacros.am and the defaults in AH_BOTTOM.
 108 AC_ARG_WITH(agent-pgm,
 109     [  --with-agent-pgm=PATH  Use PATH as the default for the agent)],
 110           GNUPG_AGENT_PGM="$withval", GNUPG_AGENT_PGM="" )
 111 AC_SUBST(GNUPG_AGENT_PGM)
 112 AM_CONDITIONAL(GNUPG_AGENT_PGM, test -n "$GNUPG_AGENT_PGM")
 113 show_gnupg_agent_pgm="(default)"
 114 test -n "$GNUPG_AGENT_PGM" && show_gnupg_agent_pgm="$GNUPG_AGENT_PGM"
 115
 116 AC_ARG_WITH(pinentry-pgm,
 117     [  --with-pinentry-pgm=PATH  Use PATH as the default for the pinentry)],
 118           GNUPG_PINENTRY_PGM="$withval", GNUPG_PINENTRY_PGM="" )
 119 AC_SUBST(GNUPG_PINENTRY_PGM)
 120 AM_CONDITIONAL(GNUPG_PINENTRY_PGM, test -n "$GNUPG_PINENTRY_PGM")
 121 show_gnupg_pinentry_pgm="(default)"
 122 test -n "$GNUPG_PINENTRY_PGM" && show_gnupg_pinentry_pgm="$GNUPG_PINENTRY_PGM"
 123
 124
 125 AC_ARG_WITH(scdaemon-pgm,
 126     [  --with-scdaemon-pgm=PATH  Use PATH as the default for the scdaemon)],
 127           GNUPG_SCDAEMON_PGM="$withval", GNUPG_SCDAEMON_PGM="" )
 128 AC_SUBST(GNUPG_SCDAEMON_PGM)
 129 AM_CONDITIONAL(GNUPG_SCDAEMON_PGM, test -n "$GNUPG_SCDAEMON_PGM")
 130 show_gnupg_scdaemon_pgm="(default)"
 131 test -n "$GNUPG_SCDAEMON_PGM" && show_gnupg_scdaemon_pgm="$GNUPG_SCDAEMON_PGM"
 132
 133
 134 AC_ARG_WITH(dirmngr-pgm,
 135     [  --with-dirmngr-pgm=PATH  Use PATH as the default for the dirmngr)],
 136           GNUPG_DIRMNGR_PGM="$withval", GNUPG_DIRMNGR_PGM="" )
 137 AC_SUBST(GNUPG_DIRMNGR_PGM)
 138 AM_CONDITIONAL(GNUPG_DIRMNGR_PGM, test -n "$GNUPG_DIRMNGR_PGM")
 139 show_gnupg_dirmngr_pgm="(default)"
 140 test -n "$GNUPG_DIRMNGR_PGM" && show_gnupg_dirmngr_pgm="$GNUPG_DIRMNGR_PGM"
 141
 142 AC_ARG_WITH(protect-tool-pgm,
 143     [  --with-protect-tool-pgm=PATH  Use PATH as the default for the protect-tool)],
 144           GNUPG_PROTECT_TOOL_PGM="$withval", GNUPG_PROTECT_TOOL_PGM="" )
 145 AC_SUBST(GNUPG_PROTECT_TOOL_PGM)
 146 AM_CONDITIONAL(GNUPG_PROTECT_TOOL_PGM, test -n "$GNUPG_PROTECT_TOOL_PGM")
 147 show_gnupg_protect_tool_pgm="(default)"
 148 test -n "$GNUPG_PROTECT_TOOL_PGM" \
 149       && show_gnupg_protect_tool_pgm="$GNUPG_PROTECT_TOOL_PGM"
 150
 151
 152 # Some folks want to use only the agent from this packet.  Make it
 153 # easier for them by providing the configure option
 154 # --enable-only-agent.
 155 AC_ARG_ENABLE(agent-only,
 156     AC_HELP_STRING([--enable-agent-only],[build only the gpg-agent]),
 157     build_agent_only=$enableval)
 158
 159 # SELinux support includes tracking of sensitive files to avoid
 160 # leaking their contents through processing these files by gpg itself
 161 AC_MSG_CHECKING([whether SELinux support is requested])
 162 AC_ARG_ENABLE(selinux-support,
 163               AC_HELP_STRING([--enable-selinux-support],
 164                              [enable SELinux support]),
 165               selinux_support=$enableval, selinux_support=no)
 166 AC_MSG_RESULT($selinux_support)
 167
 168 # Allow disabling of bzib2 support.
 169 # It is defined only after we confirm the library is available later
 170 AC_MSG_CHECKING([whether to enable the BZIP2 compression algorithm])
 171 AC_ARG_ENABLE(bzip2,
 172    AC_HELP_STRING([--disable-bzip2],[disable the BZIP2 compression algorithm]),
 173    use_bzip2=$enableval)
 174 AC_MSG_RESULT($use_bzip2)
 175
 176 # Configure option to allow or disallow execution of external
 177 # programs, like a photo viewer.
 178 AC_MSG_CHECKING([whether to enable external program execution])
 179 AC_ARG_ENABLE(exec,
 180     AC_HELP_STRING([--disable-exec],[disable all external program execution]),
 181     use_exec=$enableval)
 182 AC_MSG_RESULT($use_exec)
 183 if test "$use_exec" = no ; then
 184     AC_DEFINE(NO_EXEC,1,[Define to disable all external program execution])
 185 fi
 186
 187 if test "$use_exec" = yes ; then
 188   AC_MSG_CHECKING([whether to enable photo ID viewing])
 189   AC_ARG_ENABLE(photo-viewers,
 190       [  --disable-photo-viewers disable photo ID viewers],
 191       [if test "$enableval" = no ; then
 192          AC_DEFINE(DISABLE_PHOTO_VIEWER,1,[define to disable photo viewing])
 193       fi],enableval=yes)
 194   gnupg_cv_enable_photo_viewers=$enableval
 195   AC_MSG_RESULT($enableval)
 196
 197   if test "$gnupg_cv_enable_photo_viewers" = yes ; then
 198     AC_MSG_CHECKING([whether to use a fixed photo ID viewer])
 199     AC_ARG_WITH(photo-viewer,
 200         [  --with-photo-viewer=FIXED_VIEWER  set a fixed photo ID viewer],
 201         [if test "$withval" = yes ; then
 202            withval=no
 203         elif test "$withval" != no ; then
 204            AC_DEFINE_UNQUOTED(FIXED_PHOTO_VIEWER,"$withval",
 205                             [if set, restrict photo-viewer to this])
 206         fi],withval=no)
 207     AC_MSG_RESULT($withval)
 208   fi
 209
 210   AC_MSG_CHECKING([whether to enable external keyserver helpers])
 211   AC_ARG_ENABLE(keyserver-helpers,
 212       [  --disable-keyserver-helpers  disable all external keyserver support],
 213       [if test "$enableval" = no ; then
 214          AC_DEFINE(DISABLE_KEYSERVER_HELPERS,1,
 215                   [define to disable keyserver helpers])
 216       fi],enableval=yes)
 217   gnupg_cv_enable_keyserver_helpers=$enableval
 218   AC_MSG_RESULT($enableval)
 219
 220   if test "$gnupg_cv_enable_keyserver_helpers" = yes ; then
 221     # LDAP is defined only after we confirm the library is available later
 222     AC_MSG_CHECKING([whether LDAP keyserver support is requested])
 223     AC_ARG_ENABLE(ldap,
 224       AC_HELP_STRING([--disable-ldap],[disable LDAP keyserver interface only]),
 225       try_ldap=$enableval, try_ldap=yes)
 226     AC_MSG_RESULT($try_ldap)
 227
 228     AC_MSG_CHECKING([whether HKP keyserver support is requested])
 229     AC_ARG_ENABLE(hkp,
 230       AC_HELP_STRING([--disable-hkp],[disable HKP keyserver interface only]),
 231       try_hkp=$enableval, try_hkp=yes)
 232     AC_MSG_RESULT($try_hkp)
 233
 234     AC_MSG_CHECKING([whether finger key fetching support is requested])
 235     AC_ARG_ENABLE(finger,
 236       AC_HELP_STRING([--disable-finger],
 237         [disable finger key fetching interface only]),
 238       try_finger=$enableval, try_finger=yes)
 239     AC_MSG_RESULT($try_finger)
 240
 241     AC_MSG_CHECKING([whether generic object key fetching support is requested])
 242     AC_ARG_ENABLE(generic,
 243       AC_HELP_STRING([--disable-generic],
 244         [disable generic object key fetching interface only]),
 245       try_generic=$enableval, try_generic=yes)
 246     AC_MSG_RESULT($try_generic)
 247
 248     AC_MSG_CHECKING([whether email keyserver support is requested])
 249     AC_ARG_ENABLE(mailto,
 250       AC_HELP_STRING([--enable-mailto],
 251         [enable email keyserver interface only]),
 252       try_mailto=$enableval, try_mailto=no)
 253     AC_MSG_RESULT($try_mailto)
 254     fi
 255
 256     AC_MSG_CHECKING([whether keyserver exec-path is enabled])
 257     AC_ARG_ENABLE(keyserver-path,
 258       AC_HELP_STRING([--disable-keyserver-path],
 259         [disable the exec-path option for keyserver helpers]),
 260       [if test "$enableval" = no ; then
 261          disable_keyserver_path=yes
 262       fi],enableval=yes)
 263     AC_MSG_RESULT($enableval)
 264   fi
 265
 266
 267 #
 268 # Check for the key/uid cache size.  This can't be zero, but can be
 269 # pretty small on embedded systems.  This is used for the gpg part.
 270 #
 271 AC_MSG_CHECKING([for the size of the key and uid cache])
 272 AC_ARG_ENABLE(key-cache,
 273         AC_HELP_STRING([--enable-key-cache=SIZE],
 274                        [Set key cache to SIZE (default 4096)]),,enableval=4096)
 275 if test "$enableval" = "no"; then
 276    enableval=5
 277 elif test "$enableval" = "yes" || test "$enableval" = ""; then
 278    enableval=4096
 279 fi
 280 changequote(,)dnl
 281 key_cache_size=`echo "$enableval" | sed 's/[A-Za-z]//g'`
 282 changequote([,])dnl
 283 if test "$enableval" != "$key_cache_size" || test "$key_cache_size" -lt 5; then
 284    AC_MSG_ERROR([invalid key-cache size])
 285 fi
 286 AC_MSG_RESULT($key_cache_size)
 287 AC_DEFINE_UNQUOTED(PK_UID_CACHE_SIZE,$key_cache_size,
 288                   [Size of the key and UID caches])
 289
 290
 291
 292 #
 293 # Check whether we want to use Linux capabilities
 294 #
 295 AC_MSG_CHECKING([whether use of capabilities is requested])
 296 AC_ARG_WITH(capabilities,
 297     [  --with-capabilities     use linux capabilities [default=no]],
 298 [use_capabilities="$withval"],[use_capabilities=no])
 299 AC_MSG_RESULT($use_capabilities)
 300
 301 #
 302 # To avoid double inclusion of config.h which might happen at some
 303 # places, we add the usual double inclusion protection at the top of
 304 # config.h.
 305 #
 306 AH_TOP([
 307 #ifndef GNUPG_CONFIG_H_INCLUDED
 308 #define GNUPG_CONFIG_H_INCLUDED
 309 ])
 310
 311 #
 312 # Stuff which goes at the bottom of config.h.
 313 #
 314 AH_BOTTOM([
 315 /* This is the major version number of GnuPG so that
 316    source included files can test for this.  Note, that
 317    we use 2 here even for GnuPG 1.9.x. */
 318 #define GNUPG_MAJOR_VERSION 2
 319
 320 /* Now to separate file name parts.
 321    Please note that the string version must not contain more
 322    than one character because the code assumes strlen()==1 */
 323 #ifdef HAVE_DOSISH_SYSTEM
 324 #define DIRSEP_C '\\'
 325 #define DIRSEP_S "\\"
 326 #define EXTSEP_C '.'
 327 #define EXTSEP_S "."
 328 #define PATHSEP_C ';'
 329 #define PATHSEP_S ";"
 330 #define EXEEXT_S ".exe"
 331 #else
 332 #define DIRSEP_C '/'
 333 #define DIRSEP_S "/"
 334 #define EXTSEP_C '.'
 335 #define EXTSEP_S "."
 336 #define PATHSEP_C ':'
 337 #define PATHSEP_S ":"
 338 #define EXEEXT_S ""
 339 #endif
 340
 341 /* This is the same as VERSION, but should be overridden if the
 342    platform cannot handle things like dots '.' in filenames. Set
 343    SAFE_VERSION_DOT and SAFE_VERSION_DASH to whatever SAFE_VERSION
 344    uses for dots and dashes. */
 345 #define SAFE_VERSION VERSION
 346 #define SAFE_VERSION_DOT  '.'
 347 #define SAFE_VERSION_DASH '-'
 348
 349 /* Some global constants. */
 350 #ifdef HAVE_DRIVE_LETTERS
 351 #define GNUPG_DEFAULT_HOMEDIR "c:/gnupg"
 352 #elif defined(__VMS)
 353 #define GNUPG_DEFAULT_HOMEDIR "/SYS\$LOGIN/gnupg"
 354 #else
 355 #define GNUPG_DEFAULT_HOMEDIR "~/.gnupg"
 356 #endif
 357 #define GNUPG_PRIVATE_KEYS_DIR "private-keys-v1.d"
 358
 359 /* For some systems (DOS currently), we hardcode the path here.  For
 360    POSIX systems the values are constructed by the Makefiles, so that
 361    the values may be overridden by the make invocations; this is to
 362    comply with the GNU coding standards. */
 363 #ifdef HAVE_DRIVE_LETTERS
 364  /* FIXME: We need to use a function to determine these values depending
 365     on the actual installation directory. */
 366 #define GNUPG_BINDIR      "c:\\gnupg"
 367 #define GNUPG_LIBEXECDIR  "c:\\gnupg"
 368 #define GNUPG_LIBDIR      "c:\\gnupg"
 369 #define GNUPG_DATADIR     "c:\\gnupg"
 370 #define GNUPG_SYSCONFDIR  "c:\\gnupg"
 371 #endif
 372
 373 /* Derive some other constants. */
 374 #if !(defined(HAVE_FORK) && defined(HAVE_PIPE) && defined(HAVE_WAITPID))
 375 #define EXEC_TEMPFILE_ONLY
 376 #endif
 377
 378
 379 /* We didn't define endianness above, so get it from OS macros.  This
 380    is intended for making fat binary builds on OS X. */
 381 #if !defined(BIG_ENDIAN_HOST) && !defined(LITTLE_ENDIAN_HOST)
 382 #if defined(__BIG_ENDIAN__)
 383 #define BIG_ENDIAN_HOST 1
 384 #elif defined(__LITTLE_ENDIAN__)
 385 #define LITTLE_ENDIAN_HOST 1
 386 #else
 387 #error "No endianness found"
 388 #endif
 389 #endif
 390
 391
 392 /* Hack used for W32: ldap.m4 also tests for the ASCII version of
 393    ldap_start_tls_s because that is the actual symbol used in the
 394    library.  winldap.h redefines it to our commonly used value,
 395    thus we define our usual macro here.  */
 396 #ifdef HAVE_LDAP_START_TLS_SA
 397 # ifndef HAVE_LDAP_START_TLS_S
 398 #  define HAVE_LDAP_START_TLS_S 1
 399 # endif
 400 #endif
 401
 402
 403 /* Tell libgcrypt not to use its own libgpg-error implementation. */
 404 #define USE_LIBGPG_ERROR 1
 405
 406 /* We use jnlib, so tell other modules about it.  */
 407 #define HAVE_JNLIB_LOGGING 1
 408
 409 /* Our HTTP code is used in estream mode.  */
 410 #define HTTP_USE_ESTREAM 1
 411
 412 /* Under W32 we do an explicit socket initialization, thus we need to
 413    avoid the on-demand initialization which would also install an atexit
 414    handler.  */
 415 #define HTTP_NO_WSASTARTUP
 416
 417 /* We always include support for the OpenPGP card.  */
 418 #define ENABLE_CARD_SUPPORT 1
 419
 420 /* We don't want the old assuan codes anymore. */
 421 #define _ASSUAN_ONLY_GPG_ERRORS 1
 422
 423 /* We explicitly need to disable PTH's soft mapping as Debian
 424    currently enables it by default for no reason. */
 425 #define PTH_SYSCALL_SOFT 0
 426
 427 /* We want to use the libgcrypt provided memory allocation for
 428    asprintf.  */
 429 #define _ESTREAM_PRINTF_MALLOC        gcry_malloc
 430 #define _ESTREAM_PRINTF_FREE          gcry_free
 431 #define _ESTREAM_PRINTF_EXTRA_INCLUDE "util.h"
 432
 433 #endif /*GNUPG_CONFIG_H_INCLUDED*/
 434 ])
 435
 436
 437 AM_MAINTAINER_MODE
 438
 439 # Checks for programs.
 440 AC_MSG_NOTICE([checking for programs])
 441 AC_PROG_MAKE_SET
 442 AM_SANITY_CHECK
 443 missing_dir=`cd $ac_aux_dir && pwd`
 444 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 445 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 446 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
 447 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
 448 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
 449 AC_PROG_AWK
 450 AC_PROG_CC
 451 AC_PROG_CPP
 452 AM_PROG_CC_C_O
 453 if test "x$ac_cv_prog_cc_c89" = "xno" ; then
 454   AC_MSG_ERROR([[No C-89 compiler found]])
 455 fi
 456 AC_PROG_INSTALL
 457 AC_PROG_LN_S
 458 AC_PROG_RANLIB
 459 AC_CHECK_TOOL(AR, ar, :)
 460 AC_PATH_PROG(PERL,"perl")
 461 AC_CHECK_TOOL(WINDRES, windres, :)
 462 AC_ISC_POSIX
 463 gl_EARLY
 464 AC_SYS_LARGEFILE
 465 GNUPG_CHECK_FAQPROG
 466 GNUPG_CHECK_USTAR
 467
 468 # We need to compile and run a program on the build machine.  A
 469 # comment in libgpg-error says that the AC_PROG_CC_FOR_BUILD macro in
 470 # the AC archive is broken for autoconf 2.57.  Given that tehre is no
 471 # newer version of that macro, we assume that it is also broken for
 472 # autoconf 2.61 and thus we use a simple but usually sufficient
 473 # approach.
 474 AC_MSG_CHECKING(for cc for build)
 475 if test "$cross_compiling" = "yes"; then
 476   CC_FOR_BUILD="${CC_FOR_BUILD-cc}"
 477 else
 478   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
 479 fi
 480 AC_MSG_RESULT($CC_FOR_BUILD)
 481 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
 482
 483
 484
 485 try_gettext=yes
 486 have_dosish_system=no
 487 have_w32_system=no
 488 use_simple_gettext=no
 489 case "${host}" in
 490     *-mingw32*)
 491         # special stuff for Windoze NT
 492         ac_cv_have_dev_random=no
 493         AC_DEFINE(USE_ONLY_8DOT3,1,
 494                   [set this to limit filenames to the 8.3 format])
 495         AC_DEFINE(HAVE_DRIVE_LETTERS,1,
 496                   [defined if we must run on a stupid file system])
 497         AC_DEFINE(USE_SIMPLE_GETTEXT,1,
 498                   [because the Unix gettext has too much overhead on
 499                    MingW32 systems and these systems lack Posix functions,
 500                    we use a simplified version of gettext])
 501         disable_keyserver_path=yes
 502         have_dosish_system=yes
 503         have_w32_system=yes
 504         try_gettext="no"
 505         use_simple_gettext=yes
 506         ;;
 507     i?86-emx-os2 | i?86-*-os2*emx )
 508         # OS/2 with the EMX environment
 509         ac_cv_have_dev_random=no
 510         AC_DEFINE(HAVE_DRIVE_LETTERS)
 511         have_dosish_system=yes
 512         try_gettext="no"
 513         ;;
 514
 515     i?86-*-msdosdjgpp*)
 516         # DOS with the DJGPP environment
 517         ac_cv_have_dev_random=no
 518         AC_DEFINE(HAVE_DRIVE_LETTERS)
 519         have_dosish_system=yes
 520         try_gettext="no"
 521         ;;
 522
 523     *-*-freebsd*)
 524        # FreeBSD
 525        CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 526        LDFLAGS="$LDFLAGS -L/usr/local/lib"
 527        ;;
 528
 529     *-*-hpux*)
 530         if test -z "$GCC" ; then
 531             CFLAGS="$CFLAGS -Ae -D_HPUX_SOURCE"
 532         fi
 533         ;;
 534     *-dec-osf4*)
 535         if test -z "$GCC" ; then
 536             # Suppress all warnings
 537             # to get rid of the unsigned/signed char mismatch warnings.
 538             CFLAGS="$CFLAGS -w"
 539         fi
 540         ;;
 541     *-dec-osf5*)
 542         if test -z "$GCC" ; then
 543             # Use the newer compiler `-msg_disable ptrmismatch1' to
 544             # get rid of the unsigned/signed char mismatch warnings.
 545             # Using this may hide other pointer mismatch warnings, but
 546             # it at least lets other warning classes through
 547             CFLAGS="$CFLAGS -msg_disable ptrmismatch1"
 548         fi
 549         ;;
 550     m68k-atari-mint)
 551         ;;
 552     *)
 553        ;;
 554 esac
 555
 556 if test "$have_dosish_system" = yes; then
 557    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
 558              [Defined if we run on some of the PCDOS like systems
 559               (DOS, Windoze. OS/2) with special properties like
 560               no file modes])
 561 fi
 562 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
 563
 564 AM_CONDITIONAL(USE_SIMPLE_GETTEXT, test x"$use_simple_gettext" = xyes)
 565
 566 if test "$have_w32_system" = yes; then
 567    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 568 fi
 569 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 570
 571 if test "$disable_keyserver_path" = yes; then
 572     AC_DEFINE(DISABLE_KEYSERVER_PATH,1,
 573               [Defined to disable exec-path for keyserver helpers])
 574 fi
 575
 576 # (These need to go after AC_PROG_CC so that $EXEEXT is defined)
 577 AC_DEFINE_UNQUOTED(EXEEXT,"$EXEEXT",[The executable file extension, if any])
 578
 579 if test x"$try_hkp" = xyes ; then
 580   AC_SUBST(GPGKEYS_HKP,"gpg2keys_hkp$EXEEXT")
 581 fi
 582
 583 if test x"$try_finger" = xyes ; then
 584   AC_SUBST(GPGKEYS_FINGER,"gpg2keys_finger$EXEEXT")
 585 fi
 586
 587
 588
 589 #
 590 # Checks for libraries.
 591 #
 592 AC_MSG_NOTICE([checking for libraries])
 593
 594
 595 #
 596 # libgpg-error is a library with error codes shared between GnuPG
 597 # related projects.
 598 #
 599 AM_PATH_GPG_ERROR("$NEED_GPG_ERROR_VERSION",
 600                   have_gpg_error=yes,have_gpg_error=no)
 601
 602
 603 #
 604 # Libgcrypt is our generic crypto library
 605 #
 606 AM_PATH_LIBGCRYPT("$NEED_LIBGCRYPT_API:$NEED_LIBGCRYPT_VERSION",
 607         have_libgcrypt=yes,have_libgcrypt=no)
 608
 609
 610 #
 611 # libassuan is used for IPC
 612 #
 613 AM_PATH_LIBASSUAN("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
 614                   have_libassuan=yes,have_libassuan=no)
 615 if test "$have_libassuan" = "yes"; then
 616   have_libassuan=no
 617   AM_PATH_LIBASSUAN_PTH("$NEED_LIBASSUAN_API:$NEED_LIBASSUAN_VERSION",
 618                         have_libassuan=yes,have_libassuan=no)
 619   AM_CHECK_LIBASSUAN("$NEED_LIBASSUAN_API:1.0.1",
 620        [AC_DEFINE(HAVE_ASSUAN_SET_IO_MONITOR, 1,
 621          [Define to 1 if you have the `assuan_set_io_monitor' function.])],)
 622   AC_DEFINE_UNQUOTED(GNUPG_LIBASSUAN_VERSION, "$libassuan_version",
 623             [version of the libbassuan library])
 624 fi
 625
 626
 627
 628 #
 629 # libksba is our X.509 support library
 630 #
 631 AM_PATH_KSBA("$NEED_KSBA_API:$NEED_KSBA_VERSION",have_ksba=yes,have_ksba=no)
 632
 633
 634 #
 635 # libusb allows us to use the integrated CCID smartcard reader driver.
 636 #
 637 # FiXME: Use GNUPG_CHECK_LIBUSB and modify to use separate AC_SUBSTs.
 638 AC_CHECK_LIB(usb, usb_bulk_write,
 639               [ LIBUSB_LIBS="$LIBUSB_LIBS -lusb"
 640                 AC_DEFINE(HAVE_LIBUSB,1,
 641                          [defined if libusb is available])
 642                 have_libusb=yes
 643              ])
 644 AC_SUBST(LIBUSB_LIBS)
 645 AC_CHECK_FUNCS(usb_create_match)
 646
 647 #
 648 # Check wether it is necessary to link against libdl.
 649 #
 650 gnupg_dlopen_save_libs="$LIBS"
 651 LIBS=""
 652 AC_SEARCH_LIBS(dlopen, c dl,,,)
 653 DL_LIBS=$LIBS
 654 AC_SUBST(DL_LIBS)
 655 LIBS="$gnupg_dlopen_save_libs"
 656
 657 #
 658 # Checks for symcryptrun:
 659 #
 660
 661 # libutil has openpty() and login_tty().
 662 AC_CHECK_LIB(util, openpty,
 663               [ LIBUTIL_LIBS="$LIBUTIL_LIBS -lutil"
 664                 AC_DEFINE(HAVE_LIBUTIL,1,
 665                          [defined if libutil is available])
 666              ])
 667 AC_SUBST(LIBUTIL_LIBS)
 668
 669 # shred is used to clean temporary plain text files.
 670 AC_PATH_PROG(SHRED, shred, /usr/bin/shred)
 671 AC_DEFINE_UNQUOTED(SHRED,
 672         "${SHRED}", [defines the filename of the shred program])
 673
 674
 675
 676 #
 677 # Check whether the GNU Pth library is available
 678 # Note, that we include a Pth emulation for W32.
 679 #
 680 GNUPG_PATH_PTH
 681 if test "$have_pth" = "yes"; then
 682   AC_DEFINE(USE_GNU_PTH, 1,
 683               [Defined if the GNU Portable Thread Library should be used])
 684 else
 685   AC_MSG_WARN([[
 686 ***
 687 *** To support concurrent access to the gpg-agent and the SCdaemon
 688 *** we need the support of the GNU Portable Threads Library.
 689 *** Download it from ftp://ftp.gnu.org/gnu/pth/
 690 *** On a Debian GNU/Linux system you might want to try
 691 ***   apt-get install libpth-dev
 692 ***]])
 693 fi
 694
 695
 696 AC_MSG_NOTICE([checking for networking options])
 697
 698 #
 699 # Must check for network library requirements before doing link tests
 700 # for ldap, for example. If ldap libs are static (or dynamic and without
 701 # ELF runtime link paths), then link will fail and LDAP support won't
 702 # be detected.
 703 #
 704 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
 705         [NETLIBS="-lnsl $NETLIBS"]))
 706 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
 707         [NETLIBS="-lsocket $NETLIBS"]))
 708
 709 #
 710 # Now try for the resolver functions so we can use DNS for SRV, PA and CERT.
 711 #
 712 if test x"$try_hkp" = xyes || test x"$try_http" = xyes ; then
 713   AC_ARG_ENABLE(dns-srv,
 714      AC_HELP_STRING([--disable-dns-srv],
 715                     [disable the use of DNS SRV in HKP and HTTP]),
 716                 use_dns_srv=$enableval,use_dns_srv=yes)
 717 fi
 718
 719 AC_ARG_ENABLE(dns-pka,
 720    AC_HELP_STRING([--disable-dns-pka],
 721         [disable the use of PKA records in DNS]),
 722    use_dns_pka=$enableval,use_dns_pka=yes)
 723
 724 AC_ARG_ENABLE(dns-cert,
 725    AC_HELP_STRING([--disable-dns-cert],
 726         [disable the use of CERT records in DNS]),
 727    use_dns_cert=$enableval,use_dns_cert=yes)
 728
 729 if test x"$use_dns_pka" = xyes || test x"$use_dns_srv" = xyes \
 730    || test x"$use_dns_cert" = xyes; then
 731   _dns_save_libs=$LIBS
 732   LIBS=""
 733   # the double underscore thing is a glibc-ism?
 734   AC_SEARCH_LIBS(res_query,resolv bind,,
 735                  AC_SEARCH_LIBS(__res_query,resolv bind,,have_resolver=no))
 736   AC_SEARCH_LIBS(dn_expand,resolv bind,,
 737                  AC_SEARCH_LIBS(__dn_expand,resolv bind,,have_resolver=no))
 738   AC_SEARCH_LIBS(dn_skipname,resolv bind,,
 739                  AC_SEARCH_LIBS(__dn_skipname,resolv bind,,have_resolver=no))
 740
 741   if test x"$have_resolver" != xno ; then
 742
 743     # Make sure that the BIND 4 resolver interface is workable before
 744     # enabling any code that calls it.  At some point I'll rewrite the
 745     # code to use the BIND 8 resolver API.
 746     # We might also want to use adns instead.
 747
 748     AC_MSG_CHECKING([whether the resolver is usable])
 749     AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 750 #include <netinet/in.h>
 751 #include <arpa/nameser.h>
 752 #include <resolv.h>],
 753 [[unsigned char answer[PACKETSZ];
 754   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
 755   dn_skipname(0,0);
 756   dn_expand(0,0,0,0,0);
 757 ]])],have_resolver=yes,have_resolver=no)
 758     AC_MSG_RESULT($have_resolver)
 759
 760     # This is Apple-specific and somewhat bizarre as they changed the
 761     # define in bind 8 for some reason.
 762
 763     if test x"$have_resolver" != xyes ; then
 764        AC_MSG_CHECKING(
 765              [whether I can make the resolver usable with BIND_8_COMPAT])
 766        AC_LINK_IFELSE([AC_LANG_PROGRAM([#define BIND_8_COMPAT
 767 #include <sys/types.h>
 768 #include <netinet/in.h>
 769 #include <arpa/nameser.h>
 770 #include <resolv.h>],
 771 [[unsigned char answer[PACKETSZ];
 772   res_query("foo.bar",C_IN,T_A,answer,PACKETSZ);
 773   dn_skipname(0,0); dn_expand(0,0,0,0,0);
 774 ]])],[have_resolver=yes ; need_compat=yes])
 775        AC_MSG_RESULT($have_resolver)
 776     fi
 777   fi
 778
 779   if test x"$have_resolver" = xyes ; then
 780      DNSLIBS=$LIBS
 781
 782      if test x"$use_dns_srv" = xyes ; then
 783         AC_DEFINE(USE_DNS_SRV,1,[define to use DNS SRV])
 784      fi
 785
 786      if test x"$use_dns_pka" = xyes ; then
 787         AC_DEFINE(USE_DNS_PKA,1,[define to use our experimental DNS PKA])
 788      fi
 789
 790      if test x"$use_dns_cert" = xyes ; then
 791         AC_DEFINE(USE_DNS_CERT,1,[define to use DNS CERT])
 792      fi
 793
 794      if test x"$need_compat" = xyes ; then
 795         AC_DEFINE(BIND_8_COMPAT,1,[an Apple OSXism])
 796      fi
 797   else
 798      use_dns_srv=no
 799      use_dns_pka=no
 800      use_dns_cert=no
 801   fi
 802
 803   LIBS=$_dns_save_libs
 804 fi
 805
 806 AC_SUBST(DNSLIBS)
 807
 808 AM_CONDITIONAL(USE_DNS_SRV, test x"$use_dns_srv" = xyes)
 809
 810
 811 #
 812 # Check for ADNS.
 813 #
 814 _cppflags="${CPPFLAGS}"
 815 _ldflags="${LDFLAGS}"
 816 AC_ARG_WITH(adns,
 817             AC_HELP_STRING([--with-adns=DIR],
 818                            [look for the adns library in DIR]),
 819             [if test -d "$withval"; then
 820                CPPFLAGS="${CPPFLAGS} -I$withval/include"
 821                LDFLAGS="${LDFLAGS} -L$withval/lib"
 822              fi])
 823 if test "$with_adns" != "no"; then
 824   AC_CHECK_HEADERS(adns.h,
 825                 AC_CHECK_LIB(adns, adns_init,
 826                              [have_adns=yes],
 827                              [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}]),
 828                 [CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}])
 829 fi
 830 if test "$have_adns" = "yes"; then
 831   ADNSLIBS="-ladns"
 832 fi
 833 AC_SUBST(ADNSLIBS)
 834 # Newer adns versions feature a free function to be used under W32.
 835 AC_CHECK_FUNCS(adns_free)
 836
 837
 838 #
 839 # Check for LDAP
 840 #
 841 if test "$try_ldap" = yes ; then
 842    GNUPG_CHECK_LDAP($NETLIBS)
 843 fi
 844
 845 #
 846 # Check for curl.  We fake the curl API if libcurl isn't installed.
 847 # We require 7.10 or later as we use curl_version_info().
 848 #
 849 LIBCURL_CHECK_CONFIG([yes],[7.10],,[fake_curl=yes])
 850 AM_CONDITIONAL(FAKE_CURL,test x"$fake_curl" = xyes)
 851
 852 # Generic, for us, means curl
 853
 854 if test x"$try_generic" = xyes ; then
 855    AC_SUBST(GPGKEYS_CURL,"gpg2keys_curl$EXEEXT")
 856 fi
 857
 858 #
 859 # Check for sendmail
 860 #
 861 # This isn't necessarily sendmail itself, but anything that gives a
 862 # sendmail-ish interface to the outside world.  That includes Exim,
 863 # Postfix, etc.  Basically, anything that can handle "sendmail -t".
 864 if test "$try_mailto" = yes ; then
 865   AC_ARG_WITH(mailprog,
 866       AC_HELP_STRING([--with-mailprog=NAME],
 867                      [use "NAME -t" for mail transport]),
 868              ,with_mailprog=yes)
 869
 870   if test x"$with_mailprog" = xyes ; then
 871     AC_PATH_PROG(SENDMAIL,sendmail,,$PATH:/usr/sbin:/usr/libexec:/usr/lib)
 872     if test "$ac_cv_path_SENDMAIL" ; then
 873       GPGKEYS_MAILTO="gpg2keys_mailto"
 874     fi
 875   elif test x"$with_mailprog" != xno ; then
 876     AC_MSG_CHECKING([for a mail transport program])
 877     AC_SUBST(SENDMAIL,$with_mailprog)
 878     AC_MSG_RESULT($with_mailprog)
 879     GPGKEYS_MAILTO="gpg2keys_mailto"
 880   fi
 881 fi
 882
 883 AC_SUBST(GPGKEYS_MAILTO)
 884
 885 #
 886 # Construct a printable name of the OS
 887 #
 888 case "${host}" in
 889     *-mingw32*)
 890         PRINTABLE_OS_NAME="MingW32"
 891         ;;
 892     *-*-cygwin*)
 893         PRINTABLE_OS_NAME="Cygwin"
 894         ;;
 895     i?86-emx-os2 | i?86-*-os2*emx )
 896         PRINTABLE_OS_NAME="OS/2"
 897         ;;
 898     i?86-*-msdosdjgpp*)
 899         PRINTABLE_OS_NAME="MSDOS/DJGPP"
 900         try_dynload=no
 901         ;;
 902     *-linux*)
 903         PRINTABLE_OS_NAME="GNU/Linux"
 904         ;;
 905     *)
 906         PRINTABLE_OS_NAME=`uname -s || echo "Unknown"`
 907         ;;
 908 esac
 909 AC_DEFINE_UNQUOTED(PRINTABLE_OS_NAME, "$PRINTABLE_OS_NAME",
 910                    [A human readable text with the name of the OS])
 911
 912
 913 #
 914 # Checking for iconv
 915 #
 916 AM_ICONV
 917
 918
 919 #
 920 # Check for gettext
 921 #
 922 # This is "GNU gnupg" - The project-id script from gettext
 923 #                       needs this string
 924 #
 925 AC_MSG_NOTICE([checking for gettext])
 926 AM_PO_SUBDIRS
 927 AM_GNU_GETTEXT_VERSION([0.17])
 928 if test "$try_gettext" = yes; then
 929   AM_GNU_GETTEXT([external],[need-ngettext])
 930
 931   # gettext requires some extra checks.  These really should be part of
 932   # the basic AM_GNU_GETTEXT macro.  TODO: move other gettext-specific
 933   # function checks to here.
 934
 935   AC_CHECK_FUNCS(strchr)
 936 else
 937   USE_NLS=no
 938   USE_INCLUDED_LIBINTL=no
 939   BUILD_INCLUDED_LIBINTL=no
 940   POSUB=po
 941   AC_SUBST(USE_NLS)
 942   AC_SUBST(USE_INCLUDED_LIBINTL)
 943   AC_SUBST(BUILD_INCLUDED_LIBINTL)
 944   AC_SUBST(POSUB)
 945 fi
 946
 947 # We use HAVE_LANGINFO_CODESET in a couple of places.
 948 AM_LANGINFO_CODESET
 949
 950 # Checks required for our use locales
 951 gt_LC_MESSAGES
 952
 953
 954 #
 955 # SELinux support
 956 #
 957 if test "$selinux_support" = yes ; then
 958   AC_DEFINE(ENABLE_SELINUX_HACKS,1,[Define to enable SELinux support])
 959 fi
 960
 961
 962 #
 963 # Checks for header files.
 964 #
 965 AC_MSG_NOTICE([checking for header files])
 966 AC_HEADER_STDC
 967 AC_CHECK_HEADERS([string.h unistd.h langinfo.h termio.h locale.h getopt.h])
 968 AC_CHECK_HEADERS([pty.h pwd.h inttypes.h])
 969 AC_HEADER_TIME
 970
 971
 972 #
 973 # Checks for typedefs, structures, and compiler characteristics.
 974 #
 975 AC_MSG_NOTICE([checking for system characteristics])
 976 AC_C_CONST
 977 AC_C_INLINE
 978 AC_C_VOLATILE
 979 AC_TYPE_SIZE_T
 980 AC_TYPE_MODE_T
 981 AC_TYPE_SIGNAL
 982 AC_DECL_SYS_SIGLIST
 983
 984 gl_HEADER_SYS_SOCKET
 985 gl_TYPE_SOCKLEN_T
 986
 987 AC_ARG_ENABLE(endian-check,
 988               AC_HELP_STRING([--disable-endian-check],
 989               [disable the endian check and trust the OS provided macros]),
 990               endiancheck=$enableval,endiancheck=yes)
 991
 992 if test x"$endiancheck" = xyes ; then
 993   GNUPG_CHECK_ENDIAN
 994 fi
 995
 996 # fixme: we should get rid of the byte type
 997 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
 998 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
 999 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
1000 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
1001 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
1002
1003 AC_CHECK_SIZEOF(unsigned short)
1004 AC_CHECK_SIZEOF(unsigned int)
1005 AC_CHECK_SIZEOF(unsigned long)
1006 AC_CHECK_SIZEOF(unsigned long long)
1007 AC_CHECK_SIZEOF(time_t,,[[
1008 #include <stdio.h>
1009 #if TIME_WITH_SYS_TIME
1010 # include <sys/time.h>
1011 # include <time.h>
1012 #else
1013 # if HAVE_SYS_TIME_H
1014 #  include <sys/time.h>
1015 # else
1016 #  include <time.h>
1017 # endif
1018 #endif
1019 ]])
1020
1021
1022 # Ensure that we have UINT64_C before we bother to check for uint64_t
1023 # Fixme: really needed in gnupg?  I think it is only useful in libcgrypt.
1024 AC_CACHE_CHECK([for UINT64_C],[gnupg_cv_uint64_c_works],
1025    AC_COMPILE_IFELSE(AC_LANG_PROGRAM([#include <inttypes.h>
1026        uint64_t foo=UINT64_C(42);]),
1027      gnupg_cv_uint64_c_works=yes,gnupg_cv_uint64_c_works=no))
1028 if test "$gnupg_cv_uint64_c_works" = "yes" ; then
1029    AC_CHECK_SIZEOF(uint64_t)
1030 fi
1031
1032 if test "$ac_cv_sizeof_unsigned_short" = "0" \
1033    || test "$ac_cv_sizeof_unsigned_int" = "0" \
1034    || test "$ac_cv_sizeof_unsigned_long" = "0"; then
1035     AC_MSG_WARN([Hmmm, something is wrong with the sizes - using defaults]);
1036 fi
1037
1038
1039 #
1040 # Checks for library functions.
1041 #
1042 AC_MSG_NOTICE([checking for library functions])
1043 AC_CHECK_DECLS(getpagesize)
1044 AC_FUNC_FSEEKO
1045 AC_FUNC_VPRINTF
1046 AC_FUNC_FORK
1047 AC_CHECK_FUNCS([strerror strlwr tcgetattr mmap])
1048 AC_CHECK_FUNCS([strcasecmp strncasecmp ctermid times gmtime_r])
1049 AC_CHECK_FUNCS([unsetenv fcntl ftruncate])
1050 AC_CHECK_FUNCS([gettimeofday getrusage getrlimit setrlimit clock_gettime])
1051 AC_CHECK_FUNCS([atexit raise getpagesize strftime nl_langinfo setlocale])
1052 AC_CHECK_FUNCS([waitpid wait4 sigaction sigprocmask pipe stat getaddrinfo])
1053 AC_CHECK_FUNCS([ttyname rand ftello fsync])
1054
1055 AC_CHECK_TYPES([struct sigaction, sigset_t],,,[#include <signal.h>])
1056
1057 #
1058 # These are needed by libjnlib - fixme: we should use a jnlib.m4
1059 # Note:  We already checked pwd.h.
1060 AC_CHECK_FUNCS([memicmp stpcpy strsep strlwr strtoul memmove stricmp strtol])
1061 AC_CHECK_FUNCS([memrchr isascii timegm getrusage setrlimit stat setlocale])
1062 AC_CHECK_FUNCS([flockfile funlockfile fopencookie funopen getpwnam getpwuid])
1063
1064 #
1065 # gnulib checks
1066 #
1067 gl_SOURCE_BASE([gl])
1068 gl_M4_BASE([gl/m4])
1069 gl_MODULES([setenv mkdtemp xsize strpbrk])
1070 gl_INIT
1071
1072
1073 #
1074 # W32 specific test
1075 #
1076 GNUPG_FUNC_MKDIR_TAKES_ONE_ARG
1077
1078 #
1079 # Sanity check regex.  Tests adapted from mutt.
1080 #
1081 AC_MSG_CHECKING([whether regular expression support is requested])
1082 AC_ARG_ENABLE(regex,
1083   AC_HELP_STRING([--disable-regex],
1084     [do not handle regular expressions in trust signatures]),
1085   use_regex=$enableval, use_regex=yes)
1086 AC_MSG_RESULT($use_regex)
1087
1088 if test "$use_regex" = yes ; then
1089   _cppflags="${CPPFLAGS}"
1090   _ldflags="${LDFLAGS}"
1091   AC_ARG_WITH(regex,
1092      AC_HELP_STRING([--with-regex=DIR],[look for regex in DIR]),
1093       [
1094       if test -d "$withval" ; then
1095         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1096         LDFLAGS="${LDFLAGS} -L$withval/lib"
1097       fi
1098       ],withval="")
1099
1100   # Does the system have regex functions at all?
1101   AC_SEARCH_LIBS([regcomp], [regex])
1102   AC_CHECK_FUNC(regcomp, gnupg_cv_have_regex=yes, gnupg_cv_have_regex=no)
1103
1104   if test $gnupg_cv_have_regex = no; then
1105     use_regex=no
1106   else
1107     if test x"$cross_compiling" = xyes; then
1108       AC_MSG_WARN([cross compiling; assuming regexp libray is not broken])
1109     else
1110       AC_CACHE_CHECK([whether your system's regexp library is broken],
1111        [gnupg_cv_regex_broken],
1112        AC_TRY_RUN([
1113 #include <unistd.h>
1114 #include <regex.h>
1115 main() { regex_t blah ; regmatch_t p; p.rm_eo = p.rm_eo; return regcomp(&blah, "foo.*bar", REG_NOSUB) || regexec (&blah, "foobar", 0, NULL, 0); }],
1116        gnupg_cv_regex_broken=no, gnupg_cv_regex_broken=yes, gnupg_cv_regex_broken=yes))
1117
1118       if test $gnupg_cv_regex_broken = yes; then
1119         AC_MSG_WARN([your regex is broken - disabling regex use])
1120         use_regex=no
1121       fi
1122     fi
1123   fi
1124   CPPFLAGS="${_cppflags}"
1125   LDFLAGS="${_ldflags}"
1126 fi
1127
1128 if test "$use_regex" != yes ; then
1129   AC_DEFINE(DISABLE_REGEX,1, [Define to disable regular expression support])
1130 fi
1131 AM_CONDITIONAL(DISABLE_REGEX, test x"$use_regex" != xyes)
1132
1133
1134
1135 #
1136 # Do we have zlib? Must do it here because Solaris failed
1137 # when compiling a conftest (due to the "-lz" from LIBS).
1138 # Note that we combine zlib and bzlib2 in ZLIBS.
1139 #
1140 _cppflags="${CPPFLAGS}"
1141 _ldflags="${LDFLAGS}"
1142 AC_ARG_WITH(zlib,
1143   [  --with-zlib=DIR         use libz in DIR],[
1144     if test -d "$withval"; then
1145       CPPFLAGS="${CPPFLAGS} -I$withval/include"
1146       LDFLAGS="${LDFLAGS} -L$withval/lib"
1147     fi
1148   ])
1149
1150 AC_CHECK_HEADER(zlib.h,
1151       AC_CHECK_LIB(z, deflateInit2_,
1152        ZLIBS="-lz",
1153        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1154        CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags})
1155
1156 #
1157 # Check whether we can support bzip2
1158 #
1159 if test "$use_bzip2" = yes ; then
1160   _cppflags="${CPPFLAGS}"
1161   _ldflags="${LDFLAGS}"
1162   AC_ARG_WITH(bzip2,
1163      AC_HELP_STRING([--with-bzip2=DIR],[look for bzip2 in DIR]),
1164       [
1165       if test -d "$withval" ; then
1166         CPPFLAGS="${CPPFLAGS} -I$withval/include"
1167         LDFLAGS="${LDFLAGS} -L$withval/lib"
1168       fi
1169       ],withval="")
1170
1171   # Checking alongside stdio.h as an early version of bzip2 (1.0)
1172   # required stdio.h to be included before bzlib.h, and Solaris 9 is
1173   # woefully out of date.
1174   if test "$withval" != no ; then
1175      AC_CHECK_HEADER(bzlib.h,
1176         AC_CHECK_LIB(bz2,BZ2_bzCompressInit,
1177           [
1178           have_bz2=yes
1179           ZLIBS="$ZLIBS -lbz2"
1180           AC_DEFINE(HAVE_BZIP2,1,
1181                   [Defined if the bz2 compression library is available])
1182           ],
1183           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags}),
1184           CPPFLAGS=${_cppflags} LDFLAGS=${_ldflags},[#include <stdio.h>])
1185   fi
1186 fi
1187 AM_CONDITIONAL(ENABLE_BZIP2_SUPPORT,test x"$have_bz2" = "xyes")
1188 AC_SUBST(ZLIBS)
1189
1190
1191 # Check for readline support
1192 GNUPG_CHECK_READLINE
1193
1194 #
1195 # Allow users to append something to the version string without
1196 # flagging it as development version.  The user version parts is
1197 # considered everything after a dash.
1198 #
1199 if test "$development_version" != yes; then
1200   changequote(,)dnl
1201   tmp_pat='[a-zA-Z]'
1202   changequote([,])dnl
1203   if echo "$VERSION" | sed 's/-.*//' | grep "$tmp_pat" >/dev/null ; then
1204     development_version=yes
1205   fi
1206 fi
1207 if test "$development_version" = yes; then
1208     AC_DEFINE(IS_DEVELOPMENT_VERSION,1,
1209             [Defined if this is not a regular release])
1210 fi
1211
1212 AM_CONDITIONAL(CROSS_COMPILING, test x$cross_compiling = xyes)
1213
1214 GNUPG_CHECK_GNUMAKE
1215
1216 # Add some extra libs here so that previous tests don't fail for
1217 # mysterious reasons - the final link step should bail out.
1218 # W32SOCKLIBS is also defined so that if can be used for tools not
1219 # requiring any network stuff but linking to code in libcommon which
1220 # tracks in winsock stuff (e.g. init_common_subsystems.
1221 if test "$have_w32_system" = yes; then
1222    W32SOCKLIBS="-lws2_32"
1223    NETLIBS="${NETLIBS} ${W32SOCKLIBS}"
1224 fi
1225
1226 AC_SUBST(NETLIBS)
1227 AC_SUBST(W32SOCKLIBS)
1228
1229 #
1230 # Setup gcc specific options
1231 #
1232 AC_MSG_NOTICE([checking for cc features])
1233 if test "$GCC" = yes; then
1234     # Note that it is okay to use CFLAGS here because this are just
1235     # warning options and the user should have a chance of overriding
1236     # them.
1237     if test "$USE_MAINTAINER_MODE" = "yes"; then
1238         CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
1239         CFLAGS="$CFLAGS -Wformat -Wno-format-y2k -Wformat-security"
1240         AC_MSG_CHECKING([if gcc supports -Wno-missing-field-initializers])
1241         _gcc_cflags_save=$CFLAGS
1242         CFLAGS="-Wno-missing-field-initializers"
1243         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1244         AC_MSG_RESULT($_gcc_wopt)
1245         CFLAGS=$_gcc_cflags_save;
1246         if test x"$_gcc_wopt" = xyes ; then
1247           CFLAGS="$CFLAGS -W -Wno-sign-compare -Wno-missing-field-initializers"
1248         fi
1249         AC_MSG_CHECKING([if gcc supports -Wdeclaration-after-statement])
1250         _gcc_cflags_save=$CFLAGS
1251         CFLAGS="-Wdeclaration-after-statement"
1252         AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_wopt=yes,_gcc_wopt=no)
1253         AC_MSG_RESULT($_gcc_wopt)
1254         CFLAGS=$_gcc_cflags_save;
1255         if test x"$_gcc_wopt" = xyes ; then
1256           CFLAGS="$CFLAGS -Wdeclaration-after-statement"
1257         fi
1258     else
1259         CFLAGS="$CFLAGS -Wall"
1260     fi
1261
1262     AC_MSG_CHECKING([if gcc supports -Wno-pointer-sign])
1263     _gcc_cflags_save=$CFLAGS
1264     CFLAGS="-Wno-pointer-sign"
1265     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1266     AC_MSG_RESULT($_gcc_psign)
1267     CFLAGS=$_gcc_cflags_save;
1268     if test x"$_gcc_psign" = xyes ; then
1269        CFLAGS="$CFLAGS -Wno-pointer-sign"
1270     fi
1271
1272     AC_MSG_CHECKING([if gcc supports -Wpointer-arith])
1273     _gcc_cflags_save=$CFLAGS
1274     CFLAGS="-Wpointer-arith"
1275     AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),_gcc_psign=yes,_gcc_psign=no)
1276     AC_MSG_RESULT($_gcc_psign)
1277     CFLAGS=$_gcc_cflags_save;
1278     if test x"$_gcc_psign" = xyes ; then
1279        CFLAGS="$CFLAGS -Wpointer-arith"
1280     fi
1281 fi
1282
1283
1284 #
1285 # This is handy for debugging so the compiler doesn't rearrange
1286 # things and eliminate variables.
1287 #
1288 AC_ARG_ENABLE(optimization,
1289    AC_HELP_STRING([--disable-optimization],
1290                   [disable compiler optimization]),
1291                   [if test $enableval = no ; then
1292                       CFLAGS=`echo $CFLAGS | sed 's/-O[[0-9]]//'`
1293                    fi])
1294
1295 #
1296 # Prepare building of estream
1297 #
1298 estream_INIT
1299
1300
1301 #
1302 # Decide what to build
1303 #
1304 if test "$have_adns" = "yes"; then
1305   AC_SUBST(GPGKEYS_KDNS, "gpg2keys_kdns$EXEEXT")
1306 fi
1307
1308
1309 missing_pth=no
1310 if test $have_ksba = no; then
1311   build_gpgsm=no
1312   build_scdaemon=no
1313 fi
1314
1315 build_agent_threaded=""
1316 if test "$build_agent" = "yes"; then
1317   if test $have_pth = no; then
1318      build_agent_threaded="(not multi-threaded)"
1319      missing_pth=yes
1320   fi
1321 fi
1322
1323 build_scdaemon_extra=""
1324 if test "$build_scdaemon" = "yes"; then
1325   tmp=""
1326   if test $have_pth = no; then
1327      build_scdaemon_extra="not multi-threaded"
1328      tmp=", "
1329      missing_pth=yes
1330   fi
1331   if test $have_libusb = no; then
1332      build_scdaemon_extra="${tmp}without internal CCID driver"
1333      tmp=", "
1334   fi
1335   if test -n "$build_scdaemon_extra"; then
1336      build_scdaemon_extra="(${build_scdaemon_extra})"
1337   fi
1338 fi
1339
1340
1341 if test "$build_agent_only" = "yes" ; then
1342   build_gpg=no
1343   build_gpgsm=no
1344   build_scdaemon=no
1345   build_tools=no
1346   build_doc=no
1347 fi
1348
1349
1350 AM_CONDITIONAL(BUILD_GPG,   test "$build_gpg" = "yes")
1351 AM_CONDITIONAL(BUILD_GPGSM, test "$build_gpgsm" = "yes")
1352 AM_CONDITIONAL(BUILD_AGENT, test "$build_agent" = "yes")
1353 AM_CONDITIONAL(BUILD_SCDAEMON, test "$build_scdaemon" = "yes")
1354 AM_CONDITIONAL(BUILD_TOOLS, test "$build_tools" = "yes")
1355 AM_CONDITIONAL(BUILD_DOC,   test "$build_doc" = "yes")
1356 AM_CONDITIONAL(BUILD_SYMCRYPTRUN, test "$build_symcryptrun" = "yes")
1357
1358 AM_CONDITIONAL(RUN_GPG_TESTS,
1359         test x$cross_compiling = xno -a "$build_gpg" = yes )
1360
1361
1362 #
1363 # Print errors here so that they are visible all
1364 # together and the user can acquire them all together.
1365 #
1366 die=no
1367 if test "$have_gpg_error" = "no"; then
1368    die=yes
1369    AC_MSG_NOTICE([[
1370 ***
1371 *** You need libgpg-error to build this program.
1372 **  This library is for example available at
1373 ***   ftp://ftp.gnupg.org/gcrypt/libgpg-error
1374 *** (at least version $NEED_GPG_ERROR_VERSION is required.)
1375 ***]])
1376 fi
1377 if test "$have_libgcrypt" = "no"; then
1378    die=yes
1379    AC_MSG_NOTICE([[
1380 ***
1381 *** You need libgcrypt to build this program.
1382 **  This library is for example available at
1383 ***   ftp://ftp.gnupg.org/gcrypt/libgcrypt/
1384 *** (at least version $NEED_LIBGCRYPT_VERSION using API $NEED_LIBGCRYPT_API is required.)
1385 ***]])
1386 fi
1387 if test "$have_libassuan" = "no"; then
1388    die=yes
1389    AC_MSG_NOTICE([[
1390 ***
1391 *** You need libassuan with Pth support to build this program.
1392 *** This library is for example available at
1393 ***   ftp://ftp.gnupg.org/gcrypt/libassuan/
1394 *** (at least version $NEED_LIBASSUAN_VERSION (API $NEED_LIBASSUAN_API) is required).
1395 ***]])
1396 fi
1397 if test "$have_ksba" = "no"; then
1398     AC_MSG_NOTICE([[
1399 ***
1400 *** You need libksba to build this program.
1401 *** This library is for example available at
1402 ***   ftp://ftp.gnupg.org/gcrypt/libksba/
1403 *** (at least version $NEED_KSBA_VERSION using API $NEED_KSBA_API is required).
1404 ***]])
1405 fi
1406 if test "$missing_pth" = "yes"; then
1407     AC_MSG_NOTICE([[
1408 ***
1409 *** It is now required to build with support for the
1410 *** GNU Portable Threads Library (Pth). Please install this
1411 *** library first.  The library is for example available at
1412 ***   ftp://ftp.gnu.org/gnu/pth/
1413 *** On a Debian GNU/Linux system you can install it using
1414 ***   apt-get install libpth-dev
1415 *** To build GnuPG for Windows you need to use the W32PTH
1416 *** package; available at:
1417 ***   ftp://ftp.g10code.com/g10code/w32pth/
1418 ***]])
1419    die=yes
1420 fi
1421
1422 if test "$die" = "yes"; then
1423     AC_MSG_ERROR([[
1424 ***
1425 *** Required libraries not found. Please consult the above messages
1426 *** and install them before running configure again.
1427 ***]])
1428 fi
1429
1430
1431
1432 AC_CONFIG_FILES([ m4/Makefile
1433 Makefile
1434 po/Makefile.in
1435 gl/Makefile
1436 include/Makefile
1437 jnlib/Makefile
1438 common/Makefile
1439 kbx/Makefile
1440 g10/Makefile
1441 sm/Makefile
1442 agent/Makefile
1443 scd/Makefile
1444 keyserver/Makefile
1445 keyserver/gpg2keys_mailto
1446 keyserver/gpg2keys_test
1447 tools/gpg-zip
1448 tools/Makefile
1449 doc/Makefile
1450 tests/Makefile
1451 tests/openpgp/Makefile
1452 tests/pkits/Makefile
1453 ])
1454 AC_OUTPUT
1455
1456
1457 echo "
1458         GnuPG v${VERSION} has been configured as follows:
1459
1460         Platform:  $PRINTABLE_OS_NAME ($host)
1461
1462         OpenPGP:   $build_gpg
1463         S/MIME:    $build_gpgsm
1464         Agent:     $build_agent $build_agent_threaded
1465         Smartcard: $build_scdaemon $build_scdaemon_extra
1466
1467         Protect tool:      $show_gnupg_protect_tool_pgm
1468         Default agent:     $show_gnupg_agent_pgm
1469         Default pinentry:  $show_gnupg_pinentry_pgm
1470         Default scdaemon:  $show_gnupg_scdaemon_pgm
1471         Default dirmngr:   $show_gnupg_dirmngr_pgm
1472 "
1473 if test x"$use_regex" != xyes ; then
1474 echo "
1475         Warning: No regular expression support available.
1476                  OpenPGP trust signatures won't work.
1477                  gpg-check-pattern will not be build.
1478 "
1479 fi