CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxBuildTreeInfo)
  56 include(gmxVersionInfo)
  57
  58 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  59     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  60 endif()
  61 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  62     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  63 endif()
  64
  65 include(gmxBuildTypeReference)
  66 include(gmxBuildTypeProfile)
  67 include(gmxBuildTypeTSAN)
  68 include(gmxBuildTypeASAN)
  69 include(gmxBuildTypeMSAN)
  70 include(gmxBuildTypeReleaseWithAssert)
  71
  72 if(NOT CMAKE_BUILD_TYPE)
  73     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135 # Permit the user to specify a particular standard library, e.g. compiling
 136 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 137 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 138 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 139 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 140 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 141
 142 ########################################################################
 143 # Detect CXX11 support and flags
 144 ########################################################################
 145 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 146 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 147 # invalid options with the Intel Compilers, and we have added a line
 148 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 149 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 150 # a semicolon. Since this is also used as a separator in lists inside CMake,
 151 # that string ends up being split into two separate patterns, and the last
 152 # part is just a single word that also matches other messages. We solved this
 153 # by replacing the semicolon with a period that matches any character.
 154 #
 155 # These files should be removed from the source tree when a CMake version that
 156 # includes the features in question becomes required for building GROMACS.
 157 include(CheckCCompilerFlag)
 158 include(CheckCXXCompilerFlag)
 159
 160 # This must come early, since some of our configuration flag tests
 161 # depend on being able to compile C++11 source files.
 162 include(gmxTestCXX11)
 163 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 164
 165 # Make sure all C++ code will be compiled in C++11 mode, with the
 166 # expected standard library.
 167 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 168
 169 ########################################################################
 170 # User input options                                                   #
 171 ########################################################################
 172 include(gmxOptionUtilities)
 173
 174 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 175
 176 # Fujitsu only has SIMD in double precision, so this will be faster
 177 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 178 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 179 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 180 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 181
 182 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 183 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 184 gmx_dependent_option(
 185     GMX_MPI_IN_PLACE
 186     "Enable MPI_IN_PLACE for MPIs that have it defined"
 187     ON
 188     GMX_MPI)
 189 mark_as_advanced(GMX_MPI_IN_PLACE)
 190 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 191 mark_as_advanced(GMX_FAHCORE)
 192
 193 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 194 mark_as_advanced(GMX_COOL_QUOTES)
 195 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 196
 197 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 198
 199 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 200 # GCC 4.6 requires CUDA 5.0 and VS2015 requires CUDA 8.0
 201 if(MSVC)
 202     set(REQUIRED_CUDA_VERSION 8.0)
 203 else()
 204     set(REQUIRED_CUDA_VERSION 5.0)
 205 endif()
 206 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 207
 208 # OpenCL required version: 1.1 or newer
 209 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 210
 211 if(NOT GMX_USE_OPENCL)
 212     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 213     include(gmxManageGPU)
 214     set(GMX_USE_CUDA ${GMX_GPU})
 215     if(GMX_GPU)
 216         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 217     else()
 218         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 219     endif()
 220 else()
 221     #Now the OpenCL path (for both AMD and NVIDIA)
 222     if(GMX_GPU)
 223         include(gmxManageOpenCL)
 224         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 225     else()
 226         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 227     endif()
 228 endif()
 229
 230 include(gmxDetectSimd)
 231 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 232
 233 gmx_option_multichoice(
 234     GMX_SIMD
 235     "SIMD instruction set for CPU kernels and compiler optimization"
 236     "${GMX_SUGGESTED_SIMD}"
 237     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 238
 239 if(GMX_TARGET_MIC)
 240     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 241 else()
 242     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 243 endif()
 244
 245 gmx_option_multichoice(
 246     GMX_FFT_LIBRARY
 247     "FFT library"
 248     "${GMX_FFT_LIBRARY_DEFAULT}"
 249     fftw3 mkl "fftpack[built-in]")
 250 gmx_dependent_option(
 251     GMX_BUILD_OWN_FFTW
 252     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 253     OFF
 254     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 255 gmx_dependent_option(
 256     GMX_DISABLE_FFTW_MEASURE
 257     "Do not optimize FFTW setups (not needed with SSE)"
 258     OFF
 259     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 260 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 261 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 262
 263 gmx_option_multichoice(
 264     GMX_QMMM_PROGRAM
 265     "QM package for QM/MM"
 266     None
 267     none gaussian mopac gamess orca)
 268
 269 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 270 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 271
 272 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 273
 274 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 275 mark_as_advanced(GMX_BROKEN_CALLOC)
 276 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 277 mark_as_advanced(GMX_LOAD_PLUGINS)
 278
 279 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 280
 281 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 282
 283 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 284
 285 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 286 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 287
 288 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 289 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 290
 291 option(GMX_BUILD_FOR_COVERAGE
 292        "Tune build for better code coverage metrics (e.g., disable asserts)"
 293        OFF)
 294 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 295
 296 option(GMX_DEVELOPER_BUILD
 297     "Enable Developer convenience features: always build unit-tests"
 298     OFF)
 299 mark_as_advanced(GMX_DEVELOPER_BUILD)
 300
 301 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 302 option(GMX_COMPILER_WARNINGS
 303     "Enable a default set of compiler warnings"
 304     ${GMX_COMPILER_WARNINGS_DEFAULT})
 305 mark_as_advanced(GMX_COMPILER_WARNINGS)
 306 # Always turn on compiler warnings with a developer build.
 307 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 308
 309 option(GMX_BUILD_SHARED_EXE
 310     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 311     ON)
 312 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 313
 314 ######################################################################
 315 # Detect OpenMP support
 316 ######################################################################
 317 # The OpenMP detection _must_ come before tests for other CFLAGS.
 318 include(gmxManageOpenMP)
 319
 320
 321
 322 ######################################################################
 323 # Compiler tests
 324 # These need to be done early (before further tests).
 325 #####################################################################
 326
 327 include(gmxCFlags)
 328 gmx_c_flags()
 329
 330 # This variable should be used for additional compiler flags which are not
 331 # generated in gmxCFlags nor are SIMD or MPI related.
 332 set(EXTRA_C_FLAGS "")
 333 set(EXTRA_CXX_FLAGS "")
 334
 335 # Run through a number of tests for buggy compilers and other issues
 336 include(gmxTestCompilerProblems)
 337 gmx_test_compiler_problems()
 338 # GMX_SIMD will not be set automatically until the second
 339 # pass (which is not strictly guaranteed to occur), so putting this
 340 # check here among logically-related tests is inefficient, but the
 341 # potential loss is likely zero.
 342 if(GMX_SIMD STREQUAL "AVX_256"
 343         AND CMAKE_COMPILER_IS_GNUCC
 344         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 345             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 346     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 347     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 348 endif()
 349
 350 # Implement double-precision option. This is complicated because we
 351 # need installed headers to use the precision mode of the build that
 352 # produced the library, but cannot use config.h in that case. We also
 353 # want such variables to always have a definition, because #if is more
 354 # robust than #ifdef. So, we put this value on the compiler command
 355 # line in all cases.
 356 #
 357 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 358 # because no installed header needs it
 359 if(GMX_DOUBLE)
 360     set(GMX_DOUBLE_VALUE 1)
 361 else()
 362     set(GMX_DOUBLE_VALUE 0)
 363 endif()
 364 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 365 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 366
 367 if(WIN32)
 368     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 369     add_definitions(-DGMX_HAVE_WINSOCK)
 370 endif()
 371
 372
 373
 374 ########################################################################
 375 # Basic system tests (standard libraries, headers, functions, types)   #
 376 ########################################################################
 377 include(CheckIncludeFiles)
 378 include(CheckIncludeFileCXX)
 379 check_include_files(unistd.h     HAVE_UNISTD_H)
 380 check_include_files(pwd.h        HAVE_PWD_H)
 381 check_include_files(dirent.h     HAVE_DIRENT_H)
 382 check_include_files(time.h       HAVE_TIME_H)
 383 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 384 check_include_files(io.h         HAVE_IO_H)
 385 check_include_files(sched.h      HAVE_SCHED_H)
 386
 387 check_include_files(regex.h      HAVE_POSIX_REGEX)
 388 # TODO: It could be nice to inform the user if no regex support is found,
 389 # as selections won't be fully functional.
 390
 391 include(CheckCXXSymbolExists)
 392 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 393 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 394 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 395 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 396 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 397 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 398 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 399 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 400
 401 # We cannot check for the __builtins as symbols, but check if code compiles
 402 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 403 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 404 if(MSVC)
 405     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 406     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 407 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 408     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 409     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 410 endif()
 411
 412 include(CheckLibraryExists)
 413 find_library(HAVE_LIBM m)
 414 mark_as_advanced(HAVE_LIBM)
 415 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 416 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 417
 418 include(TestSchedAffinity)
 419 test_sched_affinity(HAVE_SCHED_AFFINITY)
 420
 421 # Aligned memory allocation. We need to check for both mm_malloc(),
 422 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 423 include(gmxTestMMMalloc)
 424 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 425 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 426 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 427 if(MSVC)
 428     # No need to waste time on this test on platforms where it will never be true
 429     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 430 endif()
 431
 432 include(TestBigEndian)
 433 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 434
 435 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 436
 437 # Management of GROMACS options for specific toolchains should go
 438 # here. Because the initial settings for some of the main options have
 439 # already happened, but things like library detection and MPI compiler
 440 # feature detection have not, the docstrings for any over-rides of
 441 # GROMACS defaults or user settings will make sense. Also, any
 442 # toolchain-related reasons for choosing whether to detect various
 443 # things can be sorted out now, before the detection takes place.
 444 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 445     include(gmxManageBlueGene)
 446 endif()
 447
 448 if(GMX_TARGET_FUJITSU_SPARC64)
 449     include(gmxManageFujitsuSparc64)
 450 endif()
 451
 452 ########################################################################
 453 #Process MPI settings
 454 ########################################################################
 455 include(gmxManageMPI)
 456
 457
 458 ########################################################################
 459 #Process shared/static library settings
 460 ########################################################################
 461 include(gmxManageSharedLibraries)
 462
 463
 464 ########################################################################
 465 # Find external packages                                               #
 466 ########################################################################
 467
 468 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 469 find_package(ZLIB QUIET)
 470 include(gmxTestZLib)
 471 gmx_test_zlib(HAVE_ZLIB)
 472
 473 # Unconditionally find the package, as it is also required for unit
 474 # tests. This exports LIBXML2_FOUND, which we should not use because
 475 # it does not tell us that linking will succeed. Instead, we test that
 476 # next.
 477 #if(DEFINED LIBXML2_LIBRARIES)
 478 #  set(LibXml2_FIND_QUIETLY TRUE)
 479 #endif()
 480 #find_package(LibXml2)
 481 #include(gmxTestLibXml2)
 482 #gmx_test_libxml2(HAVE_LIBXML2)
 483 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 484 #set(PKG_XML "")
 485 #mark_as_advanced(GMX_XML)
 486 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 487 #if(GMX_XML AND NOT HAVE_LIBXML2)
 488 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 489 #endif()
 490 #if(GMX_XML)
 491 #    include_directories(${LIBXML2_INCLUDE_DIR})
 492 #    set(PKG_XML libxml-2.0)
 493 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 494 #endif()
 495
 496 if(DEFINED HWLOC_LIBRARIES)
 497   set(Hwloc_FIND_QUIETLY TRUE)
 498 endif()
 499 find_package(Hwloc 1.5)
 500 if(HWLOC_FOUND)
 501     set(GMX_HWLOC_DEFAULT ON)
 502 else()
 503     set(GMX_HWLOC_DEFAULT OFF)
 504 endif()
 505 option(GMX_HWLOC "Add support for hwloc Portable Hardware locality library" ${GMX_HWLOC_DEFAULT})
 506 if(GMX_HWLOC)
 507     if(HWLOC_FOUND)
 508         include_directories(${HWLOC_INCLUDE_DIRS})
 509         list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 510     else()
 511         message(FATAL_ERROR "Hwloc package support requested, but not found.")
 512     endif()
 513 endif()
 514
 515 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 516 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 517 if(GMX_EXTERNAL_TINYXML2)
 518     # Find an external TinyXML-2 library.
 519     find_package(TinyXML-2 3.0.0)
 520     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 521     if(NOT HAVE_TINYXML2)
 522         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 523     endif()
 524 endif()
 525
 526 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 527 mark_as_advanced(GMX_EXTRAE)
 528
 529 if (GMX_EXTRAE)
 530   find_package(EXTRAE)
 531   if(EXTRAE_FOUND)
 532     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 533     set(HAVE_EXTRAE 1)
 534   else()
 535     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 536   endif()
 537 endif()
 538
 539 option(GMX_X11 "Use X window system" OFF)
 540 if (GMX_X11)
 541     find_package(X11)
 542     # X11 includes/libraries are only set in the ngmx subdirectory!
 543     if(NOT X11_FOUND)
 544         message(FATAL_ERROR
 545                 "X11 include files and/or libraries were not found. "
 546                 "Set GMX_X11=OFF to compile without X11 support. "
 547                 "gmx view will not be available.")
 548     endif()
 549     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 550 endif()
 551
 552 include(ThreadMPI)
 553 # Enable core threading facilities
 554 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 555 # Enable tMPI C++ support
 556 tmpi_enable_cxx()
 557 if(GMX_THREAD_MPI)
 558     # enable MPI functions
 559     tmpi_enable()
 560     set(MPI_IN_PLACE_EXISTS 1)
 561 endif()
 562 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 563 if (TMPI_ATOMICS_DISABLED)
 564    add_definitions(-DTMPI_ATOMICS_DISABLED)
 565 endif()
 566
 567 # Note this relies on zlib detection having already run
 568 include(gmxManageTNG)
 569
 570 include(gmxManageLmfit)
 571
 572 if(GMX_GPU)
 573     # now that we have detected the dependencies, do the second configure pass
 574     gmx_gpu_setup()
 575 else()
 576     mark_as_advanced(CUDA_HOST_COMPILER)
 577 endif()
 578
 579 if(CYGWIN)
 580     set(GMX_CYGWIN 1)
 581 endif()
 582
 583 if(WIN32)
 584     set(GMX_NATIVE_WINDOWS 1)
 585     # This makes windows.h not declare min/max as macros that would break
 586     # C++ code using std::min/std::max.
 587     add_definitions(-DNOMINMAX)
 588 endif()
 589
 590 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 591     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 592         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 593     endif()
 594     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 595         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 596     endif()
 597 endif()
 598
 599 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 600 mark_as_advanced(GMX_BUILD_UNITTESTS)
 601 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 602
 603 ########################################################################
 604 # Our own GROMACS tests
 605 ########################################################################
 606
 607 add_definitions( -DHAVE_CONFIG_H )
 608 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 609 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 610 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 611 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 612
 613 include(gmxTestInlineASM)
 614 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 615
 616 include(gmxSetBuildInformation)
 617 gmx_set_build_information()
 618 # Turn on RDTSCP if:
 619 # - the build system's CPU supports it
 620 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 621 #   at this point means that the user set it).
 622 # Note: it's better to not use the later set value of GMX_SIMD because
 623 # it reflects the system's capability of both compiling and running AVX code.
 624 # TODO: After merge with 5.0 one could implement a cache variable dependency
 625 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 626 # after the first cmake pass.
 627 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 628     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 629 else()
 630     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 631 endif()
 632 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 633 mark_as_advanced(GMX_USE_RDTSCP)
 634 if(GMX_USE_RDTSCP)
 635     set(HAVE_RDTSCP 1)
 636 endif()
 637
 638 include(gmxTestLargeFiles)
 639 gmx_test_large_files(GMX_LARGEFILES)
 640
 641 include(gmxTestSignal)
 642 gmx_test_sigusr1(HAVE_SIGUSR1)
 643
 644 include(gmxTestPipes)
 645 gmx_test_pipes(HAVE_PIPES)
 646
 647 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 648
 649 include(gmxTestXDR)
 650 gmx_test_xdr(GMX_SYSTEM_XDR)
 651 if(NOT GMX_SYSTEM_XDR)
 652     set(GMX_INTERNAL_XDR 1)
 653 endif()
 654
 655
 656 ##################################################
 657 # Process SIMD instruction settings
 658 ##################################################
 659 # This checks what flags to add in order to
 660 # support the SIMD instructions we need, it sets
 661 # correct defines for the SIMD instructions supported,
 662 # and adds advanced options to control accuracy
 663 # for SIMD math operations.
 664 include(gmxManageSimd)
 665 gmx_manage_simd()
 666
 667 include(gmxManageCycleCounters)
 668 gmx_manage_cycle_counters()
 669
 670 # Process QM/MM Settings
 671 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 672     set(GMX_QMMM_GAUSSIAN 1)
 673 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 674     set(GMX_QMMM_MOPAC 1)
 675 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 676     set(GMX_QMMM_GAMESS 1)
 677 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 678     set(GMX_QMMM_ORCA 1)
 679 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 680     # nothing to do
 681 else()
 682     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 683 endif()
 684
 685
 686 ##################################################
 687 # Process FFT library settings
 688 ##################################################
 689 include(gmxManageFFTLibraries)
 690
 691
 692 include(gmxManageLinearAlgebraLibraries)
 693
 694 # Whether GROMACS will really try to compile support for VMD plugins
 695 set(GMX_USE_PLUGINS OFF)
 696
 697 if(GMX_LOAD_PLUGINS)
 698   if(NOT WIN32)
 699     # Native Windows does not have, nor need dlopen
 700     include(gmxTestdlopen)
 701     gmx_test_dlopen(HAVE_DLOPEN)
 702   endif()
 703
 704   # so, should we use plug-ins?
 705   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 706     if(NOT VMD_QUIETLY)
 707       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 708     endif()
 709     if(NOT GMX_VMD_PLUGIN_PATH)
 710       find_package(VMD)
 711     endif()
 712     set(GMX_USE_PLUGINS ON)
 713     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 714     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 715   else()
 716     set(PKG_DL_LIBS)
 717   endif()
 718 endif()
 719 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 720
 721 # Link real-time library for POSIX timers. The check for clock_gettime
 722 # confirms the linkability of rt.
 723 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 724     list(APPEND GMX_EXTRA_LIBRARIES rt)
 725 endif()
 726
 727 # Math and thread libraries must often come after all others when linking...
 728 if(HAVE_LIBM)
 729     list(APPEND GMX_EXTRA_LIBRARIES m)
 730 endif()
 731
 732 option(GMX_NACL "Configure for Native Client builds" OFF)
 733 if (GMX_NACL)
 734   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 735   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 736   # TODO: Is this still necessary with the check for its presence?
 737   set(GMX_USE_NICE 0)
 738   set(GMX_NO_RENAME 1)
 739 endif()
 740 mark_as_advanced(GMX_NACL)
 741
 742 if(GMX_FAHCORE)
 743   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 744       "Path to swindirect.h")
 745   include_directories(${COREWRAP_INCLUDE_DIR})
 746 endif()
 747
 748 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 749 # produce warnings if that fails.
 750 set(build_help_default AUTO)
 751 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 752     set(build_help_default OFF)
 753 endif()
 754 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 755 mark_as_advanced(GMX_BUILD_HELP)
 756 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 757     message(FATAL_ERROR
 758         "Rebuilding shell completions or man pages is not supported for "
 759         "in-source builds from a source distribution. "
 760         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 761 endif()
 762
 763 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 764 # these are set after everything else
 765 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 766     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 767     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 768     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 769     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 770 else()
 771     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 772     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 773     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 774     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 775     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 776     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 777     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 778     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 779     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 780 endif()
 781
 782 if(NOT GMX_OPENMP)
 783     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 784     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 785     unset(OpenMP_C_FLAGS CACHE)
 786     unset(OpenMP_CXX_FLAGS CACHE)
 787 else()
 788     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 789     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 790 endif()
 791
 792 ########################################################################
 793 # Specify install locations
 794 ########################################################################
 795 # Use GNUInstallDirs to set paths on multiarch systems.
 796 include(GNUInstallDirs)
 797
 798 # Customization for the installation tree paths.
 799 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 800     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 801 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 802     "Data installation directory under share/ (default: gromacs)")
 803 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 804
 805 # These variables are used internally to provide a central location for
 806 # customizing the install locations.
 807 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 808 set(BIN_INSTALL_DIR       bin)
 809 # This variable also gets written into config.h for use in finding the data
 810 # directories.
 811 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 812 set(MAN_INSTALL_DIR       share/man)
 813 # If the nesting level wrt. the installation root is changed,
 814 # gromacs-config.cmake.cmakein needs to be adapted.
 815 set(CMAKE_INSTALL_DIR     share/cmake)
 816 # TODO: Make GMXRC adapt if this is changed
 817 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 818 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 819 set(INCL_INSTALL_DIR      include)
 820
 821 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 822
 823 # Binary and library suffix options
 824 include(gmxManageSuffixes)
 825
 826 ################################################################
 827 # Shared library load path settings
 828 ################################################################
 829 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 830 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 831 # was added.
 832
 833 if(NOT GMX_BUILD_SHARED_EXE)
 834     # No rpath
 835     set(CMAKE_SKIP_RPATH TRUE)
 836     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 837     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 838 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 839    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 840     # The build folder always has bin/ and lib/; if we are also going to
 841     # install to lib/, then the installation RPATH works also in the build
 842     # tree.  This makes installation slightly faster (no need to rewrite the
 843     # RPATHs), and makes the binaries in the build tree relocatable.
 844     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 845         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 846     endif()
 847     # Set the RPATH as relative to the executable location to make the
 848     # binaries relocatable.
 849     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 850         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 851     else()
 852         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 853     endif()
 854     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 855     set(CMAKE_MACOSX_RPATH 1)
 856 else()
 857     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 858     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 859         # Set the RPATH options manually.
 860         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 861         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 862     else()
 863         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 864         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 865     endif()
 866 endif()
 867
 868 #COPYING file: Only necessary for binary distributions.
 869 #Simpler to always install.
 870 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 871
 872 if (GMX_BUILD_FOR_COVERAGE)
 873     # Code heavy with asserts makes conditional coverage close to useless metric,
 874     # as by design most of the false branches are impossible to trigger in
 875     # correctly functioning code.  And the benefit of testing those that could
 876     # be triggered by using an API against its specification isn't usually
 877     # worth the effort.
 878     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 879 endif()
 880
 881 if (BUILD_TESTING)
 882     # "tests" target builds all the separate test binaries.
 883     add_custom_target(tests)
 884     # "run-ctest" is an internal target that actually runs the tests.
 885     # This is necessary to be able to add separate targets that execute as part
 886     # of 'make check', but are ensured to be executed after the actual tests.
 887     add_custom_target(run-ctest
 888                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 889                       COMMENT "Running all tests"
 890                       VERBATIM)
 891     add_dependencies(run-ctest tests)
 892     # "check" target builds and runs all tests.
 893     add_custom_target(check DEPENDS run-ctest)
 894 endif()
 895
 896 if (NOT GMX_BUILD_MDRUN_ONLY)
 897     add_subdirectory(docs)
 898     add_subdirectory(share)
 899     add_subdirectory(scripts)
 900 endif()
 901 add_subdirectory(src)
 902
 903 if (BUILD_TESTING)
 904     add_subdirectory(tests)
 905 endif()
 906
 907 gmx_cpack_write_config()
 908
 909 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 910 # Don't bother the user after the first configure pass.
 911 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 912     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 913 endif()
 914 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 915
 916 #######################
 917 ## uninstall target
 918 #######################
 919 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 920                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 921                   IMMEDIATE @ONLY)
 922 ###########################
 923 ADD_CUSTOM_TARGET(uninstall
 924                   "${CMAKE_COMMAND}" -P
 925                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 926 ###########################
 927 set_directory_properties(PROPERTIES
 928             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")