CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxBuildTreeInfo)
  56 include(gmxVersionInfo)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  62     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  63 endif()
  64
  65 include(gmxBuildTypeReference)
  66 include(gmxBuildTypeProfile)
  67 include(gmxBuildTypeTSAN)
  68 include(gmxBuildTypeASAN)
  69 include(gmxBuildTypeMSAN)
  70 include(gmxBuildTypeReleaseWithAssert)
  71
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  74     # There's no need to offer a user the choice of ThreadSanitizer
  75     # Set the possible values of build type for cmake-gui
  76     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  77         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  78 endif()
  79 if(CMAKE_CONFIGURATION_TYPES)
  80     # Add appropriate GROMACS-specific build types for the Visual
  81     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  82     # are already present by default).
  83     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  84     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  85     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  86         "List of configuration types"
  87         FORCE)
  88 endif()
  89 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  90
  91 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  92
  93 # Set a default valgrind suppression file.
  94 # This unfortunately needs to duplicate information from CTest to work as
  95 # expected...
  96 set(MEMORYCHECK_SUPPRESSIONS_FILE
  97     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  98     CACHE FILEPATH
  99     "File that contains suppressions for the memory checker")
 100 include(CTest)
 101
 102 include(gmxCPackUtilities)
 103 gmx_cpack_init()
 104
 105 # Variables that accumulate stuff influencing the installed headers
 106 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 107 set(INSTALLED_HEADER_DEFINITIONS "")
 108
 109 ########################################################################
 110 # Check and warn if cache generated on a different host is being reused
 111 ########################################################################
 112 if(CMAKE_HOST_UNIX)
 113     execute_process(COMMAND hostname
 114                     OUTPUT_VARIABLE TMP_HOSTNAME
 115                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 116     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 117         message(WARNING "
 118             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 119             is being reused! This could lead to inconsistencies; therefore, it is
 120             recommended to regenerate the cache!")
 121     endif()
 122     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 123             "Hostname of the machine where the cache was generated.")
 124 endif()
 125
 126 ########################################################################
 127 # Detect architecture before setting options so we can alter defaults
 128 ########################################################################
 129 # Detect the architecture the compiler is targetting, detect
 130 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 131 # to use if none is specified, and populate the cache option for CPU
 132 # SIMD.
 133 include(gmxDetectTargetArchitecture)
 134 gmx_detect_target_architecture()
 135
 136 # Permit the user to specify a particular standard library, e.g. compiling
 137 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 138 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 139 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 140 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 141 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 142
 143 ########################################################################
 144 # Detect CXX11 support and flags
 145 ########################################################################
 146 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 147 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 148 # invalid options with the Intel Compilers, and we have added a line
 149 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 150 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 151 # a semicolon. Since this is also used as a separator in lists inside CMake,
 152 # that string ends up being split into two separate patterns, and the last
 153 # part is just a single word that also matches other messages. We solved this
 154 # by replacing the semicolon with a period that matches any character.
 155 #
 156 # These files should be removed from the source tree when a CMake version that
 157 # includes the features in question becomes required for building GROMACS.
 158 include(CheckCCompilerFlag)
 159 include(CheckCXXCompilerFlag)
 160
 161 # This must come early, since some of our configuration flag tests
 162 # depend on being able to compile C++11 source files.
 163 include(gmxTestCXX11)
 164 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 165
 166 # Make sure all C++ code will be compiled in C++11 mode, with the
 167 # expected standard library.
 168 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 192 mark_as_advanced(GMX_FAHCORE)
 193
 194 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 195 mark_as_advanced(GMX_COOL_QUOTES)
 196 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 197
 198 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 199
 200 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 201 # GCC 4.6 requires CUDA 5.0 and VS2015 requires CUDA 8.0
 202 if(MSVC)
 203     set(REQUIRED_CUDA_VERSION 8.0)
 204 else()
 205     set(REQUIRED_CUDA_VERSION 5.0)
 206 endif()
 207 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 208
 209 # OpenCL required version: 1.1 or newer
 210 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 211
 212 if(NOT GMX_USE_OPENCL)
 213     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 214     include(gmxManageGPU)
 215     set(GMX_USE_CUDA ${GMX_GPU})
 216     if(GMX_GPU)
 217         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 218     else()
 219         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 220     endif()
 221 else()
 222     #Now the OpenCL path (for both AMD and NVIDIA)
 223     if(GMX_GPU)
 224         include(gmxManageOpenCL)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 226     else()
 227         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 228     endif()
 229 endif()
 230
 231 include(gmxDetectSimd)
 232 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 233
 234 gmx_option_multichoice(
 235     GMX_SIMD
 236     "SIMD instruction set for CPU kernels and compiler optimization"
 237     "${GMX_SUGGESTED_SIMD}"
 238     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 239
 240 if(GMX_TARGET_MIC)
 241     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 242 else()
 243     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 244 endif()
 245
 246 gmx_option_multichoice(
 247     GMX_FFT_LIBRARY
 248     "FFT library"
 249     "${GMX_FFT_LIBRARY_DEFAULT}"
 250     fftw3 mkl "fftpack[built-in]")
 251 gmx_dependent_option(
 252     GMX_BUILD_OWN_FFTW
 253     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 254     OFF
 255     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 256 gmx_dependent_option(
 257     GMX_DISABLE_FFTW_MEASURE
 258     "Do not optimize FFTW setups (not needed with SSE)"
 259     OFF
 260     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 261 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 262 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 263
 264 gmx_option_multichoice(
 265     GMX_QMMM_PROGRAM
 266     "QM package for QM/MM"
 267     None
 268     none gaussian mopac gamess orca)
 269
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 271 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 272
 273 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 274
 275 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 276 mark_as_advanced(GMX_BROKEN_CALLOC)
 277
 278 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 279
 280 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 281
 282 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 283
 284 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 285 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 286
 287 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 288 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 289
 290 option(GMX_BUILD_FOR_COVERAGE
 291        "Tune build for better code coverage metrics (e.g., disable asserts)"
 292        OFF)
 293 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 294
 295 option(GMX_DEVELOPER_BUILD
 296     "Enable Developer convenience features: always build unit-tests"
 297     OFF)
 298 mark_as_advanced(GMX_DEVELOPER_BUILD)
 299
 300 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 301 option(GMX_COMPILER_WARNINGS
 302     "Enable a default set of compiler warnings"
 303     ${GMX_COMPILER_WARNINGS_DEFAULT})
 304 mark_as_advanced(GMX_COMPILER_WARNINGS)
 305 # Always turn on compiler warnings with a developer build.
 306 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 307
 308 option(GMX_BUILD_SHARED_EXE
 309     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 310     ON)
 311 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 312
 313 ######################################################################
 314 # Detect OpenMP support
 315 ######################################################################
 316 # The OpenMP detection _must_ come before tests for other CFLAGS.
 317 include(gmxManageOpenMP)
 318
 319
 320
 321 ######################################################################
 322 # Compiler tests
 323 # These need to be done early (before further tests).
 324 #####################################################################
 325
 326 include(gmxCFlags)
 327 gmx_c_flags()
 328
 329 # This variable should be used for additional compiler flags which are not
 330 # generated in gmxCFlags nor are SIMD or MPI related.
 331 set(EXTRA_C_FLAGS "")
 332 set(EXTRA_CXX_FLAGS "")
 333
 334 # Run through a number of tests for buggy compilers and other issues
 335 include(gmxTestCompilerProblems)
 336 gmx_test_compiler_problems()
 337 # GMX_SIMD will not be set automatically until the second
 338 # pass (which is not strictly guaranteed to occur), so putting this
 339 # check here among logically-related tests is inefficient, but the
 340 # potential loss is likely zero.
 341 if(GMX_SIMD STREQUAL "AVX_256"
 342         AND CMAKE_COMPILER_IS_GNUCC
 343         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 344             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 345     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 346     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 347 endif()
 348
 349 # Implement double-precision option. This is complicated because we
 350 # need installed headers to use the precision mode of the build that
 351 # produced the library, but cannot use config.h in that case. We also
 352 # want such variables to always have a definition, because #if is more
 353 # robust than #ifdef. So, we put this value on the compiler command
 354 # line in all cases.
 355 #
 356 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 357 # because no installed header needs it
 358 if(GMX_DOUBLE)
 359     set(GMX_DOUBLE_VALUE 1)
 360 else()
 361     set(GMX_DOUBLE_VALUE 0)
 362 endif()
 363 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 364 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 365
 366 if(WIN32)
 367     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 368     add_definitions(-DGMX_HAVE_WINSOCK)
 369 endif()
 370
 371
 372
 373 ########################################################################
 374 # Basic system tests (standard libraries, headers, functions, types)   #
 375 ########################################################################
 376 include(CheckIncludeFiles)
 377 include(CheckIncludeFileCXX)
 378 check_include_files(unistd.h     HAVE_UNISTD_H)
 379 check_include_files(pwd.h        HAVE_PWD_H)
 380 check_include_files(dirent.h     HAVE_DIRENT_H)
 381 check_include_files(time.h       HAVE_TIME_H)
 382 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 383 check_include_files(io.h         HAVE_IO_H)
 384 check_include_files(sched.h      HAVE_SCHED_H)
 385
 386 check_include_files(regex.h      HAVE_POSIX_REGEX)
 387 # TODO: It could be nice to inform the user if no regex support is found,
 388 # as selections won't be fully functional.
 389
 390 include(CheckCXXSymbolExists)
 391 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 392 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 393 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 394 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 395 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 396 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 397 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 398 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 399
 400 # We cannot check for the __builtins as symbols, but check if code compiles
 401 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 402 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 403 if(MSVC)
 404     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 405     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 406 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 407     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 408     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 409 endif()
 410
 411 include(CheckLibraryExists)
 412 find_library(HAVE_LIBM m)
 413 mark_as_advanced(HAVE_LIBM)
 414 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 415 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 416
 417 include(TestSchedAffinity)
 418 test_sched_affinity(HAVE_SCHED_AFFINITY)
 419
 420 # Aligned memory allocation. We need to check for both mm_malloc(),
 421 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 422 include(gmxTestMMMalloc)
 423 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 424 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 425 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 426 if(MSVC)
 427     # No need to waste time on this test on platforms where it will never be true
 428     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 429 endif()
 430
 431 include(TestBigEndian)
 432 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 433
 434 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 435
 436 # Management of GROMACS options for specific toolchains should go
 437 # here. Because the initial settings for some of the main options have
 438 # already happened, but things like library detection and MPI compiler
 439 # feature detection have not, the docstrings for any over-rides of
 440 # GROMACS defaults or user settings will make sense. Also, any
 441 # toolchain-related reasons for choosing whether to detect various
 442 # things can be sorted out now, before the detection takes place.
 443 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 444     include(gmxManageBlueGene)
 445 endif()
 446
 447 if(GMX_TARGET_FUJITSU_SPARC64)
 448     include(gmxManageFujitsuSparc64)
 449 endif()
 450
 451 ########################################################################
 452 #Process MPI settings
 453 ########################################################################
 454 include(gmxManageMPI)
 455
 456
 457 ########################################################################
 458 #Process shared/static library settings
 459 ########################################################################
 460 include(gmxManageSharedLibraries)
 461
 462
 463 ########################################################################
 464 # Find external packages                                               #
 465 ########################################################################
 466
 467 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 468 find_package(ZLIB QUIET)
 469 include(gmxTestZLib)
 470 gmx_test_zlib(HAVE_ZLIB)
 471
 472 # Unconditionally find the package, as it is also required for unit
 473 # tests. This exports LIBXML2_FOUND, which we should not use because
 474 # it does not tell us that linking will succeed. Instead, we test that
 475 # next.
 476 #if(DEFINED LIBXML2_LIBRARIES)
 477 #  set(LibXml2_FIND_QUIETLY TRUE)
 478 #endif()
 479 #find_package(LibXml2)
 480 #include(gmxTestLibXml2)
 481 #gmx_test_libxml2(HAVE_LIBXML2)
 482 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 483 #set(PKG_XML "")
 484 #mark_as_advanced(GMX_XML)
 485 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 486 #if(GMX_XML AND NOT HAVE_LIBXML2)
 487 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 488 #endif()
 489 #if(GMX_XML)
 490 #    include_directories(${LIBXML2_INCLUDE_DIR})
 491 #    set(PKG_XML libxml-2.0)
 492 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 493 #endif()
 494
 495 if(DEFINED HWLOC_LIBRARIES)
 496   set(Hwloc_FIND_QUIETLY TRUE)
 497 endif()
 498 find_package(Hwloc 1.5)
 499 if (HWLOC_FOUND)
 500     if (HWLOC_LIBRARIES MATCHES ".a$")
 501         set(_STATIC_HWLOC TRUE)
 502     endif()
 503
 504     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 505     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 506         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 507         set(GMX_HWLOC_DEFAULT OFF)
 508     else()
 509         set(GMX_HWLOC_DEFAULT ON)
 510     endif()
 511 else()
 512     set(GMX_HWLOC_DEFAULT OFF)
 513 endif()
 514 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 515 if(GMX_HWLOC)
 516     if(HWLOC_FOUND)
 517         include_directories(${HWLOC_INCLUDE_DIRS})
 518         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 519     else()
 520         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 521     endif()
 522 endif()
 523
 524 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 525 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 526 if(GMX_EXTERNAL_TINYXML2)
 527     # Find an external TinyXML-2 library.
 528     find_package(TinyXML-2 3.0.0)
 529     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 530     if(NOT HAVE_TINYXML2)
 531         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 532     endif()
 533 endif()
 534
 535 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 536 mark_as_advanced(GMX_EXTRAE)
 537
 538 if (GMX_EXTRAE)
 539   find_package(EXTRAE)
 540   if(EXTRAE_FOUND)
 541     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 542     set(HAVE_EXTRAE 1)
 543   else()
 544     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 545   endif()
 546 endif()
 547
 548 option(GMX_X11 "Use X window system" OFF)
 549 if (GMX_X11)
 550     find_package(X11)
 551     # X11 includes/libraries are only set in the ngmx subdirectory!
 552     if(NOT X11_FOUND)
 553         message(FATAL_ERROR
 554                 "X11 include files and/or libraries were not found. "
 555                 "Set GMX_X11=OFF to compile without X11 support. "
 556                 "gmx view will not be available.")
 557     endif()
 558     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 559 endif()
 560
 561 include(ThreadMPI)
 562 # Enable core threading facilities
 563 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 564 # Enable tMPI C++ support
 565 tmpi_enable_cxx()
 566 if(GMX_THREAD_MPI)
 567     # enable MPI functions
 568     tmpi_enable()
 569     set(MPI_IN_PLACE_EXISTS 1)
 570 endif()
 571 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 572 if (TMPI_ATOMICS_DISABLED)
 573    add_definitions(-DTMPI_ATOMICS_DISABLED)
 574 endif()
 575
 576 # Note this relies on zlib detection having already run
 577 include(gmxManageTNG)
 578
 579 include(gmxManageLmfit)
 580
 581 if(GMX_GPU)
 582     # now that we have detected the dependencies, do the second configure pass
 583     gmx_gpu_setup()
 584 else()
 585     mark_as_advanced(CUDA_HOST_COMPILER)
 586 endif()
 587
 588 if(CYGWIN)
 589     set(GMX_CYGWIN 1)
 590 endif()
 591
 592 if(WIN32)
 593     set(GMX_NATIVE_WINDOWS 1)
 594     # This makes windows.h not declare min/max as macros that would break
 595     # C++ code using std::min/std::max.
 596     add_definitions(-DNOMINMAX)
 597 endif()
 598
 599 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 600     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 601         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 602     endif()
 603     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 604         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 605     endif()
 606 endif()
 607
 608 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 609 mark_as_advanced(GMX_BUILD_UNITTESTS)
 610 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 611
 612 ########################################################################
 613 # Our own GROMACS tests
 614 ########################################################################
 615
 616 add_definitions( -DHAVE_CONFIG_H )
 617 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 618 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 619 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 620 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 621
 622 include(gmxTestInlineASM)
 623 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 624
 625 include(gmxSetBuildInformation)
 626 gmx_set_build_information()
 627 # Turn on RDTSCP if:
 628 # - the build system's CPU supports it
 629 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 630 #   at this point means that the user set it).
 631 # Note: it's better to not use the later set value of GMX_SIMD because
 632 # it reflects the system's capability of both compiling and running AVX code.
 633 # TODO: After merge with 5.0 one could implement a cache variable dependency
 634 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 635 # after the first cmake pass.
 636 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 637     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 638 else()
 639     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 640 endif()
 641 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 642 mark_as_advanced(GMX_USE_RDTSCP)
 643 if(GMX_USE_RDTSCP)
 644     set(HAVE_RDTSCP 1)
 645 endif()
 646
 647 include(gmxTestLargeFiles)
 648 gmx_test_large_files(GMX_LARGEFILES)
 649
 650 include(gmxTestSignal)
 651 gmx_test_sigusr1(HAVE_SIGUSR1)
 652
 653 include(gmxTestPipes)
 654 gmx_test_pipes(HAVE_PIPES)
 655
 656 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 657
 658 include(gmxTestXDR)
 659 gmx_test_xdr(GMX_SYSTEM_XDR)
 660 if(NOT GMX_SYSTEM_XDR)
 661     set(GMX_INTERNAL_XDR 1)
 662 endif()
 663
 664
 665 ##################################################
 666 # Process SIMD instruction settings
 667 ##################################################
 668 # This checks what flags to add in order to
 669 # support the SIMD instructions we need, it sets
 670 # correct defines for the SIMD instructions supported,
 671 # and adds advanced options to control accuracy
 672 # for SIMD math operations.
 673 include(gmxManageSimd)
 674 gmx_manage_simd()
 675
 676 include(gmxManageCycleCounters)
 677 gmx_manage_cycle_counters()
 678
 679 # Process QM/MM Settings
 680 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 681     set(GMX_QMMM_GAUSSIAN 1)
 682 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 683     set(GMX_QMMM_MOPAC 1)
 684 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 685     set(GMX_QMMM_GAMESS 1)
 686 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 687     set(GMX_QMMM_ORCA 1)
 688 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 689     # nothing to do
 690 else()
 691     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 692 endif()
 693
 694
 695 ##################################################
 696 # Process FFT library settings
 697 ##################################################
 698 include(gmxManageFFTLibraries)
 699
 700
 701 include(gmxManageLinearAlgebraLibraries)
 702
 703 include(gmxManagePluginSupport)
 704
 705 if (GMX_USE_PLUGINS)
 706     if(NOT GMX_VMD_PLUGIN_PATH)
 707         find_package(VMD)
 708     endif()
 709 endif()
 710
 711 # Link real-time library for POSIX timers. The check for clock_gettime
 712 # confirms the linkability of rt.
 713 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 714     list(APPEND GMX_EXTRA_LIBRARIES rt)
 715 endif()
 716
 717 # Math and thread libraries must often come after all others when linking...
 718 if(HAVE_LIBM)
 719     list(APPEND GMX_EXTRA_LIBRARIES m)
 720 endif()
 721
 722 option(GMX_NACL "Configure for Native Client builds" OFF)
 723 if (GMX_NACL)
 724   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 725   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 726   # TODO: Is this still necessary with the check for its presence?
 727   set(GMX_USE_NICE 0)
 728   set(GMX_NO_RENAME 1)
 729 endif()
 730 mark_as_advanced(GMX_NACL)
 731
 732 if(GMX_FAHCORE)
 733   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 734       "Path to swindirect.h")
 735   include_directories(${COREWRAP_INCLUDE_DIR})
 736 endif()
 737
 738 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 739 # produce warnings if that fails.
 740 set(build_help_default AUTO)
 741 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 742     set(build_help_default OFF)
 743 endif()
 744 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 745 mark_as_advanced(GMX_BUILD_HELP)
 746 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 747     message(FATAL_ERROR
 748         "Rebuilding shell completions or man pages is not supported for "
 749         "in-source builds from a source distribution. "
 750         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 751 endif()
 752
 753 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 754 # these are set after everything else
 755 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 756     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 757     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 758     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 759     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 760 else()
 761     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 762     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 763     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 764     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 765     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 766     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 767     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 768     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 769     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 770 endif()
 771
 772 if(NOT GMX_OPENMP)
 773     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 774     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 775     unset(OpenMP_C_FLAGS CACHE)
 776     unset(OpenMP_CXX_FLAGS CACHE)
 777 else()
 778     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 779     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 780 endif()
 781
 782 ########################################################################
 783 # Specify install locations
 784 ########################################################################
 785 # Use GNUInstallDirs to set paths on multiarch systems.
 786 include(GNUInstallDirs)
 787
 788 # Customization for the installation tree paths.
 789 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 790     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 791 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 792     "Data installation directory under share/ (default: gromacs)")
 793 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 794
 795 # These variables are used internally to provide a central location for
 796 # customizing the install locations.
 797 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 798 set(BIN_INSTALL_DIR       bin)
 799 # This variable also gets written into config.h for use in finding the data
 800 # directories.
 801 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 802 set(MAN_INSTALL_DIR       share/man)
 803 # If the nesting level wrt. the installation root is changed,
 804 # gromacs-config.cmake.cmakein needs to be adapted.
 805 set(CMAKE_INSTALL_DIR     share/cmake)
 806 # TODO: Make GMXRC adapt if this is changed
 807 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 808 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 809 set(INCL_INSTALL_DIR      include)
 810
 811 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 812
 813 # Binary and library suffix options
 814 include(gmxManageSuffixes)
 815
 816 ################################################################
 817 # Shared library load path settings
 818 ################################################################
 819 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 820 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 821 # was added.
 822
 823 if(NOT GMX_BUILD_SHARED_EXE)
 824     # No rpath
 825     set(CMAKE_SKIP_RPATH TRUE)
 826     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 827     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 828 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 829    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 830     # The build folder always has bin/ and lib/; if we are also going to
 831     # install to lib/, then the installation RPATH works also in the build
 832     # tree.  This makes installation slightly faster (no need to rewrite the
 833     # RPATHs), and makes the binaries in the build tree relocatable.
 834     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 835         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 836     endif()
 837     # Set the RPATH as relative to the executable location to make the
 838     # binaries relocatable.
 839     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 840         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 841     else()
 842         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 843     endif()
 844     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 845     set(CMAKE_MACOSX_RPATH 1)
 846 else()
 847     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 848     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 849         # Set the RPATH options manually.
 850         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 851         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 852     else()
 853         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 854         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 855     endif()
 856 endif()
 857
 858 #COPYING file: Only necessary for binary distributions.
 859 #Simpler to always install.
 860 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 861
 862 if (GMX_BUILD_FOR_COVERAGE)
 863     # Code heavy with asserts makes conditional coverage close to useless metric,
 864     # as by design most of the false branches are impossible to trigger in
 865     # correctly functioning code.  And the benefit of testing those that could
 866     # be triggered by using an API against its specification isn't usually
 867     # worth the effort.
 868     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 869 endif()
 870
 871 if (BUILD_TESTING)
 872     # "tests" target builds all the separate test binaries.
 873     add_custom_target(tests)
 874     # "run-ctest" is an internal target that actually runs the tests.
 875     # This is necessary to be able to add separate targets that execute as part
 876     # of 'make check', but are ensured to be executed after the actual tests.
 877     add_custom_target(run-ctest
 878                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 879                       COMMENT "Running all tests"
 880                       VERBATIM)
 881     add_dependencies(run-ctest tests)
 882     # "check" target builds and runs all tests.
 883     add_custom_target(check DEPENDS run-ctest)
 884 endif()
 885
 886 if (NOT GMX_BUILD_MDRUN_ONLY)
 887     add_subdirectory(docs)
 888     add_subdirectory(share)
 889     add_subdirectory(scripts)
 890 endif()
 891 add_subdirectory(src)
 892
 893 if (BUILD_TESTING)
 894     add_subdirectory(tests)
 895 endif()
 896
 897 gmx_cpack_write_config()
 898
 899 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 900 # Don't bother the user after the first configure pass.
 901 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 902     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 903 endif()
 904 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 905
 906 #######################
 907 ## uninstall target
 908 #######################
 909 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 910                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 911                   IMMEDIATE @ONLY)
 912 ###########################
 913 ADD_CUSTOM_TARGET(uninstall
 914                   "${CMAKE_COMMAND}" -P
 915                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 916 ###########################
 917 set_directory_properties(PROPERTIES
 918             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")