src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  36 # make an "object library" that we can re-use for multiple targets
  37 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  38
  39 if(GMX_FAHCORE)
  40     # The lack of a real source file here alongside the object library
  41     # may break some generators, according to CMake documentation. If
  42     # so, we can consider adding some dummy file to make it work.
  43     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  44     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES})
  45 elseif(GMX_BUILD_MDRUN_ONLY)
  46     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  47     target_link_libraries(mdrun libgromacs
  48         ${GMX_COMMON_LIBRARIES}
  49         ${GMX_EXE_LINKER_FLAGS}
  50         ${GMX_STDLIB_LIBRARIES})
  51     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  52     set_target_properties(mdrun PROPERTIES
  53         OUTPUT_NAME "${BINARY_NAME}"
  54         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  55     install(TARGETS mdrun DESTINATION ${BIN_INSTALL_DIR} COMPONENT mdrun)
  56     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  57          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  58     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  59             DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
  60 else()
  61     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  62     if(GMX_X11)
  63         file(GLOB VIEW_SOURCES view/*.cpp)
  64     else()
  65         file(GLOB VIEW_SOURCES view/view.cpp)
  66     endif()
  67     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  68     add_executable(gmx
  69         ${GMX_MAIN_SOURCES}
  70         $<TARGET_OBJECTS:mdrun_objlib>
  71         $<TARGET_OBJECTS:view_objlib>)
  72     target_link_libraries(gmx libgromacs
  73         ${GMX_COMMON_LIBRARIES}
  74         ${GMX_EXE_LINKER_FLAGS}
  75         ${GMX_STDLIB_LIBRARIES})
  76     if(GMX_X11)
  77         target_link_libraries(gmx ${X11_LIBRARIES})
  78     endif()
  79     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  80     set_target_properties(gmx PROPERTIES
  81         OUTPUT_NAME "${BINARY_NAME}"
  82         COMPILE_FLAGS "${OpenMP_C_FLAGS}")
  83     install(TARGETS gmx
  84             RUNTIME DESTINATION ${BIN_INSTALL_DIR})
  85
  86     ########################
  87     # Completion generation
  88
  89     include(gmxCustomCommandUtilities)
  90
  91     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
  92     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
  93     # this can be done are exactly the same (ability to run the compiled
  94     # binaries).
  95     if (GMX_BUILD_HELP)
  96         gmx_add_custom_output_target(completion OUTPUT STAMP
  97             COMMAND ${CMAKE_COMMAND}
  98                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
  99                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 100                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 101             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 102             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 103             COMMENT "Generating command-line completions for programs")
 104         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 105         set_directory_properties(PROPERTIES
 106             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 107         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 108     endif()
 109     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 110         install(DIRECTORY ${COMPLETION_DIR}/
 111                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime OPTIONAL)
 112         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 113              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 114         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 115                 DESTINATION ${BIN_INSTALL_DIR} COMPONENT runtime)
 116     endif()
 117     gmx_cpack_add_generated_source_directory(completion)
 118
 119     if(BUILD_TESTING)
 120         add_subdirectory(mdrun/tests)
 121     endif()
 122 endif()