src/gromacs/selection/scanner.l

   1 /*
   2  * This file is part of the GROMACS molecular simulation package.
   3  *
   4  * Copyright (c) 2009,2010,2011,2012,2013 by the GROMACS development team.
   5  * Copyright (c) 2014,2015,2016,2020, by the GROMACS development team, led by
   6  * Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   7  * and including many others, as listed in the AUTHORS file in the
   8  * top-level source directory and at http://www.gromacs.org.
   9  *
  10  * GROMACS is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU Lesser General Public License
  12  * as published by the Free Software Foundation; either version 2.1
  13  * of the License, or (at your option) any later version.
  14  *
  15  * GROMACS is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18  * Lesser General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU Lesser General Public
  21  * License along with GROMACS; if not, see
  22  * http://www.gnu.org/licenses, or write to the Free Software Foundation,
  23  * Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  24  *
  25  * If you want to redistribute modifications to GROMACS, please
  26  * consider that scientific software is very special. Version
  27  * control is crucial - bugs must be traceable. We will be happy to
  28  * consider code for inclusion in the official distribution, but
  29  * derived work must not be called official GROMACS. Details are found
  30  * in the README & COPYING files - if they are missing, get the
  31  * official version at http://www.gromacs.org.
  32  *
  33  * To help us fund GROMACS development, we humbly ask that you cite
  34  * the research papers on the package. Check out http://www.gromacs.org.
  35  */
  36 /*! \cond \internal \file scanner.l
  37  * \brief
  38  * Tokenizer for the selection language.
  39  *
  40  * \author Teemu Murtola <teemu.murtola@gmail.com>
  41  * \ingroup module_selection
  42  * \endcond
  43  */
  44 /*! \internal \file scanner.cpp
  45  * \brief
  46  * Generated (from scanner.l by Flex) tokenizer for the selection language.
  47  *
  48  * \ingroup module_selection
  49  */
  50 %top{
  51 #if !defined _gmx_sel_yyIN_HEADER
  52 #include "gmxpre.h"
  53 #endif
  54
  55 // Required before flex definitions, since it includes <stdint.h>.
  56 // Otherwise, compilers not strictly C99 get macro redefinition errors,
  57 // since flex defines INT32_MAX etc. in such cases.
  58 #include "gromacs/utility/basedefinitions.h"
  59 }
  60 %{
  61 #include "gromacs/utility/cstringutil.h"
  62 #include "gromacs/utility/stringutil.h"
  63
  64 #include "parser.h"
  65 #include "scanner.h"
  66 #include "scanner_internal.h"
  67
  68 // This macro makes the actions a bit shorter, since nearly every action needs
  69 // this call.
  70 #define ADD_TOKEN _gmx_sel_lexer_add_token(yylloc, yytext, yyleng, state)
  71
  72 // Set YY_BREAK to an empty value to avoid warnings (for the PGI compiler)
  73 // when we have return statements followed by break. Instead, we add breaks
  74 // manually.
  75 #define YY_BREAK
  76
  77 #ifdef __INTEL_COMPILER
  78 // Ignore unused variables in generated code.
  79 #pragma warning(disable:593)
  80 #endif
  81 %}
  82
  83 INTEGER    [[:digit:]]+
  84 DSEQ       ([[:digit:]]+)
  85 FRAC       (([[:digit:]]*"."{DSEQ})|{DSEQ}".")
  86 EXP        ([eE][+-]?{DSEQ})
  87 REAL       (({FRAC}{EXP}?)|({DSEQ}{EXP}))
  88 STRING     (\"([^\"\\\n]|(\\\"))*\")
  89 IDENTIFIER ([[:alpha:]][_[:alnum:]]*)
  90 CMPOP      (([<>]=?)|([!=]=))
  91 COMMENT    (#.*)
  92
  93 %option nodefault
  94 %option noyywrap
  95 %option reentrant
  96 %option prefix="_gmx_sel_yy"
  97 %option header-file="scanner_flex.h"
  98 %option nounistd
  99 %option never-interactive
 100
 101 %s matchof
 102 %s matchbool
 103 %s cmdstart
 104
 105 %%
 106
 107 %{
 108     gmx_sel_lexer_t *state = yyget_extra(yyscanner);
 109     int              retval;
 110     /* Return a token if one is pending */
 111     retval = _gmx_sel_lexer_process_pending(yylval, yylloc, state);
 112     if (retval != 0)
 113     {
 114         return retval;
 115     }
 116     /* Handle the start conditions for 'of' matching */
 117     if (state->bMatchOf)
 118     {
 119         BEGIN(matchof);
 120         state->bMatchOf = false;
 121     }
 122     else if (state->bMatchBool)
 123     {
 124         BEGIN(matchbool);
 125         state->bMatchBool = false;
 126     }
 127     else if (state->bCmdStart)
 128     {
 129         BEGIN(cmdstart);
 130         state->bCmdStart = false;
 131     }
 132     else
 133     {
 134         BEGIN(0);
 135     }
 136 %}
 137
 138 {COMMENT}       break;
 139 {INTEGER}       { yylval->i   = strtol(yytext, NULL, 10);    ADD_TOKEN; return TOK_INT; }
 140 {REAL}          { yylval->r   = strtod(yytext, NULL);        ADD_TOKEN; return TOK_REAL; }
 141 {STRING}        { yylval->str = gmx_strndup(yytext+1, yyleng-2); ADD_TOKEN; return STR;  }
 142
 143 \\\n            { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 144 ";"|\n          {
 145                     if (yytext[0] == ';' || state->statusWriter != NULL)
 146                     {
 147                         state->pselstr = gmx::stripString(state->pselstr);
 148                         state->bCmdStart = true;
 149                         return CMD_SEP;
 150                     }
 151                     else
 152                     {
 153                         _gmx_sel_lexer_add_token(yylloc, " ", 1, state);
 154                     }
 155                     break;
 156                 }
 157
 158 <cmdstart><<EOF>> { state->bCmdStart = true; yyterminate(); }
 159 <<EOF>>         { state->bCmdStart = true; return CMD_SEP; }
 160
 161 <matchbool>{
 162 yes|on          { ADD_TOKEN; yylval->i = 1; return TOK_INT; }
 163 no|off          { ADD_TOKEN; yylval->i = 0; return TOK_INT; }
 164 }
 165 group           { ADD_TOKEN; return GROUP; }
 166 to              { ADD_TOKEN; return TO; }
 167 <matchof>of     { ADD_TOKEN; BEGIN(0); return OF; }
 168 and|"&&"        { ADD_TOKEN; return AND; }
 169 or|"||"         { ADD_TOKEN; return OR; }
 170 xor             { ADD_TOKEN; return XOR; }
 171 not|"!"         { ADD_TOKEN; return NOT; }
 172 {CMPOP}         { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return CMP_OP; }
 173
 174 {IDENTIFIER}    { return _gmx_sel_lexer_process_identifier(yylval, yylloc, yytext, yyleng, state); }
 175
 176 [[:space:]]+    { _gmx_sel_lexer_add_token(yylloc, " ", 1, state); break; }
 177 [_[:alnum:]]+   { yylval->str = gmx_strndup(yytext, yyleng); ADD_TOKEN; return STR; }
 178 .               { ADD_TOKEN; return yytext[0]; }