src/gromacs/gromacs-config.cmake.cmakein

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2016,2019,2020, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 set(_gmx_cmake_dir ${CMAKE_CURRENT_LIST_DIR})
  36 get_filename_component(_gmx_root_dir "${_gmx_cmake_dir}" PATH)
  37 get_filename_component(_gmx_root_dir "${_gmx_root_dir}" PATH)
  38 get_filename_component(_gmx_root_dir "${_gmx_root_dir}" PATH)
  39
  40 # Find the exported targets (file name depends on whether shared or static
  41 # libraries were built to allow both to coexist in the same prefix), and
  42 # import them.
  43 set(_gmx_import_file ${_gmx_cmake_dir}/libgromacs.cmake)
  44 if (GROMACS_PREFER_STATIC OR NOT EXISTS ${_gmx_import_file})
  45     set(_gmx_import_file_static ${_gmx_cmake_dir}/libgromacs_static.cmake)
  46     if (EXISTS ${_gmx_import_file_static})
  47         set(_gmx_import_file ${_gmx_import_file_static})
  48     endif()
  49     unset(_gmx_import_file_static)
  50 endif()
  51 if (NOT EXISTS ${_gmx_import_file})
  52     message(FATAL_ERROR
  53         "The GROMACS installation at ${_gmx_root_dir} does not contain "
  54         "libgromacs.cmake or libgromacs_static.cmake to define the imported "
  55         "targets.")
  56 endif()
  57 include(${_gmx_import_file})
  58 unset(_gmx_import_file)
  59
  60 get_target_property(_libs Gromacs::libgromacs INTERFACE_LINK_LIBRARIES)
  61 if (_libs MATCHES "tng_io::tng_io")
  62     include(CMakeFindDependencyMacro)
  63     find_dependency(TNG_IO REQUIRED)
  64 endif()
  65 if (_libs MATCHES "OpenMP::OpenMP_CXX")
  66     include(CMakeFindDependencyMacro)
  67     find_dependency(OpenMP REQUIRED)
  68 endif()
  69 unset(_libs)
  70
  71 set(GROMACS_INCLUDE_DIRS)
  72 set(_include_dirs "@INSTALLED_HEADER_INCLUDE_DIRS@")
  73 foreach (_dir ${_include_dirs})
  74     if (IS_ABSOLUTE ${_dir})
  75         list(APPEND GROMACS_INCLUDE_DIRS ${_dir})
  76     else()
  77         list(APPEND GROMACS_INCLUDE_DIRS ${_gmx_root_dir}/${_dir})
  78     endif()
  79 endforeach()
  80 set(GROMACS_LIBRARIES Gromacs::libgromacs)
  81 set(GROMACS_DEFINITIONS @INSTALLED_HEADER_DEFINITIONS@)
  82 set(GROMACS_IS_DOUBLE @GMX_DOUBLE@)
  83 if (DEFINED GROMACS_SUFFIX AND NOT "${GROMACS_SUFFIX}" STREQUAL "@GMX_LIBS_SUFFIX@")
  84     message(FATAL_ERROR "GROMACS_SUFFIX is set inconsistently, expected '@GMX_LIBS_SUFFIX@'")
  85 endif()
  86 set(GROMACS_SUFFIX "@GMX_LIBS_SUFFIX@")
  87 set(GROMACS_CXX_COMPILER "@GROMACS_CXX_COMPILER@")
  88 set(GROMACS_CXX_COMPILER_ID "@CMAKE_CXX_COMPILER_ID@")
  89 set(GROMACS_CXX_COMPILER_VERSION "@CMAKE_CXX_COMPILER_VERSION@")
  90 set(GROMACS_CXX_FLAGS "")
  91
  92 # Produce a message, since find_package() prints nothing on success.
  93 include(FindPackageMessage)
  94 # The version info is set by CMake when it determines whether this file
  95 # is suitable (by calling the version file, which sets PACKAGE_VERSION).
  96 # TODO: Make also the full version string available from somewhere.
  97 set(_gmx_info "${GROMACS_VERSION}")
  98 if (GROMACS_SUFFIX)
  99     set(_gmx_info "${_gmx_info} (suffix: ${GROMACS_SUFFIX})")
 100 endif()
 101 find_package_message(GROMACS "Found GROMACS: ${_gmx_info}" "${CMAKE_CURRENT_LIST_FILE}")
 102
 103 unset(_gmx_cmake_dir)
 104 unset(_gmx_root_dir)
 105 unset(_gmx_info)
 106
 107 #####################################################################
 108 # Macros for use in calling code
 109
 110 # This does not work as a function if called as gromacs_check_double(GMX_DOUBLE)
 111 # (i.e., with the parameter value equal to the formal parameter name) because
 112 # of scoping rules.
 113 macro (gromacs_check_double GMX_DOUBLE)
 114     if (${GMX_DOUBLE} AND NOT GROMACS_IS_DOUBLE)
 115         message(FATAL_ERROR
 116             "The found GROMACS installation is compiled in mixed precision, "
 117             "but double-precision compilation was requested with ${GMX_DOUBLE}=${${GMX_DOUBLE}}")
 118     elseif (NOT ${GMX_DOUBLE} AND GROMACS_IS_DOUBLE)
 119         message(FATAL_ERROR
 120             "The found GROMACS installation is compiled in double precision, "
 121             "but mixed-precision compilation was requested with ${GMX_DOUBLE}=${${GMX_DOUBLE}}")
 122     endif()
 123 endmacro()
 124
 125 function (gromacs_check_compiler LANG)
 126     if (NOT LANG STREQUAL CXX)
 127         message(FATAL_ERROR
 128             "gromacs_check_compiler(CXX) is currently the only supported call")
 129     endif()
 130     # Deal with possible symlinks (it is fine if one of the used compilers was
 131     # a symlink to another one).
 132     get_filename_component(_cmake_compiler_realpath ${CMAKE_${LANG}_COMPILER} REALPATH)
 133     if (NOT "${_cmake_compiler_realpath}" STREQUAL "${GROMACS_${LANG}_COMPILER}" OR
 134         NOT "${CMAKE_${LANG}_COMPILER_ID}" STREQUAL "${GROMACS_${LANG}_COMPILER_ID}" OR
 135         NOT "${CMAKE_${LANG}_COMPILER_VERSION}" STREQUAL "${GROMACS_${LANG}_COMPILER_VERSION}")
 136         message(WARNING
 137             "You are compiling with a different C++ compiler from the one that was "
 138             "used to compile GROMACS. This may lead to linking or runtime problems. "
 139             "GROMACS was compiled with "
 140             "${GROMACS_${LANG}_COMPILER_ID} ${GROMACS_${LANG}_COMPILER_VERSION} "
 141             "(${GROMACS_${LANG}_COMPILER}).")
 142     endif()
 143 endfunction()