CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36 if(POLICY CMP0074) #3.12
  37     cmake_policy(SET CMP0074 NEW)
  38 endif()
  39 cmake_policy(SET CMP0068 NEW) # From CMake-3.9
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  46     # Providing a default value >=10.9 helps to find modern C++ compatibility,
  47     # such as by defaulting to the Clang libc++ instead of libstdc++.
  48     set(CMAKE_OSX_DEPLOYMENT_TARGET 10.9 CACHE STRING
  49         "OS X deployment target affects default SDK version and compiler flags."
  50         FORCE)
  51     # By default, limit the binary architecture to a single 64-bit build.
  52     set(CMAKE_OSX_ARCHITECTURES x86_64 CACHE STRING
  53         "OS X architecture affects the compatibility of the (potentially fat) binaries produced."
  54         FORCE)
  55 endif()
  56
  57 project(Gromacs)
  58
  59 set(CMAKE_CXX_STANDARD 14)
  60 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  61 set(CMAKE_CXX_EXTENSIONS OFF)
  62
  63 include(gmxManageCcache)
  64
  65 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  66 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  67 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  68
  69 find_package(LibStdCpp)
  70
  71 # Set up common version variables, as well as general information about
  72 # the build tree (whether the build is from a source package or from a git
  73 # repository).  Also declares a few functions that will be used for generating
  74 # version info files later.
  75 include(gmxBuildTreeInfo)
  76 include(gmxVersionInfo)
  77
  78 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  79     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  80 endif()
  81 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  82     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  83 endif()
  84
  85 include(gmxBuildTypeReference)
  86 include(gmxBuildTypeProfile)
  87 include(gmxBuildTypeTSAN)
  88 include(gmxBuildTypeASAN)
  89 include(gmxBuildTypeMSAN)
  90 include(gmxBuildTypeReleaseWithAssert)
  91
  92 if(NOT CMAKE_BUILD_TYPE)
  93     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  94     # Set the possible values of build type for cmake-gui
  95     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  96         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  97 endif()
  98 if(CMAKE_CONFIGURATION_TYPES)
  99     # Add appropriate GROMACS-specific build types for the Visual
 100     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 101     # are already present by default).
 102     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 103     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 104     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 105         "List of configuration types"
 106         FORCE)
 107 endif()
 108 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
 109
 110 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 111
 112 include(gmxCTestUtilities)
 113 gmx_ctest_init()
 114
 115 include(gmxCPackUtilities)
 116 gmx_cpack_init()
 117
 118 # Variables that accumulate stuff influencing the installed headers
 119 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 120 set(INSTALLED_HEADER_DEFINITIONS "")
 121
 122 ########################################################################
 123 # Global non-cache variables for implementing the build system
 124 ########################################################################
 125
 126 # These variables collect libraries that GROMACS requires for
 127 # linking. They should be appended to with list(APPEND ${name}
 128 # new-library) calls. They are:
 129 #  - Libraries that are required for libgromacs (only)
 130 set(GMX_EXTRA_LIBRARIES "")
 131 #  - Libraries that are required for all code in the repository
 132 set(GMX_COMMON_LIBRARIES "")
 133 #  - Libraries that all code linked against libgromacs needs
 134 #    (i.e., something that is exposed in installed headers).
 135 set(GMX_PUBLIC_LIBRARIES "")
 136
 137 ########################################################################
 138 # Check and warn if cache generated on a different host is being reused
 139 ########################################################################
 140 if(CMAKE_HOST_UNIX)
 141     execute_process(COMMAND hostname
 142                     OUTPUT_VARIABLE TMP_HOSTNAME
 143                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 144     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 145         message(WARNING "
 146             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 147             is being reused! This could lead to inconsistencies; therefore, it is
 148             recommended to regenerate the cache!")
 149     endif()
 150     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 151             "Hostname of the machine where the cache was generated.")
 152 endif()
 153
 154 ########################################################################
 155 # Detect architecture before setting options so we can alter defaults
 156 ########################################################################
 157 # Detect the architecture the compiler is targetting, detect
 158 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 159 # to use if none is specified, and populate the cache option for CPU
 160 # SIMD.
 161 include(gmxDetectTargetArchitecture)
 162 gmx_detect_target_architecture()
 163
 164 ########################################################################
 165 # User input options                                                   #
 166 ########################################################################
 167 include(gmxOptionUtilities)
 168
 169 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 170
 171 # Fujitsu only has SIMD in double precision, so this will be faster
 172 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 173 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 174 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 175 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 176
 177 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 178 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 179 gmx_dependent_option(
 180     GMX_MPI_IN_PLACE
 181     "Enable MPI_IN_PLACE for MPIs that have it defined"
 182     ON
 183     GMX_MPI)
 184 mark_as_advanced(GMX_MPI_IN_PLACE)
 185
 186 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 187
 188 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 189 mark_as_advanced(GMX_FAHCORE)
 190
 191 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 192 mark_as_advanced(GMX_COOL_QUOTES)
 193 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 194
 195 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 196
 197 option(GMX_INSTALL_LEGACY_API "Install legacy headers" OFF)
 198
 199 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 200 set(REQUIRED_CUDA_VERSION 9.0)
 201 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 202
 203 # OpenCL required version: 1.2 or newer
 204 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 205 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 206 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 207
 208 if(NOT GMX_USE_OPENCL)
 209     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 210     include(gmxManageGPU)
 211     set(GMX_USE_CUDA ${GMX_GPU})
 212     if(GMX_GPU)
 213         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 214     else()
 215         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 216     endif()
 217 else()
 218     #Now the OpenCL path (for both AMD and NVIDIA)
 219     if(GMX_GPU)
 220         include(gmxManageOpenCL)
 221         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 222     else()
 223         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 224     endif()
 225 endif()
 226
 227 gmx_option_multichoice(
 228     GMX_SIMD
 229     "SIMD instruction set for CPU kernels and compiler optimization"
 230     "AUTO"
 231     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 232
 233 if(GMX_TARGET_MIC)
 234     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 235 else()
 236     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 237 endif()
 238
 239 gmx_option_multichoice(
 240     GMX_FFT_LIBRARY
 241     "FFT library"
 242     "${GMX_FFT_LIBRARY_DEFAULT}"
 243     fftw3 mkl "fftpack[built-in]")
 244 gmx_dependent_option(
 245     GMX_BUILD_OWN_FFTW
 246     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 247     OFF
 248     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 249 gmx_dependent_option(
 250     GMX_DISABLE_FFTW_MEASURE
 251     "Do not optimize FFTW setups (not needed with SSE)"
 252     OFF
 253     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 254 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 255 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 256
 257 gmx_option_multichoice(
 258     GMX_QMMM_PROGRAM
 259     "QM package for QM/MM"
 260     None
 261     none gaussian mopac gamess orca)
 262
 263 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 264 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 265
 266 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 267
 268 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 269 mark_as_advanced(GMX_BROKEN_CALLOC)
 270
 271 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 272
 273 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 274
 275 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 276
 277 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 278 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 279
 280 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 281 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 282
 283 option(GMX_BUILD_FOR_COVERAGE
 284        "Tune build for better code coverage metrics (e.g., disable asserts)"
 285        OFF)
 286 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 287
 288 option(GMX_DEVELOPER_BUILD
 289     "Enable Developer convenience features: always build unit-tests"
 290     OFF)
 291 mark_as_advanced(GMX_DEVELOPER_BUILD)
 292
 293 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 294 option(GMX_COMPILER_WARNINGS
 295     "Enable a default set of compiler warnings"
 296     ${GMX_COMPILER_WARNINGS_DEFAULT})
 297 mark_as_advanced(GMX_COMPILER_WARNINGS)
 298 # Always turn on compiler warnings with a developer build.
 299 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 300
 301 option(GMX_BUILD_SHARED_EXE
 302     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 303     ON)
 304 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 305
 306 option(GMX_PHYSICAL_VALIDATION
 307        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 308        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 309        OFF)
 310 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 311
 312 ######################################################################
 313 # Detect OpenMP support
 314 ######################################################################
 315 # The OpenMP detection _must_ come before tests for other CFLAGS.
 316 include(gmxManageOpenMP)
 317
 318
 319
 320 ######################################################################
 321 # Compiler tests
 322 # These need to be done early (before further tests).
 323 #####################################################################
 324
 325 include(gmxCFlags)
 326 gmx_c_flags()
 327
 328 # These variables should be used for CMake-style lists (ie. separated
 329 # by semicolons) of additional compiler flags which are not generated
 330 # in gmxCFlags nor are SIMD or MPI related.
 331 #
 332 # TODO These variables should be consolidated into
 333 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 334 # things that work in C compilation (e.g. merging from old branches)
 335 # might not also work for C++ compilation.
 336 set(EXTRA_C_FLAGS "")
 337 set(EXTRA_CXX_FLAGS "")
 338
 339 # Run through a number of tests for buggy compilers and other issues
 340 include(gmxTestCompilerProblems)
 341 gmx_test_compiler_problems()
 342
 343 # Implement double-precision option. This is complicated because we
 344 # need installed headers to use the precision mode of the build that
 345 # produced the library, but cannot use config.h in that case. We also
 346 # want such variables to always have a definition, because #if is more
 347 # robust than #ifdef. So, we put this value on the compiler command
 348 # line in all cases.
 349 #
 350 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 351 # because no installed header needs it
 352 if(GMX_DOUBLE)
 353     set(GMX_DOUBLE_VALUE 1)
 354 else()
 355     set(GMX_DOUBLE_VALUE 0)
 356 endif()
 357 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 358 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 359
 360 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 361 if(GMX_IMD AND WIN32)
 362     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 363 endif()
 364
 365
 366
 367 ########################################################################
 368 # Basic system tests (standard libraries, headers, functions, types)   #
 369 ########################################################################
 370 include(CheckIncludeFiles)
 371 include(CheckIncludeFileCXX)
 372 check_include_files(unistd.h     HAVE_UNISTD_H)
 373 check_include_files(pwd.h        HAVE_PWD_H)
 374 check_include_files(dirent.h     HAVE_DIRENT_H)
 375 check_include_files(time.h       HAVE_TIME_H)
 376 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 377 check_include_files(io.h         HAVE_IO_H)
 378 check_include_files(sched.h      HAVE_SCHED_H)
 379 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 380
 381 include(CheckCXXSymbolExists)
 382 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 383 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 384 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 385 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 386 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 387 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 388 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 389 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 390
 391 # We cannot check for the __builtins as symbols, but check if code compiles
 392 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 393 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 394 if(MSVC)
 395     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 396     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 397 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 398     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 399     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 400 endif()
 401
 402 include(CheckLibraryExists)
 403 find_library(HAVE_LIBM m)
 404 mark_as_advanced(HAVE_LIBM)
 405 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 406 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 407 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 408
 409 include(TestSchedAffinity)
 410 test_sched_affinity(HAVE_SCHED_AFFINITY)
 411
 412 # Aligned memory allocation. We need to check for both mm_malloc(),
 413 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 414 include(gmxTestMMMalloc)
 415 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 416 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 417 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 418 if(MSVC)
 419     # No need to waste time on this test on platforms where it will never be true
 420     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 421 endif()
 422
 423 include(TestBigEndian)
 424 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 425
 426 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 427
 428 # Management of GROMACS options for specific toolchains should go
 429 # here. Because the initial settings for some of the main options have
 430 # already happened, but things like library detection and MPI compiler
 431 # feature detection have not, the docstrings for any over-rides of
 432 # GROMACS defaults or user settings will make sense. Also, any
 433 # toolchain-related reasons for choosing whether to detect various
 434 # things can be sorted out now, before the detection takes place.
 435 if(GMX_TARGET_FUJITSU_SPARC64)
 436     include(gmxManageFujitsuSparc64)
 437 endif()
 438
 439 ########################################################################
 440 #Process MPI settings
 441 ########################################################################
 442 include(gmxManageMPI)
 443
 444 ########################################################################
 445 #Process MiMiC settings
 446 ########################################################################
 447 include(gmxManageMimic)
 448
 449 ########################################################################
 450 #Process shared/static library settings
 451 ########################################################################
 452 include(gmxManageSharedLibraries)
 453
 454
 455 ########################################################################
 456 # Find external packages                                               #
 457 ########################################################################
 458
 459 # Unconditionally find the package, as it is also required for unit
 460 # tests. This exports LIBXML2_FOUND, which we should not use because
 461 # it does not tell us that linking will succeed. Instead, we test that
 462 # next.
 463 #if(DEFINED LIBXML2_LIBRARIES)
 464 #  set(LibXml2_FIND_QUIETLY TRUE)
 465 #endif()
 466 #find_package(LibXml2)
 467 #include(gmxTestLibXml2)
 468 #gmx_test_libxml2(HAVE_LIBXML2)
 469 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 470 #set(PKG_XML "")
 471 #mark_as_advanced(GMX_XML)
 472 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 473 #if(GMX_XML AND NOT HAVE_LIBXML2)
 474 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 475 #endif()
 476 #if(GMX_XML)
 477 #    include_directories(${LIBXML2_INCLUDE_DIR})
 478 #    set(PKG_XML libxml-2.0)
 479 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 480 #endif()
 481
 482 gmx_option_trivalue(
 483     GMX_HWLOC
 484     "Use hwloc portable hardware locality library"
 485     "AUTO")
 486
 487 if (GMX_HWLOC)
 488     # Find quietly the second time.
 489     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 490         set(HWLOC_FIND_QUIETLY TRUE)
 491     endif()
 492     find_package(HWLOC 1.5)
 493
 494     if (HWLOC_FOUND)
 495         if (HWLOC_LIBRARIES MATCHES ".a$")
 496             set(_STATIC_HWLOC TRUE)
 497         endif()
 498
 499         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 500         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 501             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 502             set(GMX_USE_HWLOC OFF)
 503         else()
 504             set(GMX_USE_HWLOC ON)
 505         endif()
 506
 507         if (GMX_USE_HWLOC)
 508             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 509             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 510         endif()
 511     elseif(GMX_HWLOC_FORCE)
 512         message(FATAL_ERROR "HWLOC package support required, but not found.")
 513     endif()
 514
 515     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 516 endif()
 517
 518 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 519 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 520 if(GMX_EXTERNAL_TINYXML2)
 521     # Find an external TinyXML-2 library.
 522     find_package(TinyXML-2 3.0.0)
 523     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 524     if(NOT HAVE_TINYXML2)
 525         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 526     endif()
 527 endif()
 528
 529 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 530 mark_as_advanced(GMX_EXTRAE)
 531
 532 if (GMX_EXTRAE)
 533   find_package(EXTRAE)
 534   if(EXTRAE_FOUND)
 535     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 536     set(HAVE_EXTRAE 1)
 537   else()
 538     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 539   endif()
 540 endif()
 541
 542 option(GMX_X11 "Use X window system" OFF)
 543 if (GMX_X11)
 544     find_package(X11)
 545     # X11 includes/libraries are only set in the ngmx subdirectory!
 546     if(NOT X11_FOUND)
 547         message(FATAL_ERROR
 548                 "X11 include files and/or libraries were not found. "
 549                 "Set GMX_X11=OFF to compile without X11 support. "
 550                 "gmx view will not be available.")
 551     endif()
 552     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 553 endif()
 554
 555 include(ThreadMPI)
 556 # Enable core threading facilities
 557 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 558 if(GMX_THREAD_MPI)
 559     # enable MPI functions
 560     tmpi_enable()
 561     set(MPI_IN_PLACE_EXISTS 1)
 562 endif()
 563 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 564 if (TMPI_ATOMICS_DISABLED)
 565    add_definitions(-DTMPI_ATOMICS_DISABLED)
 566 endif()
 567
 568 include(gmxManageTNG)
 569
 570 include(gmxManageLmfit)
 571
 572 if(GMX_GPU)
 573     # now that we have detected the dependencies, do the second configure pass
 574     gmx_gpu_setup()
 575     if (GMX_CLANG_CUDA)
 576         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 577         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 578     endif()
 579 endif()
 580
 581 if(CYGWIN)
 582     set(GMX_CYGWIN 1)
 583 endif()
 584
 585 if(WIN32)
 586     set(GMX_NATIVE_WINDOWS 1)
 587     # This makes windows.h not declare min/max as macros that would break
 588     # C++ code using std::min/std::max.
 589     add_definitions(-DNOMINMAX)
 590 endif()
 591
 592 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 593 mark_as_advanced(GMX_BUILD_UNITTESTS)
 594 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 595
 596 ########################################################################
 597 # Our own GROMACS tests
 598 ########################################################################
 599
 600 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 601 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 602 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 603
 604 include(gmxTestInlineASM)
 605 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 606
 607 include(gmxSetBuildInformation)
 608 gmx_set_build_information()
 609
 610 gmx_option_multichoice(
 611     GMX_USE_RDTSCP
 612     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 613     "AUTO"
 614     OFF ON AUTO DETECT)
 615 mark_as_advanced(GMX_USE_RDTSCP)
 616
 617 macro(gmx_check_rdtscp)
 618     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 619         set(HAVE_RDTSCP 1)
 620         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 621     else()
 622         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 623     endif()
 624 endmacro()
 625
 626 set(HAVE_RDTSCP 0)
 627 if (GMX_USE_RDTSCP STREQUAL "ON")
 628     set(HAVE_RDTSCP 1)
 629 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 630     gmx_check_rdtscp()
 631 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 632     # If the user specified automated SIMD selection, that the choice
 633     # is made based on detection on the build host. If so, then RDTSCP
 634     # should be chosen the same way.
 635     #
 636     # If the user specified an AVX SIMD level (e.g. when
 637     # cross-compiling GROMACS) then they will get our best guess, ie
 638     # that in practice AVX mostly correlates with rdtscp (and anyway
 639     # is only relevant in rather old x86 hardware).
 640     if (GMX_SIMD STREQUAL "AUTO")
 641         gmx_check_rdtscp()
 642     elseif (GMX_SIMD MATCHES "AVX")
 643         set(HAVE_RDTSCP 1)
 644     endif()
 645 endif()
 646 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 647 if (HAVE_RDTSCP_CHANGED)
 648     if (HAVE_RDTSCP)
 649         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 650     else()
 651         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 652     endif()
 653 endif()
 654
 655 include(gmxTestLargeFiles)
 656 gmx_test_large_files(GMX_LARGEFILES)
 657
 658 include(gmxTestSignal)
 659 gmx_test_sigusr1(HAVE_SIGUSR1)
 660
 661 include(gmxTestPipes)
 662 gmx_test_pipes(HAVE_PIPES)
 663
 664 include(gmxTestXDR)
 665 gmx_test_xdr(GMX_SYSTEM_XDR)
 666 # Darwin has system XDR, but it uses a three-argument flavour of
 667 # xdrproc_t that it guarantees will still work if you pass the normal
 668 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 669 # to do that, so it's simpler to just use our own XDR library.
 670 #
 671 # TODO It would be better to craft a cmake test which fails if such
 672 # XDR operations cause warnings, and succeeds otherwise, because it is
 673 # generally preferable to use system libraries where possible.
 674 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 675     set(GMX_INTERNAL_XDR 1)
 676 endif()
 677
 678
 679 ##################################################
 680 # Process SIMD instruction settings
 681 ##################################################
 682 # This checks what flags to add in order to
 683 # support the SIMD instructions we need, it sets
 684 # correct defines for the SIMD instructions supported,
 685 # and adds advanced options to control accuracy
 686 # for SIMD math operations.
 687 include(gmxManageSimd)
 688 gmx_manage_simd()
 689
 690 include(gmxManageCycleCounters)
 691 gmx_manage_cycle_counters()
 692
 693 # Process QM/MM Settings
 694 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 695     set(GMX_QMMM_GAUSSIAN 1)
 696 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 697     set(GMX_QMMM_MOPAC 1)
 698 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 699     set(GMX_QMMM_GAMESS 1)
 700 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 701     set(GMX_QMMM_ORCA 1)
 702 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 703     # nothing to do
 704 else()
 705     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 706 endif()
 707
 708
 709 ##################################################
 710 # Process FFT library settings
 711 ##################################################
 712 include(gmxManageFFTLibraries)
 713
 714
 715 include(gmxManageLinearAlgebraLibraries)
 716
 717 include(gmxManagePluginSupport)
 718
 719 if (GMX_USE_PLUGINS)
 720     if(NOT GMX_VMD_PLUGIN_PATH)
 721         find_package(VMD)
 722     endif()
 723 endif()
 724
 725 # Link real-time library for POSIX timers. The check for clock_gettime
 726 # confirms the linkability of rt.
 727 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 728     list(APPEND GMX_EXTRA_LIBRARIES rt)
 729 endif()
 730
 731 # Math and thread libraries must often come after all others when linking...
 732 if (HAVE_LIBM)
 733     list(APPEND GMX_PUBLIC_LIBRARIES m)
 734 endif()
 735
 736 option(GMX_NACL "Configure for Native Client builds" OFF)
 737 if (GMX_NACL)
 738   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 739   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 740   # TODO: Is this still necessary with the check for its presence?
 741   set(GMX_USE_NICE 0)
 742   set(GMX_NO_RENAME 1)
 743 endif()
 744 mark_as_advanced(GMX_NACL)
 745
 746 if(GMX_FAHCORE)
 747   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 748       "Path to swindirect.h")
 749   include_directories(${COREWRAP_INCLUDE_DIR})
 750 endif()
 751
 752 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 753 # produce warnings if that fails.
 754 set(build_help_default AUTO)
 755 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 756     set(build_help_default OFF)
 757 endif()
 758 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 759 mark_as_advanced(GMX_BUILD_HELP)
 760 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 761     message(FATAL_ERROR
 762         "Rebuilding shell completions or man pages is not supported for "
 763         "in-source builds from a source distribution. "
 764         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 765 endif()
 766
 767 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 768 # these are set after everything else
 769 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 770     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 771     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 772 else()
 773     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 774     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 775     foreach(build_type ${build_types_with_explicit_flags})
 776         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 777     endforeach()
 778     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 779     foreach(build_type ${build_types_with_explicit_flags})
 780         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 781     endforeach()
 782     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 783     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 784 endif()
 785
 786 ########################################################################
 787 # Specify install locations
 788 ########################################################################
 789 # Use GNUInstallDirs to set paths on multiarch systems.
 790 include(GNUInstallDirs)
 791
 792 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 793 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 794
 795 # Internal convenience so we do not have to join two path segments in the code
 796 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 797
 798 # If the nesting level wrt. the installation root is changed,
 799 # gromacs-config.cmake.cmakein needs to be adapted.
 800 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 801
 802 # TODO: Make GMXRC adapt if this is changed
 803 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 804 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 805
 806 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 807
 808 # Binary and library suffix options
 809 include(gmxManageSuffixes)
 810
 811 ################################################################
 812 # Shared library load path settings
 813 ################################################################
 814 if(NOT GMX_BUILD_SHARED_EXE)
 815     # No rpath
 816     set(CMAKE_SKIP_RPATH TRUE)
 817     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 818     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 819 else()
 820     # The build folder always has bin/ and lib/; if we are also going to
 821     # install to lib/, then the installation RPATH works also in the build
 822     # tree.  This makes installation slightly faster (no need to rewrite the
 823     # RPATHs), and makes the binaries in the build tree relocatable.
 824     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 825         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 826         set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 827     endif()
 828     # Set the RPATH as relative to the executable location to make the
 829     # binaries relocatable.
 830     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 831         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 832         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 833     else()
 834         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 835     endif()
 836     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 837     set(CMAKE_MACOSX_RPATH 1)
 838 endif()
 839
 840 #COPYING file: Only necessary for binary distributions.
 841 #Simpler to always install.
 842 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 843
 844 if (GMX_BUILD_FOR_COVERAGE)
 845     # Code heavy with asserts makes conditional coverage close to useless metric,
 846     # as by design most of the false branches are impossible to trigger in
 847     # correctly functioning code.  And the benefit of testing those that could
 848     # be triggered by using an API against its specification isn't usually
 849     # worth the effort.
 850     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 851 endif()
 852
 853 if (BUILD_TESTING)
 854     include(tests/CheckTarget.cmake)
 855 endif()
 856
 857 # TODO: Determine control flow and defaults for package installation and testing use cases.
 858 # Ref: http://redmine.gromacs.org/issues/2896
 859 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 860 mark_as_advanced(GMX_PYTHON_PACKAGE)
 861
 862 if (NOT GMX_BUILD_MDRUN_ONLY)
 863     # Note: Though only documented as an output variable, PYTHON_EXECUTABLE is
 864     # also effective as a CMake input variable to effectively hint the location
 865     # of the Python interpreter. This may be helpful in environments with both
 866     # Python 2 and Python 3 on the default PATH.
 867     # Ref: https://cmake.org/cmake/help/latest/module/FindPythonInterp.html
 868     if(FIND_PACKAGE_MESSAGE_DETAILS_PythonInterp)
 869         # Keep quiet on subsequent runs of cmake
 870         set(PythonInterp_FIND_QUIETLY ON)
 871     endif()
 872     # Older CMake versions might not search for Python newer than 3.7.
 873     set(Python_ADDITIONAL_VERSIONS 3.8)
 874     if(GMX_PYTHON_PACKAGE)
 875         find_package(PythonInterp 3.5 REQUIRED)
 876         # Note: PythonLibs will be found later by pybind11.
 877         # TODO: (issue #2998) When CMake >= 3.12 is required, update detection.
 878         # I.e.  find_package(Python3 3.5 COMPONENTS Interpreter Development REQUIRED)
 879     else()
 880         find_package(PythonInterp 3.5)
 881     endif()
 882     find_package(ImageMagick QUIET COMPONENTS convert)
 883     include(gmxTestImageMagick)
 884     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 885     # TODO: Resolve circular dependency between docs, gromacs, and python_packaging
 886     add_subdirectory(docs)
 887     add_subdirectory(share)
 888     add_subdirectory(scripts)
 889 endif()
 890 add_subdirectory(src)
 891
 892 if (BUILD_TESTING)
 893     add_subdirectory(tests)
 894 endif()
 895
 896 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 897     add_subdirectory(python_packaging)
 898 endif()
 899
 900 gmx_cpack_write_config()
 901
 902 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 903 # Don't bother the user after the first configure pass.
 904 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 905     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 906 endif()
 907 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 908
 909 #######################
 910 ## uninstall target
 911 #######################
 912 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 913                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 914                   IMMEDIATE @ONLY)
 915 ###########################
 916 ADD_CUSTOM_TARGET(uninstall
 917                   "${CMAKE_COMMAND}" -P
 918                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 919 ###########################
 920 set_directory_properties(PROPERTIES
 921             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")