cmake/FindPythonModule.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2015,2019,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Adapted from code posted on cmake-users by Mark Moll (the execute_process()
  36 # call remains, but other things have been rewritten for nicer behavior).
  37
  38 function (find_python_module module)
  39     string(TOUPPER ${module} _module_upper)
  40     set(_find_package_module ${module})
  41     set(_out_var PYTHONMODULE_${_module_upper})
  42
  43     include(CMakeParseArguments)
  44     set(_options QUIET REQUIRED)
  45     cmake_parse_arguments(ARG "${_options}" "" "" ${ARGN})
  46     if (ARG_UNPARSED_ARGUMENTS)
  47         message(FATAL_ERROR "Unknown arguments: ${ARG_UNPARSED_ARGUMENTS}")
  48     endif()
  49     if (ARG_REQUIRED)
  50         set(${_find_package_module}_FIND_REQUIRED TRUE)
  51     endif()
  52     if (ARG_QUIET)
  53         set(${_find_package_module}_FIND_QUIETLY TRUE)
  54     endif()
  55
  56     if (NOT ${_out_var})
  57         set(_status 1)
  58         if (PYTHON_EXECUTABLE)
  59             # A module's location is usually a directory, but for binary modules
  60             # it's a .so file.
  61             execute_process(COMMAND "${PYTHON_EXECUTABLE}" "-c"
  62                 "import re, ${module}; print(re.compile('/__init__.py.*').sub('',${module}.__file__))"
  63                 RESULT_VARIABLE _status
  64                 OUTPUT_VARIABLE _location
  65                 ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE)
  66         endif()
  67         if(_status)
  68             set(_location ${_find_package_module}-NOTFOUND)
  69         endif()
  70         set(${_out_var} ${_location} CACHE STRING
  71             "Location of Python module ${module}" FORCE)
  72         mark_as_advanced(${_out_var})
  73     endif()
  74     include(FindPackageHandleStandardArgs)
  75     find_package_handle_standard_args(
  76         ${_find_package_module} DEFAULT_MSG
  77         ${_out_var} PYTHON_EXECUTABLE)
  78 endfunction()