cmake/gmxSetBuildInformation.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # Check the username performing the build, as well as date, time, and
  36 # build CPU features.
  37 #
  38 # The following variables will be set to the user/host/cpu used for
  39 # configuration, or anonymous/unknown if it cannot be detected
  40 # (Windows).
  41 #
  42 # BUILD_TIME
  43 # BUILD_USER
  44 # BUILD_HOST
  45 # BUILD_CPU_VENDOR
  46 # BUILD_CPU_BRAND
  47 # BUILD_CPU_FAMILY
  48 # BUILD_CPU_MODEL
  49 # BUILD_CPU_STEPPING
  50 # BUILD_CPU_FEATURES
  51 #
  52
  53 include(gmxDetectCpu)
  54
  55 function(gmx_set_build_information)
  56     if(NOT BUILD_USER)
  57         if(CMAKE_HOST_UNIX)
  58             execute_process( COMMAND whoami OUTPUT_VARIABLE TMP_USER OUTPUT_STRIP_TRAILING_WHITESPACE)
  59             execute_process( COMMAND hostname OUTPUT_VARIABLE TMP_HOSTNAME OUTPUT_STRIP_TRAILING_WHITESPACE)
  60         else()
  61             set(TMP_USER "Anonymous")
  62             set(TMP_HOSTNAME "unknown")
  63         endif()
  64         set(BUILD_USER "${TMP_USER}\@${TMP_HOSTNAME} [CMAKE]" CACHE INTERNAL "Build user")
  65         message(STATUS "Setting build user - ${BUILD_USER}")
  66     endif()
  67
  68     if(NOT BUILD_TIME)
  69         STRING(TIMESTAMP TMP_TIME "%Y-%m-%d %H:%M:%S" UTC)
  70         set(BUILD_TIME "${TMP_TIME}" CACHE INTERNAL "Build date & time")
  71         message(STATUS "Setting build time - ${BUILD_TIME}")
  72     endif()
  73
  74     if(NOT BUILD_HOST)
  75         if(CMAKE_HOST_UNIX)
  76             execute_process( COMMAND uname -srm OUTPUT_VARIABLE TMP_HOST OUTPUT_STRIP_TRAILING_WHITESPACE)
  77         else()
  78             set(TMP_HOST "${CMAKE_HOST_SYSTEM} ${CMAKE_HOST_SYSTEM_PROCESSOR}")
  79         endif()
  80         set(BUILD_HOST "${TMP_HOST}" CACHE INTERNAL "Build host & architecture")
  81         message(STATUS "Setting build host - ${BUILD_HOST}")
  82     endif()
  83
  84     # Set up some defaults that will usually be overwritten
  85     if(CMAKE_CROSSCOMPILING)
  86         set(_reason ", cross-compiled")
  87     endif()
  88
  89     # Run the cpu detection. If it produces an empty output, set a
  90     # local value in the parent scope with a suitable fallback (which
  91     # hides the cached value).
  92
  93     macro(gmx_get_build_cpu_string TYPE DEFAULT_VALUE)
  94         string(TOUPPER ${TYPE} UPPERTYPE)
  95         gmx_run_cpu_detection(${TYPE})
  96         set(OUTPUT_VALUE "${DEFAULT_VALUE}")
  97         if (CPU_DETECTION_${UPPERTYPE})
  98             set(OUTPUT_VALUE ${CPU_DETECTION_${UPPERTYPE}})
  99         endif()
 100         set(BUILD_CPU_${UPPERTYPE} ${OUTPUT_VALUE} PARENT_SCOPE)
 101     endmacro()
 102
 103     gmx_get_build_cpu_string(vendor   "Unknown${_reason}")
 104     gmx_get_build_cpu_string(brand    "Unknown${_reason}")
 105     gmx_get_build_cpu_string(family   "0")
 106     gmx_get_build_cpu_string(model    "0")
 107     gmx_get_build_cpu_string(stepping "0")
 108     gmx_get_build_cpu_string(features "Unknown${_reason}")
 109 endfunction()