CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # Set up common version variables, as well as general information about
  48 # the build tree (whether the build is from a source package or from a git
  49 # repository).  Also declares a few functions that will be used for generating
  50 # version info files later.
  51 include(gmxBuildTreeInfo)
  52 include(gmxVersionInfo)
  53
  54 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  55     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  56 endif()
  57 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  58     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeMSAN)
  66 include(gmxBuildTypeReleaseWithAssert)
  67
  68 if(NOT CMAKE_BUILD_TYPE)
  69     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 include(gmxCTestUtilities)
  89 gmx_ctest_init()
  90
  91 include(gmxCPackUtilities)
  92 gmx_cpack_init()
  93
  94 # Variables that accumulate stuff influencing the installed headers
  95 set(INSTALLED_HEADER_INCLUDE_DIRS "")
  96 set(INSTALLED_HEADER_DEFINITIONS "")
  97
  98 ########################################################################
  99 # Global non-cache variables for implementing the build system
 100 ########################################################################
 101
 102 # These variables collect libraries that GROMACS requires for
 103 # linking. They should be appended to with list(APPEND ${name}
 104 # new-library) calls. They are:
 105 #  - Libraries that are required for libgromacs (only)
 106 set(GMX_EXTRA_LIBRARIES "")
 107 #  - Libraries that are required for all code in the repository
 108 set(GMX_COMMON_LIBRARIES "")
 109 #  - Libraries that all code linked against libgromacs needs
 110 #    (i.e., something that is exposed in installed headers).
 111 set(GMX_PUBLIC_LIBRARIES "")
 112
 113 ########################################################################
 114 # Check and warn if cache generated on a different host is being reused
 115 ########################################################################
 116 if(CMAKE_HOST_UNIX)
 117     execute_process(COMMAND hostname
 118                     OUTPUT_VARIABLE TMP_HOSTNAME
 119                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 120     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 121         message(WARNING "
 122             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 123             is being reused! This could lead to inconsistencies; therefore, it is
 124             recommended to regenerate the cache!")
 125     endif()
 126     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 127             "Hostname of the machine where the cache was generated.")
 128 endif()
 129
 130 ########################################################################
 131 # Detect architecture before setting options so we can alter defaults
 132 ########################################################################
 133 # Detect the architecture the compiler is targetting, detect
 134 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 135 # to use if none is specified, and populate the cache option for CPU
 136 # SIMD.
 137 include(gmxDetectTargetArchitecture)
 138 gmx_detect_target_architecture()
 139
 140 # Permit the user to specify a particular standard library, e.g. compiling
 141 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 142 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 143 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 144 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 145 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 146
 147 ########################################################################
 148 # Detect CXX11 support and flags
 149 ########################################################################
 150 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 151 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 152 # invalid options with the Intel Compilers, and we have added a line
 153 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 154 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 155 # a semicolon. Since this is also used as a separator in lists inside CMake,
 156 # that string ends up being split into two separate patterns, and the last
 157 # part is just a single word that also matches other messages. We solved this
 158 # by replacing the semicolon with a period that matches any character.
 159 #
 160 # These files should be removed from the source tree when a CMake version that
 161 # includes the features in question becomes required for building GROMACS.
 162 include(CheckCCompilerFlag)
 163 include(CheckCXXCompilerFlag)
 164
 165 # This must come early, since some of our configuration flag tests
 166 # depend on being able to compile C++11 source files.
 167 include(gmxTestCXX11)
 168 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 169
 170 # Make sure all C++ code will be compiled in C++11 mode, with the
 171 # expected standard library.
 172 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 173
 174 ########################################################################
 175 # User input options                                                   #
 176 ########################################################################
 177 include(gmxOptionUtilities)
 178
 179 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 180
 181 # Fujitsu only has SIMD in double precision, so this will be faster
 182 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 183 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 184 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 185 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 186
 187 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 188 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 189 gmx_dependent_option(
 190     GMX_MPI_IN_PLACE
 191     "Enable MPI_IN_PLACE for MPIs that have it defined"
 192     ON
 193     GMX_MPI)
 194 mark_as_advanced(GMX_MPI_IN_PLACE)
 195 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 196 mark_as_advanced(GMX_FAHCORE)
 197
 198 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 199 mark_as_advanced(GMX_COOL_QUOTES)
 200 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 201
 202 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 203
 204 # Decide on GPU settings based on user-settings and GPU/CUDA
 205 # detection.  GCC 4.8 requires CUDA 6.0 (but we choose 6.5 for the
 206 # preliminary C++11 support), icc 15 requires CUDA 7.0, and VS2015
 207 # requires CUDA 8.0
 208 if(MSVC)
 209     set(REQUIRED_CUDA_VERSION 8.0)
 210 elseif(CMAKE_CXX_COMPILER_ID MATCHES "Intel")
 211     set(REQUIRED_CUDA_VERSION 7.0)
 212 else()
 213     set(REQUIRED_CUDA_VERSION 6.5)
 214 endif()
 215 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 216
 217 # OpenCL required version: 1.1 or newer
 218 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 219
 220 if(NOT GMX_USE_OPENCL)
 221     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 222     include(gmxManageGPU)
 223     set(GMX_USE_CUDA ${GMX_GPU})
 224     if(GMX_GPU)
 225         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 226     else()
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 228     endif()
 229 else()
 230     #Now the OpenCL path (for both AMD and NVIDIA)
 231     if(GMX_GPU)
 232         include(gmxManageOpenCL)
 233         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 234     else()
 235         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 236     endif()
 237 endif()
 238
 239 include(gmxDetectSimd)
 240 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 241
 242 gmx_option_multichoice(
 243     GMX_SIMD
 244     "SIMD instruction set for CPU kernels and compiler optimization"
 245     "${GMX_SUGGESTED_SIMD}"
 246     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 247
 248 if(GMX_TARGET_MIC)
 249     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 250 else()
 251     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 252 endif()
 253
 254 gmx_option_multichoice(
 255     GMX_FFT_LIBRARY
 256     "FFT library"
 257     "${GMX_FFT_LIBRARY_DEFAULT}"
 258     fftw3 mkl "fftpack[built-in]")
 259 gmx_dependent_option(
 260     GMX_BUILD_OWN_FFTW
 261     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 262     OFF
 263     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 264 gmx_dependent_option(
 265     GMX_DISABLE_FFTW_MEASURE
 266     "Do not optimize FFTW setups (not needed with SSE)"
 267     OFF
 268     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 269 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 270 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 271
 272 gmx_option_multichoice(
 273     GMX_QMMM_PROGRAM
 274     "QM package for QM/MM"
 275     None
 276     none gaussian mopac gamess orca)
 277
 278 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 279 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 280
 281 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 282
 283 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 284 mark_as_advanced(GMX_BROKEN_CALLOC)
 285
 286 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 287
 288 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 289
 290 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 291
 292 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 293 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 294
 295 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 296 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 297
 298 option(GMX_BUILD_FOR_COVERAGE
 299        "Tune build for better code coverage metrics (e.g., disable asserts)"
 300        OFF)
 301 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 302
 303 option(GMX_DEVELOPER_BUILD
 304     "Enable Developer convenience features: always build unit-tests"
 305     OFF)
 306 mark_as_advanced(GMX_DEVELOPER_BUILD)
 307
 308 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 309 option(GMX_COMPILER_WARNINGS
 310     "Enable a default set of compiler warnings"
 311     ${GMX_COMPILER_WARNINGS_DEFAULT})
 312 mark_as_advanced(GMX_COMPILER_WARNINGS)
 313 # Always turn on compiler warnings with a developer build.
 314 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 315
 316 option(GMX_BUILD_SHARED_EXE
 317     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 318     ON)
 319 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 320
 321 ######################################################################
 322 # Detect OpenMP support
 323 ######################################################################
 324 # The OpenMP detection _must_ come before tests for other CFLAGS.
 325 include(gmxManageOpenMP)
 326
 327
 328
 329 ######################################################################
 330 # Compiler tests
 331 # These need to be done early (before further tests).
 332 #####################################################################
 333
 334 include(gmxCFlags)
 335 gmx_c_flags()
 336
 337 # This variable should be used for additional compiler flags which are not
 338 # generated in gmxCFlags nor are SIMD or MPI related.
 339 set(EXTRA_C_FLAGS "")
 340 set(EXTRA_CXX_FLAGS "")
 341
 342 # Run through a number of tests for buggy compilers and other issues
 343 include(gmxTestCompilerProblems)
 344 gmx_test_compiler_problems()
 345
 346 # Implement double-precision option. This is complicated because we
 347 # need installed headers to use the precision mode of the build that
 348 # produced the library, but cannot use config.h in that case. We also
 349 # want such variables to always have a definition, because #if is more
 350 # robust than #ifdef. So, we put this value on the compiler command
 351 # line in all cases.
 352 #
 353 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 354 # because no installed header needs it
 355 if(GMX_DOUBLE)
 356     set(GMX_DOUBLE_VALUE 1)
 357 else()
 358     set(GMX_DOUBLE_VALUE 0)
 359 endif()
 360 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 361 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 362
 363 if(WIN32)
 364     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 365     add_definitions(-DGMX_HAVE_WINSOCK)
 366 endif()
 367
 368
 369
 370 ########################################################################
 371 # Basic system tests (standard libraries, headers, functions, types)   #
 372 ########################################################################
 373 include(CheckIncludeFiles)
 374 include(CheckIncludeFileCXX)
 375 check_include_files(unistd.h     HAVE_UNISTD_H)
 376 check_include_files(pwd.h        HAVE_PWD_H)
 377 check_include_files(dirent.h     HAVE_DIRENT_H)
 378 check_include_files(time.h       HAVE_TIME_H)
 379 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 380 check_include_files(io.h         HAVE_IO_H)
 381 check_include_files(sched.h      HAVE_SCHED_H)
 382
 383 check_include_files(regex.h      HAVE_POSIX_REGEX)
 384 # TODO: It could be nice to inform the user if no regex support is found,
 385 # as selections won't be fully functional.
 386
 387 include(CheckCXXSymbolExists)
 388 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 389 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 390 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 391 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 392 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 393 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 394 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 395 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 396
 397 # We cannot check for the __builtins as symbols, but check if code compiles
 398 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 399 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 400 if(MSVC)
 401     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 402     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 403 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 404     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 405     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 406 endif()
 407
 408 include(CheckLibraryExists)
 409 find_library(HAVE_LIBM m)
 410 mark_as_advanced(HAVE_LIBM)
 411 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 412 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 413
 414 include(TestSchedAffinity)
 415 test_sched_affinity(HAVE_SCHED_AFFINITY)
 416
 417 # Aligned memory allocation. We need to check for both mm_malloc(),
 418 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 419 include(gmxTestMMMalloc)
 420 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 421 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 422 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 423 if(MSVC)
 424     # No need to waste time on this test on platforms where it will never be true
 425     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 426 endif()
 427
 428 include(TestBigEndian)
 429 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 430
 431 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 432
 433 # Management of GROMACS options for specific toolchains should go
 434 # here. Because the initial settings for some of the main options have
 435 # already happened, but things like library detection and MPI compiler
 436 # feature detection have not, the docstrings for any over-rides of
 437 # GROMACS defaults or user settings will make sense. Also, any
 438 # toolchain-related reasons for choosing whether to detect various
 439 # things can be sorted out now, before the detection takes place.
 440 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 441     include(gmxManageBlueGene)
 442 endif()
 443
 444 if(GMX_TARGET_FUJITSU_SPARC64)
 445     include(gmxManageFujitsuSparc64)
 446 endif()
 447
 448 ########################################################################
 449 #Process MPI settings
 450 ########################################################################
 451 include(gmxManageMPI)
 452
 453
 454 ########################################################################
 455 #Process shared/static library settings
 456 ########################################################################
 457 include(gmxManageSharedLibraries)
 458
 459
 460 ########################################################################
 461 # Find external packages                                               #
 462 ########################################################################
 463
 464 # Unconditionally find the package, as it is also required for unit
 465 # tests. This exports LIBXML2_FOUND, which we should not use because
 466 # it does not tell us that linking will succeed. Instead, we test that
 467 # next.
 468 #if(DEFINED LIBXML2_LIBRARIES)
 469 #  set(LibXml2_FIND_QUIETLY TRUE)
 470 #endif()
 471 #find_package(LibXml2)
 472 #include(gmxTestLibXml2)
 473 #gmx_test_libxml2(HAVE_LIBXML2)
 474 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 475 #set(PKG_XML "")
 476 #mark_as_advanced(GMX_XML)
 477 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 478 #if(GMX_XML AND NOT HAVE_LIBXML2)
 479 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 480 #endif()
 481 #if(GMX_XML)
 482 #    include_directories(${LIBXML2_INCLUDE_DIR})
 483 #    set(PKG_XML libxml-2.0)
 484 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 485 #endif()
 486
 487 if(DEFINED HWLOC_LIBRARIES)
 488   set(Hwloc_FIND_QUIETLY TRUE)
 489 endif()
 490 find_package(Hwloc 1.5)
 491 if (HWLOC_FOUND)
 492     if (HWLOC_LIBRARIES MATCHES ".a$")
 493         set(_STATIC_HWLOC TRUE)
 494     endif()
 495
 496     gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 497     if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 498         message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 499         set(GMX_HWLOC_DEFAULT OFF)
 500     else()
 501         set(GMX_HWLOC_DEFAULT ON)
 502     endif()
 503 else()
 504     set(GMX_HWLOC_DEFAULT OFF)
 505 endif()
 506 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 507 if(GMX_HWLOC)
 508     if(HWLOC_FOUND)
 509         include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 510         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 511     else()
 512         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 513     endif()
 514 endif()
 515
 516 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 517 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 518 if(GMX_EXTERNAL_TINYXML2)
 519     # Find an external TinyXML-2 library.
 520     find_package(TinyXML-2 3.0.0)
 521     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 522     if(NOT HAVE_TINYXML2)
 523         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 524     endif()
 525 endif()
 526
 527 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 528 mark_as_advanced(GMX_EXTRAE)
 529
 530 if (GMX_EXTRAE)
 531   find_package(EXTRAE)
 532   if(EXTRAE_FOUND)
 533     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 534     set(HAVE_EXTRAE 1)
 535   else()
 536     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 537   endif()
 538 endif()
 539
 540 option(GMX_X11 "Use X window system" OFF)
 541 if (GMX_X11)
 542     find_package(X11)
 543     # X11 includes/libraries are only set in the ngmx subdirectory!
 544     if(NOT X11_FOUND)
 545         message(FATAL_ERROR
 546                 "X11 include files and/or libraries were not found. "
 547                 "Set GMX_X11=OFF to compile without X11 support. "
 548                 "gmx view will not be available.")
 549     endif()
 550     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 551 endif()
 552
 553 include(ThreadMPI)
 554 # Enable core threading facilities
 555 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 556 # Enable tMPI C++ support
 557 tmpi_enable_cxx()
 558 if(GMX_THREAD_MPI)
 559     # enable MPI functions
 560     tmpi_enable()
 561     set(MPI_IN_PLACE_EXISTS 1)
 562 endif()
 563 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 564 if (TMPI_ATOMICS_DISABLED)
 565    add_definitions(-DTMPI_ATOMICS_DISABLED)
 566 endif()
 567
 568 include(gmxManageTNG)
 569
 570 include(gmxManageLmfit)
 571
 572 if(GMX_GPU)
 573     # now that we have detected the dependencies, do the second configure pass
 574     gmx_gpu_setup()
 575 endif()
 576
 577 if(CYGWIN)
 578     set(GMX_CYGWIN 1)
 579 endif()
 580
 581 if(WIN32)
 582     set(GMX_NATIVE_WINDOWS 1)
 583     # This makes windows.h not declare min/max as macros that would break
 584     # C++ code using std::min/std::max.
 585     add_definitions(-DNOMINMAX)
 586 endif()
 587
 588 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 589     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 590         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 591     endif()
 592     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 593         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 594     endif()
 595 endif()
 596
 597 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 598 mark_as_advanced(GMX_BUILD_UNITTESTS)
 599 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 600
 601 ########################################################################
 602 # Our own GROMACS tests
 603 ########################################################################
 604
 605 add_definitions( -DHAVE_CONFIG_H )
 606 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 607 # TODO required at high level because both libgromacs and progs/mdrun
 608 # require it, both for thread-MPI and its atomics and mutexes.
 609 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 610 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 611 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 612
 613 include(gmxTestInlineASM)
 614 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 615
 616 include(gmxSetBuildInformation)
 617 gmx_set_build_information()
 618 # Turn on RDTSCP if:
 619 # - the build system's CPU supports it
 620 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 621 #   at this point means that the user set it).
 622 # Note: it's better to not use the later set value of GMX_SIMD because
 623 # it reflects the system's capability of both compiling and running AVX code.
 624 # TODO: After merge with 5.0 one could implement a cache variable dependency
 625 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 626 # after the first cmake pass.
 627 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 628     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 629 else()
 630     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 631 endif()
 632 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 633 mark_as_advanced(GMX_USE_RDTSCP)
 634 if(GMX_USE_RDTSCP)
 635     set(HAVE_RDTSCP 1)
 636 endif()
 637
 638 include(gmxTestLargeFiles)
 639 gmx_test_large_files(GMX_LARGEFILES)
 640
 641 include(gmxTestSignal)
 642 gmx_test_sigusr1(HAVE_SIGUSR1)
 643
 644 include(gmxTestPipes)
 645 gmx_test_pipes(HAVE_PIPES)
 646
 647 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 648
 649 include(gmxTestXDR)
 650 gmx_test_xdr(GMX_SYSTEM_XDR)
 651 if(NOT GMX_SYSTEM_XDR)
 652     set(GMX_INTERNAL_XDR 1)
 653 endif()
 654
 655
 656 ##################################################
 657 # Process SIMD instruction settings
 658 ##################################################
 659 # This checks what flags to add in order to
 660 # support the SIMD instructions we need, it sets
 661 # correct defines for the SIMD instructions supported,
 662 # and adds advanced options to control accuracy
 663 # for SIMD math operations.
 664 include(gmxManageSimd)
 665 gmx_manage_simd()
 666
 667 include(gmxManageCycleCounters)
 668 gmx_manage_cycle_counters()
 669
 670 # Process QM/MM Settings
 671 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 672     set(GMX_QMMM_GAUSSIAN 1)
 673 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 674     set(GMX_QMMM_MOPAC 1)
 675 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 676     set(GMX_QMMM_GAMESS 1)
 677 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 678     set(GMX_QMMM_ORCA 1)
 679 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 680     # nothing to do
 681 else()
 682     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 683 endif()
 684
 685
 686 ##################################################
 687 # Process FFT library settings
 688 ##################################################
 689 include(gmxManageFFTLibraries)
 690
 691
 692 include(gmxManageLinearAlgebraLibraries)
 693
 694 include(gmxManagePluginSupport)
 695
 696 if (GMX_USE_PLUGINS)
 697     if(NOT GMX_VMD_PLUGIN_PATH)
 698         find_package(VMD)
 699     endif()
 700 endif()
 701
 702 # Link real-time library for POSIX timers. The check for clock_gettime
 703 # confirms the linkability of rt.
 704 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 705     list(APPEND GMX_EXTRA_LIBRARIES rt)
 706 endif()
 707
 708 # Math and thread libraries must often come after all others when linking...
 709 if (HAVE_LIBM)
 710     list(APPEND GMX_PUBLIC_LIBRARIES m)
 711 endif()
 712
 713 option(GMX_NACL "Configure for Native Client builds" OFF)
 714 if (GMX_NACL)
 715   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 716   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 717   # TODO: Is this still necessary with the check for its presence?
 718   set(GMX_USE_NICE 0)
 719   set(GMX_NO_RENAME 1)
 720 endif()
 721 mark_as_advanced(GMX_NACL)
 722
 723 if(GMX_FAHCORE)
 724   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 725       "Path to swindirect.h")
 726   include_directories(${COREWRAP_INCLUDE_DIR})
 727 endif()
 728
 729 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 730 # produce warnings if that fails.
 731 set(build_help_default AUTO)
 732 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 733     set(build_help_default OFF)
 734 endif()
 735 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 736 mark_as_advanced(GMX_BUILD_HELP)
 737 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 738     message(FATAL_ERROR
 739         "Rebuilding shell completions or man pages is not supported for "
 740         "in-source builds from a source distribution. "
 741         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 742 endif()
 743
 744 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 745 # these are set after everything else
 746 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 747     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 748     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 749     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 750     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 751 else()
 752     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 753     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 754     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 755     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 756     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 757     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 758     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 759     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 760     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 761 endif()
 762
 763 if(NOT GMX_OPENMP)
 764     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 765     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 766     unset(OpenMP_C_FLAGS CACHE)
 767     unset(OpenMP_CXX_FLAGS CACHE)
 768 else()
 769     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 770     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 771 endif()
 772
 773 ########################################################################
 774 # Specify install locations
 775 ########################################################################
 776 # Use GNUInstallDirs to set paths on multiarch systems.
 777 include(GNUInstallDirs)
 778
 779 # Customization for the installation tree paths.
 780 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 781     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 782 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 783     "Data installation directory under share/ (default: gromacs)")
 784 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 785
 786 # These variables are used internally to provide a central location for
 787 # customizing the install locations.
 788 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 789 set(BIN_INSTALL_DIR       bin)
 790 # This variable also gets written into config.h for use in finding the data
 791 # directories.
 792 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 793 set(MAN_INSTALL_DIR       share/man)
 794 # If the nesting level wrt. the installation root is changed,
 795 # gromacs-config.cmake.cmakein needs to be adapted.
 796 set(CMAKE_INSTALL_DIR     share/cmake)
 797 # TODO: Make GMXRC adapt if this is changed
 798 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 799 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 800 set(INCL_INSTALL_DIR      include)
 801
 802 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 803
 804 # Binary and library suffix options
 805 include(gmxManageSuffixes)
 806
 807 ################################################################
 808 # Shared library load path settings
 809 ################################################################
 810 if(NOT GMX_BUILD_SHARED_EXE)
 811     # No rpath
 812     set(CMAKE_SKIP_RPATH TRUE)
 813     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 814     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 815 else()
 816     # The build folder always has bin/ and lib/; if we are also going to
 817     # install to lib/, then the installation RPATH works also in the build
 818     # tree.  This makes installation slightly faster (no need to rewrite the
 819     # RPATHs), and makes the binaries in the build tree relocatable.
 820     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 821         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 822     endif()
 823     # Set the RPATH as relative to the executable location to make the
 824     # binaries relocatable.
 825     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 826         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 827     else()
 828         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 829     endif()
 830     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 831     set(CMAKE_MACOSX_RPATH 1)
 832 endif()
 833
 834 #COPYING file: Only necessary for binary distributions.
 835 #Simpler to always install.
 836 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 837
 838 if (GMX_BUILD_FOR_COVERAGE)
 839     # Code heavy with asserts makes conditional coverage close to useless metric,
 840     # as by design most of the false branches are impossible to trigger in
 841     # correctly functioning code.  And the benefit of testing those that could
 842     # be triggered by using an API against its specification isn't usually
 843     # worth the effort.
 844     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 845 endif()
 846
 847 if (BUILD_TESTING)
 848     include(tests/CheckTarget.cmake)
 849 endif()
 850
 851 if (NOT GMX_BUILD_MDRUN_ONLY)
 852     add_subdirectory(docs)
 853     add_subdirectory(share)
 854     add_subdirectory(scripts)
 855 endif()
 856 add_subdirectory(src)
 857
 858 if (BUILD_TESTING)
 859     add_subdirectory(tests)
 860 endif()
 861
 862 gmx_cpack_write_config()
 863
 864 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 865 # Don't bother the user after the first configure pass.
 866 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 867     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 868 endif()
 869 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 870
 871 #######################
 872 ## uninstall target
 873 #######################
 874 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 875                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 876                   IMMEDIATE @ONLY)
 877 ###########################
 878 ADD_CUSTOM_TARGET(uninstall
 879                   "${CMAKE_COMMAND}" -P
 880                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 881 ###########################
 882 set_directory_properties(PROPERTIES
 883             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")