CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.4.3)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 # Use ccache if available to wrap CMAKE_C_COMPILER and CMAKE_CXX_COMPILER.
  44 # Reference https://ccache.samba.org
  45 option(ENABLE_CCACHE "Allow CMake to use ccache compiler wrappers if available." ON)
  46 # CMAKE_C_COMPILER and CMAKE_CXX_COMPILER do not change after this line.
  47 if(ENABLE_CCACHE)
  48     include(gmxCcache)
  49 endif()
  50
  51 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  52 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  53 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  54
  55 # Set up common version variables, as well as general information about
  56 # the build tree (whether the build is from a source package or from a git
  57 # repository).  Also declares a few functions that will be used for generating
  58 # version info files later.
  59 include(gmxBuildTreeInfo)
  60 include(gmxVersionInfo)
  61
  62 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  63     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  64 endif()
  65 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  66     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  67 endif()
  68
  69 include(gmxBuildTypeReference)
  70 include(gmxBuildTypeProfile)
  71 include(gmxBuildTypeTSAN)
  72 include(gmxBuildTypeASAN)
  73 include(gmxBuildTypeMSAN)
  74 include(gmxBuildTypeReleaseWithAssert)
  75
  76 if(NOT CMAKE_BUILD_TYPE)
  77     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  78     # Set the possible values of build type for cmake-gui
  79     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  80         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  81 endif()
  82 if(CMAKE_CONFIGURATION_TYPES)
  83     # Add appropriate GROMACS-specific build types for the Visual
  84     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  85     # are already present by default).
  86     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  87     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  88     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  89         "List of configuration types"
  90         FORCE)
  91 endif()
  92 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  93
  94 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  95
  96 include(gmxCTestUtilities)
  97 gmx_ctest_init()
  98
  99 include(gmxCPackUtilities)
 100 gmx_cpack_init()
 101
 102 # Variables that accumulate stuff influencing the installed headers
 103 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 104 set(INSTALLED_HEADER_DEFINITIONS "")
 105
 106 ########################################################################
 107 # Global non-cache variables for implementing the build system
 108 ########################################################################
 109
 110 # These variables collect libraries that GROMACS requires for
 111 # linking. They should be appended to with list(APPEND ${name}
 112 # new-library) calls. They are:
 113 #  - Libraries that are required for libgromacs (only)
 114 set(GMX_EXTRA_LIBRARIES "")
 115 #  - Libraries that are required for all code in the repository
 116 set(GMX_COMMON_LIBRARIES "")
 117 #  - Libraries that all code linked against libgromacs needs
 118 #    (i.e., something that is exposed in installed headers).
 119 set(GMX_PUBLIC_LIBRARIES "")
 120
 121 ########################################################################
 122 # Check and warn if cache generated on a different host is being reused
 123 ########################################################################
 124 if(CMAKE_HOST_UNIX)
 125     execute_process(COMMAND hostname
 126                     OUTPUT_VARIABLE TMP_HOSTNAME
 127                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 128     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 129         message(WARNING "
 130             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 131             is being reused! This could lead to inconsistencies; therefore, it is
 132             recommended to regenerate the cache!")
 133     endif()
 134     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 135             "Hostname of the machine where the cache was generated.")
 136 endif()
 137
 138 ########################################################################
 139 # Detect architecture before setting options so we can alter defaults
 140 ########################################################################
 141 # Detect the architecture the compiler is targetting, detect
 142 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 143 # to use if none is specified, and populate the cache option for CPU
 144 # SIMD.
 145 include(gmxDetectTargetArchitecture)
 146 gmx_detect_target_architecture()
 147
 148 # Permit the user to specify a particular standard library, e.g. compiling
 149 # with "-stdlib=libc++" and linking with "-lc++abi -lc++" to get clang's libcxx.
 150 set(GMX_STDLIB_CXX_FLAGS "" CACHE STRING "Compiler flag for a C++ standard library flavour")
 151 set(GMX_STDLIB_LIBRARIES "" CACHE STRING "Linker libraries for a particular C++ standard library")
 152 mark_as_advanced(GMX_STDLIB_CXX_FLAGS)
 153 mark_as_advanced(GMX_STDLIB_LIBRARIES)
 154
 155 ########################################################################
 156 # Detect CXX11 support and flags
 157 ########################################################################
 158 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 159 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 160 # invalid options with the Intel Compilers, and we have added a line
 161 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 162 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 163 # a semicolon. Since this is also used as a separator in lists inside CMake,
 164 # that string ends up being split into two separate patterns, and the last
 165 # part is just a single word that also matches other messages. We solved this
 166 # by replacing the semicolon with a period that matches any character.
 167 #
 168 # These files should be removed from the source tree when a CMake version that
 169 # includes the features in question becomes required for building GROMACS.
 170 include(CheckCCompilerFlag)
 171 include(CheckCXXCompilerFlag)
 172
 173 # This must come early, since some of our configuration flag tests
 174 # depend on being able to compile C++11 source files.
 175 include(gmxTestCXX11)
 176 gmx_test_cxx11(GMX_CXX11_FLAGS GMX_STDLIB_CXX_FLAGS GMX_STDLIB_LIBRARIES)
 177
 178 # Make sure all C++ code will be compiled in C++11 mode, with the
 179 # expected standard library.
 180 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${GMX_CXX11_FLAGS} ${GMX_STDLIB_CXX_FLAGS}")
 181
 182 ########################################################################
 183 # User input options                                                   #
 184 ########################################################################
 185 include(gmxOptionUtilities)
 186
 187 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 188
 189 # Fujitsu only has SIMD in double precision, so this will be faster
 190 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 191 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 192 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 193 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 194
 195 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 196 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 197 gmx_dependent_option(
 198     GMX_MPI_IN_PLACE
 199     "Enable MPI_IN_PLACE for MPIs that have it defined"
 200     ON
 201     GMX_MPI)
 202 mark_as_advanced(GMX_MPI_IN_PLACE)
 203
 204 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 205
 206 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 207 mark_as_advanced(GMX_FAHCORE)
 208
 209 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 210 mark_as_advanced(GMX_COOL_QUOTES)
 211 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 212
 213 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 214
 215 # Decide on GPU settings based on user-settings and GPU/CUDA
 216 # detection. VS2017 requires CUDA 9.0, for the other arch/compilers
 217 # rest we require CUDA 7.0 or later (including for clang-CUDA).
 218 if(MSVC)
 219     set(REQUIRED_CUDA_VERSION 9.0)
 220 else()
 221     set(REQUIRED_CUDA_VERSION 7.0)
 222 endif()
 223 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 224
 225 # OpenCL required version: 1.2 or newer
 226 set(REQUIRED_OPENCL_MIN_VERSION 1.2)
 227
 228 if(NOT GMX_USE_OPENCL)
 229     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 230     include(gmxManageGPU)
 231     set(GMX_USE_CUDA ${GMX_GPU})
 232     if(GMX_GPU)
 233         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 234     else()
 235         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 236     endif()
 237 else()
 238     #Now the OpenCL path (for both AMD and NVIDIA)
 239     if(GMX_GPU)
 240         include(gmxManageOpenCL)
 241         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 242     else()
 243         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 244     endif()
 245 endif()
 246
 247 gmx_option_multichoice(
 248     GMX_SIMD
 249     "SIMD instruction set for CPU kernels and compiler optimization"
 250     "AUTO"
 251     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 252
 253 if(GMX_TARGET_MIC)
 254     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 255 else()
 256     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 257 endif()
 258
 259 gmx_option_multichoice(
 260     GMX_FFT_LIBRARY
 261     "FFT library"
 262     "${GMX_FFT_LIBRARY_DEFAULT}"
 263     fftw3 mkl "fftpack[built-in]")
 264 gmx_dependent_option(
 265     GMX_BUILD_OWN_FFTW
 266     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 267     OFF
 268     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 269 gmx_dependent_option(
 270     GMX_DISABLE_FFTW_MEASURE
 271     "Do not optimize FFTW setups (not needed with SSE)"
 272     OFF
 273     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 274 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 275 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 276
 277 gmx_option_multichoice(
 278     GMX_QMMM_PROGRAM
 279     "QM package for QM/MM"
 280     None
 281     none gaussian mopac gamess orca)
 282
 283 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 284 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 285
 286 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 287
 288 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 289 mark_as_advanced(GMX_BROKEN_CALLOC)
 290
 291 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 292
 293 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 294
 295 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 296
 297 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 298 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 299
 300 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 301 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 302
 303 option(GMX_BUILD_FOR_COVERAGE
 304        "Tune build for better code coverage metrics (e.g., disable asserts)"
 305        OFF)
 306 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 307
 308 option(GMX_DEVELOPER_BUILD
 309     "Enable Developer convenience features: always build unit-tests"
 310     OFF)
 311 mark_as_advanced(GMX_DEVELOPER_BUILD)
 312
 313 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 314 option(GMX_COMPILER_WARNINGS
 315     "Enable a default set of compiler warnings"
 316     ${GMX_COMPILER_WARNINGS_DEFAULT})
 317 mark_as_advanced(GMX_COMPILER_WARNINGS)
 318 # Always turn on compiler warnings with a developer build.
 319 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 320
 321 option(GMX_BUILD_SHARED_EXE
 322     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 323     ON)
 324 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 325
 326 option(GMX_PHYSICAL_VALIDATION
 327        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 328        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 329        OFF)
 330 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 331
 332 ######################################################################
 333 # Detect OpenMP support
 334 ######################################################################
 335 # The OpenMP detection _must_ come before tests for other CFLAGS.
 336 include(gmxManageOpenMP)
 337
 338
 339
 340 ######################################################################
 341 # Compiler tests
 342 # These need to be done early (before further tests).
 343 #####################################################################
 344
 345 include(gmxCFlags)
 346 gmx_c_flags()
 347
 348 # This variable should be used for additional compiler flags which are not
 349 # generated in gmxCFlags nor are SIMD or MPI related.
 350 #
 351 # TODO These variables should be consolidated into
 352 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 353 # things that work in C compilation (e.g. merging from old branches)
 354 # also work for C++ compilation.
 355 set(EXTRA_C_FLAGS "")
 356 set(EXTRA_CXX_FLAGS "")
 357
 358 # Run through a number of tests for buggy compilers and other issues
 359 include(gmxTestCompilerProblems)
 360 gmx_test_compiler_problems()
 361
 362 # Implement double-precision option. This is complicated because we
 363 # need installed headers to use the precision mode of the build that
 364 # produced the library, but cannot use config.h in that case. We also
 365 # want such variables to always have a definition, because #if is more
 366 # robust than #ifdef. So, we put this value on the compiler command
 367 # line in all cases.
 368 #
 369 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 370 # because no installed header needs it
 371 if(GMX_DOUBLE)
 372     set(GMX_DOUBLE_VALUE 1)
 373 else()
 374     set(GMX_DOUBLE_VALUE 0)
 375 endif()
 376 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 377 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 378
 379 if(WIN32)
 380     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 381     add_definitions(-DGMX_HAVE_WINSOCK)
 382 endif()
 383
 384
 385
 386 ########################################################################
 387 # Basic system tests (standard libraries, headers, functions, types)   #
 388 ########################################################################
 389 include(CheckIncludeFiles)
 390 include(CheckIncludeFileCXX)
 391 check_include_files(unistd.h     HAVE_UNISTD_H)
 392 check_include_files(pwd.h        HAVE_PWD_H)
 393 check_include_files(dirent.h     HAVE_DIRENT_H)
 394 check_include_files(time.h       HAVE_TIME_H)
 395 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 396 check_include_files(io.h         HAVE_IO_H)
 397 check_include_files(sched.h      HAVE_SCHED_H)
 398
 399 check_include_files(regex.h      HAVE_POSIX_REGEX)
 400 # TODO: It could be nice to inform the user if no regex support is found,
 401 # as selections won't be fully functional.
 402
 403 include(CheckCXXSymbolExists)
 404 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 405 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 406 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 407 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 408 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 409 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 410 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 411 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 412
 413 # We cannot check for the __builtins as symbols, but check if code compiles
 414 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 415 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 416 if(MSVC)
 417     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 418     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 419 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 420     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 421     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 422 endif()
 423
 424 include(CheckLibraryExists)
 425 find_library(HAVE_LIBM m)
 426 mark_as_advanced(HAVE_LIBM)
 427 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 428 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 429 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 430
 431 include(TestSchedAffinity)
 432 test_sched_affinity(HAVE_SCHED_AFFINITY)
 433
 434 # Aligned memory allocation. We need to check for both mm_malloc(),
 435 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 436 include(gmxTestMMMalloc)
 437 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 438 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 439 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 440 if(MSVC)
 441     # No need to waste time on this test on platforms where it will never be true
 442     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 443 endif()
 444
 445 include(TestBigEndian)
 446 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 447
 448 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 449
 450 # Management of GROMACS options for specific toolchains should go
 451 # here. Because the initial settings for some of the main options have
 452 # already happened, but things like library detection and MPI compiler
 453 # feature detection have not, the docstrings for any over-rides of
 454 # GROMACS defaults or user settings will make sense. Also, any
 455 # toolchain-related reasons for choosing whether to detect various
 456 # things can be sorted out now, before the detection takes place.
 457 if(GMX_TARGET_FUJITSU_SPARC64)
 458     include(gmxManageFujitsuSparc64)
 459 endif()
 460
 461 ########################################################################
 462 #Process MPI settings
 463 ########################################################################
 464 include(gmxManageMPI)
 465
 466 ########################################################################
 467 #Process MiMiC settings
 468 ########################################################################
 469 include(gmxManageMimic)
 470
 471 ########################################################################
 472 #Process shared/static library settings
 473 ########################################################################
 474 include(gmxManageSharedLibraries)
 475
 476
 477 ########################################################################
 478 # Find external packages                                               #
 479 ########################################################################
 480
 481 # Unconditionally find the package, as it is also required for unit
 482 # tests. This exports LIBXML2_FOUND, which we should not use because
 483 # it does not tell us that linking will succeed. Instead, we test that
 484 # next.
 485 #if(DEFINED LIBXML2_LIBRARIES)
 486 #  set(LibXml2_FIND_QUIETLY TRUE)
 487 #endif()
 488 #find_package(LibXml2)
 489 #include(gmxTestLibXml2)
 490 #gmx_test_libxml2(HAVE_LIBXML2)
 491 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 492 #set(PKG_XML "")
 493 #mark_as_advanced(GMX_XML)
 494 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 495 #if(GMX_XML AND NOT HAVE_LIBXML2)
 496 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 497 #endif()
 498 #if(GMX_XML)
 499 #    include_directories(${LIBXML2_INCLUDE_DIR})
 500 #    set(PKG_XML libxml-2.0)
 501 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 502 #endif()
 503
 504 gmx_option_trivalue(
 505     GMX_HWLOC
 506     "Use hwloc portable hardware locality library"
 507     "AUTO")
 508
 509 if (GMX_HWLOC)
 510     # Find quietly the second time.
 511     if(DEFINED HWLOC_LIBRARIES)
 512         set(Hwloc_FIND_QUIETLY TRUE)
 513     endif()
 514     find_package(Hwloc 1.5)
 515
 516     if (HWLOC_FOUND)
 517         if (HWLOC_LIBRARIES MATCHES ".a$")
 518             set(_STATIC_HWLOC TRUE)
 519         endif()
 520
 521         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 522         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED)
 523             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 524             set(GMX_USE_HWLOC OFF)
 525         else()
 526             set(GMX_USE_HWLOC ON)
 527         endif()
 528
 529         if (GMX_USE_HWLOC)
 530             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 531             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 532         endif()
 533     elseif(GMX_HWLOC_FORCE)
 534         message(FATAL_ERROR "Hwloc package support required, but not found.")
 535     endif()
 536 endif()
 537
 538 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 539 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 540 if(GMX_EXTERNAL_TINYXML2)
 541     # Find an external TinyXML-2 library.
 542     find_package(TinyXML-2 3.0.0)
 543     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 544     if(NOT HAVE_TINYXML2)
 545         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 546     endif()
 547 endif()
 548
 549 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 550 mark_as_advanced(GMX_EXTRAE)
 551
 552 if (GMX_EXTRAE)
 553   find_package(EXTRAE)
 554   if(EXTRAE_FOUND)
 555     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 556     set(HAVE_EXTRAE 1)
 557   else()
 558     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 559   endif()
 560 endif()
 561
 562 option(GMX_X11 "Use X window system" OFF)
 563 if (GMX_X11)
 564     find_package(X11)
 565     # X11 includes/libraries are only set in the ngmx subdirectory!
 566     if(NOT X11_FOUND)
 567         message(FATAL_ERROR
 568                 "X11 include files and/or libraries were not found. "
 569                 "Set GMX_X11=OFF to compile without X11 support. "
 570                 "gmx view will not be available.")
 571     endif()
 572     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 573 endif()
 574
 575 include(ThreadMPI)
 576 # Enable core threading facilities
 577 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 578 if(GMX_THREAD_MPI)
 579     # enable MPI functions
 580     tmpi_enable()
 581     set(MPI_IN_PLACE_EXISTS 1)
 582 endif()
 583 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 584 if (TMPI_ATOMICS_DISABLED)
 585    add_definitions(-DTMPI_ATOMICS_DISABLED)
 586 endif()
 587
 588 include(gmxManageTNG)
 589
 590 include(gmxManageLmfit)
 591
 592 if(GMX_GPU)
 593     # now that we have detected the dependencies, do the second configure pass
 594     gmx_gpu_setup()
 595     if (GMX_CLANG_CUDA)
 596         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 597         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 598     endif()
 599 endif()
 600
 601 if(CYGWIN)
 602     set(GMX_CYGWIN 1)
 603 endif()
 604
 605 if(WIN32)
 606     set(GMX_NATIVE_WINDOWS 1)
 607     # This makes windows.h not declare min/max as macros that would break
 608     # C++ code using std::min/std::max.
 609     add_definitions(-DNOMINMAX)
 610 endif()
 611
 612 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 613     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 614         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 615     endif()
 616     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 617         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 618     endif()
 619 endif()
 620
 621 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 622 mark_as_advanced(GMX_BUILD_UNITTESTS)
 623 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 624
 625 ########################################################################
 626 # Our own GROMACS tests
 627 ########################################################################
 628
 629 add_definitions( -DHAVE_CONFIG_H )
 630 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 631 # TODO required at high level because both libgromacs and progs/mdrun
 632 # require it, both for thread-MPI and its atomics and mutexes.
 633 include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 634 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 635 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 636
 637 include(gmxTestInlineASM)
 638 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 639
 640 include(gmxSetBuildInformation)
 641 gmx_set_build_information()
 642
 643 gmx_option_multichoice(
 644     GMX_USE_RDTSCP
 645     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 646     "AUTO"
 647     OFF ON AUTO DETECT)
 648 mark_as_advanced(GMX_USE_RDTSCP)
 649
 650 macro(gmx_check_rdtscp)
 651     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 652         set(HAVE_RDTSCP 1)
 653         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 654     else()
 655         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 656     endif()
 657 endmacro()
 658
 659 set(HAVE_RDTSCP 0)
 660 if (GMX_USE_RDTSCP STREQUAL "ON")
 661     set(HAVE_RDTSCP 1)
 662 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 663     gmx_check_rdtscp()
 664 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 665     # If the user specified automated SIMD selection, that the choice
 666     # is made based on detection on the build host. If so, then RDTSCP
 667     # should be chosen the same way.
 668     #
 669     # If the user specified an AVX SIMD level (e.g. when
 670     # cross-compiling GROMACS) then they will get our best guess, ie
 671     # that in practice AVX mostly correlates with rdtscp (and anyway
 672     # is only relevant in rather old x86 hardware).
 673     if (GMX_SIMD STREQUAL "AUTO")
 674         gmx_check_rdtscp()
 675     elseif (GMX_SIMD MATCHES "AVX")
 676         set(HAVE_RDTSCP 1)
 677     endif()
 678 endif()
 679 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 680 if (HAVE_RDTSCP_CHANGED)
 681     if (HAVE_RDTSCP)
 682         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 683     else()
 684         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 685     endif()
 686 endif()
 687
 688 include(gmxTestLargeFiles)
 689 gmx_test_large_files(GMX_LARGEFILES)
 690
 691 include(gmxTestSignal)
 692 gmx_test_sigusr1(HAVE_SIGUSR1)
 693
 694 include(gmxTestPipes)
 695 gmx_test_pipes(HAVE_PIPES)
 696
 697 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 698
 699 include(gmxTestXDR)
 700 gmx_test_xdr(GMX_SYSTEM_XDR)
 701 # Darwin has system XDR, but it uses a three-argument flavour of
 702 # xdrproc_t that it guarantees will still work if you pass the normal
 703 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 704 # to do that, so it's simpler to just use our own XDR library.
 705 #
 706 # TODO It would be better to craft a cmake test which fails if such
 707 # XDR operations cause warnings, and succeeds otherwise, because it is
 708 # generally preferable to use system libraries where possible.
 709 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 710     set(GMX_INTERNAL_XDR 1)
 711 endif()
 712
 713
 714 ##################################################
 715 # Process SIMD instruction settings
 716 ##################################################
 717 # This checks what flags to add in order to
 718 # support the SIMD instructions we need, it sets
 719 # correct defines for the SIMD instructions supported,
 720 # and adds advanced options to control accuracy
 721 # for SIMD math operations.
 722 include(gmxManageSimd)
 723 gmx_manage_simd()
 724
 725 include(gmxManageCycleCounters)
 726 gmx_manage_cycle_counters()
 727
 728 # Process QM/MM Settings
 729 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 730     set(GMX_QMMM_GAUSSIAN 1)
 731 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 732     set(GMX_QMMM_MOPAC 1)
 733 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 734     set(GMX_QMMM_GAMESS 1)
 735 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 736     set(GMX_QMMM_ORCA 1)
 737 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 738     # nothing to do
 739 else()
 740     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 741 endif()
 742
 743
 744 ##################################################
 745 # Process FFT library settings
 746 ##################################################
 747 include(gmxManageFFTLibraries)
 748
 749
 750 include(gmxManageLinearAlgebraLibraries)
 751
 752 include(gmxManagePluginSupport)
 753
 754 if (GMX_USE_PLUGINS)
 755     if(NOT GMX_VMD_PLUGIN_PATH)
 756         find_package(VMD)
 757     endif()
 758 endif()
 759
 760 # Link real-time library for POSIX timers. The check for clock_gettime
 761 # confirms the linkability of rt.
 762 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 763     list(APPEND GMX_EXTRA_LIBRARIES rt)
 764 endif()
 765
 766 # Math and thread libraries must often come after all others when linking...
 767 if (HAVE_LIBM)
 768     list(APPEND GMX_PUBLIC_LIBRARIES m)
 769 endif()
 770
 771 option(GMX_NACL "Configure for Native Client builds" OFF)
 772 if (GMX_NACL)
 773   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 774   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 775   # TODO: Is this still necessary with the check for its presence?
 776   set(GMX_USE_NICE 0)
 777   set(GMX_NO_RENAME 1)
 778 endif()
 779 mark_as_advanced(GMX_NACL)
 780
 781 if(GMX_FAHCORE)
 782   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 783       "Path to swindirect.h")
 784   include_directories(${COREWRAP_INCLUDE_DIR})
 785 endif()
 786
 787 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 788 # produce warnings if that fails.
 789 set(build_help_default AUTO)
 790 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 791     set(build_help_default OFF)
 792 endif()
 793 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 794 mark_as_advanced(GMX_BUILD_HELP)
 795 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 796     message(FATAL_ERROR
 797         "Rebuilding shell completions or man pages is not supported for "
 798         "in-source builds from a source distribution. "
 799         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 800 endif()
 801
 802 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 803 # these are set after everything else
 804 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 805     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 806     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 807     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 808     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 809 else()
 810     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 811     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 812     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 813     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 814     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 815     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 816     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 817     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 818     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 819 endif()
 820
 821 if(NOT GMX_OPENMP)
 822     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 823     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 824     unset(OpenMP_C_FLAGS CACHE)
 825     unset(OpenMP_CXX_FLAGS CACHE)
 826 else()
 827     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 828     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 829 endif()
 830
 831
 832 ########################################################################
 833 # Specify install locations
 834 ########################################################################
 835 # Use GNUInstallDirs to set paths on multiarch systems.
 836 include(GNUInstallDirs)
 837
 838 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 839 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 840
 841 # Internal convenience so we do not have to join two path segments in the code
 842 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 843
 844 # If the nesting level wrt. the installation root is changed,
 845 # gromacs-config.cmake.cmakein needs to be adapted.
 846 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 847
 848 # TODO: Make GMXRC adapt if this is changed
 849 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 850 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 851
 852 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 853
 854 # Binary and library suffix options
 855 include(gmxManageSuffixes)
 856
 857 ################################################################
 858 # Shared library load path settings
 859 ################################################################
 860 if(NOT GMX_BUILD_SHARED_EXE)
 861     # No rpath
 862     set(CMAKE_SKIP_RPATH TRUE)
 863     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 864     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 865 else()
 866     # The build folder always has bin/ and lib/; if we are also going to
 867     # install to lib/, then the installation RPATH works also in the build
 868     # tree.  This makes installation slightly faster (no need to rewrite the
 869     # RPATHs), and makes the binaries in the build tree relocatable.
 870     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 871         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 872         if(POLICY CMP0068)
 873             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 874             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 875         endif()
 876     endif()
 877     # Set the RPATH as relative to the executable location to make the
 878     # binaries relocatable.
 879     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 880         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 881         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 882     else()
 883         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 884     endif()
 885     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 886     set(CMAKE_MACOSX_RPATH 1)
 887 endif()
 888
 889 #COPYING file: Only necessary for binary distributions.
 890 #Simpler to always install.
 891 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 892
 893 if (GMX_BUILD_FOR_COVERAGE)
 894     # Code heavy with asserts makes conditional coverage close to useless metric,
 895     # as by design most of the false branches are impossible to trigger in
 896     # correctly functioning code.  And the benefit of testing those that could
 897     # be triggered by using an API against its specification isn't usually
 898     # worth the effort.
 899     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 900 endif()
 901
 902 if (BUILD_TESTING)
 903     include(tests/CheckTarget.cmake)
 904 endif()
 905
 906 if (NOT GMX_BUILD_MDRUN_ONLY)
 907     add_subdirectory(docs)
 908     add_subdirectory(share)
 909     add_subdirectory(scripts)
 910 endif()
 911 add_subdirectory(src)
 912
 913 if (BUILD_TESTING)
 914     add_subdirectory(tests)
 915 endif()
 916
 917 gmx_cpack_write_config()
 918
 919 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 920 # Don't bother the user after the first configure pass.
 921 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 922     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 923 endif()
 924 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 925
 926 #######################
 927 ## uninstall target
 928 #######################
 929 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 930                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 931                   IMMEDIATE @ONLY)
 932 ###########################
 933 ADD_CUSTOM_TARGET(uninstall
 934                   "${CMAKE_COMMAND}" -P
 935                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 936 ###########################
 937 set_directory_properties(PROPERTIES
 938             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")