cmake/gmxManageTNG.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2016,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(GMX_TNG_MINIMUM_REQUIRED_VERSION "1.7.10")
  36
  37 gmx_dependent_option(
  38     GMX_EXTERNAL_TNG
  39     "Use external TNG instead of compiling the version shipped with GROMACS."
  40     OFF
  41     GMX_USE_TNG)
  42 gmx_dependent_option(
  43     GMX_EXTERNAL_ZLIB
  44     "Use external ZLIB instead of compiling the version shipped with GROMACS as part of TNG."
  45     OFF
  46     "NOT GMX_EXTERNAL_TNG")
  47
  48 if(GMX_USE_TNG)
  49     # Detect TNG if GMX_EXTERNAL_TNG is explicitly ON
  50     if(GMX_EXTERNAL_TNG)
  51         find_package(TNG_IO ${GMX_TNG_MINIMUM_REQUIRED_VERSION})
  52         if(NOT TNG_IO_FOUND)
  53             message(FATAL_ERROR "TNG >= ${GMX_TNG_MINIMUM_REQUIRED_VERSION} not found. You can set GMX_EXTERNAL_TNG=OFF to compile the TNG bundled with GROMACS.")
  54         endif()
  55     else()
  56         # Detect zlib if the user requires us to use an external
  57         # version. If found, it can be used by TNG.
  58         if(GMX_EXTERNAL_ZLIB)
  59             find_package(ZLIB)
  60             if(NOT ZLIB_FOUND)
  61                 message(FATAL_ERROR "External zlib compression library was required but could not be found. Set GMX_EXTERNAL_ZLIB=OFF to compile zlib as part of GROMACS.")
  62             endif()
  63             include(gmxTestZLib)
  64             gmx_test_zlib(HAVE_ZLIB)
  65             if(NOT HAVE_ZLIB)
  66                 message(FATAL_ERROR "External zlib compression library was required but could not compile and link. Set GMX_EXTERNAL_ZLIB=OFF to compile zlib as part of GROMACS.")
  67             endif()
  68         endif()
  69     endif()
  70 endif()
  71
  72 function(gmx_setup_tng_for_libgromacs)
  73     set(BUNDLED_TNG_LOCATION "${CMAKE_SOURCE_DIR}/src/external/tng_io")
  74     if (GMX_USE_TNG)
  75         if (GMX_EXTERNAL_TNG)
  76             target_link_libraries(libgromacs PRIVATE tng_io::tng_io)
  77         else()
  78             set(_zlib_arg)
  79             if (NOT GMX_EXTERNAL_ZLIB)
  80                 set(_zlib_arg OWN_ZLIB)
  81             endif()
  82             include(${BUNDLED_TNG_LOCATION}/BuildTNG.cmake)
  83             add_tng_io_library(tng_io OBJECT ${_zlib_arg})
  84             add_library(tng_io::tng_io ALIAS tng_io)
  85             gmx_target_compile_options(tng_io_obj)
  86             target_link_libraries(libgromacs PRIVATE $<BUILD_INTERFACE:tng_io::tng_io>)
  87         endif()
  88     endif()
  89 endfunction()