CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5 # Copyright (c) 2014,2015,2016,2017,2018 by the GROMACS development team.
   6 # Copyright (c) 2019,2020, by the GROMACS development team, led by
   7 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   8 # and including many others, as listed in the AUTHORS file in the
   9 # top-level source directory and at http://www.gromacs.org.
  10 #
  11 # GROMACS is free software; you can redistribute it and/or
  12 # modify it under the terms of the GNU Lesser General Public License
  13 # as published by the Free Software Foundation; either version 2.1
  14 # of the License, or (at your option) any later version.
  15 #
  16 # GROMACS is distributed in the hope that it will be useful,
  17 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 # Lesser General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU Lesser General Public
  22 # License along with GROMACS; if not, see
  23 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  24 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  25 #
  26 # If you want to redistribute modifications to GROMACS, please
  27 # consider that scientific software is very special. Version
  28 # control is crucial - bugs must be traceable. We will be happy to
  29 # consider code for inclusion in the official distribution, but
  30 # derived work must not be called official GROMACS. Details are found
  31 # in the README & COPYING files - if they are missing, get the
  32 # official version at http://www.gromacs.org.
  33 #
  34 # To help us fund GROMACS development, we humbly ask that you cite
  35 # the research papers on the package. Check out http://www.gromacs.org.
  36
  37 cmake_minimum_required(VERSION 3.13)
  38 cmake_policy(SET CMP0074 NEW) # From CMake 3.12
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.14 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.14 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags."
  50         FORCE)
  51     # By default, limit the binary architecture to a single 64-bit build.
  52     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  54         FORCE)
  55 endif()
  56
  57 project(Gromacs)
  58
  59 set(CMAKE_CXX_STANDARD 17)
  60 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  61 set(CMAKE_CXX_EXTENSIONS OFF)
  62
  63 include(gmxManageCcache)
  64
  65 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  67 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  68
  69 find_package(LibStdCpp)
  70
  71 # Python is first referenced in gmxVersionInfo, so we perform the search early
  72 # to find a suitable installation for all components.
  73 include(gmxPythonDiscovery)
  74 # Set up common version variables, as well as general information about
  75 # the build tree (whether the build is from a source package or from a git
  76 # repository).  Also declares a few functions that will be used for generating
  77 # version info files later.
  78 include(gmxBuildTreeInfo)
  79 include(gmxVersionInfo)
  80
  81 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  82     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  83 endif()
  84 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  85     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  86 endif()
  87
  88 include(gmxBuildTypeReference)
  89 include(gmxBuildTypeProfile)
  90 include(gmxBuildTypeTSAN)
  91 include(gmxBuildTypeASAN)
  92 include(gmxBuildTypeMSAN)
  93 include(gmxBuildTypeReleaseWithAssert)
  94
  95 if(NOT CMAKE_BUILD_TYPE)
  96     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  97     # Set the possible values of build type for cmake-gui
  98     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  99         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
 100 endif()
 101 if(CMAKE_CONFIGURATION_TYPES)
 102     # Add appropriate GROMACS-specific build types for the Visual
 103     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 104     # are already present by default).
 105     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 106     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 107     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 108         "List of configuration types"
 109         FORCE)
 110 endif()
 111 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 112
 113 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 114
 115 include(gmxCTestUtilities)
 116 gmx_ctest_init()
 117
 118 include(gmxCPackUtilities)
 119 gmx_cpack_init()
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Global non-cache variables for implementing the build system
 127 ########################################################################
 128
 129 # These variables collect libraries that GROMACS requires for
 130 # linking. They should be appended to with list(APPEND ${name}
 131 # new-library) calls. They are:
 132 #  - Libraries that are required for libgromacs (only)
 133 set(GMX_EXTRA_LIBRARIES "")
 134 #  - Libraries that are required for all code in the repository
 135 set(GMX_COMMON_LIBRARIES "")
 136 #  - Libraries that all code linked against libgromacs needs
 137 #    (i.e., something that is exposed in installed headers).
 138 set(GMX_PUBLIC_LIBRARIES "")
 139
 140 ########################################################################
 141 # Check and warn if cache generated on a different host is being reused
 142 ########################################################################
 143 if(CMAKE_HOST_UNIX)
 144     execute_process(COMMAND hostname
 145                     OUTPUT_VARIABLE TMP_HOSTNAME
 146                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 147     # Only check for host name if not running in a CI environment, as the cache might
 148     # be reused there between different machines in different stages
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}"
 150             AND NOT DEFINED ENV{CI_JOB_ID})
 151         message(WARNING "
 152             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 153             is being reused! This could lead to inconsistencies; therefore, it is
 154             recommended to regenerate the cache!")
 155     endif()
 156     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 157             "Hostname of the machine where the cache was generated.")
 158 endif()
 159
 160 ########################################################################
 161 # Detect architecture before setting options so we can alter defaults
 162 ########################################################################
 163 # Detect the architecture the compiler is targetting, detect
 164 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 165 # to use if none is specified, and populate the cache option for CPU
 166 # SIMD.
 167 include(gmxDetectTargetArchitecture)
 168 gmx_detect_target_architecture()
 169
 170 ########################################################################
 171 # User input options                                                   #
 172 ########################################################################
 173 include(gmxOptionUtilities)
 174
 175 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 176
 177 # Fujitsu only has SIMD in double precision, so this will be faster
 178 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 179 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 180 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 181 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 182
 183 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 184 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 185 gmx_dependent_option(
 186     GMX_MPI_IN_PLACE
 187     "Enable MPI_IN_PLACE for MPIs that have it defined"
 188     ON
 189     GMX_MPI)
 190 mark_as_advanced(GMX_MPI_IN_PLACE)
 191
 192 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 193
 194 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 195 mark_as_advanced(GMX_FAHCORE)
 196
 197 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 198 mark_as_advanced(GMX_COOL_QUOTES)
 199 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 200
 201 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 202
 203 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 204
 205 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 206 set(REQUIRED_CUDA_VERSION 9.0)
 207 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 208
 209 # OpenCL required version: 1.2 or newer
 210 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 211 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 212 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 213
 214 if(NOT GMX_USE_OPENCL)
 215     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 216     include(gmxManageGPU)
 217     set(GMX_USE_CUDA ${GMX_GPU})
 218     if(GMX_GPU)
 219         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 220     else()
 221         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 222     endif()
 223 else()
 224     #Now the OpenCL path (for both AMD and NVIDIA)
 225     if(GMX_GPU)
 226         include(gmxManageOpenCL)
 227         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 228     else()
 229         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 230     endif()
 231 endif()
 232
 233 gmx_option_multichoice(
 234     GMX_SIMD
 235     "SIMD instruction set for CPU kernels and compiler optimization"
 236     "AUTO"
 237     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 238
 239 if(GMX_TARGET_MIC)
 240     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 241 else()
 242     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 243 endif()
 244
 245 gmx_option_multichoice(
 246     GMX_FFT_LIBRARY
 247     "FFT library"
 248     "${GMX_FFT_LIBRARY_DEFAULT}"
 249     fftw3 mkl "fftpack[built-in]")
 250 gmx_dependent_option(
 251     GMX_BUILD_OWN_FFTW
 252     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 253     OFF
 254     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 255 gmx_dependent_option(
 256     GMX_DISABLE_FFTW_MEASURE
 257     "Do not optimize FFTW setups (not needed with SSE)"
 258     OFF
 259     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 260 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 261 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 262
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 264 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 265
 266 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 267
 268 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 269 mark_as_advanced(GMX_BROKEN_CALLOC)
 270
 271 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 272
 273 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 274
 275 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 276
 277 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 278 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 279
 280 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 281 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 282
 283 option(GMX_BUILD_FOR_COVERAGE
 284        "Tune build for better code coverage metrics (e.g., disable asserts)"
 285        OFF)
 286 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 287
 288 option(GMX_DEVELOPER_BUILD
 289     "Enable Developer convenience features: always build unit-tests"
 290     OFF)
 291 mark_as_advanced(GMX_DEVELOPER_BUILD)
 292
 293 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 294 option(GMX_COMPILER_WARNINGS
 295     "Enable a default set of compiler warnings"
 296     ${GMX_COMPILER_WARNINGS_DEFAULT})
 297 mark_as_advanced(GMX_COMPILER_WARNINGS)
 298 # Always turn on compiler warnings with a developer build.
 299 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 300
 301 option(GMX_BUILD_SHARED_EXE
 302     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 303     ON)
 304 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 305
 306 option(GMX_PHYSICAL_VALIDATION
 307        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 308        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 309        OFF)
 310 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 311
 312 ######################################################################
 313 # Detect OpenMP support
 314 ######################################################################
 315 # The OpenMP detection _must_ come before tests for other CFLAGS.
 316 include(gmxManageOpenMP)
 317
 318
 319
 320 ######################################################################
 321 # Compiler tests
 322 # These need to be done early (before further tests).
 323 #####################################################################
 324
 325 include(gmxCFlags)
 326 gmx_c_flags()
 327
 328 # These variables should be used for CMake-style lists (ie. separated
 329 # by semicolons) of additional compiler flags which are not generated
 330 # in gmxCFlags nor are SIMD or MPI related.
 331 #
 332 # TODO These variables should be consolidated into
 333 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 334 # things that work in C compilation (e.g. merging from old branches)
 335 # might not also work for C++ compilation.
 336 set(EXTRA_C_FLAGS "")
 337 set(EXTRA_CXX_FLAGS "")
 338
 339 # Run through a number of tests for buggy compilers and other issues
 340 include(gmxTestCompilerProblems)
 341 gmx_test_compiler_problems()
 342
 343 # Implement double-precision option. This is complicated because we
 344 # need installed headers to use the precision mode of the build that
 345 # produced the library, but cannot use config.h in that case. We also
 346 # want such variables to always have a definition, because #if is more
 347 # robust than #ifdef. So, we put this value on the compiler command
 348 # line in all cases.
 349 #
 350 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 351 # because no installed header needs it
 352 if(GMX_DOUBLE)
 353     set(GMX_DOUBLE_VALUE 1)
 354 else()
 355     set(GMX_DOUBLE_VALUE 0)
 356 endif()
 357 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 358 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 359
 360 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 361 if(GMX_IMD AND WIN32)
 362     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 363 endif()
 364
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 include(CheckIncludeFileCXX)
 372 check_include_files(unistd.h     HAVE_UNISTD_H)
 373 check_include_files(pwd.h        HAVE_PWD_H)
 374 check_include_files(dirent.h     HAVE_DIRENT_H)
 375 check_include_files(time.h       HAVE_TIME_H)
 376 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 377 check_include_files(io.h         HAVE_IO_H)
 378 check_include_files(sched.h      HAVE_SCHED_H)
 379 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 380
 381 include(CheckCXXSymbolExists)
 382 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 383 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 384 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 385 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 386 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 387 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 388 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 389 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 390
 391 # We cannot check for the __builtins as symbols, but check if code compiles
 392 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 393 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 394 if(MSVC)
 395     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 396     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 397 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 398     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 399     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 400 endif()
 401
 402 include(CheckLibraryExists)
 403 find_library(HAVE_LIBM m)
 404 mark_as_advanced(HAVE_LIBM)
 405 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 406 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 407 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 408
 409 include(TestSchedAffinity)
 410 test_sched_affinity(HAVE_SCHED_AFFINITY)
 411
 412 # Aligned memory allocation. We need to check for both mm_malloc(),
 413 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 414 include(gmxTestMMMalloc)
 415 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 416 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 417 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 418 if(MSVC)
 419     # No need to waste time on this test on platforms where it will never be true
 420     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 421 endif()
 422
 423 include(TestBigEndian)
 424 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 425
 426 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 427
 428 # Management of GROMACS options for specific toolchains should go
 429 # here. Because the initial settings for some of the main options have
 430 # already happened, but things like library detection and MPI compiler
 431 # feature detection have not, the docstrings for any over-rides of
 432 # GROMACS defaults or user settings will make sense. Also, any
 433 # toolchain-related reasons for choosing whether to detect various
 434 # things can be sorted out now, before the detection takes place.
 435 if(GMX_TARGET_FUJITSU_SPARC64)
 436     include(gmxManageFujitsuSparc64)
 437 endif()
 438
 439 ########################################################################
 440 #Process MPI settings
 441 ########################################################################
 442 include(gmxManageMPI)
 443
 444 ########################################################################
 445 #Process MiMiC settings
 446 ########################################################################
 447 include(gmxManageMimic)
 448
 449 ########################################################################
 450 #Process shared/static library settings
 451 ########################################################################
 452 include(gmxManageSharedLibraries)
 453
 454
 455 ########################################################################
 456 # Find external packages                                               #
 457 ########################################################################
 458
 459 # Unconditionally find the package, as it is also required for unit
 460 # tests. This exports LIBXML2_FOUND, which we should not use because
 461 # it does not tell us that linking will succeed. Instead, we test that
 462 # next.
 463 #if(DEFINED LIBXML2_LIBRARIES)
 464 #  set(LibXml2_FIND_QUIETLY TRUE)
 465 #endif()
 466 #find_package(LibXml2)
 467 #include(gmxTestLibXml2)
 468 #gmx_test_libxml2(HAVE_LIBXML2)
 469 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 470 #set(PKG_XML "")
 471 #mark_as_advanced(GMX_XML)
 472 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 473 #if(GMX_XML AND NOT HAVE_LIBXML2)
 474 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 475 #endif()
 476 #if(GMX_XML)
 477 #    include_directories(${LIBXML2_INCLUDE_DIR})
 478 #    set(PKG_XML libxml-2.0)
 479 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 480 #endif()
 481
 482 option(GMX_HWLOC "Use hwloc portable hardware locality library" OFF)
 483
 484 if (GMX_HWLOC)
 485     # Find quietly the second time.
 486     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 487         set(HWLOC_FIND_QUIETLY TRUE)
 488     endif()
 489     find_package(HWLOC 1.5)
 490
 491     if (HWLOC_FOUND)
 492         if (HWLOC_LIBRARIES MATCHES ".a$")
 493             set(_STATIC_HWLOC TRUE)
 494         endif()
 495
 496         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 497         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 498             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 499             set(GMX_USE_HWLOC OFF)
 500         else()
 501             set(GMX_USE_HWLOC ON)
 502         endif()
 503
 504         if (GMX_USE_HWLOC)
 505             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 506             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 507         endif()
 508     elseif(GMX_HWLOC_FORCE)
 509         message(FATAL_ERROR "HWLOC package support required, but not found.")
 510     endif()
 511
 512     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 513 endif()
 514
 515 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 516 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 517 if(GMX_EXTERNAL_TINYXML2)
 518     # Find an external TinyXML-2 library.
 519     find_package(TinyXML-2 3.0.0)
 520     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 521     if(NOT HAVE_TINYXML2)
 522         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 523     endif()
 524 endif()
 525
 526 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 527 mark_as_advanced(GMX_EXTRAE)
 528
 529 if (GMX_EXTRAE)
 530   find_package(EXTRAE)
 531   if(EXTRAE_FOUND)
 532     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 533     set(HAVE_EXTRAE 1)
 534   else()
 535     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 536   endif()
 537 endif()
 538
 539 option(GMX_X11 "Use X window system" OFF)
 540 if (GMX_X11)
 541     find_package(X11)
 542     # X11 includes/libraries are only set in the ngmx subdirectory!
 543     if(NOT X11_FOUND)
 544         message(FATAL_ERROR
 545                 "X11 include files and/or libraries were not found. "
 546                 "Set GMX_X11=OFF to compile without X11 support. "
 547                 "gmx view will not be available.")
 548     endif()
 549     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 550 endif()
 551
 552 include(ThreadMPI)
 553 # Enable core threading facilities
 554 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 555 if(GMX_THREAD_MPI)
 556     # enable MPI functions
 557     tmpi_enable()
 558     set(MPI_IN_PLACE_EXISTS 1)
 559 endif()
 560 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 561 if (TMPI_ATOMICS_DISABLED)
 562    add_definitions(-DTMPI_ATOMICS_DISABLED)
 563 endif()
 564
 565 include(gmxManageTNG)
 566
 567 include(gmxManageLmfit)
 568
 569 if(GMX_GPU)
 570     # now that we have detected the dependencies, do the second configure pass
 571     gmx_gpu_setup()
 572     if (GMX_CLANG_CUDA)
 573         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 574         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 575     endif()
 576 endif()
 577
 578 if(CYGWIN)
 579     set(GMX_CYGWIN 1)
 580 endif()
 581
 582 if(WIN32)
 583     set(GMX_NATIVE_WINDOWS 1)
 584     # This makes windows.h not declare min/max as macros that would break
 585     # C++ code using std::min/std::max.
 586     add_definitions(-DNOMINMAX)
 587 endif()
 588
 589 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 590 mark_as_advanced(GMX_BUILD_UNITTESTS)
 591 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 592
 593 ########################################################################
 594 # Our own GROMACS tests
 595 ########################################################################
 596
 597 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 598 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 599 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 600
 601 include(gmxTestInlineASM)
 602 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 603
 604 include(gmxSetBuildInformation)
 605 gmx_set_build_information()
 606
 607 # Anything but truly ancient hardware should support rdtscp, so we enable it by default
 608 option(GMX_USE_RDTSCP "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)" ON)
 609 mark_as_advanced(GMX_USE_RDTSCP)
 610
 611 include(gmxTestLargeFiles)
 612 gmx_test_large_files(GMX_LARGEFILES)
 613
 614 include(gmxTestSignal)
 615 gmx_test_sigusr1(HAVE_SIGUSR1)
 616
 617 include(gmxTestPipes)
 618 gmx_test_pipes(HAVE_PIPES)
 619
 620 include(gmxTestXDR)
 621 gmx_test_xdr(GMX_SYSTEM_XDR)
 622 # Darwin has system XDR, but it uses a three-argument flavour of
 623 # xdrproc_t that it guarantees will still work if you pass the normal
 624 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 625 # to do that, so it's simpler to just use our own XDR library.
 626 #
 627 # TODO It would be better to craft a cmake test which fails if such
 628 # XDR operations cause warnings, and succeeds otherwise, because it is
 629 # generally preferable to use system libraries where possible.
 630 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 631     set(GMX_INTERNAL_XDR 1)
 632 endif()
 633
 634
 635 ##################################################
 636 # Process SIMD instruction settings
 637 ##################################################
 638 # This checks what flags to add in order to
 639 # support the SIMD instructions we need, it sets
 640 # correct defines for the SIMD instructions supported,
 641 # and adds advanced options to control accuracy
 642 # for SIMD math operations.
 643 include(gmxManageSimd)
 644 gmx_manage_simd()
 645
 646 ##################################################
 647 # Process FFT library settings
 648 ##################################################
 649 include(gmxManageFFTLibraries)
 650
 651
 652 include(gmxManageLinearAlgebraLibraries)
 653
 654 include(gmxManagePluginSupport)
 655 gmx_manage_plugin_support()
 656
 657 if(GMX_USE_PLUGINS)
 658     if(NOT GMX_VMD_PLUGIN_PATH)
 659         find_package(VMD)
 660     endif()
 661 endif()
 662
 663 # Link real-time library for POSIX timers. The check for clock_gettime
 664 # confirms the linkability of rt.
 665 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 666     list(APPEND GMX_EXTRA_LIBRARIES rt)
 667 endif()
 668
 669 # Math and thread libraries must often come after all others when linking...
 670 if (HAVE_LIBM)
 671     list(APPEND GMX_PUBLIC_LIBRARIES m)
 672 endif()
 673
 674 option(GMX_NACL "Configure for Native Client builds" OFF)
 675 if (GMX_NACL)
 676   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 677   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 678   # TODO: Is this still necessary with the check for its presence?
 679   set(GMX_USE_NICE 0)
 680   set(GMX_NO_RENAME 1)
 681 endif()
 682 mark_as_advanced(GMX_NACL)
 683
 684 if(GMX_FAHCORE)
 685   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 686       "Path to swindirect.h")
 687   include_directories(${COREWRAP_INCLUDE_DIR})
 688 endif()
 689
 690 option(GMX_BUILD_HELP "Build completions (requires that compiled binaries can be executed on build host) and install man pages if built (requires building the 'man' target manually)" OFF)
 691 mark_as_advanced(GMX_BUILD_HELP)
 692 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 693     message(FATAL_ERROR
 694         "Rebuilding shell completions or man pages is not supported for "
 695         "in-source builds from a source distribution. "
 696         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 697 endif()
 698
 699 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 700 # these are set after everything else
 701 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 702     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 703     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 704 else()
 705     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 706     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 707     foreach(build_type ${build_types_with_explicit_flags})
 708         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 709     endforeach()
 710     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 711     foreach(build_type ${build_types_with_explicit_flags})
 712         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 713     endforeach()
 714     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 715     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 716 endif()
 717 # Allow `admin` directory to be easily conveyed to nested CMake commands.
 718 set(GMX_ADMIN_DIR ${CMAKE_SOURCE_DIR}/admin)
 719
 720 ########################################################################
 721 # Specify install locations
 722 ########################################################################
 723 # Use GNUInstallDirs to set paths on multiarch systems.
 724 include(GNUInstallDirs)
 725
 726 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 727 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 728
 729 # Internal convenience so we do not have to join two path segments in the code
 730 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 731
 732 # If the nesting level wrt. the installation root is changed,
 733 # gromacs-config.cmake.cmakein needs to be adapted.
 734 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 735
 736 # TODO: Make GMXRC adapt if this is changed
 737 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 738 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 739
 740 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 741
 742 # Binary and library suffix options
 743 include(gmxManageSuffixes)
 744
 745 ################################################################
 746 # Shared library load path settings
 747 ################################################################
 748 if(NOT GMX_BUILD_SHARED_EXE)
 749     # No rpath
 750     set(CMAKE_SKIP_RPATH TRUE)
 751     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 752     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 753 else()
 754     # The build folder always has bin/ and lib/; if we are also going to
 755     # install to lib/, then the installation RPATH works also in the build
 756     # tree.  This makes installation slightly faster (no need to rewrite the
 757     # RPATHs), and makes the binaries in the build tree relocatable.
 758     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 759         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 760         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 761     endif()
 762     # Set the RPATH as relative to the executable location to make the
 763     # binaries relocatable.
 764     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 765         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 766         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 767     else()
 768         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 769     endif()
 770     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 771     set(CMAKE_MACOSX_RPATH 1)
 772 endif()
 773
 774 #COPYING file: Only necessary for binary distributions.
 775 #Simpler to always install.
 776 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 777
 778 if (GMX_BUILD_FOR_COVERAGE)
 779     # Code heavy with asserts makes conditional coverage close to useless metric,
 780     # as by design most of the false branches are impossible to trigger in
 781     # correctly functioning code.  And the benefit of testing those that could
 782     # be triggered by using an API against its specification isn't usually
 783     # worth the effort.
 784     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 785 endif()
 786
 787 if (BUILD_TESTING)
 788     include(tests/CheckTarget.cmake)
 789 endif()
 790
 791 # TODO: Determine control flow and defaults for package installation and testing use cases.
 792 # Ref: https://gitlab.com/gromacs/gromacs/-/issues/2896
 793 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 794 mark_as_advanced(GMX_PYTHON_PACKAGE)
 795
 796 if (NOT GMX_BUILD_MDRUN_ONLY)
 797     find_package(ImageMagick QUIET COMPONENTS convert)
 798     include(gmxTestImageMagick)
 799     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 800     # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 801     add_subdirectory(docs)
 802     add_subdirectory(share)
 803     add_subdirectory(scripts)
 804 endif()
 805 add_subdirectory(src)
 806
 807 if (BUILD_TESTING)
 808     add_subdirectory(tests)
 809 endif()
 810
 811 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 812     add_subdirectory(python_packaging)
 813 endif()
 814
 815 gmx_cpack_write_config()
 816
 817 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 818 # Don't bother the user after the first configure pass.
 819 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 820     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 821 endif()
 822 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 823
 824 #######################
 825 ## uninstall target
 826 #######################
 827 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 828                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 829                   IMMEDIATE @ONLY)
 830 ###########################
 831 ADD_CUSTOM_TARGET(uninstall
 832                   "${CMAKE_COMMAND}" -P
 833                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 834 ###########################
 835 set_directory_properties(PROPERTIES
 836             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")