src/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 ######################################
  36 # Output compiler and CFLAGS used
  37 ######################################
  38 include(GetCompilerInfo.cmake)
  39 get_compiler_info(C BUILD_C_COMPILER BUILD_CFLAGS)
  40 get_compiler_info(CXX BUILD_CXX_COMPILER BUILD_CXXFLAGS)
  41 if(GMX_USE_CUDA)
  42     if(NOT GMX_CLANG_CUDA)
  43         GMX_SET_CUDA_NVCC_FLAGS()
  44     endif()
  45
  46     get_cuda_compiler_info(CUDA_COMPILER_INFO CUDA_COMPILER_FLAGS)
  47 endif()
  48
  49 string(TOUPPER "${CMAKE_BUILD_TYPE}" CMAKE_BUILD_TYPE_UPPER)
  50 configure_file(config.h.cmakein config.h)
  51 configure_file(gmxpre-config.h.cmakein gmxpre-config.h)
  52 configure_file(buildinfo.h.cmakein buildinfo.h ESCAPE_QUOTES)
  53
  54 ####
  55 set(IGNORED_CLANG_ALL_WARNINGS
  56     "-Wno-c++98-compat -Wno-c++98-compat-pedantic" #No intention of C++98 compability
  57     "-Wno-source-uses-openmp" #Don't warn for no-omp build
  58     "-Wno-c++17-extensions"   #Allowed in attributes (compilers are required to ignore unknown attributes)
  59     "-Wno-documentation-unknown-command" #Custom commands are used
  60     "-Wno-covered-switch-default" #GCC gives maybe-uninitialized without default label and checks for illegal enum values.
  61     "-Wno-switch-enum" # default statement for enum is OK
  62
  63     # TODO uncomment the next few ignore lines when we upgrade to test with clang 8 in Jenkins
  64
  65     # The barriers we use for tMPI and Nbnxm are sufficient, but it's
  66     # not known whether they're excessive. We assume they not
  67     # excessive.
  68     # "-Wno-atomic-implicit-seq-cst"
  69
  70     # We need to use macros like
  71     # GMX_CATCH_ALL_AND_EXIT_WITH_FATAL_ERROR. Those will look strange
  72     # if they don't have a semicolon after them, and might confuse
  73     # tools like IDEs also.
  74     # "-Wno-extra-semi-stmt"
  75
  76     #Following ones are undecided/TODO
  77     "-Wno-disabled-macro-expansion"
  78     "-Wno-cast-align"
  79     "-Wno-reserved-id-macro"
  80     "-Wno-global-constructors"
  81     "-Wno-exit-time-destructors"
  82     "-Wno-unused-macros"
  83     "-Wno-weak-vtables"
  84     "-Wno-conditional-uninitialized"
  85     "-Wno-format-nonliteral"
  86     "-Wno-shadow"
  87     "-Wno-cast-qual"
  88     "-Wno-documentation"
  89     "-Wno-used-but-marked-unused"
  90     "-Wno-padded"
  91     "-Wno-float-equal"
  92     "-Wno-old-style-cast"
  93     "-Wno-conversion"
  94     "-Wno-double-promotion")
  95 string(REPLACE " " ";" IGNORED_CLANG_ALL_WARNINGS "${IGNORED_CLANG_ALL_WARNINGS}")
  96
  97 if (GMX_CLANG_TIDY)
  98    set(CLANG_TIDY "clang-tidy" CACHE STRING "Name of clang-tidy executable")
  99    find_program(CLANG_TIDY_EXE NAMES "${CLANG_TIDY}"
 100        DOC "Path to clang-tidy executable")
 101    if(NOT CLANG_TIDY_EXE)
 102        message(FATAL_ERROR "clang-tidy not found.")
 103    endif()
 104 endif()
 105 #####
 106
 107 if (BUILD_TESTING)
 108     if(NOT GMX_DEVELOPER_BUILD)
 109         set(UNITTEST_TARGET_OPTIONS EXCLUDE_FROM_ALL)
 110     endif()
 111     if (GMX_BUILD_UNITTESTS)
 112         add_subdirectory(external/googletest)
 113     endif()
 114     include(testutils/TestMacros.cmake)
 115     add_subdirectory(testutils)
 116 endif()
 117
 118 add_subdirectory(gromacs)
 119 add_subdirectory(programs)
 120
 121 # Activate targets for new C++ API components and docs.
 122 if(GMX_NATIVE_WINDOWS OR GMX_BUILD_MDRUN_ONLY OR NOT BUILD_SHARED_LIBS)
 123     # GMXAPI has not been tested in Microsoft environments.
 124     # GMXAPI relies on libgromacs and is incompatible with an `mdrun`-only build.
 125     # GMXAPI requires position-independent code
 126     set(_GMXAPI_DEFAULT OFF)
 127 else()
 128     set(_GMXAPI_DEFAULT OFF)
 129 endif()
 130 option(GMXAPI "Experimental external interfaces" ${_GMXAPI_DEFAULT})
 131 if (GMXAPI)
 132    if (GMX_BUILD_MDRUN_ONLY)
 133        message(FATAL_ERROR "GMXAPI relies on libgromacs and is incompatible with GMX_BUILD_MDRUN_ONLY.")
 134    endif()
 135    if(NOT ${BUILD_SHARED_LIBS})
 136        # Note: this conditional should check for the existence of a libgromacs target supporting PIC
 137        # using the POSITION_INDEPENDENT_CODE property, but for now the only facility we have is the global
 138        # variable, BUILD_SHARED_LIBS.
 139        # TODO: gmxapi should gracefully build for dynamic linking or static linking for PIC or without.
 140        message(FATAL_ERROR "GMXAPI requires position-independent code. Set -DGMXAPI=OFF or -DBUILD_SHARED_LIBS=ON.")
 141    endif()
 142    add_subdirectory(api)
 143 endif()