CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  56 # defined.
  57 set(PROJECT_VERSION "5.0-rc1-dev")
  58 # If this is a released tarball, "-dev" will not be present in
  59 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  60 # number of the regressiontest tarball against which the code tarball
  61 # can be tested. This will be the version of the last patch release.
  62 set(REGRESSIONTEST_VERSION "5.0-rc1")
  63 # If this is not a released tarball, "-dev" will be present in
  64 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  65 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  66 # code contains all recent fixes from the corresponding code branch.
  67 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  68
  69 set(CUSTOM_VERSION_STRING ""
  70     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  71 mark_as_advanced(CUSTOM_VERSION_STRING)
  72 if (CUSTOM_VERSION_STRING)
  73     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  74 endif()
  75 set(LIBRARY_SOVERSION 0)
  76 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  77 # It is a bit irritating, but this has to be set separately for now!
  78 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  79 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  80 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  81
  82 # The numerical gromacs version. It is 40600 for 4.6.0.
  83 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  84 math(EXPR NUM_VERSION
  85     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  86 if(CPACK_PACKAGE_VERSION_PATCH)
  87     math(EXPR NUM_VERSION
  88          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  89 endif()
  90
  91 # The API version tracks the numerical Gromacs version (for now).
  92 # It is potentially different from the Gromacs version in the future, if
  93 # the programs/libraries diverge from the presumably more stable API.
  94 # The #define GMX_API_VERSION in version.h is set to this value to
  95 # provide backward compatibility of software written against the Gromacs API.
  96 set(API_VERSION ${NUM_VERSION})
  97
  98 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  99     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 100 endif()
 101
 102 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
 103 mark_as_advanced(GMX_INSTALL_PREFIX)
 104
 105 include(gmxBuildTypeReference)
 106 include(gmxBuildTypeThreadSanitizer)
 107 include(gmxBuildTypeReleaseWithAssert)
 108
 109 if(NOT CMAKE_BUILD_TYPE)
 110     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 111     # There's no need to offer a user the choice of ThreadSanitizer
 112     # Set the possible values of build type for cmake-gui
 113     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 114         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 115 endif()
 116 if(CMAKE_CONFIGURATION_TYPES)
 117     # Add appropriate GROMACS-specific build types for the Visual
 118     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 119     # are already present by default).
 120     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 121     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 122     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 123         "List of configuration types"
 124         FORCE)
 125 endif()
 126 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 127
 128 enable_language(C)
 129 enable_language(CXX)
 130
 131 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 132 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 133 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 134 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 135 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 136 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 137 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 138 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 139 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 140 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 141 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 142
 143 #must come after all cpack settings!
 144 include(CPack)
 145
 146 # Set a default valgrind suppression file.
 147 # This unfortunately needs to duplicate information from CTest to work as
 148 # expected...
 149 set(MEMORYCHECK_SUPPRESSIONS_FILE
 150     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 151     CACHE FILEPATH
 152     "File that contains suppressions for the memory checker")
 153 include(CTest)
 154
 155 set(SOURCE_IS_GIT_REPOSITORY OFF)
 156 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 157 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 158     set(SOURCE_IS_GIT_REPOSITORY ON)
 159 endif()
 160 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 161     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 162 endif()
 163
 164 ########################################################################
 165 # Check and warn if cache generated on a different host is being reused
 166 ########################################################################
 167 if(CMAKE_HOST_UNIX)
 168     execute_process(COMMAND hostname
 169                     OUTPUT_VARIABLE TMP_HOSTNAME
 170                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 171     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 172         message(WARNING "
 173             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 174             is being reused! This could lead to inconsitencies; therefore, it is
 175             recommended to regenerate the cache!")
 176     endif()
 177     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 178             "Hostname of the machine where the cache was generated.")
 179 endif()
 180
 181 ########################################################################
 182 # User input options                                                   #
 183 ########################################################################
 184 include(gmxOptionUtilities)
 185
 186 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 187
 188 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 189 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 190 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 191 gmx_dependent_option(
 192     GMX_MPI_IN_PLACE
 193     "Enable MPI_IN_PLACE for MPIs that have it defined"
 194     ON
 195     GMX_MPI)
 196 mark_as_advanced(GMX_MPI_IN_PLACE)
 197 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 198 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 199 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 200 mark_as_advanced(GMX_FAHCORE)
 201
 202 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 203 mark_as_advanced(GMX_COOL_QUOTES)
 204 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 205
 206 # decide on GPU settings based on user-settings and GPU/CUDA detection
 207 include(gmxManageGPU)
 208
 209 # Detect the architecture the compiler is targetting, detect
 210 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 211 # to use if none is specified, and populate the cache option for CPU
 212 # SIMD.
 213 include(gmxDetectTargetArchitecture)
 214 gmx_detect_target_architecture()
 215
 216 if(GMX_CPU_ACCELERATION)
 217     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 218     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 219     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 220     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 221 endif()
 222
 223 if(NOT GMX_TARGET_MIC)
 224     include(gmxDetectSimd)
 225     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 226 else()
 227     set(GMX_SUGGESTED_SIMD "None")
 228 endif()
 229
 230 gmx_option_multichoice(
 231     GMX_SIMD
 232     "SIMD instruction set for CPU kernels and compiler optimization"
 233     "${GMX_SUGGESTED_SIMD}"
 234     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 235
 236 gmx_option_multichoice(
 237     GMX_FFT_LIBRARY
 238     "FFT library"
 239     "fftw3"
 240     fftw3 mkl "fftpack[built-in]")
 241 gmx_dependent_option(
 242     GMX_BUILD_OWN_FFTW
 243     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 244     OFF
 245     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 246 gmx_dependent_option(
 247     GMX_DISABLE_FFTW_MEASURE
 248     "Do not optimize FFTW setups (not needed with SSE)"
 249     OFF
 250     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 251 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 252 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 253
 254 gmx_option_multichoice(
 255     GMX_QMMM_PROGRAM
 256     "QM package for QM/MM"
 257     None
 258     none gaussian mopac gamess orca)
 259
 260 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 261 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 262
 263 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 264
 265 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 266 mark_as_advanced(GMX_BROKEN_CALLOC)
 267 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 268 mark_as_advanced(GMX_LOAD_PLUGINS)
 269
 270 option(GMX_GPU  "Enable GPU acceleration" ON)
 271 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 272
 273 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 274
 275 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 276 mark_as_advanced(GMX_GIT_VERSION_INFO)
 277
 278 if(UNIX)
 279     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 280 endif()
 281 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 282
 283 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 284 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 285
 286 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 287 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 288
 289 option(GMX_BUILD_FOR_COVERAGE
 290        "Tune build for better code coverage metrics (e.g., disable asserts)"
 291        OFF)
 292 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 293
 294
 295 ######################################################################
 296 # Detect OpenMP support
 297 ######################################################################
 298 # The OpenMP detection _must_ come before tests for other CFLAGS.
 299 include(gmxManageOpenMP)
 300
 301
 302
 303 ######################################################################
 304 # Compiler tests
 305 # These need to be done early (before further tests).
 306 #####################################################################
 307
 308 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 309 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 310 # invalid options with the Intel Compilers.
 311 # These files should be removed from the source tree when a CMake version that
 312 # includes the features in question becomes required for building GROMACS.
 313 include(CheckCCompilerFlag)
 314 include(CheckCXXCompilerFlag)
 315
 316
 317 include(gmxCFlags)
 318 gmx_c_flags()
 319
 320 # This variable should be used for additional compiler flags which are not
 321 # generated in gmxCFlags nor are SIMD or MPI related.
 322 set(EXTRA_C_FLAGS "")
 323 set(EXTRA_CXX_FLAGS "")
 324
 325 # Run through a number of tests for buggy compilers and other issues
 326 include(gmxTestCompilerProblems)
 327 gmx_test_compiler_problems()
 328 # GMX_SIMD will not be set automatically until the second
 329 # pass (which is not strictly guaranteed to occur), so putting this
 330 # check here among logically-related tests is inefficient, but the
 331 # potential loss is likely zero.
 332 if(GMX_SIMD STREQUAL "AVX_256"
 333         AND CMAKE_COMPILER_IS_GNUCC
 334         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 335             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 336     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 337     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 338 endif()
 339
 340
 341
 342 set(PKG_CFLAGS "")
 343 if(GMX_DOUBLE)
 344     add_definitions(-DGMX_DOUBLE)
 345     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 346 endif()
 347 if(GMX_SOFTWARE_INVSQRT)
 348   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 349 endif()
 350
 351 if(WIN32 AND NOT CYGWIN)
 352     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 353     mark_as_advanced(GMX_WSOCKLIB_PATH)
 354     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 355     if(WSOCK32_LIBRARY)
 356         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 357         add_definitions(-DGMX_HAVE_WINSOCK)
 358     else()
 359         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 360     endif(WSOCK32_LIBRARY)
 361 endif()
 362
 363
 364
 365 ########################################################################
 366 # Basic system tests (standard libraries, headers, functions, types)   #
 367 ########################################################################
 368 include(CheckIncludeFiles)
 369 include(CheckIncludeFileCXX)
 370 check_include_files(unistd.h     HAVE_UNISTD_H)
 371 check_include_files(pwd.h        HAVE_PWD_H)
 372 check_include_files(dirent.h     HAVE_DIRENT_H)
 373 check_include_files(time.h       HAVE_TIME_H)
 374 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 375 check_include_files(io.h         HAVE_IO_H)
 376 check_include_files(sched.h      HAVE_SCHED_H)
 377
 378 check_include_files(regex.h      HAVE_POSIX_REGEX)
 379 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 380 # TODO: It could be nice to inform the user if no regex support is found,
 381 # as selections won't be fully functional.
 382
 383 include(CheckFunctionExists)
 384 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 385 check_function_exists(memalign          HAVE_MEMALIGN)
 386 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 387 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 388 check_function_exists(fsync             HAVE_FSYNC)
 389 check_function_exists(_fileno           HAVE__FILENO)
 390 check_function_exists(fileno            HAVE_FILENO)
 391 check_function_exists(_commit           HAVE__COMMIT)
 392 check_function_exists(sigaction         HAVE_SIGACTION)
 393 check_function_exists(sysconf           HAVE_SYSCONF)
 394 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 395 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 396 check_function_exists(rsqrt             HAVE_RSQRT)
 397 check_function_exists(rsqrtf            HAVE_RSQRTF)
 398 check_function_exists(sqrtf             HAVE_SQRTF)
 399
 400 include(CheckLibraryExists)
 401 check_library_exists(m sqrt "" HAVE_LIBM)
 402 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 403
 404 include(TestBigEndian)
 405 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 406
 407 # Management of GROMACS options for specific toolchains should go
 408 # here. Because the initial settings for some of the main options have
 409 # already happened, but things like library detection and MPI compiler
 410 # feature detection have not, the docstrings for any over-rides of
 411 # GROMACS defaults or user settings will make sense. Also, any
 412 # toolchain-related reasons for choosing whether to detect various
 413 # things can be sorted out now, before the detection takes place.
 414 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 415     include(gmxManageBlueGene)
 416 endif()
 417
 418 ########################################################################
 419 #Process MPI settings
 420 ########################################################################
 421 include(gmxManageMPI)
 422
 423
 424 ########################################################################
 425 #Process shared/static library settings
 426 ########################################################################
 427 include(gmxManageSharedLibraries)
 428
 429
 430 ########################################################################
 431 # Find external packages                                               #
 432 ########################################################################
 433
 434 # Unconditionally find the package, as it is also required for unit
 435 # tests. This exports LIBXML2_FOUND, which we should not use because
 436 # it does not tell us that linking will succeed. Instead, we test that
 437 # next.
 438 find_package(LibXml2)
 439 include(gmxTestLibXml2)
 440 gmx_test_libxml2(HAVE_LIBXML2)
 441 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 442 set(PKG_XML "")
 443 mark_as_advanced(GMX_XML)
 444 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 445 #if(GMX_XML AND NOT HAVE_LIBXML2)
 446 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 447 #endif()
 448 #if(GMX_XML)
 449 #    include_directories(${LIBXML2_INCLUDE_DIR})
 450 #    set(PKG_XML libxml-2.0)
 451 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 452 #endif()
 453
 454 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 455 mark_as_advanced(GMX_EXTRAE)
 456
 457 if (GMX_EXTRAE)
 458   find_package(EXTRAE)
 459   if(EXTRAE_FOUND)
 460     include_directories(${EXTRAE_INCLUDE_DIR})
 461     set(HAVE_EXTRAE 1)
 462   else()
 463     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 464   endif()
 465 endif()
 466
 467 option(GMX_X11 "Use X window system" OFF)
 468 if (GMX_X11)
 469     find_package(X11)
 470     # X11 includes/libraries are only set in the ngmx subdirectory!
 471     if(NOT X11_FOUND)
 472         message(FATAL_ERROR
 473                 "X11 include files and/or libraries were not found. "
 474                 "Set GMX_X11=OFF to compile without X11 support. "
 475                 "gmx view will not be available.")
 476     endif()
 477     include_directories(${X11_INCLUDE_DIR})
 478 endif()
 479
 480 include(ThreadMPI)
 481 # Enable core threading facilities
 482 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 483 # Enable tMPI C++ support
 484 tmpi_enable_cxx()
 485 if(GMX_THREAD_MPI)
 486     # enable MPI functions
 487     tmpi_enable()
 488     set(GMX_MPI 1)
 489     set(MPI_IN_PLACE_EXISTS 1)
 490 endif()
 491 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 492 if (TMPI_ATOMICS_DISABLED)
 493    add_definitions(-DTMPI_ATOMICS_DISABLED)
 494 endif()
 495
 496 if(GMX_GPU)
 497     # now that we have detected the dependencies, do the second configure pass
 498     gmx_gpu_setup()
 499 endif()
 500
 501 if(CYGWIN)
 502     set(GMX_CYGWIN 1)
 503 endif()
 504
 505 if(WIN32 AND NOT CYGWIN)
 506     set(GMX_NATIVE_WINDOWS 1)
 507     # This makes windows.h not declare min/max as macros that would break
 508     # C++ code using std::min/std::max.
 509     add_definitions(-DNOMINMAX)
 510 endif()
 511
 512 # only bother with finding git and using version.h if the source is a git repo
 513 if(GMX_GIT_VERSION_INFO)
 514     if (NOT SOURCE_IS_GIT_REPOSITORY)
 515         message(FATAL_ERROR
 516             "Cannot generate git version information from source tree not under git. "
 517             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 518     endif()
 519     # We need at least git v1.5.3 be able to parse git's date output. If not
 520     # found or the version is too small, we can't generate version information.
 521     find_package(Git)
 522
 523     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 524         message(FATAL_ERROR
 525             "No compatible git version found (>= 1.5.3 required). "
 526             "Won't be able to generate development version information. "
 527             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 528     endif()
 529 endif()
 530
 531 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 532 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 533 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 534     find_package(Boost 1.44.0)
 535     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 536         set(Boost_FOUND FALSE)
 537     endif()
 538     # Print the notification only on first run, when determining the default
 539     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 540         message("Boost >= 1.44 not found. Using minimal internal version. "
 541                 "This may cause trouble if you plan on compiling/linking other "
 542                 "software that uses Boost against Gromacs.")
 543     endif()
 544 endif()
 545 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 546        ${Boost_FOUND})
 547 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 548     message(FATAL_ERROR
 549         "Boost >= 1.44 not found. "
 550         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 551         "version of Boost included with Gromacs.")
 552 endif()
 553
 554 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 555 mark_as_advanced(GMX_BUILD_UNITTESTS)
 556 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 557 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 558     message(FATAL_ERROR
 559         "Cannot build unit tests without libxml2. "
 560         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 561 endif()
 562
 563 ########################################################################
 564 # Generate development version info for cache
 565 ########################################################################
 566 # set(GEN_VERSION_INFO_INTERNAL "ON")
 567 # include(gmxGenerateVersionString)
 568
 569 ########################################################################
 570 # Our own GROMACS tests
 571 ########################################################################
 572
 573 add_definitions( -DHAVE_CONFIG_H )
 574 include_directories(${CMAKE_SOURCE_DIR}/src)
 575 include_directories(${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 576 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 577 include_directories(${CMAKE_BINARY_DIR}/src)
 578 # Required for gmx_header_config_gen.h to be found before installation
 579 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 580 # Required for now to make old code compile
 581 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 582
 583 include(gmxTestInlineASM)
 584 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 585
 586 include(gmxSetBuildInformation)
 587 gmx_set_build_information()
 588 # Turn on RDTSCP if:
 589 # - the build system's CPU supports it
 590 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 591 #   at this point means that the user set it).
 592 # Note: it's better to not use the later set value of GMX_SIMD because
 593 # it reflects the system's capability of both compiling and running AVX code.
 594 # TODO: After merge with 5.0 one could implement a cache variable dependency
 595 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 596 # after the first cmake pass.
 597 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 598     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 599 else()
 600     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 601 endif()
 602 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 603 mark_as_advanced(GMX_USE_RDTSCP)
 604 if(GMX_USE_RDTSCP)
 605     set(HAVE_RDTSCP 1)
 606 endif()
 607
 608 include(gmxTestFloatFormat)
 609 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 610                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 611                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 612
 613 include(gmxTestLargeFiles)
 614 gmx_test_large_files(GMX_LARGEFILES)
 615
 616 include(gmxTestSignal)
 617 gmx_test_sigusr1(HAVE_SIGUSR1)
 618
 619 include(gmxTestPipes)
 620 gmx_test_pipes(HAVE_PIPES)
 621
 622 include(gmxTestIsfinite)
 623 gmx_test_isfinite(HAVE_ISFINITE)
 624 gmx_test__isfinite(HAVE__ISFINITE)
 625 gmx_test__finite(HAVE__FINITE)
 626
 627 include(gmxTestCXX11)
 628 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 629 include(CMakeDependentOption)
 630 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 631 # entirely to keep the compilation environment uniform.
 632 cmake_dependent_option(GMX_CXX11
 633     "Use C++11 features"
 634     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 635 mark_as_advanced(GMX_CXX11)
 636 if(GMX_CXX11)
 637     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 638 endif()
 639
 640
 641 include(gmxTestXDR)
 642 gmx_test_xdr(GMX_SYSTEM_XDR)
 643 if(NOT GMX_SYSTEM_XDR)
 644     set(GMX_INTERNAL_XDR 1)
 645 endif()
 646
 647
 648 ##################################################
 649 # Process SIMD instruction settings
 650 ##################################################
 651 # This checks what flags to add in order to
 652 # support the SIMD instructions we need, and sets
 653 # correct defines for the SIMD instructions supported.
 654 include(gmxTestSimd)
 655 gmx_test_simd()
 656
 657
 658 # Process QM/MM Settings
 659 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 660     set(GMX_QMMM_GAUSSIAN 1)
 661 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 662     set(GMX_QMMM_MOPAC 1)
 663 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 664     set(GMX_QMMM_GAMESS 1)
 665 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 666     set(GMX_QMMM_ORCA 1)
 667 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 668     # nothing to do
 669 else()
 670     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 671 endif()
 672
 673
 674 ##################################################
 675 # Process FFT library settings
 676 ##################################################
 677 include(gmxManageFFTLibraries)
 678
 679
 680 include(gmxManageLinearAlgebraLibraries)
 681
 682 # Whether GROMACS will really try to compile support for VMD plugins
 683 set(GMX_USE_PLUGINS OFF)
 684
 685 if(GMX_LOAD_PLUGINS)
 686   if(CYGWIN OR NOT WIN32)
 687     # Native Windows does not have, nor need dlopen
 688     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 689     include(gmxTestdlopen)
 690     gmx_test_dlopen(HAVE_DLOPEN)
 691   endif()
 692
 693   # so, should we use plug-ins?
 694   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 695     if(NOT VMD_QUIETLY)
 696       MESSAGE(STATUS
 697           "Found the ability to use plug-ins when building shared libaries, "
 698           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 699           "formats).")
 700     endif()
 701     if(NOT GMX_VMD_PLUGIN_PATH)
 702       find_package(VMD)
 703     endif()
 704     set(GMX_USE_PLUGINS ON)
 705     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 706     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 707   else()
 708     set(PKG_DL_LIBS)
 709   endif()
 710 endif()
 711 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 712
 713 # Link real-time library for POSIX timers. The check for clock_gettime
 714 # confirms the linkability of rt.
 715 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 716     list(APPEND GMX_EXTRA_LIBRARIES rt)
 717 endif()
 718
 719 # Math and thread libraries must often come after all others when linking...
 720 if(HAVE_LIBM)
 721     list(APPEND GMX_EXTRA_LIBRARIES m)
 722 endif()
 723
 724 option(GMX_NACL "Configure for Native Client builds" OFF)
 725 if (GMX_NACL)
 726   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 727   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 728   set(GMX_NO_NICE 1)
 729   set(GMX_NO_RENAME 1)
 730 endif()
 731 mark_as_advanced(GMX_NACL)
 732
 733 if(GMX_FAHCORE)
 734   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 735       "Path to swindirect.h")
 736   include_directories(${COREWRAP_INCLUDE_DIR})
 737 endif()
 738
 739 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 740 mark_as_advanced(GMX_BUILD_HELP)
 741 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 742     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 743
 744     message(FATAL_ERROR
 745         "Rebuilding HTML and man pages is not supported for in-source "
 746         "builds from a source distribution. "
 747         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 748 endif()
 749
 750 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 751 # these are set after everything else
 752 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 753     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 754     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 755     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 756     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 757 else()
 758     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 759     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 760     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 761     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 762     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 763     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 764     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 765     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 766     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 767 endif()
 768
 769 if(NOT GMX_OPENMP)
 770     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 771     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 772     unset(OpenMP_C_FLAGS CACHE)
 773     unset(OpenMP_CXX_FLAGS CACHE)
 774 else()
 775     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 776     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 777 endif()
 778 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 779
 780 ########################################################################
 781 # Specify install locations
 782 ########################################################################
 783 # Use GNUInstallDirst to set paths on multiarch systems
 784 include(GNUInstallDirs)
 785
 786 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 787     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 788 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 789     "Data installation directory under share/ (default: gromacs)")
 790 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 791
 792 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 793 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 794 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 795 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 796 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 797
 798 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 799 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 800
 801 # Binary and library suffix options
 802 include(gmxManageSuffixes)
 803
 804 ##################################################################
 805 # Shared library settings
 806 ##################################################################
 807 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 808     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 809         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 810     endif()
 811     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 812     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 813 else()
 814     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 815         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 816         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 817     else()
 818         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 819     endif()
 820 endif()
 821
 822 #COPYING file: Only necessary for binary distributions.
 823 #Simpler to always install.
 824 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 825
 826 if(GMX_EXTERNAL_BOOST)
 827     include_directories(${Boost_INCLUDE_DIRS})
 828     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 829 else()
 830     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 831     # typeid not supported for minimal internal version
 832     # (would add significant amount of code)
 833     add_definitions(-DBOOST_NO_TYPEID)
 834     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 835     # (from share/template/)
 836     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 837     if (NOT GMX_BUILD_MDRUN_ONLY)
 838         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 839                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 840                 COMPONENT development)
 841     endif()
 842 endif()
 843
 844 if(GMX_USE_TNG)
 845     find_package(ZLIB QUIET)
 846     include(gmxTestZLib)
 847     gmx_test_zlib(HAVE_ZLIB)
 848     set(TNG_BUILD_WITH_ZLIB ${HAVE_ZLIB} CACHE BOOL  "Build TNG with zlib compression")
 849     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 850     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 851     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 852     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 853     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 854     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 855     set(GMX_TNG_LIBRARIES tng_io)
 856 endif()
 857 mark_as_advanced(TNG_BUILD_FORTRAN)
 858 mark_as_advanced(TNG_BUILD_EXAMPLES)
 859 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 860 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 861 mark_as_advanced(TNG_BUILD_TEST)
 862 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 863
 864 if (GMX_BUILD_FOR_COVERAGE)
 865     # Code heavy with asserts makes conditional coverage close to useless metric,
 866     # as by design most of the false branches are impossible to trigger in
 867     # correctly functioning code.  And the benefit of testing those that could
 868     # be triggered by using an API against its specification isn't usually
 869     # worth the effort.
 870     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 871 endif()
 872
 873 if (BUILD_TESTING)
 874     # "tests" target builds all the separate test binaries.
 875     add_custom_target(tests)
 876     # "run-ctest" is an internal target that actually runs the tests.
 877     # This is necessary to be able to add separate targets that execute as part
 878     # of 'make check', but are ensured to be executed after the actual tests.
 879     add_custom_target(run-ctest
 880                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 881                       COMMENT "Running all tests"
 882                       VERBATIM)
 883     add_dependencies(run-ctest tests)
 884     # "check" target builds and runs all tests.
 885     add_custom_target(check DEPENDS run-ctest)
 886 endif()
 887
 888 if (NOT GMX_BUILD_MDRUN_ONLY)
 889     add_subdirectory(doxygen)
 890     add_subdirectory(share)
 891     add_subdirectory(scripts)
 892 endif()
 893 add_subdirectory(src)
 894
 895 if (BUILD_TESTING)
 896     add_subdirectory(tests)
 897 endif()
 898
 899 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 900 # Don't bother the user after the first configure pass.
 901 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 902     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 903 endif()
 904 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 905
 906 #######################
 907 ## uninstall target
 908 #######################
 909     CONFIGURE_FILE(
 910                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 911                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 912                    IMMEDIATE @ONLY)
 913 ###########################
 914 ADD_CUSTOM_TARGET(uninstall
 915                   "${CMAKE_COMMAND}" -P
 916                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 917 ###########################
 918
 919 ########################################################################
 920 # Manual                                                               #
 921 ########################################################################
 922
 923 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 924 mark_as_advanced(GMX_BUILD_MANUAL)
 925 if(GMX_BUILD_MANUAL)
 926     # Make sure we only do detection of manual-building dependencies
 927     # when the user opted in for that.
 928     add_subdirectory(manual)
 929 endif()