mpi/i586/mpih-sub1.S

   1 /* i80586 sub_n -- Sub two limb vectors of the same length > 0 and store
   2  *                 sum in a third limb vector.
   3  *
   4  *      Copyright (C) 1992, 1994, 1995, 1998,
   5  *                    2001 Free Software Foundation, Inc.
   6  *
   7  * This file is part of GnuPG.
   8  *
   9  * GnuPG is free software; you can redistribute it and/or modify
  10  * it under the terms of the GNU General Public License as published by
  11  * the Free Software Foundation; either version 2 of the License, or
  12  * (at your option) any later version.
  13  *
  14  * GnuPG is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17  * GNU General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU General Public License
  20  * along with this program; if not, write to the Free Software
  21  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
  22  * USA.
  23  *
  24  * Note: This code is heavily based on the GNU MP Library.
  25  *       Actually it's the same code with only minor changes in the
  26  *       way the data is stored; this is to support the abstraction
  27  *       of an optional secure memory allocation which may be used
  28  *       to avoid revealing of sensitive data due to paging etc.
  29  *       The GNU MP Library itself is published under the LGPL;
  30  *       however I decided to publish this code under the plain GPL.
  31  */
  32
  33
  34 #include "sysdep.h"
  35 #include "asm-syntax.h"
  36
  37
  38 /*******************
  39  *  mpi_limb_t
  40  *  mpihelp_sub_n( mpi_ptr_t res_ptr,   (sp + 4)
  41  *                 mpi_ptr_t s1_ptr,    (sp + 8)
  42  *                 mpi_ptr_t s2_ptr,    (sp + 12)
  43  *                 mpi_size_t size)     (sp + 16)
  44  */
  45
  46
  47 .text
  48         ALIGN (3)
  49         .globl C_SYMBOL_NAME(mpihelp_sub_n)
  50 C_SYMBOL_NAME(mpihelp_sub_n:)
  51
  52         pushl   %edi
  53         pushl   %esi
  54         pushl   %ebx
  55         pushl   %ebp
  56
  57         movl    20(%esp),%edi           /* res_ptr */
  58         movl    24(%esp),%esi           /* s1_ptr */
  59         movl    28(%esp),%ebp           /* s2_ptr */
  60         movl    32(%esp),%ecx           /* size */
  61
  62         movl    (%ebp),%ebx
  63
  64         decl    %ecx
  65         movl    %ecx,%edx
  66         shrl    $3,%ecx
  67         andl    $7,%edx
  68         testl   %ecx,%ecx               /* zero carry flag */
  69         jz      Lend
  70         pushl   %edx
  71
  72         ALIGN (3)
  73 Loop:   movl    28(%edi),%eax           /* fetch destination cache line */
  74         leal    32(%edi),%edi
  75
  76 L1:     movl    (%esi),%eax
  77         movl    4(%esi),%edx
  78         sbbl    %ebx,%eax
  79         movl    4(%ebp),%ebx
  80         sbbl    %ebx,%edx
  81         movl    8(%ebp),%ebx
  82         movl    %eax,-32(%edi)
  83         movl    %edx,-28(%edi)
  84
  85 L2:     movl    8(%esi),%eax
  86         movl    12(%esi),%edx
  87         sbbl    %ebx,%eax
  88         movl    12(%ebp),%ebx
  89         sbbl    %ebx,%edx
  90         movl    16(%ebp),%ebx
  91         movl    %eax,-24(%edi)
  92         movl    %edx,-20(%edi)
  93
  94 L3:     movl    16(%esi),%eax
  95         movl    20(%esi),%edx
  96         sbbl    %ebx,%eax
  97         movl    20(%ebp),%ebx
  98         sbbl    %ebx,%edx
  99         movl    24(%ebp),%ebx
 100         movl    %eax,-16(%edi)
 101         movl    %edx,-12(%edi)
 102
 103 L4:     movl    24(%esi),%eax
 104         movl    28(%esi),%edx
 105         sbbl    %ebx,%eax
 106         movl    28(%ebp),%ebx
 107         sbbl    %ebx,%edx
 108         movl    32(%ebp),%ebx
 109         movl    %eax,-8(%edi)
 110         movl    %edx,-4(%edi)
 111
 112         leal    32(%esi),%esi
 113         leal    32(%ebp),%ebp
 114         decl    %ecx
 115         jnz     Loop
 116
 117         popl    %edx
 118 Lend:
 119         decl    %edx                    /* test %edx w/o clobbering carry */
 120         js      Lend2
 121         incl    %edx
 122 Loop2:
 123         leal    4(%edi),%edi
 124         movl    (%esi),%eax
 125         sbbl    %ebx,%eax
 126         movl    4(%ebp),%ebx
 127         movl    %eax,-4(%edi)
 128         leal    4(%esi),%esi
 129         leal    4(%ebp),%ebp
 130         decl    %edx
 131         jnz     Loop2
 132 Lend2:
 133         movl    (%esi),%eax
 134         sbbl    %ebx,%eax
 135         movl    %eax,(%edi)
 136
 137         sbbl    %eax,%eax
 138         negl    %eax
 139
 140         popl    %ebp
 141         popl    %ebx
 142         popl    %esi
 143         popl    %edi
 144         ret
 145