cmake/gmxDetectSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # - Check the username performing the build, as well as date and time
  36 #
  37 # gmx_detect_simd(GMX_SUGGESTED_SIMD)
  38 #
  39 # Try to detect CPU information and suggest SIMD instruction set
  40 # that fits the current CPU. This should work on all architectures
  41 # where we are not cross-compiling; depending on the architecture the
  42 # detection will either use special assembly instructions (like cpuid),
  43 # preprocessor defines, or probing /proc/cpuinfo on Linux.
  44 #
  45 # This assumes gmx_detect_target_architecture() has already been run,
  46 # so that things like GMX_TARGET_X86 are already available.
  47 # (otherwise we cannot use inline ASM on x86).
  48 #
  49 # Sets ${GMX_SUGGESTED_SIMD} in the parent scope if
  50 # GMX_SIMD is not set (e.g. by the user, or a previous run
  51 # of CMake).
  52 #
  53
  54 # we rely on inline asm support for GNU!
  55 include(gmxTestInlineASM)
  56
  57 function(gmx_suggest_simd _suggested_simd)
  58     if(${_suggested_simd})
  59         # There's already been a suggestion made, which can't change
  60         return()
  61     endif()
  62
  63     # for x86 we need inline asm to use cpuid
  64     gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
  65
  66     if(GMX_X86_GCC_INLINE_ASM)
  67         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM=1")
  68     else()
  69         set(GCC_INLINE_ASM_DEFINE "-DGMX_X86_GCC_INLINE_ASM=0")
  70     endif()
  71
  72     message(STATUS "Detecting best SIMD instructions for this CPU")
  73
  74     # Get CPU SIMD properties information
  75     if(GMX_TARGET_X86)
  76         set(GMX_TARGET_X86_VALUE 1)
  77     else()
  78         set(GMX_TARGET_X86_VALUE 0)
  79     endif()
  80     set(_compile_definitions "${GCC_INLINE_ASM_DEFINE} -I${CMAKE_SOURCE_DIR}/src -DGMX_CPUINFO_STANDALONE ${GMX_STDLIB_CXX_FLAGS} -DGMX_TARGET_X86=${GMX_TARGET_X86_VALUE}")
  81
  82     # Prepare a default suggestion
  83     set(OUTPUT_SIMD "None")
  84
  85     # We need to execute the binary, so this only works if not cross-compiling.
  86     # However, note that we are NOT limited to x86.
  87     if(NOT CMAKE_CROSSCOMPILING)
  88         # TODO Extract this try_compile to a helper function, because
  89         # it duplicates code in gmxSetBuildInformation.cmake
  90         set(GMX_DETECTSIMD_BINARY "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/GmxDetectSimd${CMAKE_EXECUTABLE_SUFFIX}")
  91         set(LINK_LIBRARIES "${GMX_STDLIB_LIBRARIES}")
  92         try_compile(GMX_DETECTSIMD_COMPILED
  93             "${CMAKE_CURRENT_BINARY_DIR}"
  94             "${CMAKE_CURRENT_SOURCE_DIR}/src/gromacs/hardware/cpuinfo.cpp"
  95             COMPILE_DEFINITIONS "${_compile_definitions}"
  96             CMAKE_FLAGS "-DLINK_LIBRARIES=${LINK_LIBRARIES}"
  97             OUTPUT_VARIABLE GMX_DETECTSIMD_COMPILED_OUTPUT
  98             COPY_FILE ${GMX_DETECTSIMD_BINARY})
  99         unset(_compile_definitions)
 100
 101         if(GMX_DETECTSIMD_COMPILED)
 102             if(NOT DEFINED GMX_DETECTSIMD_RUN)
 103                 execute_process(COMMAND ${GMX_DETECTSIMD_BINARY} "-features"
 104                     RESULT_VARIABLE GMX_DETECTSIMD_RUN
 105                     OUTPUT_VARIABLE OUTPUT_TMP
 106                     ERROR_QUIET)
 107                 set(GMX_DETECTSIMD_RUN "${GMX_DETECTSIMD_RUN}" CACHE INTERNAL "Result of running cpuinfo code to detect SIMD support")
 108                 if(GMX_DETECTSIMD_RUN EQUAL 0)
 109                     # Make a concrete suggestion of SIMD level
 110                     if(GMX_TARGET_X86)
 111                         if(OUTPUT_TMP MATCHES " avx512er ")
 112                             set(OUTPUT_SIMD "AVX_512_KNL")
 113                         elseif(OUTPUT_TMP MATCHES " avx512f ")
 114                             set(OUTPUT_SIMD "AVX_512")
 115                         elseif(OUTPUT_TMP MATCHES " avx2 ")
 116                             if(OUTPUT_TMP MATCHES " amd ")
 117                                 set(OUTPUT_SIMD "AVX2_128")
 118                             else()
 119                                 set(OUTPUT_SIMD "AVX2_256")
 120                             endif()
 121                         elseif(OUTPUT_TMP MATCHES " avx ")
 122                             if(OUTPUT_TMP MATCHES " fma4 ")
 123                                 # AMD that works better with avx-128-fma
 124                                 set(OUTPUT_SIMD "AVX_128_FMA")
 125                             else()
 126                                 # Intel
 127                                 set(OUTPUT_SIMD "AVX_256")
 128                             endif()
 129                         elseif(OUTPUT_TMP MATCHES " sse4.1 ")
 130                             set(OUTPUT_SIMD "SSE4.1")
 131                         elseif(OUTPUT_TMP MATCHES " sse2 ")
 132                             set(OUTPUT_SIMD "SSE2")
 133                         endif()
 134                     else()
 135                         if(OUTPUT_TMP MATCHES " vsx ")
 136                             set(OUTPUT_SIMD "IBM_VSX")
 137                         elseif(OUTPUT_TMP MATCHES " vmx ")
 138                             set(OUTPUT_SIMD "IBM_VMX")
 139                         elseif(OUTPUT_TMP MATCHES " qpx ")
 140                             set(OUTPUT_SIMD "IBM_QPX")
 141                         elseif(OUTPUT_TMP MATCHES " neon_asimd ")
 142                             set(OUTPUT_SIMD "ARM_NEON_ASIMD")
 143                         elseif(OUTPUT_TMP MATCHES " neon ")
 144                             set(OUTPUT_SIMD "ARM_NEON")
 145                         endif()
 146                     endif()
 147                     message(STATUS "Detected best SIMD instructions for this CPU - ${OUTPUT_SIMD}")
 148                 else()
 149                     message(WARNING "Cannot run cpuinfo code, which means no SIMD suggestion can be made.")
 150                     message(STATUS "Run output: ${OUTPUT_TMP}")
 151                 endif()
 152             endif()
 153         else()
 154             message(WARNING "Cannot compile cpuinfo code, which means no SIMD instructions.")
 155             message(STATUS "Compile output: ${GMX_DETECTSIMD_COMPILED_OUTPUT}")
 156         endif()
 157     else()
 158         message(WARNING "Cannot detect SIMD architecture for this cross-compile; you should check it manually.")
 159     endif()
 160
 161     set(${_suggested_simd} "${OUTPUT_SIMD}" CACHE INTERNAL "Suggested SIMD")
 162 endfunction()
 163
 164 function(gmx_detect_simd _suggested_simd)
 165     if(NOT DEFINED GMX_SIMD)
 166         if(GMX_TARGET_BGQ)
 167             set(${_suggested_simd} "IBM_QPX")
 168         elseif(GMX_TARGET_FUJITSU_SPARC64)
 169             # HPC-ACE is always present. In the future we
 170             # should add detection for HPC-ACE2 here.
 171             set(${_suggested_simd} "Sparc64_HPC_ACE")
 172         elseif(GMX_TARGET_MIC)
 173             set(${_suggested_simd} "MIC")
 174         else()
 175             gmx_suggest_simd(${_suggested_simd})
 176         endif()
 177
 178         set(${_suggested_simd} ${${_suggested_simd}} PARENT_SCOPE)
 179     endif()
 180 endfunction()