docs/manual/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # TODO: Consider whether this could just be replaced by using
  36 # GMX_DEVELOPER_BUILD to control this as well.
  37 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
  38 mark_as_advanced(GMX_BUILD_MANUAL)
  39
  40 set(MANUAL_BUILD_IS_POSSIBLE ON)
  41 set(MANUAL_BUILD_NOT_POSSIBLE_REASON)
  42 if (NOT GMX_BUILD_MANUAL)
  43     # Make sure we only do detection of manual-building dependencies
  44     # when the user opted in for that.
  45     set(MANUAL_BUILD_IS_POSSIBLE OFF)
  46     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "GMX_BUILD_MANUAL is not ON")
  47 elseif (BUILD_IS_INSOURCE)
  48     # UseLATEX.cmake does not work with an in-source build
  49     set(MANUAL_BUILD_IS_POSSIBLE OFF)
  50     set(MANUAL_BUILD_NOT_POSSIBLE_REASON "the build is in-source")
  51 else()
  52     include(UseLATEX.cmake)
  53
  54     if(NOT PDFLATEX_COMPILER OR NOT IMAGEMAGICK_CONVERT)
  55         set(MANUAL_BUILD_IS_POSSIBLE OFF)
  56         set(MANUAL_BUILD_NOT_POSSIBLE_REASON "pdflatex or some other dependency (ImageMagick convert) is not available")
  57
  58         # TODO Later, identify other dependencies like bibtex,
  59         # make_index, date, some graphics conversion program,
  60         # etc. Perhaps patch UseLATEX.cmake and contribute upstream.
  61     endif()
  62 endif()
  63
  64 if(MANUAL_BUILD_IS_POSSIBLE)
  65     LATEX_GET_OUTPUT_PATH(output_dir)
  66
  67     # Avoid generating a global "html" target that clashes with the
  68     # html target from program generaion of help text in share/html.
  69     set(LATEX2HTML_CONVERTER off)
  70
  71     # This helps make the index look decent.
  72     set(MAKEINDEX_COMPILER_FLAGS -s ${CMAKE_CURRENT_SOURCE_DIR}/hfill.ist)
  73     # UseLATEX.cmake is hacked to call Anton Feenstra's subindex script
  74     # to improve the index generation. Don't replace UseLATEX.cmake
  75     # blindly from upstream!
  76
  77     # Here follows various custom CMake "commands" that call our various
  78     # GROMACS helper scripts to make bits of the manual from the installed
  79     # binaries and/or source distribution, as appropriate.
  80     #
  81     # Only files that can be built should be listed in DEPENDS. Makefile
  82     # rules are generated for those files.
  83
  84     # Finally, the command to build the manual.
  85
  86     ADD_LATEX_DOCUMENT(gromacs.tex
  87         # Normal LaTeX \included files
  88         INPUTS algorithms.tex  defunits.tex    implement.tex  macros.tex     special.tex
  89         analyse.tex     files.tex       topology.tex
  90         averages.tex    forcefield.tex  gromacs.tex    intro.tex      programs.tex
  91
  92         # CMake does variable replacement in these files
  93         CONFIGURE macros.tex
  94
  95         BIBFILES monster.bib unpubl.bib
  96         IMAGE_DIRS plots
  97         DEFAULT_PDF
  98         USE_INDEX
  99         )
 100 endif()
 101
 102 if(MANUAL_BUILD_IS_POSSIBLE)
 103     # An explicit "make manual" will still be required for the manual
 104     # to be built.
 105     add_custom_target(manual DEPENDS pdf)
 106 else()
 107     add_custom_target(manual
 108         COMMAND ${CMAKE_COMMAND} -E echo
 109         "Cannot build PDF manual, because ${MANUAL_BUILD_NOT_POSSIBLE_REASON}"
 110         VERBATIM)
 111 endif()
 112
 113 set(MANUAL_BUILD_IS_POSSIBLE ${MANUAL_BUILD_IS_POSSIBLE} PARENT_SCOPE)