cmake/gmxCFlags.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Test C flags FLAGS, and set VARIABLE to true if the work. Also add the
  36 # flags to CFLAGSVAR.
  37 MACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  38     IF(NOT DEFINED ${VARIABLE})
  39         CHECK_C_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  40     ENDIF()
  41     IF (${VARIABLE})
  42         SET (${CFLAGSVAR} "${FLAGS} ${${CFLAGSVAR}}")
  43     ENDIF ()
  44 ENDMACRO(GMX_TEST_CFLAG VARIABLE FLAGS CFLAGSVAR)
  45
  46 # Test C++ flags FLAGS, and set VARIABLE to true if the work. Also add the
  47 # flags to CXXFLAGSVAR.
  48 MACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  49     IF(NOT DEFINED ${VARIABLE})
  50         CHECK_CXX_COMPILER_FLAG("${FLAGS}" ${VARIABLE})
  51     ENDIF()
  52     IF (${VARIABLE})
  53         SET (${CXXFLAGSVAR} "${FLAGS} ${${CXXFLAGSVAR}}")
  54     ENDIF ()
  55 ENDMACRO(GMX_TEST_CXXFLAG VARIABLE FLAGS CXXFLAGSVAR)
  56
  57 # Set the real CMake variables for compiler flags. This should be a function
  58 # so we can have proper local variables while avoiding duplicating code.
  59 function(gmx_set_cmake_compiler_flags)
  60     foreach(language C CXX)
  61         # Copy the flags for the release build type to the build types
  62         # that are modified forms of it. Ideally, the list of build
  63         # types that are modifications of the Release build type would
  64         # be set up elsewhere and passed to this function, but it is
  65         # inconvenient in CMake to pass more than one list, and such a
  66         # list is only used here.
  67         foreach(build_type RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  68             set(GMXC_${language}FLAGS_${build_type} "${GMXC_${language}FLAGS_RELEASE}")
  69         endforeach()
  70         # Copy the flags that are only used by the real Release build
  71         # type. Used for, e.g., -Wno-array-bounds in Release to work around
  72         # gcc-4.8 being a little too vocal about some perfectly good code,
  73         # while using RelWithAssert (ie. without that suppression) in Jenkins.
  74         set(GMXC_${language}FLAGS_RELEASE "${GMXC_${language}FLAGS_RELEASE} ${GMXC_${language}FLAGS_RELEASE_ONLY}")
  75
  76         # Modify the real CMake variables for compiler flags for all
  77         # builds and language types, and also those common to all
  78         # build types.
  79         foreach(build_type "" ${build_types_with_explicit_flags})
  80             if("${build_type}" STREQUAL "")
  81                 set(punctuation "") # for general compiler flags (e.g.) CMAKE_CXX_FLAGS
  82             else()
  83                 set(punctuation "_") # for build-type-specific compiler flags (e.g.) CMAKE_CXX_FLAGS_RELEASE
  84             endif()
  85
  86             # Append to the variables for the given build type for
  87             # each language, in the parent scope. We add our new variables at the end, so
  88             # compiler-specific choices are more likely to override default CMake choices.
  89             # This is for instance useful for RelWithDebInfo builds, where we want to use the full
  90             # set of our optimization flags detected in this file, rather than having -O2 override them.
  91             set(CMAKE_${language}_FLAGS${punctuation}${build_type}
  92                 "${CMAKE_${language}_FLAGS${punctuation}${build_type}} ${GMXC_${language}FLAGS${punctuation}${build_type}}"
  93                 PARENT_SCOPE)
  94         endforeach()
  95     endforeach()
  96 endfunction()
  97
  98 # This is the actual exported function to be called
  99 macro (gmx_c_flags)
 100
 101     include(CheckCCompilerFlag)
 102     include(CheckCXXCompilerFlag)
 103
 104     # gcc
 105     if(CMAKE_COMPILER_IS_GNUCC)
 106         #flags are added in reverse order and -Wno* need to appear after -Wall
 107         if(NOT GMX_OPENMP)
 108             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 109         endif()
 110         if (GMX_COMPILER_WARNINGS)
 111             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 112             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wno-sign-compare -Wpointer-arith" GMXC_CFLAGS)
 113             if(NOT GMX_USE_CUDA) #TODO: Fix that CUDA code has warnings
 114                 GMX_TEST_CFLAG(CFLAGS_WARN_UNDEF "-Wundef" GMXC_CFLAGS)
 115             endif()
 116             # Since 4.8 on by default. For previous version disabling is a no-op. Only disabling for Release because with assert
 117             # the warnings are OK.
 118             GMX_TEST_CFLAG(CFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CFLAGS_RELEASE_ONLY)
 119             if(CYGWIN)
 120                 GMX_TEST_CFLAG(CFLAGS_WARN_SUBSCRIPT "-Wno-char-subscripts" GMXC_CFLAGS)
 121             endif()
 122         endif()
 123         # new in gcc 4.5
 124         GMX_TEST_CFLAG(CFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CFLAGS_RELEASE)
 125         GMX_TEST_CFLAG(CFLAGS_COPT "-funroll-all-loops"
 126                        GMXC_CFLAGS_RELEASE)
 127         GMX_TEST_CFLAG(CFLAGS_NOINLINE "-fno-inline" GMXC_CFLAGS_DEBUG)
 128     endif()
 129     # g++
 130     if(CMAKE_COMPILER_IS_GNUCXX)
 131         if(NOT GMX_OPENMP)
 132             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 133         endif()
 134         if (GMX_COMPILER_WARNINGS)
 135             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 136             # Problematic with CUDA
 137             # GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EFFCXX "-Wnon-virtual-dtor" GMXC_CXXFLAGS)
 138             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 139             if(NOT GMX_USE_CUDA)
 140                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN_UNDEF "-Wundef" GMXC_CXXFLAGS)
 141             endif()
 142             GMX_TEST_CFLAG(CXXFLAGS_WARN_REL "-Wno-array-bounds" GMXC_CXXFLAGS_RELEASE_ONLY)
 143         endif()
 144         # new in gcc 4.5
 145         GMX_TEST_CXXFLAG(CXXFLAGS_EXCESS_PREC "-fexcess-precision=fast" GMXC_CXXFLAGS_RELEASE)
 146         GMX_TEST_CXXFLAG(CXXFLAGS_COPT "-funroll-all-loops"
 147                          GMXC_CXXFLAGS_RELEASE)
 148         GMX_TEST_CXXFLAG(CXXFLAGS_NOINLINE "-fno-inline" GMXC_CXXFLAGS_DEBUG)
 149     endif()
 150
 151     # icc
 152     if (CMAKE_C_COMPILER_ID MATCHES "Intel")
 153         if (NOT WIN32)
 154             if(NOT GMX_OPENMP)
 155                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 156 # 3180: unrecognized OpenMP #pragma
 157                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd3180" GMXC_CFLAGS)
 158                 else()
 159 # 161: unrecognized #pragma
 160                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "-wd161" GMXC_CFLAGS)
 161                 endif()
 162             endif()
 163             if (GMX_COMPILER_WARNINGS)
 164                 if(CMAKE_C_COMPILER_VERSION VERSION_LESS 15.00.00)
 165 # 193: zero used for undefined preprocessing identifier ".."
 166                     GMX_TEST_CFLAG(CFLAGS_WARN_OLD -wd193 GMXC_CFLAGS)
 167                 endif()
 168 # 177: function/variable ".." was declared but never referenced
 169 # 271: trailing comma is nonstandard
 170 # 304: access control not specified ("public" by default)
 171 # 383: value copied to temporary, reference to temporary used
 172 # 424: extra ";" ignored
 173 # 444: destructor for base class ".." is not virtual
 174 # 522: function ".." redeclared "inline" after being called
 175 # 593: variable ".." was set but never used
 176 # 869: parameter ".." was never referenced
 177 # 981: operands are evaluated in unspecified order
 178 #1418: external function definition with no prior declaration
 179 #1419: external declaration in primary source file
 180 #1572: floating-point equality and inequality comparisons are unreliable
 181 #1599: declaration hides variable ".."
 182 #2259: non-pointer conversion from ".." to ".." may lose significant bits
 183 #2415: variable ".." of static storage duration was declared but never referenced
 184 #2547: ".." was specified as both a system and non-system include directory
 185 #2557: comparison between signed and unsigned operands
 186 #3280: declaration hides member ".."
 187 #3346: dynamic exception specifications are deprecated
 188 #11074: Inlining inhibited by limit max-size(/max-total-size)
 189 #11076: To get full report use -opt-report=3 -opt-report-phase ipo (shown for previous remark)
 190                 GMX_TEST_CFLAG(CFLAGS_WARN "-w3 -wd177 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076" GMXC_CFLAGS)
 191             endif()
 192             GMX_TEST_CFLAG(CFLAGS_STDGNU "-std=gnu99" GMXC_CFLAGS)
 193             GMX_TEST_CFLAG(CFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CFLAGS_RELEASE)
 194             GMX_TEST_CFLAG(CFLAGS_DEBUG "-O0" GMXC_CFLAGS_DEBUG) #icc defaults to -O2 even with -g
 195             GMX_TEST_CFLAG(CFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CFLAGS_RELWITHASSERT)
 196         else()
 197             if(NOT GMX_OPENMP)
 198                 if(CMAKE_C_COMPILER_VERSION VERSION_GREATER 13.99.99)
 199                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 200                 else()
 201                     GMX_TEST_CFLAG(CFLAGS_PRAGMA "/wd161" GMXC_CFLAGS)
 202                 endif()
 203             endif()
 204             if (GMX_COMPILER_WARNINGS)
 205                 if(CMAKE_C_COMPILER_VERSION VERSION_LESS 15.00.00)
 206                     GMX_TEST_CFLAG(CFLAGS_WARN_OLD /wd193 GMXC_CFLAGS)
 207                 endif()
 208                 GMX_TEST_CFLAG(CFLAGS_WARN "/W3 /wd177 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346" GMXC_CFLAGS)
 209             endif()
 210             GMX_TEST_CFLAG(CFLAGS_OPT "/Qip" GMXC_CFLAGS_RELEASE)
 211         endif()
 212     endif()
 213
 214     if (CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 215         if (NOT WIN32)
 216             if(NOT GMX_OPENMP)
 217                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 218                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd3180" GMXC_CXXFLAGS)
 219                 else()
 220                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-wd161" GMXC_CXXFLAGS)
 221                 endif()
 222             endif()
 223             if (GMX_COMPILER_WARNINGS)
 224                 if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 15.00.00)
 225                     GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD -wd193 GMXC_CXXFLAGS)
 226                 endif()
 227 #All but the following warnings are identical for the C-compiler (see above)
 228 #1782: #pragma once is obsolete
 229 #2282: unrecognized GCC pragma
 230                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-w3 -wd177 -wd271 -wd304 -wd383 -wd424 -wd444 -wd522 -wd593 -wd869 -wd981 -wd1418 -wd1419 -wd1572 -wd1599 -wd2259 -wd2415 -wd2547 -wd2557 -wd3280 -wd3346 -wd11074 -wd11076 -wd1782 -wd2282" GMXC_CXXFLAGS)
 231             endif()
 232             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-ip -funroll-all-loops -alias-const -ansi-alias" GMXC_CXXFLAGS_RELEASE)
 233             GMX_TEST_CXXFLAG(CXXFLAGS_DEBUG "-O0" GMXC_CXXFLAGS_DEBUG)
 234             GMX_TEST_CXXFLAG(CXXFLAGS_FP_RELASSERT "-fp-model except -fp-model precise" GMXC_CXXFLAGS_RELWITHASSERT)
 235         else()
 236             if(NOT GMX_OPENMP)
 237                 if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 13.99.99)
 238                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd3180" GMXC_CFLAGS)
 239                 else()
 240                     GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "/wd161" GMXC_CXXFLAGS)
 241                 endif()
 242             endif()
 243             if (GMX_COMPILER_WARNINGS)
 244                 if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 15.00.00)
 245                     GMX_TEST_CXXFLAG(CXXFLAGS_WARN_OLD /wd193 GMXC_CXXFLAGS)
 246                 endif()
 247                 GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/W3 /wd177 /wd271 /wd304 /wd383 /wd424 /wd444 /wd522 /wd593 /wd869 /wd981 /wd1418 /wd1419 /wd1572 /wd1599 /wd2259 /wd2415 /wd2547 /wd2557 /wd3280 /wd3346 /wd1782 /wd2282" GMXC_CXXFLAGS)
 248             endif()
 249             GMX_TEST_CXXFLAG(CXXFLAGS_OPT "/Qip" GMXC_CXXFLAGS_RELEASE)
 250         endif()
 251     endif()
 252
 253     # PGI
 254     # Inter-procedural analysis causes pgcc/pgc++ to crash when linking the library with PGI release 15.7.
 255     if (CMAKE_C_COMPILER_ID MATCHES "PGI")
 256         GMX_TEST_CFLAG(CFLAGS_OPT "-Mnoipa" GMXC_CFLAGS_RELEASE)
 257     endif()
 258     if (CMAKE_CXX_COMPILER_ID MATCHES "PGI")
 259         # Using ipa exposes internal PGI-15.7 compiler bugs at compile time
 260         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-Mnoipa" GMXC_CXXFLAGS_RELEASE)
 261         # PGI identifies itself as GCC, but does not understand the GCC
 262         # pragmas that occur in parser.cpp. Since that file is generated
 263         # we cannot add a define there, but supress the warning instead.
 264         GMX_TEST_CXXFLAG(CXXFLAGS_WARN "--diag_suppress=1675" GMXC_CXXFLAGS)
 265     endif()
 266
 267     # Pathscale
 268     if (CMAKE_C_COMPILER_ID MATCHES "PathScale")
 269         if(NOT GMX_OPENMP)
 270             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 271         endif()
 272         if (GMX_COMPILER_WARNINGS)
 273             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CFLAGS)
 274         endif()
 275         GMX_TEST_CFLAG(CFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 276                          GMXC_CFLAGS_RELEASE)
 277         GMX_TEST_CFLAG(CFLAGS_LANG "-std=gnu99" GMXC_CFLAGS)
 278     endif()
 279     if (CMAKE_CXX_COMPILER_ID MATCHES "PathScale")
 280         if(NOT GMX_OPENMP)
 281             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 282         endif()
 283         if (GMX_COMPILER_WARNINGS)
 284             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused -Wunused-value" GMXC_CXXFLAGS)
 285         endif()
 286         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-OPT:Ofast -fno-math-errno -ffast-math"
 287                          GMXC_CXXFLAGS_RELEASE)
 288     endif()
 289
 290     # xlc
 291     # The suppressions below stop
 292     # 1500-036: (I) about -O3 causing non-strict IEEE compliance that changes the semantics of the program (duh)
 293     # 1500-010: (W) about correct PBC-related use of maximum array indices of DIM-sized C arrays
 294     # 1500-030: (I) Additional optimization may be attained by recompiling and specifying MAXMEM option with a value greater than 8192.
 295     if (CMAKE_C_COMPILER_ID MATCHES "XL")
 296         GMX_TEST_CFLAG(CFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CFLAGS)
 297         GMX_TEST_CFLAG(CFLAGS_OPT  "-O3" GMXC_CFLAGS_RELEASE)
 298         GMX_TEST_CFLAG(CFLAGS_LANG "-qlanglvl=extc99" GMXC_CFLAGS)
 299         GMX_TEST_CFLAG(CFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CFLAGS)
 300     endif()
 301     if (CMAKE_CXX_COMPILER_ID MATCHES "XL")
 302         GMX_TEST_CXXFLAG(CXXFLAGS_ARCH "-qarch=auto -qtune=auto" GMXC_CXXFLAGS)
 303         GMX_TEST_CXXFLAG(CXXFLAGS_OPT "-O3" GMXC_CXXFLAGS_RELEASE)
 304         GMX_TEST_CXXFLAG(CXXFLAGS_LANG "-qsuppress=1500-036 -qsuppress=1500-010 -qsuppress=1500-030" GMXC_CXXFLAGS)
 305     endif()
 306
 307     # msvc
 308     if (MSVC)
 309         # disable warnings for:
 310         #      forcing value to bool
 311         #      "this" in initializer list
 312         #      deprecated (posix, secure) functions
 313         #      truncation (double -> float)
 314         #      conversion from 'double' to 'real', possible loss of data
 315         #      unreferenced local variable (only C)
 316         #      conversion from 'size_t' to 'int', possible loss of data
 317         #      conversion from 'const char*' to 'void*', different 'const' qualifiers (only C)
 318         if(NOT CMAKE_CONFIGURATION_TYPES)
 319             GMX_TEST_CFLAG(CFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CFLAGS)
 320             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4267" GMXC_CXXFLAGS)
 321         else() #Projects only use the C++ flags
 322             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "/wd4800 /wd4355 /wd4996 /wd4305 /wd4244 /wd4101 /wd4267 /wd4090" GMXC_CXXFLAGS)
 323         endif()
 324     endif()
 325
 326     if (CMAKE_C_COMPILER_ID MATCHES "Clang")
 327         if(NOT GMX_OPENMP)
 328             GMX_TEST_CFLAG(CFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CFLAGS)
 329         endif()
 330         if (GMX_COMPILER_WARNINGS)
 331             GMX_TEST_CFLAG(CFLAGS_WARN "-Wall -Wno-unused -Wunused-value -Wunused-parameter" GMXC_CFLAGS)
 332             GMX_TEST_CFLAG(CFLAGS_WARN_EXTRA "-Wpointer-arith" GMXC_CFLAGS_EXTRA)
 333         endif()
 334     endif()
 335
 336     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 337         if(NOT GMX_OPENMP)
 338             GMX_TEST_CXXFLAG(CXXFLAGS_PRAGMA "-Wno-unknown-pragmas" GMXC_CXXFLAGS)
 339         endif()
 340         if (GMX_COMPILER_WARNINGS)
 341             GMX_TEST_CXXFLAG(CXXFLAGS_WARN "-Wall -Wno-unused-function" GMXC_CXXFLAGS)
 342             GMX_TEST_CXXFLAG(CXXFLAGS_WARN_EXTRA "-Wextra -Wno-missing-field-initializers -Wpointer-arith" GMXC_CXXFLAGS)
 343         endif()
 344     endif()
 345
 346     # Fujitsu compilers on PrimeHPC/Sparc64
 347     if(${CMAKE_C_COMPILER_ID} MATCHES Fujitsu OR
 348        (${CMAKE_C_COMPILER_ID} MATCHES unknown AND ${CMAKE_C_COMPILER} MATCHES ^fcc))
 349         GMX_TEST_CFLAG(CFLAG_GNUCOMPAT "-Xg -w" GMXC_CFLAGS)
 350         GMX_TEST_CFLAG(CFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CFLAGS)
 351     endif()
 352
 353     if(${CMAKE_CXX_COMPILER_ID} MATCHES Fujitsu OR
 354        (${CMAKE_CXX_COMPILER_ID} MATCHES unknown AND ${CMAKE_CXX_COMPILER} MATCHES ^FCC))
 355         GMX_TEST_CXXFLAG(CXXFLAG_GNUCOMPAT "-Xg -w" GMXC_CXXFLAGS)
 356         GMX_TEST_CXXFLAG(CXXFLAG_OPT "-Kfast,reduction,swp,simd=2,uxsimd,fsimple -x100" GMXC_CXXFLAGS)
 357     endif()
 358
 359     # now actually set the flags:
 360     if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 361         gmx_set_cmake_compiler_flags()
 362     endif()
 363
 364 endmacro()