src/programs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2010,2011,2012,2013,2014 by the GROMACS development team.
   5 # Copyright (c) 2015,2016,2018,2019,2020, by the GROMACS development team, led by
   6 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7 # and including many others, as listed in the AUTHORS file in the
   8 # top-level source directory and at http://www.gromacs.org.
   9 #
  10 # GROMACS is free software; you can redistribute it and/or
  11 # modify it under the terms of the GNU Lesser General Public License
  12 # as published by the Free Software Foundation; either version 2.1
  13 # of the License, or (at your option) any later version.
  14 #
  15 # GROMACS is distributed in the hope that it will be useful,
  16 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 # Lesser General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU Lesser General Public
  21 # License along with GROMACS; if not, see
  22 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24 #
  25 # If you want to redistribute modifications to GROMACS, please
  26 # consider that scientific software is very special. Version
  27 # control is crucial - bugs must be traceable. We will be happy to
  28 # consider code for inclusion in the official distribution, but
  29 # derived work must not be called official GROMACS. Details are found
  30 # in the README & COPYING files - if they are missing, get the
  31 # official version at http://www.gromacs.org.
  32 #
  33 # To help us fund GROMACS development, we humbly ask that you cite
  34 # the research papers on the package. Check out http://www.gromacs.org.
  35
  36 file(GLOB MDRUN_SOURCES mdrun/*.cpp)
  37 # make an "object library" that we can re-use for multiple targets
  38 add_library(mdrun_objlib OBJECT ${MDRUN_SOURCES})
  39 gmx_target_compile_options(mdrun_objlib)
  40 target_compile_definitions(mdrun_objlib PRIVATE HAVE_CONFIG_H)
  41 target_include_directories(mdrun_objlib SYSTEM BEFORE PRIVATE ${PROJECT_SOURCE_DIR}/src/external/thread_mpi/include)
  42 # Should be possible to remove this when resolving #3290
  43 target_include_directories(mdrun_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  44
  45 if(GMX_FAHCORE)
  46     # The lack of a real source file here alongside the object library
  47     # may break some generators, according to CMake documentation. If
  48     # so, we can consider adding some dummy file to make it work.
  49     add_library(fahcore $<TARGET_OBJECTS:mdrun_objlib>)
  50     target_link_libraries(fahcore PRIVATE ${GMX_COMMON_LIBRARIES})
  51 elseif(GMX_BUILD_MDRUN_ONLY)
  52     add_executable(mdrun $<TARGET_OBJECTS:mdrun_objlib> mdrun_main.cpp)
  53     gmx_target_compile_options(mdrun)
  54     target_compile_definitions(mdrun PRIVATE HAVE_CONFIG_H)
  55     target_link_libraries(mdrun libgromacs
  56         ${GMX_COMMON_LIBRARIES}
  57         ${GMX_EXE_LINKER_FLAGS})
  58     set(BINARY_NAME "mdrun${GMX_BINARY_SUFFIX}")
  59     set_target_properties(mdrun PROPERTIES
  60         OUTPUT_NAME "${BINARY_NAME}")
  61     install(TARGETS mdrun DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT mdrun)
  62     file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  63          "complete -o nospace -F _gmx_mdrun_compl ${BINARY_NAME}")
  64     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
  65             DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
  66 else()
  67     file(GLOB GMX_MAIN_SOURCES gmx.cpp legacymodules.cpp)
  68     if(GMX_X11)
  69         file(GLOB VIEW_SOURCES view/*.cpp)
  70     else()
  71         file(GLOB VIEW_SOURCES view/view.cpp)
  72     endif()
  73     add_library(view_objlib OBJECT ${VIEW_SOURCES})
  74     gmx_target_compile_options(view_objlib)
  75     target_compile_definitions(view_objlib PRIVATE HAVE_CONFIG_H)
  76     target_include_directories(view_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  77     add_library(gmx_objlib OBJECT ${GMX_MAIN_SOURCES})
  78     target_include_directories(gmx_objlib SYSTEM PRIVATE ${PROJECT_SOURCE_DIR}/src/external)
  79     add_executable(gmx
  80         $<TARGET_OBJECTS:gmx_objlib>
  81         $<TARGET_OBJECTS:mdrun_objlib>
  82         $<TARGET_OBJECTS:view_objlib>)
  83     add_executable(Gromacs::gmx ALIAS gmx)
  84     gmx_target_compile_options(gmx)
  85     target_compile_definitions(gmx PRIVATE HAVE_CONFIG_H)
  86     target_link_libraries(gmx libgromacs
  87         ${GMX_COMMON_LIBRARIES}
  88         ${GMX_EXE_LINKER_FLAGS})
  89     if(GMX_X11)
  90         target_link_libraries(gmx ${X11_LIBRARIES})
  91     endif()
  92     set(BINARY_NAME "gmx${GMX_BINARY_SUFFIX}")
  93     set_target_properties(gmx PROPERTIES
  94         OUTPUT_NAME "${BINARY_NAME}")
  95     # Add the executable to the INSTALL target and to the libgromacs EXPORT configuration.
  96     # The GROMACS installation then provides an importable (e.g. find_package(GROMACS))
  97     # Gromacs::gmx target, which may be used as the executable COMMAND argument for functions like
  98     # add_custom_command() or add_test(). The full path to the installed binary may retrieved
  99     # from the LOCATION property or with a $<TARGET_FILE:Gromacs:gmx> generator expression
 100     # (where generator expressions are allowed).
 101     install(TARGETS gmx
 102             EXPORT libgromacs
 103             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 104
 105     ########################
 106     # Completion generation
 107
 108     include(gmxCustomCommandUtilities)
 109
 110     set(COMPLETION_DIR ${CMAKE_CURRENT_SOURCE_DIR}/completion)
 111     # Using GMX_BUILD_HELP here is somewhat confusing, but the conditions when
 112     # this can be done are exactly the same (ability to run the compiled
 113     # binaries).
 114     if (GMX_BUILD_HELP)
 115         gmx_add_custom_output_target(completion OUTPUT STAMP
 116             COMMAND ${CMAKE_COMMAND}
 117                 -D GMX_EXECUTABLE=$<TARGET_FILE:gmx>
 118                 -D ERRORS_ARE_FATAL=${GMX_BUILD_HELP_FORCE}
 119                 -P ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 120             WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 121             DEPENDS gmx ${CMAKE_CURRENT_SOURCE_DIR}/BuildCompletions.cmake
 122             COMMENT "Generating command-line completions for programs")
 123         set_target_properties(completion PROPERTIES EXCLUDE_FROM_ALL OFF)
 124         set_directory_properties(PROPERTIES
 125             ADDITIONAL_MAKE_CLEAN_FILES "completion")
 126         set(COMPLETION_DIR ${CMAKE_CURRENT_BINARY_DIR}/completion)
 127     endif()
 128     if (SOURCE_IS_SOURCE_DISTRIBUTION OR GMX_BUILD_HELP)
 129         install(DIRECTORY ${COMPLETION_DIR}/
 130                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime OPTIONAL)
 131         file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 132              "complete -o nospace -F _gmx_compl ${BINARY_NAME}")
 133         install(FILES ${CMAKE_CURRENT_BINARY_DIR}/gmx-completion-${BINARY_NAME}.bash
 134                 DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime)
 135     endif()
 136     gmx_cpack_add_generated_source_directory(completion)
 137
 138     if(BUILD_TESTING)
 139         add_subdirectory(mdrun/tests)
 140     endif()
 141 endif()