configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ([2.69])
   4 AC_INIT([got-portable],
   5         m4_esyscmd_s(util/got-portable-ver.sh),
   6         [thomas@xteddy.org])
   7 AC_CONFIG_AUX_DIR(etc)
   8 AC_CONFIG_SRCDIR([lib/rcsutil.h])
   9 AM_INIT_AUTOMAKE([foreign subdir-objects])
  10
  11 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  12 AC_SUBST(VERSION)
  13 AC_SUBST(GOT_RELEASE)
  14
  15 AC_USE_SYSTEM_EXTENSIONS
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_SUBDIRS([template])
  19
  20 # When CFLAGS isn't set at this stage and gcc is detected by the macro below,
  21 # autoconf will automatically use CFLAGS="-O2 -g". Prevent that by using an
  22 # empty default.
  23 : ${CFLAGS=""}
  24
  25 # Save user CPPFLAGS, CFLAGS and LDFLAGS. We need to change them because
  26 # AC_CHECK_HEADER doesn't give us any other way to update the include
  27 # paths. But for Makefile.am we want to use AM_CPPFLAGS and friends.
  28 SAVED_CFLAGS="$CFLAGS"
  29 SAVED_CPPFLAGS="$CPPFLAGS"
  30 SAVED_LDFLAGS="$LDFLAGS"
  31
  32 # Checks for programs.
  33 AC_PROG_CC
  34 AC_PROG_CPP
  35 AC_PROG_INSTALL
  36 AC_PROG_LN_S
  37 AC_PROG_MAKE_SET
  38 AC_PROG_YACC
  39 AM_PROG_AR
  40 AC_PROG_RANLIB
  41 PKG_PROG_PKG_CONFIG
  42
  43 # Checks for header files.
  44 AC_CHECK_HEADERS([ \
  45         fcntl.h \
  46         langinfo.h \
  47         limits.h \
  48         linux/landlock.h \
  49         locale.h \
  50         netdb.h \
  51         netinet/in.h \
  52         paths.h \
  53         poll.h \
  54         stddef.h \
  55         stdint.h \
  56         stdlib.h \
  57         string.h \
  58         sys/ioctl.h \
  59         sys/param.h \
  60         sys/poll.h \
  61         sys/queue.h \
  62         sys/socket.h \
  63         sys/time.h \
  64         sys/tree.h \
  65         util.h \
  66         unistd.h \
  67         wchar.h \
  68 ])
  69
  70 # Checks for typ edefs, structures, and compiler characteristics.
  71 AC_CHECK_HEADER_STDBOOL
  72 AC_C_INLINE
  73 AC_TYPE_INT64_T
  74 AC_TYPE_MODE_T
  75 AC_TYPE_OFF_T
  76 AC_TYPE_PID_T
  77 AC_TYPE_SIZE_T
  78 AC_TYPE_SSIZE_T
  79 AC_TYPE_UINT16_T
  80 AC_TYPE_UINT32_T
  81 AC_TYPE_UINT64_T
  82 AC_TYPE_UINT8_T
  83
  84 # Check for ifgroupreq which is only available on BSD.
  85 AC_CHECK_TYPES([struct ifgroupreq])
  86
  87 # Check for sockaddr_storage.  On some systems, ss_len is filled out, although
  88 # this is not mandated by POSIX, and hence systems such as linux, don't have
  89 # it.
  90 AC_CHECK_TYPES([struct sockaddr_storage], [], [], [
  91 #include <sys/types.h>
  92 #include <sys/socket.h>
  93 ])
  94
  95 # Same thing as sockaddr_storage above, only now check if the member exists in
  96 # the struct as well.
  97 AC_CHECK_MEMBERS([struct sockaddr_storage.ss_len], , ,
  98         [ #include <netdb.h>
  99           #include <netinet/in.h>
 100           #include <sys/socket.h> ]
 101 )
 102
 103 AC_CHECK_MEMBERS([struct sockaddr.sa_len], , ,
 104         [ #include <netdb.h>
 105           #include <netinet/in.h>
 106           #include <sys/socket.h> ]
 107 )
 108
 109 # Both checks above will result in:
 110 #
 111 # HAVE_STRUCT_SOCKADDR_AS_LEN
 112 # SS_LEN
 113 #
 114 # Either being defined or not.
 115
 116 # Look for library needed for flock.
 117 AC_SEARCH_LIBS(flock, bsd)
 118
 119 # Checks for library functions.
 120 AC_FUNC_FORK
 121 AC_FUNC_FSEEKO
 122 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 123 AC_FUNC_MALLOC
 124 AC_FUNC_MMAP
 125 AC_FUNC_REALLOC
 126 AC_FUNC_STRERROR_R
 127 AC_FUNC_STRNLEN
 128 AC_CHECK_FUNCS([ \
 129         dup2 \
 130         flock \
 131         getcwd \
 132         localtime_r \
 133         memchr \
 134         memmove \
 135         memset \
 136         mkdir \
 137         munmap \
 138         nl_langinfo \
 139         realpath \
 140         regcomp \
 141         rmdir \
 142         setlocale \
 143         socket \
 144         setresgid \
 145         setresuid \
 146         setproctitle \
 147         strcasecmp \
 148         strchr \
 149         strcspn \
 150         strdup \
 151         strerror \
 152         strlcpy \
 153         strncasecmp \
 154         strndup \
 155         strrchr \
 156         strspn \
 157         strstr \
 158         strtol \
 159         strtoul \
 160         wcwidth \
 161 ])
 162
 163 AM_CONDITIONAL([HAVE_SETPROCTITLE], [test "x$ac_cv_func_setproctitle" = xyes])
 164 AM_CONDITIONAL([HAVE_SETRESGID], [test "x$ac_cv_func_setresgid" = xyes])
 165 AM_CONDITIONAL([HAVE_SETRESUID], [test "x$ac_cv_func_setresuid" = xyes])
 166
 167 # Siphash support.
 168 AC_CHECK_FUNCS([SipHash])
 169 AM_CONDITIONAL([HAVE_SIPHASH], [test "x$ac_cv_func_SipHash" = xyes])
 170
 171 # Check for functions with a compatibility implementation.
 172 AC_REPLACE_FUNCS([ \
 173         asprintf \
 174         closefrom \
 175         explicit_bzero \
 176         fmt_scaled \
 177         freezero \
 178         getdtablecount \
 179         getline \
 180         getprogname \
 181         recallocarray \
 182         reallocarray \
 183         strlcat \
 184         strlcpy \
 185         strndup \
 186         strsep \
 187         strtonum \
 188 ])
 189
 190 # Always use our getopt because 1) glibc's doesn't enforce argument order 2)
 191 # musl does not set optarg to NULL for flags without arguments (although it is
 192 # not required to, but it is helpful) 3) there are probably other weird
 193 # implementations.
 194 AC_LIBOBJ(getopt)
 195
 196 # Check the platform we're compiling on.
 197 AC_MSG_CHECKING(platform)
 198 case "$host_os" in
 199         *linux*)
 200                 AC_MSG_RESULT(linux)
 201                 PLATFORM=linux
 202                 ;;
 203         *freebsd*)
 204                 AC_MSG_RESULT(freebsd)
 205                 PLATFORM=freebsd
 206                 ;;
 207         *darwin*)
 208                 AC_MSG_RESULT(darwin)
 209                 PLATFORM=darwin
 210                 ;;
 211         *netbsd*)
 212                 AC_MSG_RESULT(netbsd)
 213                 PLATFORM=netbsd
 214                 ;;
 215         *dragonfly*)
 216                 AC_MSG_RESULT(dragonfly)
 217                 PLATFORM=dragonflybsd
 218                 ;;
 219         *)
 220                 AC_MSG_RESULT(unknown)
 221                 PLATFORM=unknown
 222                 ;;
 223 esac
 224 AC_SUBST(PLATFORM)
 225 AM_CONDITIONAL([HOST_FREEBSD], [test "$PLATFORM" = "freebsd"])
 226 AM_CONDITIONAL([HOST_LINUX], [test "$PLATFORM" = "linux"])
 227 AM_CONDITIONAL([HOST_DARWIN], [test "$PLATFORM" = "darwin"])
 228 AM_CONDITIONAL([HOST_NETBSD], [test "$PLATFORM" = "netbsd"])
 229 AM_CONDITIONAL([HOST_DRAGONFLYBSD], [test "$PLATFORM" = "dragonflybsd"])
 230
 231 if test x"$PLATFORM" = "xdarwin"; then
 232         # Check for and/or set HOMEBREW_PREFIX.  brew is a common way of
 233         # installing applications.  The other is MacPorts.
 234         #
 235         # Before Apple Silicon existed (M1 onward), the paths for applications
 236         # installed via homebrew was typically /usr/local.  However, with M1
 237         # onward, this changed to a different path.
 238         #
 239         # Rather than hardcode this, check for HOMEBREW_PREFIX in the
 240         # environment if it's already set, and use it.  Otherwise, check for
 241         # brew(1) and use that.  If that fails, default to /usr/local
 242         #
 243         # This also means that MacPorts should continue to work.
 244         #
 245         # But with MacPorts, we should also check --prefix, and use that if it
 246         # has been supplied.
 247         #
 248         # In both cases, the variable HOMEBREW_PREFIX is used for both.
 249         HB_PREFIX=""
 250         FOUND_BISON="no"
 251         GNUBISON=""
 252         if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"; then
 253                 # HOMEBREW_PREFIX not set, check for brew(1)
 254                 if command -v brew >/dev/null 2>&1; then
 255                         AC_MSG_NOTICE("HOMEBREW_PREFIX set via 'brew --prefix'")
 256                         export HOMEBREW_PREFIX="$(brew --prefix)"
 257                 fi
 258
 259                 if test -z "$HOMEBREW_PREFIX" -o "$HOMEBREW_PREFIX" = "NONE"
 260                 then
 261                         # Default.
 262                         if test -z "${prefix}" -o "${prefix}" = "NONE"; then
 263                                 export HOMEBREW_PREFIX="/usr/local"
 264                                 HB_PREFIX="/usr/local"
 265                                 AC_MSG_NOTICE("HOMEBREW_PREFIX defaulting to $HB_PREFIX")
 266                         else
 267                                 HB_PREFIX="$(eval echo ${prefix})"
 268                                 if test "$HB_PREFIX" = "NONE"; then
 269                                         HB_PREFIX="/opt/local"
 270                                 else
 271                                         AC_MSG_NOTICE("HOMEBREW_PREFIX using --prefix")
 272                                 fi
 273                                 export HOMEBREW_PREFIX="$HB_PREFIX"
 274                         fi
 275                 fi
 276         fi
 277
 278         AC_MSG_NOTICE("HOMEBREW_PREFIX determined as: $HOMEBREW_PREFIX")
 279
 280         if ! test -x "${HOMEBREW_PREFIX}/opt/bison/bin/bison"; then
 281                 AC_MSG_WARN([
 282                              "***********************************************************
 283                              GNU Bison not found: ${HOMEBREW_PREFIX}/opt/bison/bin/bison
 284                              ***********************************************************
 285
 286                              Falling back to checking either /usr/local or \${prefix}"
 287                 ])
 288
 289                 FOUND_BISON="no"
 290                 AC_MSG_WARN("Trying ${HB_PREFIX}/opt/bison/bin/bison")
 291                 if test -x "${HB_PREFIX}/opt/bison/bin/bison"; then
 292                         export HOMEBREW_PREFIX="/usr/local"
 293                         FOUND_BISON="yes"
 294                         GNUBISON="${HB_PREFIX}/opt/bison/bin/bison"
 295                 fi
 296
 297                 if test "$FOUND_BISON" = "no"; then
 298                         HB_PREFIX="/opt/local"
 299                         AC_MSG_WARN("Trying ${HB_PREFIX}/bin/bison")
 300
 301                         if test -x "${HB_PREFIX}/bin/bison"; then
 302                                 export HOMEBREW_PREFIX="${HB_PREFIX}"
 303                                 GNUBISON="${HB_PREFIX}/bin/bison"
 304                                 FOUND_BISON="yes"
 305                         fi
 306                 fi
 307         else
 308                 FOUND_BISON="yes"
 309                 GNUBISON="${HOMEBREW_PREFIX}/opt/bison/bin/bison"
 310         fi
 311
 312         if test "$FOUND_BISON" = "no"; then
 313                 AC_MSG_ERROR("*** Couldn't find GNU BISON ***")
 314         fi
 315
 316         AC_MSG_NOTICE("Found GNU Bison as: $GNUBISON")
 317
 318         # Override YACC here to point to the GNU version of bison.
 319         export YACC="${GNUBISON} -y"
 320         export LDFLAGS="-L${HOMEBREW_PREFIX}/opt/ncurses/lib -L${HOMEBREW_PREFIX}/opt/openssl@3/lib $LDFLAGS"
 321         export CPPFLAGS="-I${HOMEBREW_PREFIX}/opt/ncurses/include -I${HOMEBREW_PREFIX}/opt/openssl@3/include $CPPFLAGS"
 322         export PKG_CONFIG_PATH="${HOMEBREW_PREFIX}/opt/ncurses/lib/pkgconfig"
 323         export PKG_CONFIG_PATH="$PKG_CONFIG_PATH:${HOMEBREW_PREFIX}/opt/openssl@3/lib/pkgconfig"
 324 fi
 325
 326 # Landlock detection.
 327 AC_MSG_CHECKING([for landlock])
 328 AM_CONDITIONAL([HAVE_LINUX_LANDLOCK],
 329     [test "x$ac_cv_header_linux_landlock_h" = "xyes"])
 330 if test "x$ac_cv_header_linux_landlock_h" = "xyes"; then
 331         AC_MSG_RESULT(yes)
 332 else
 333         AC_MSG_RESULT(no)
 334 fi
 335
 336 # Clang sanitizers wrap reallocarray even if it isn't available on the target
 337 # system. When compiled it always returns NULL and crashes the program. To
 338 # detect this we need a more complicated test.
 339 AC_MSG_CHECKING([for working reallocarray])
 340 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 341                 [#include <stdlib.h>],
 342                 [return (reallocarray(NULL, 1, 1) == NULL);]
 343         )],
 344         AC_MSG_RESULT(yes),
 345         [AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])],
 346         [AC_LIBOBJ(reallocarray) AC_MSG_RESULT([no])]
 347 )
 348 AC_MSG_CHECKING([for working recallocarray])
 349 AC_RUN_IFELSE([AC_LANG_PROGRAM(
 350                 [#include <stdlib.h>],
 351                 [return (recallocarray(NULL, 1, 1, 1) == NULL);]
 352         )],
 353         AC_MSG_RESULT(yes),
 354         [AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])],
 355         [AC_LIBOBJ(recallocarray) AC_MSG_RESULT([no])]
 356 )
 357
 358 # Look for imsg_init in libutil.
 359 AC_SEARCH_LIBS(imsg_init, util, found_imsg_init=yes, found_imsg_init=no)
 360 AM_CONDITIONAL([HAVE_IMSG], [test "x$found_imsg_init" = "xyes"])
 361 if test "x$found_imsg_init" = xno; then
 362         AC_LIBOBJ(imsg)
 363         AC_LIBOBJ(imsg-buffer)
 364 fi
 365
 366 # libevent (for gotwebd).  Lifted from tmux.
 367 # Look for libevent. Try libevent_core or libevent with pkg-config first then
 368 # look for the library.
 369 PKG_CHECK_MODULES(
 370         LIBEVENT_CORE,
 371         [libevent_core >= 2],
 372         [
 373                 AM_CPPFLAGS="$LIBEVENT_CORE_CFLAGS $AM_CPPFLAGS"
 374                 CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
 375                 LIBS="$LIBEVENT_CORE_LIBS $LIBS"
 376                 found_libevent=yes
 377         ],
 378         found_libevent=no
 379 )
 380 if test x$found_libevent = xno; then
 381         PKG_CHECK_MODULES(
 382                 LIBEVENT,
 383                 [libevent >= 2],
 384                 [
 385                         AM_CPPFLAGS="$LIBEVENT_CFLAGS $AM_CPPFLAGS"
 386                         CPPFLAGS="$AM_CPPFLAGS $SAVED_CPPFLAGS"
 387                         LIBS="$LIBEVENT_LIBS $LIBS"
 388                         found_libevent=yes
 389                 ],
 390                 found_libevent=no
 391         )
 392 fi
 393 if test x$found_libevent = xno; then
 394         AC_SEARCH_LIBS(
 395                 event_init,
 396                 [event_core event event-1.4],
 397                 found_libevent=yes,
 398                 found_libevent=no
 399         )
 400 fi
 401 AC_CHECK_HEADER(
 402         event2/event.h,
 403         AC_DEFINE(HAVE_EVENT2_EVENT_H),
 404         [
 405                 AC_CHECK_HEADER(
 406                         event.h,
 407                         AC_DEFINE(HAVE_EVENT_H),
 408                         found_libevent=no
 409                 )
 410         ]
 411 )
 412 if test "x$found_libevent" = xno; then
 413         AC_MSG_ERROR("libevent not found")
 414 fi
 415
 416 # libcrypto (via libssl for SHA information)
 417 PKG_CHECK_MODULES(
 418         LIBCRYPTO,
 419         libcrypto,
 420         [
 421                 AM_CFLAGS="$LIBCRYPTO_CFLAGS $AM_CFLAGS"
 422                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 423                 LIBS="$LIBCRYPTO_LIBS $LIBS"
 424                 found_libcrypto=yes
 425         ],
 426         [
 427                 found_libcrypto=no
 428         ]
 429 )
 430
 431 if test "x$found_libcrypto" = "xyes"; then
 432         AC_DEFINE(HAVE_LIBCRYPTO)
 433 fi
 434
 435 AC_SEARCH_LIBS(uuid_create, , AC_DEFINE(HAVE_BSD_UUID))
 436 AC_SEARCH_LIBS(uuid_create, found_uuid=no, found_uuid=yes)
 437 AC_SEARCH_LIBS(mergesort, , AC_DEFINE(HAVE_BSD_MERGESORT))
 438
 439 # Don't define HAVE_BSD_UUID on darwin (Apple) as this breaks the BSD API.
 440 # Instead, use the UUID implementation wrapper that's in compat/ plus uuid
 441 # ossp
 442 if test "x$found_uuid" = "xyes" -a "x$PLATFORM" != "darwin"; then
 443         AC_DEFINE(HAVE_BSD_UUID)
 444 else
 445         PKG_CHECK_MODULES(
 446                 LIBUUID,
 447                 uuid,
 448                 [
 449                         AM_CFLAGS="$LIBUUID_CFLAGS $AM_CFLAGS"
 450                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 451                         LIBS="$LIBUUID_LIBS $LIBS"
 452                         found_libuuid=yes
 453                 ],
 454                 [
 455                         found_libuuid=no
 456                 ]
 457         )
 458
 459         if test "x$found_libuuid" = "xno"; then
 460                 AC_CHECK_HEADER(
 461                         uuid.h,
 462                         found_libuuid=yes,
 463                         found_libuuid=no)
 464         fi
 465 fi
 466
 467 if test "x$found_libuuid" = "xno"; then
 468         AC_MSG_ERROR("*** couldn't find uuid ***")
 469 fi
 470
 471 PKG_CHECK_MODULES(
 472         ZLIB,
 473         zlib,
 474         [
 475                 AM_CFLAGS="$ZLIB_CFLAGS $AM_CFLAGS"
 476                 CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 477                 LIBS="$ZLIB_LIBS $LIBS"
 478                 found_zlib=yes
 479         ],
 480         [
 481                 found_zlib=no
 482         ]
 483 )
 484
 485 if test "x$found_zlib" = "xno"; then
 486         AC_CHECK_HEADER(
 487                 zlib.h,
 488                 ,
 489                 found_zlib=no)
 490 fi
 491
 492 if test "x$found_zlib" = "xno"; then
 493         AC_MSG_ERROR("*** couldn't find zlib ***")
 494 fi
 495
 496 if test "$PLATFORM" = "linux"; then
 497         PKG_CHECK_MODULES(
 498                 LIBMD,
 499                 libmd,
 500                 [
 501                         AM_CFLAGS="$LIBMD_CFLAGS $AM_CFLAGS"
 502                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 503                         LIBS="$LIBMD_LIBS $LIBS"
 504                 ],
 505                 [
 506                         AC_MSG_ERROR("*** couldn't find libmd via pkg-config")
 507                 ]
 508         )
 509         PKG_CHECK_MODULES(
 510                 LIBBSD,
 511                 libbsd-overlay,
 512                 [
 513                         AM_CFLAGS="$LIBBSD_CFLAGS $AM_CFLAGS"
 514                         CFLAGS="$AM_CFLAGS $SAVED_CFLAGS"
 515                         LIBS="$LIBBSD_LIBS $LIBS"
 516                         found_libbsd=yes
 517                         AC_DEFINE(HAVE_LIBBSD)
 518                 ],
 519                 [
 520                         AC_MSG_ERROR("*** couldn't find libbsd-overlay via pkg-config")
 521                 ]
 522
 523         )
 524 fi
 525
 526 # Look for a suitable queue.h.  We hope libbsd is enough, but that is missing
 527 # some declarations.
 528 AC_CHECK_DECL(
 529         TAILQ_CONCAT,
 530         found_queue_h=yes,
 531         found_queue_h=no,
 532         [#include <sys/queue.h>]
 533 )
 534 AC_CHECK_DECL(
 535         TAILQ_PREV,
 536         ,
 537         found_queue_h=no,
 538         [#include <sys/queue.h>]
 539 )
 540 AC_CHECK_DECL(
 541         TAILQ_FOREACH_SAFE,
 542         ,
 543         found_queue_h=no,
 544         [#include <sys/queue.h>]
 545 )
 546
 547 if test "x$found_queue_h" = xyes; then
 548         AC_DEFINE(HAVE_QUEUE_H)
 549 else
 550         AC_MSG_ERROR("*** sys/queue.h missing key defines ***)
 551 fi
 552
 553 AC_CHECK_DECL(
 554         RB_GENERATE_STATIC,
 555         found_sys_tree_h=yes,
 556         found_sys_tree_h=no,
 557         [#include <sys/tree.h>]
 558 )
 559
 560 if test "x$found_sys_tree_h" = xyes; then
 561         AC_DEFINE(HAVE_TREE_H)
 562 else
 563         AC_MSG_NOTICE("Using compat/tree.h")
 564 fi
 565
 566 # Look for __progname.
 567 AC_MSG_CHECKING(for __progname)
 568 AC_LINK_IFELSE([AC_LANG_SOURCE(
 569         [
 570                 #include <stdio.h>
 571                 #include <stdlib.h>
 572                 extern char *__progname;
 573                 int main(void) {
 574                         const char *cp = __progname;
 575                         printf("%s\n", cp);
 576                         exit(0);
 577                 }
 578         ])],
 579         [AC_DEFINE(HAVE___PROGNAME) AC_MSG_RESULT(yes)],
 580         AC_MSG_RESULT(no)
 581 )
 582
 583 PKG_CHECK_MODULES(
 584         LIBPANELW,
 585         panelw,
 586         found_panel=yes,
 587         found_panel=no
 588 )
 589
 590 PKG_CHECK_MODULES(
 591         LIBPANELW,
 592         gnupanelw,
 593         found_panel=yes,
 594         found_panel=no
 595 )
 596
 597 PKG_CHECK_MODULES(
 598         LIBPANELW,
 599         panel,
 600         found_panel=yes,
 601         found_panel=no
 602 )
 603 if test "x$found_panel" = "xno"; then
 604         AC_CHECK_LIB(panelw, update_panels, [],
 605                 AC_MSG_ERROR([ "*** panelw not found for ncurses. ***"]),
 606                 [-lncurses]
 607         )
 608
 609         LIBPANELW_LIBS="-lpanelw"
 610 fi
 611
 612 PKG_CHECK_MODULES(
 613         LIBNCURSES,
 614         ncursesw,
 615         found_ncurses=yes,
 616         found_ncurses=no
 617 )
 618 if test "x$found_ncurses" = xyes; then
 619         AM_CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $AM_CFLAGS"
 620         CFLAGS="$LIBNCURSES_CFLAGS $LIBTINFO_CFLAGS $LIBPANELW_CFLAGS $CFLAGS"
 621         LIBS="$LIBNCURSES_LIBS $LIBTINFO_LIBS $LIBPANELW_LIBS $LIBS"
 622 else
 623         AC_CHECK_LIB(
 624                 ncursesw,
 625                 setupterm,
 626                 found_ncurses=yes,
 627                 found_ncurses=no
 628         )
 629         if test "x$found_ncurses" = xyes; then
 630                 AC_CHECK_HEADER(
 631                         ncurses.h,
 632                         AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 633                         CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 634                         LIBS="$LIBS -lncursesw $LIBPANELW_LIBS",
 635                         found_ncurses=no
 636                 )
 637         fi
 638 fi
 639 if test "x$found_ncurses" = xyes; then
 640         AC_DEFINE(HAVE_NCURSES_H)
 641 else
 642         # No ncurses, try curses.
 643         AC_CHECK_LIB(
 644                 cursesw,
 645                 setupterm,
 646                 found_curses=yes,
 647                 found_curses=no
 648         )
 649         AC_CHECK_HEADER(
 650                 curses.h,
 651                 ,
 652                 found_curses=no)
 653         if test "x$found_curses" = xyes; then
 654                 AM_CFLAGS="$LIBPANELW_CFLAGS $AM_CFLAGS"
 655                 CFLAGS="$LIBPANEL_CFLAGS $CFLAGS"
 656                 LIBS="$LIBS -lcursesw $LIBPANELW_LIBS"
 657                 AC_DEFINE(HAVE_CURSES_H)
 658         else
 659                 AC_MSG_ERROR("curses not found")
 660         fi
 661 fi
 662
 663 # Save our CFLAGS/CPPFLAGS/LDFLAGS for the Makefile and restore the old user
 664 # variables.
 665 AC_SUBST(AM_CPPFLAGS)
 666 CPPFLAGS="$SAVED_CPPFLAGS"
 667 AC_SUBST(AM_CFLAGS)
 668 CFLAGS="$SAVED_CFLAGS"
 669 AC_SUBST(AM_LDFLAGS)
 670 LDFLAGS="$SAVED_LDFLAGS"
 671
 672 AC_CONFIG_FILES([Makefile
 673                  compat/Makefile
 674                  libexec/Makefile
 675                  libexec/got-read-tree/Makefile
 676                  libexec/got-fetch-pack/Makefile
 677                  libexec/got-index-pack/Makefile
 678                  libexec/got-read-blob/Makefile
 679                  libexec/got-read-commit/Makefile
 680                  libexec/got-read-gitconfig/Makefile
 681                  libexec/got-read-gotconfig/Makefile
 682                  libexec/got-read-object/Makefile
 683                  libexec/got-read-pack/Makefile
 684                  libexec/got-read-patch/Makefile
 685                  libexec/got-read-tag/Makefile
 686                  libexec/got-send-pack/Makefile
 687                  got/Makefile
 688                  gotadmin/Makefile
 689                  gotwebd/Makefile
 690                  tog/Makefile
 691                  Makefile.common:Makefile.common.in])
 692 AC_OUTPUT
 693
 694 executables="$(eval echo ${exec_prefix}/bin)"
 695 helpers="$(eval echo ${libexecdir})"
 696 manpages="$(eval echo ${mandir})"
 697
 698 echo "
 699 Configured got-portable with:
 700
 701  Version:      $VERSION
 702
 703  Prefix:       ${prefix}
 704  Executables:  ${executables}
 705  Helpers:      ${helpers}
 706  Man pages:    ${manpages}
 707 "