gl/m4/select.m4

   1 # select.m4 serial 6
   2 dnl Copyright (C) 2009-2012 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_SELECT],
   8 [
   9   AC_REQUIRE([gl_HEADER_SYS_SELECT])
  10   AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles
  11   AC_REQUIRE([gl_SOCKETS])
  12   if test "$ac_cv_header_winsock2_h" = yes; then
  13     REPLACE_SELECT=1
  14   else
  15     dnl On Interix 3.5, select(0, NULL, NULL, NULL, timeout) fails with error
  16     dnl EFAULT.
  17     AC_CHECK_HEADERS_ONCE([sys/select.h])
  18     AC_CACHE_CHECK([whether select supports a 0 argument],
  19       [gl_cv_func_select_supports0],
  20       [
  21         AC_RUN_IFELSE([AC_LANG_SOURCE([[
  22 #include <sys/types.h>
  23 #include <sys/time.h>
  24 #if HAVE_SYS_SELECT_H
  25 #include <sys/select.h>
  26 #endif
  27 int main ()
  28 {
  29   struct timeval timeout;
  30   timeout.tv_sec = 0;
  31   timeout.tv_usec = 5;
  32   return select (0, (fd_set *)0, (fd_set *)0, (fd_set *)0, &timeout) < 0;
  33 }]])], [gl_cv_func_select_supports0=yes], [gl_cv_func_select_supports0=no],
  34           [
  35 changequote(,)dnl
  36            case "$host_os" in
  37                        # Guess no on Interix.
  38              interix*) gl_cv_func_select_supports0="guessing no";;
  39                        # Guess yes otherwise.
  40              *)        gl_cv_func_select_supports0="guessing yes";;
  41            esac
  42 changequote([,])dnl
  43           ])
  44       ])
  45     case "$gl_cv_func_select_supports0" in
  46       *yes) ;;
  47       *) REPLACE_SELECT=1 ;;
  48     esac
  49   fi
  50
  51   dnl Determine the needed libraries.
  52   LIB_SELECT="$LIBSOCKET"
  53   if test $REPLACE_SELECT = 1; then
  54     case "$host_os" in
  55       mingw*)
  56         dnl On the MSVC platform, the function MsgWaitForMultipleObjects
  57         dnl (used in lib/select.c) requires linking with -luser32. On mingw,
  58         dnl it is implicit.
  59         AC_LINK_IFELSE(
  60           [AC_LANG_SOURCE([[
  61 #define WIN32_LEAN_AND_MEAN
  62 #include <windows.h>
  63 int
  64 main ()
  65 {
  66   MsgWaitForMultipleObjects (0, NULL, 0, 0, 0);
  67   return 0;
  68 }]])],
  69           [],
  70           [LIB_SELECT="$LIB_SELECT -luser32"])
  71         ;;
  72     esac
  73   fi
  74   AC_SUBST([LIB_SELECT])
  75 ])