CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0-rc1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0-rc1")
  67 # If this is not a released tarball, "-dev" will be present in
  68 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  69 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  70 # code contains all recent fixes from the corresponding code branch.
  71 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  72
  73 set(CUSTOM_VERSION_STRING ""
  74     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  75 mark_as_advanced(CUSTOM_VERSION_STRING)
  76 if (CUSTOM_VERSION_STRING)
  77     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  78 endif()
  79 set(LIBRARY_SOVERSION 0)
  80 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  81 # It is a bit irritating, but this has to be set separately for now!
  82 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  83 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  84 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  85
  86 # The numerical gromacs version. It is 40600 for 4.6.0.
  87 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  88 math(EXPR NUM_VERSION
  89     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  90 if(CPACK_PACKAGE_VERSION_PATCH)
  91     math(EXPR NUM_VERSION
  92          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  93 endif()
  94
  95 # The API version tracks the numerical Gromacs version (for now).
  96 # It is potentially different from the Gromacs version in the future, if
  97 # the programs/libraries diverge from the presumably more stable API.
  98 # The #define GMX_API_VERSION in version.h is set to this value to
  99 # provide backward compatibility of software written against the Gromacs API.
 100 set(API_VERSION ${NUM_VERSION})
 101
 102 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 103     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 104 endif()
 105
 106 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 107 mark_as_advanced(GMX_INSTALL_PREFIX)
 108
 109 include(gmxBuildTypeReference)
 110 include(gmxBuildTypeTSAN)
 111 include(gmxBuildTypeASAN)
 112 include(gmxBuildTypeReleaseWithAssert)
 113
 114 if(NOT CMAKE_BUILD_TYPE)
 115     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 116     # There's no need to offer a user the choice of ThreadSanitizer
 117     # Set the possible values of build type for cmake-gui
 118     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 119         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 120 endif()
 121 if(CMAKE_CONFIGURATION_TYPES)
 122     # Add appropriate GROMACS-specific build types for the Visual
 123     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 124     # are already present by default).
 125     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 126     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 127     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 128         "List of configuration types"
 129         FORCE)
 130 endif()
 131 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 132
 133 enable_language(C)
 134 enable_language(CXX)
 135
 136 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 137 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 138 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 139 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 140 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 141 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 142 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 143 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 144 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 145 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 146 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 147
 148 #must come after all cpack settings!
 149 include(CPack)
 150
 151 # Set a default valgrind suppression file.
 152 # This unfortunately needs to duplicate information from CTest to work as
 153 # expected...
 154 set(MEMORYCHECK_SUPPRESSIONS_FILE
 155     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 156     CACHE FILEPATH
 157     "File that contains suppressions for the memory checker")
 158 include(CTest)
 159
 160 set(SOURCE_IS_GIT_REPOSITORY OFF)
 161 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 162 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 163     set(SOURCE_IS_GIT_REPOSITORY ON)
 164 endif()
 165 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 166     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 167 endif()
 168
 169 ########################################################################
 170 # Check and warn if cache generated on a different host is being reused
 171 ########################################################################
 172 if(CMAKE_HOST_UNIX)
 173     execute_process(COMMAND hostname
 174                     OUTPUT_VARIABLE TMP_HOSTNAME
 175                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 176     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 177         message(WARNING "
 178             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 179             is being reused! This could lead to inconsitencies; therefore, it is
 180             recommended to regenerate the cache!")
 181     endif()
 182     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 183             "Hostname of the machine where the cache was generated.")
 184 endif()
 185
 186 ########################################################################
 187 # User input options                                                   #
 188 ########################################################################
 189 include(gmxOptionUtilities)
 190
 191 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 192
 193 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 194 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 195 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 196 gmx_dependent_option(
 197     GMX_MPI_IN_PLACE
 198     "Enable MPI_IN_PLACE for MPIs that have it defined"
 199     ON
 200     GMX_MPI)
 201 mark_as_advanced(GMX_MPI_IN_PLACE)
 202 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 203 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 204 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 205 mark_as_advanced(GMX_FAHCORE)
 206
 207 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 208 mark_as_advanced(GMX_COOL_QUOTES)
 209 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 210
 211 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 212 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 213 if(MSVC)
 214     set(REQUIRED_CUDA_VERSION 4.1)
 215 else()
 216     set(REQUIRED_CUDA_VERSION 4.0)
 217 endif()
 218 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 219 include(gmxManageGPU)
 220
 221 # Detect the architecture the compiler is targetting, detect
 222 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 223 # to use if none is specified, and populate the cache option for CPU
 224 # SIMD.
 225 include(gmxDetectTargetArchitecture)
 226 gmx_detect_target_architecture()
 227
 228 if(GMX_CPU_ACCELERATION)
 229     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 230     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 231     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 232     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 233 endif()
 234
 235 if(NOT GMX_TARGET_MIC)
 236     include(gmxDetectSimd)
 237     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 238 else()
 239     set(GMX_SUGGESTED_SIMD "None")
 240 endif()
 241
 242 gmx_option_multichoice(
 243     GMX_SIMD
 244     "SIMD instruction set for CPU kernels and compiler optimization"
 245     "${GMX_SUGGESTED_SIMD}"
 246     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 247
 248 gmx_option_multichoice(
 249     GMX_FFT_LIBRARY
 250     "FFT library"
 251     "fftw3"
 252     fftw3 mkl "fftpack[built-in]")
 253 gmx_dependent_option(
 254     GMX_BUILD_OWN_FFTW
 255     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 256     OFF
 257     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 258 gmx_dependent_option(
 259     GMX_DISABLE_FFTW_MEASURE
 260     "Do not optimize FFTW setups (not needed with SSE)"
 261     OFF
 262     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 263 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 264 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 265
 266 gmx_option_multichoice(
 267     GMX_QMMM_PROGRAM
 268     "QM package for QM/MM"
 269     None
 270     none gaussian mopac gamess orca)
 271
 272 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 273 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 274
 275 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 276
 277 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 278 mark_as_advanced(GMX_BROKEN_CALLOC)
 279 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 280 mark_as_advanced(GMX_LOAD_PLUGINS)
 281
 282 option(GMX_GPU  "Enable GPU acceleration" ON)
 283 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 284
 285 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 286
 287 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 288 mark_as_advanced(GMX_GIT_VERSION_INFO)
 289
 290 if(UNIX)
 291     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 292 endif()
 293 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 294
 295 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 296 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 297
 298 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 299 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 300
 301 option(GMX_BUILD_FOR_COVERAGE
 302        "Tune build for better code coverage metrics (e.g., disable asserts)"
 303        OFF)
 304 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 305
 306
 307 ######################################################################
 308 # Detect OpenMP support
 309 ######################################################################
 310 # The OpenMP detection _must_ come before tests for other CFLAGS.
 311 include(gmxManageOpenMP)
 312
 313
 314
 315 ######################################################################
 316 # Compiler tests
 317 # These need to be done early (before further tests).
 318 #####################################################################
 319
 320 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 321 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 322 # invalid options with the Intel Compilers.
 323 # These files should be removed from the source tree when a CMake version that
 324 # includes the features in question becomes required for building GROMACS.
 325 include(CheckCCompilerFlag)
 326 include(CheckCXXCompilerFlag)
 327
 328
 329 include(gmxCFlags)
 330 gmx_c_flags()
 331
 332 # This variable should be used for additional compiler flags which are not
 333 # generated in gmxCFlags nor are SIMD or MPI related.
 334 set(EXTRA_C_FLAGS "")
 335 set(EXTRA_CXX_FLAGS "")
 336
 337 # Run through a number of tests for buggy compilers and other issues
 338 include(gmxTestCompilerProblems)
 339 gmx_test_compiler_problems()
 340 # GMX_SIMD will not be set automatically until the second
 341 # pass (which is not strictly guaranteed to occur), so putting this
 342 # check here among logically-related tests is inefficient, but the
 343 # potential loss is likely zero.
 344 if(GMX_SIMD STREQUAL "AVX_256"
 345         AND CMAKE_COMPILER_IS_GNUCC
 346         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 347             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 348     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 349     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 350 endif()
 351
 352
 353
 354 set(PKG_CFLAGS "")
 355 if(GMX_DOUBLE)
 356     add_definitions(-DGMX_DOUBLE)
 357     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 358 endif()
 359 if(GMX_SOFTWARE_INVSQRT)
 360   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 361 endif()
 362
 363 if(WIN32 AND NOT CYGWIN)
 364     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 365     mark_as_advanced(GMX_WSOCKLIB_PATH)
 366     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 367     if(WSOCK32_LIBRARY)
 368         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 369         add_definitions(-DGMX_HAVE_WINSOCK)
 370     else()
 371         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 372     endif(WSOCK32_LIBRARY)
 373 endif()
 374
 375
 376
 377 ########################################################################
 378 # Basic system tests (standard libraries, headers, functions, types)   #
 379 ########################################################################
 380 include(CheckIncludeFiles)
 381 include(CheckIncludeFileCXX)
 382 check_include_files(unistd.h     HAVE_UNISTD_H)
 383 check_include_files(pwd.h        HAVE_PWD_H)
 384 check_include_files(dirent.h     HAVE_DIRENT_H)
 385 check_include_files(time.h       HAVE_TIME_H)
 386 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 387 check_include_files(io.h         HAVE_IO_H)
 388 check_include_files(sched.h      HAVE_SCHED_H)
 389
 390 check_include_files(regex.h      HAVE_POSIX_REGEX)
 391 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 392 # TODO: It could be nice to inform the user if no regex support is found,
 393 # as selections won't be fully functional.
 394
 395 include(CheckFunctionExists)
 396 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 397 check_function_exists(memalign          HAVE_MEMALIGN)
 398 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 399 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 400 check_function_exists(fsync             HAVE_FSYNC)
 401 check_function_exists(_fileno           HAVE__FILENO)
 402 check_function_exists(fileno            HAVE_FILENO)
 403 check_function_exists(_commit           HAVE__COMMIT)
 404 check_function_exists(sigaction         HAVE_SIGACTION)
 405 check_function_exists(sysconf           HAVE_SYSCONF)
 406 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 407 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 408 check_function_exists(rsqrt             HAVE_RSQRT)
 409 check_function_exists(rsqrtf            HAVE_RSQRTF)
 410 check_function_exists(sqrtf             HAVE_SQRTF)
 411
 412 include(CheckLibraryExists)
 413 check_library_exists(m sqrt "" HAVE_LIBM)
 414 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 415
 416 include(TestBigEndian)
 417 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 418
 419 # Management of GROMACS options for specific toolchains should go
 420 # here. Because the initial settings for some of the main options have
 421 # already happened, but things like library detection and MPI compiler
 422 # feature detection have not, the docstrings for any over-rides of
 423 # GROMACS defaults or user settings will make sense. Also, any
 424 # toolchain-related reasons for choosing whether to detect various
 425 # things can be sorted out now, before the detection takes place.
 426 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 427     include(gmxManageBlueGene)
 428 endif()
 429
 430 ########################################################################
 431 #Process MPI settings
 432 ########################################################################
 433 include(gmxManageMPI)
 434
 435
 436 ########################################################################
 437 #Process shared/static library settings
 438 ########################################################################
 439 include(gmxManageSharedLibraries)
 440
 441
 442 ########################################################################
 443 # Find external packages                                               #
 444 ########################################################################
 445
 446 # Unconditionally find the package, as it is also required for unit
 447 # tests. This exports LIBXML2_FOUND, which we should not use because
 448 # it does not tell us that linking will succeed. Instead, we test that
 449 # next.
 450 find_package(LibXml2)
 451 include(gmxTestLibXml2)
 452 gmx_test_libxml2(HAVE_LIBXML2)
 453 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 454 set(PKG_XML "")
 455 mark_as_advanced(GMX_XML)
 456 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 457 #if(GMX_XML AND NOT HAVE_LIBXML2)
 458 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 459 #endif()
 460 #if(GMX_XML)
 461 #    include_directories(${LIBXML2_INCLUDE_DIR})
 462 #    set(PKG_XML libxml-2.0)
 463 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 464 #endif()
 465
 466 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 467 mark_as_advanced(GMX_EXTRAE)
 468
 469 if (GMX_EXTRAE)
 470   find_package(EXTRAE)
 471   if(EXTRAE_FOUND)
 472     include_directories(${EXTRAE_INCLUDE_DIR})
 473     set(HAVE_EXTRAE 1)
 474   else()
 475     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 476   endif()
 477 endif()
 478
 479 option(GMX_X11 "Use X window system" OFF)
 480 if (GMX_X11)
 481     find_package(X11)
 482     # X11 includes/libraries are only set in the ngmx subdirectory!
 483     if(NOT X11_FOUND)
 484         message(FATAL_ERROR
 485                 "X11 include files and/or libraries were not found. "
 486                 "Set GMX_X11=OFF to compile without X11 support. "
 487                 "gmx view will not be available.")
 488     endif()
 489     include_directories(${X11_INCLUDE_DIR})
 490 endif()
 491
 492 include(ThreadMPI)
 493 # Enable core threading facilities
 494 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 495 # Enable tMPI C++ support
 496 tmpi_enable_cxx()
 497 if(GMX_THREAD_MPI)
 498     # enable MPI functions
 499     tmpi_enable()
 500     set(GMX_MPI 1)
 501     set(MPI_IN_PLACE_EXISTS 1)
 502 endif()
 503 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 504 if (TMPI_ATOMICS_DISABLED)
 505    add_definitions(-DTMPI_ATOMICS_DISABLED)
 506 endif()
 507
 508 if(GMX_GPU)
 509     # now that we have detected the dependencies, do the second configure pass
 510     gmx_gpu_setup()
 511 endif()
 512
 513 if(CYGWIN)
 514     set(GMX_CYGWIN 1)
 515 endif()
 516
 517 if(WIN32 AND NOT CYGWIN)
 518     set(GMX_NATIVE_WINDOWS 1)
 519     # This makes windows.h not declare min/max as macros that would break
 520     # C++ code using std::min/std::max.
 521     add_definitions(-DNOMINMAX)
 522 endif()
 523
 524 # only bother with finding git and using version.h if the source is a git repo
 525 if(GMX_GIT_VERSION_INFO)
 526     if (NOT SOURCE_IS_GIT_REPOSITORY)
 527         message(FATAL_ERROR
 528             "Cannot generate git version information from source tree not under git. "
 529             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 530     endif()
 531     # We need at least git v1.5.3 be able to parse git's date output. If not
 532     # found or the version is too small, we can't generate version information.
 533     find_package(Git)
 534
 535     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 536         message(FATAL_ERROR
 537             "No compatible git version found (>= 1.5.3 required). "
 538             "Won't be able to generate development version information. "
 539             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 540     endif()
 541 endif()
 542
 543 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 544 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 545 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 546     find_package(Boost 1.44.0)
 547     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 548         set(Boost_FOUND FALSE)
 549     endif()
 550     # Print the notification only on first run, when determining the default
 551     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 552         message("Boost >= 1.44 not found. Using minimal internal version. "
 553                 "This may cause trouble if you plan on compiling/linking other "
 554                 "software that uses Boost against Gromacs.")
 555     endif()
 556 endif()
 557 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 558        ${Boost_FOUND})
 559 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 560     message(FATAL_ERROR
 561         "Boost >= 1.44 not found. "
 562         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 563         "version of Boost included with Gromacs.")
 564 endif()
 565
 566 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 567 mark_as_advanced(GMX_BUILD_UNITTESTS)
 568 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 569 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 570     message(FATAL_ERROR
 571         "Cannot build unit tests without libxml2. "
 572         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 573 endif()
 574
 575 ########################################################################
 576 # Generate development version info for cache
 577 ########################################################################
 578 # set(GEN_VERSION_INFO_INTERNAL "ON")
 579 # include(gmxGenerateVersionString)
 580
 581 ########################################################################
 582 # Our own GROMACS tests
 583 ########################################################################
 584
 585 add_definitions( -DHAVE_CONFIG_H )
 586 include_directories(${CMAKE_SOURCE_DIR}/src)
 587 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 588 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 589 include_directories(${CMAKE_BINARY_DIR}/src)
 590 # Required for gmx_header_config_gen.h to be found before installation
 591 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 592 # Required for now to make old code compile
 593 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 594
 595 include(gmxTestInlineASM)
 596 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 597
 598 include(gmxSetBuildInformation)
 599 gmx_set_build_information()
 600 # Turn on RDTSCP if:
 601 # - the build system's CPU supports it
 602 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 603 #   at this point means that the user set it).
 604 # Note: it's better to not use the later set value of GMX_SIMD because
 605 # it reflects the system's capability of both compiling and running AVX code.
 606 # TODO: After merge with 5.0 one could implement a cache variable dependency
 607 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 608 # after the first cmake pass.
 609 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 610     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 611 else()
 612     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 613 endif()
 614 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 615 mark_as_advanced(GMX_USE_RDTSCP)
 616 if(GMX_USE_RDTSCP)
 617     set(HAVE_RDTSCP 1)
 618 endif()
 619
 620 include(gmxTestFloatFormat)
 621 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 622                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 623                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 624
 625 include(gmxTestLargeFiles)
 626 gmx_test_large_files(GMX_LARGEFILES)
 627
 628 include(gmxTestSignal)
 629 gmx_test_sigusr1(HAVE_SIGUSR1)
 630
 631 include(gmxTestPipes)
 632 gmx_test_pipes(HAVE_PIPES)
 633
 634 include(gmxTestIsfinite)
 635 gmx_test_isfinite(HAVE_ISFINITE)
 636 gmx_test__isfinite(HAVE__ISFINITE)
 637 gmx_test__finite(HAVE__FINITE)
 638
 639 include(gmxTestCXX11)
 640 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 641 include(CMakeDependentOption)
 642 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 643 # entirely to keep the compilation environment uniform.
 644 cmake_dependent_option(GMX_CXX11
 645     "Use C++11 features"
 646     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 647 mark_as_advanced(GMX_CXX11)
 648 if(GMX_CXX11)
 649     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 650 endif()
 651
 652
 653 include(gmxTestXDR)
 654 gmx_test_xdr(GMX_SYSTEM_XDR)
 655 if(NOT GMX_SYSTEM_XDR)
 656     set(GMX_INTERNAL_XDR 1)
 657 endif()
 658
 659
 660 ##################################################
 661 # Process SIMD instruction settings
 662 ##################################################
 663 # This checks what flags to add in order to
 664 # support the SIMD instructions we need, and sets
 665 # correct defines for the SIMD instructions supported.
 666 include(gmxTestSimd)
 667 gmx_test_simd()
 668
 669
 670 # Process QM/MM Settings
 671 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 672     set(GMX_QMMM_GAUSSIAN 1)
 673 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 674     set(GMX_QMMM_MOPAC 1)
 675 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 676     set(GMX_QMMM_GAMESS 1)
 677 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 678     set(GMX_QMMM_ORCA 1)
 679 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 680     # nothing to do
 681 else()
 682     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 683 endif()
 684
 685
 686 ##################################################
 687 # Process FFT library settings
 688 ##################################################
 689 include(gmxManageFFTLibraries)
 690
 691
 692 include(gmxManageLinearAlgebraLibraries)
 693
 694 # Whether GROMACS will really try to compile support for VMD plugins
 695 set(GMX_USE_PLUGINS OFF)
 696
 697 if(GMX_LOAD_PLUGINS)
 698   if(CYGWIN OR NOT WIN32)
 699     # Native Windows does not have, nor need dlopen
 700     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 701     include(gmxTestdlopen)
 702     gmx_test_dlopen(HAVE_DLOPEN)
 703   endif()
 704
 705   # so, should we use plug-ins?
 706   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 707     if(NOT VMD_QUIETLY)
 708       MESSAGE(STATUS
 709           "Found the ability to use plug-ins when building shared libaries, "
 710           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 711           "formats).")
 712     endif()
 713     if(NOT GMX_VMD_PLUGIN_PATH)
 714       find_package(VMD)
 715     endif()
 716     set(GMX_USE_PLUGINS ON)
 717     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 718     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 719   else()
 720     set(PKG_DL_LIBS)
 721   endif()
 722 endif()
 723 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 724
 725 # Link real-time library for POSIX timers. The check for clock_gettime
 726 # confirms the linkability of rt.
 727 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 728     list(APPEND GMX_EXTRA_LIBRARIES rt)
 729 endif()
 730
 731 # Math and thread libraries must often come after all others when linking...
 732 if(HAVE_LIBM)
 733     list(APPEND GMX_EXTRA_LIBRARIES m)
 734 endif()
 735
 736 option(GMX_NACL "Configure for Native Client builds" OFF)
 737 if (GMX_NACL)
 738   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 739   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 740   set(GMX_NO_NICE 1)
 741   set(GMX_NO_RENAME 1)
 742 endif()
 743 mark_as_advanced(GMX_NACL)
 744
 745 if(GMX_FAHCORE)
 746   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 747       "Path to swindirect.h")
 748   include_directories(${COREWRAP_INCLUDE_DIR})
 749 endif()
 750
 751 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 752 mark_as_advanced(GMX_BUILD_HELP)
 753 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 754     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 755
 756     message(FATAL_ERROR
 757         "Rebuilding HTML and man pages is not supported for in-source "
 758         "builds from a source distribution. "
 759         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 760 endif()
 761
 762 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 763 # these are set after everything else
 764 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 765     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 766     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 767     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 768     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 769 else()
 770     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 771     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 772     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 773     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 774     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 775     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 776     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 777     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 778     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 779 endif()
 780
 781 if(NOT GMX_OPENMP)
 782     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 783     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 784     unset(OpenMP_C_FLAGS CACHE)
 785     unset(OpenMP_CXX_FLAGS CACHE)
 786 else()
 787     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 788     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 789 endif()
 790 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 791
 792 ########################################################################
 793 # Specify install locations
 794 ########################################################################
 795 # Use GNUInstallDirst to set paths on multiarch systems
 796 include(GNUInstallDirs)
 797
 798 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 799     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 800 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 801     "Data installation directory under share/ (default: gromacs)")
 802 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 803
 804 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 805 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 806 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 807 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 808 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 809
 810 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 811 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 812
 813 # Binary and library suffix options
 814 include(gmxManageSuffixes)
 815
 816 ################################################################
 817 # Shared library settings
 818 ################################################################
 819 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 820     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 821         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 822     endif()
 823     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 824         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 825     else()
 826         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 827     endif()
 828     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 829     set(CMAKE_MACOSX_RPATH 1)
 830 else()
 831     # We are on Darwin/OSX, and cmake cannot handle proper RPATHs
 832     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 833         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 834         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 835     else()
 836         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 837     endif()
 838 endif()
 839
 840 #COPYING file: Only necessary for binary distributions.
 841 #Simpler to always install.
 842 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 843
 844 if(GMX_EXTERNAL_BOOST)
 845     include_directories(${Boost_INCLUDE_DIRS})
 846     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 847 else()
 848     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 849     # typeid not supported for minimal internal version
 850     # (would add significant amount of code)
 851     add_definitions(-DBOOST_NO_TYPEID)
 852     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 853     # (from share/template/)
 854     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 855     if (NOT GMX_BUILD_MDRUN_ONLY)
 856         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 857                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 858                 COMPONENT development)
 859     endif()
 860 endif()
 861
 862 if (GMX_BUILD_FOR_COVERAGE)
 863     # Code heavy with asserts makes conditional coverage close to useless metric,
 864     # as by design most of the false branches are impossible to trigger in
 865     # correctly functioning code.  And the benefit of testing those that could
 866     # be triggered by using an API against its specification isn't usually
 867     # worth the effort.
 868     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 869 endif()
 870
 871 if (BUILD_TESTING)
 872     # "tests" target builds all the separate test binaries.
 873     add_custom_target(tests)
 874     # "run-ctest" is an internal target that actually runs the tests.
 875     # This is necessary to be able to add separate targets that execute as part
 876     # of 'make check', but are ensured to be executed after the actual tests.
 877     add_custom_target(run-ctest
 878                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 879                       COMMENT "Running all tests"
 880                       VERBATIM)
 881     add_dependencies(run-ctest tests)
 882     # "check" target builds and runs all tests.
 883     add_custom_target(check DEPENDS run-ctest)
 884 endif()
 885
 886 if (NOT GMX_BUILD_MDRUN_ONLY)
 887     add_subdirectory(doxygen)
 888     add_subdirectory(install-guide)
 889     add_subdirectory(share)
 890     add_subdirectory(scripts)
 891 endif()
 892 add_subdirectory(src)
 893
 894 if (BUILD_TESTING)
 895     add_subdirectory(tests)
 896 endif()
 897
 898 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 899 # Don't bother the user after the first configure pass.
 900 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 901     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 902 endif()
 903 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 904
 905 #######################
 906 ## uninstall target
 907 #######################
 908 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 909                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 910                   IMMEDIATE @ONLY)
 911 ###########################
 912 ADD_CUSTOM_TARGET(uninstall
 913                   "${CMAKE_COMMAND}" -P
 914                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 915 ###########################
 916 set_directory_properties(PROPERTIES
 917             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 918
 919 ########################################################################
 920 # Manual                                                               #
 921 ########################################################################
 922
 923 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 924 mark_as_advanced(GMX_BUILD_MANUAL)
 925 if(GMX_BUILD_MANUAL)
 926     # Make sure we only do detection of manual-building dependencies
 927     # when the user opted in for that.
 928     add_subdirectory(manual)
 929 endif()