CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015,2016,2017,2018,2019, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 3.9.6)
  36 if(POLICY CMP0074) #3.12
  37     cmake_policy(SET CMP0074 NEW)
  38 endif()
  39
  40 # CMake modules/macros are in a subdirectory to keep this file cleaner
  41 # This needs to be set before project() in order to pick up toolchain files
  42 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  43
  44 project(Gromacs)
  45
  46 set(CMAKE_CXX_STANDARD 14)
  47 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  48 set(CMAKE_CXX_EXTENSIONS OFF)
  49
  50 include(gmxManageCcache)
  51
  52 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  53 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  54 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  55
  56 find_package(LibStdCpp)
  57
  58 # Set up common version variables, as well as general information about
  59 # the build tree (whether the build is from a source package or from a git
  60 # repository).  Also declares a few functions that will be used for generating
  61 # version info files later.
  62 include(gmxBuildTreeInfo)
  63 include(gmxVersionInfo)
  64
  65 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  66     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  67 endif()
  68 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  69     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  70 endif()
  71
  72 include(gmxBuildTypeReference)
  73 include(gmxBuildTypeProfile)
  74 include(gmxBuildTypeTSAN)
  75 include(gmxBuildTypeASAN)
  76 include(gmxBuildTypeMSAN)
  77 include(gmxBuildTypeReleaseWithAssert)
  78
  79 if(NOT CMAKE_BUILD_TYPE)
  80     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile TSAN ASAN MSAN." FORCE)
  81     # Set the possible values of build type for cmake-gui
  82     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  83         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile" "TSAN" "ASAN" "MSAN")
  84 endif()
  85 if(CMAKE_CONFIGURATION_TYPES)
  86     # Add appropriate GROMACS-specific build types for the Visual
  87     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  88     # are already present by default).
  89     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  90     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  91     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  92         "List of configuration types"
  93         FORCE)
  94 endif()
  95 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  96
  97 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  98
  99 include(gmxCTestUtilities)
 100 gmx_ctest_init()
 101
 102 include(gmxCPackUtilities)
 103 gmx_cpack_init()
 104
 105 # Variables that accumulate stuff influencing the installed headers
 106 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 107 set(INSTALLED_HEADER_DEFINITIONS "")
 108
 109 ########################################################################
 110 # Global non-cache variables for implementing the build system
 111 ########################################################################
 112
 113 # These variables collect libraries that GROMACS requires for
 114 # linking. They should be appended to with list(APPEND ${name}
 115 # new-library) calls. They are:
 116 #  - Libraries that are required for libgromacs (only)
 117 set(GMX_EXTRA_LIBRARIES "")
 118 #  - Libraries that are required for all code in the repository
 119 set(GMX_COMMON_LIBRARIES "")
 120 #  - Libraries that all code linked against libgromacs needs
 121 #    (i.e., something that is exposed in installed headers).
 122 set(GMX_PUBLIC_LIBRARIES "")
 123
 124 ########################################################################
 125 # Check and warn if cache generated on a different host is being reused
 126 ########################################################################
 127 if(CMAKE_HOST_UNIX)
 128     execute_process(COMMAND hostname
 129                     OUTPUT_VARIABLE TMP_HOSTNAME
 130                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 131     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 132         message(WARNING "
 133             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 134             is being reused! This could lead to inconsistencies; therefore, it is
 135             recommended to regenerate the cache!")
 136     endif()
 137     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 138             "Hostname of the machine where the cache was generated.")
 139 endif()
 140
 141 ########################################################################
 142 # Detect architecture before setting options so we can alter defaults
 143 ########################################################################
 144 # Detect the architecture the compiler is targetting, detect
 145 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 146 # to use if none is specified, and populate the cache option for CPU
 147 # SIMD.
 148 include(gmxDetectTargetArchitecture)
 149 gmx_detect_target_architecture()
 150
 151 ########################################################################
 152 # User input options                                                   #
 153 ########################################################################
 154 include(gmxOptionUtilities)
 155
 156 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 157
 158 # Fujitsu only has SIMD in double precision, so this will be faster
 159 gmx_set_boolean(GMX_DOUBLE_DEFAULT GMX_TARGET_FUJITSU_SPARC64)
 160 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 161 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 162 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 163
 164 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 165 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 166 gmx_dependent_option(
 167     GMX_MPI_IN_PLACE
 168     "Enable MPI_IN_PLACE for MPIs that have it defined"
 169     ON
 170     GMX_MPI)
 171 mark_as_advanced(GMX_MPI_IN_PLACE)
 172
 173 option(GMX_MIMIC "Enable MiMiC QM/MM interface (CPMD is required)" OFF)
 174
 175 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 176 mark_as_advanced(GMX_FAHCORE)
 177
 178 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 179 mark_as_advanced(GMX_COOL_QUOTES)
 180 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 181
 182 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 183
 184 # The earliest version of the CUDA toolkit that supports c++14 is 9.0
 185 set(REQUIRED_CUDA_VERSION 9.0)
 186 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 3.0)
 187
 188 # OpenCL required version: 1.2 or newer
 189 set(REQUIRED_OPENCL_MIN_VERSION_MAJOR 1)
 190 set(REQUIRED_OPENCL_MIN_VERSION_MINOR 2)
 191 set(REQUIRED_OPENCL_MIN_VERSION ${REQUIRED_OPENCL_MIN_VERSION_MAJOR}.${REQUIRED_OPENCL_MIN_VERSION_MINOR})
 192
 193 if(NOT GMX_USE_OPENCL)
 194     # CUDA detection is done only if GMX_USE_OPENCL is OFF.
 195     include(gmxManageGPU)
 196     set(GMX_USE_CUDA ${GMX_GPU})
 197     if(GMX_GPU)
 198         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_CUDA")
 199     else()
 200         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_NONE")
 201     endif()
 202 else()
 203     #Now the OpenCL path (for both AMD and NVIDIA)
 204     if(GMX_GPU)
 205         include(gmxManageOpenCL)
 206         set(GMX_GPU_ACCELERATION_FRAMEWORK "GMX_GPU_OPENCL")
 207     else()
 208         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 209     endif()
 210 endif()
 211
 212 gmx_option_multichoice(
 213     GMX_SIMD
 214     "SIMD instruction set for CPU kernels and compiler optimization"
 215     "AUTO"
 216     AUTO None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX2_128 AVX_512 AVX_512_KNL MIC ARM_NEON ARM_NEON_ASIMD IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 217
 218 if(GMX_TARGET_MIC)
 219     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 220 else()
 221     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 222 endif()
 223
 224 gmx_option_multichoice(
 225     GMX_FFT_LIBRARY
 226     "FFT library"
 227     "${GMX_FFT_LIBRARY_DEFAULT}"
 228     fftw3 mkl "fftpack[built-in]")
 229 gmx_dependent_option(
 230     GMX_BUILD_OWN_FFTW
 231     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 232     OFF
 233     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 234 gmx_dependent_option(
 235     GMX_DISABLE_FFTW_MEASURE
 236     "Do not optimize FFTW setups (not needed with SSE)"
 237     OFF
 238     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 239 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 240 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 241
 242 gmx_option_multichoice(
 243     GMX_QMMM_PROGRAM
 244     "QM package for QM/MM"
 245     None
 246     none gaussian mopac gamess orca)
 247
 248 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 249 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 250
 251 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 252
 253 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 254 mark_as_advanced(GMX_BROKEN_CALLOC)
 255
 256 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 257
 258 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 259
 260 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 261
 262 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 263 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 264
 265 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 266 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 267
 268 option(GMX_BUILD_FOR_COVERAGE
 269        "Tune build for better code coverage metrics (e.g., disable asserts)"
 270        OFF)
 271 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 272
 273 option(GMX_DEVELOPER_BUILD
 274     "Enable Developer convenience features: always build unit-tests"
 275     OFF)
 276 mark_as_advanced(GMX_DEVELOPER_BUILD)
 277
 278 gmx_set_boolean(GMX_COMPILER_WARNINGS_DEFAULT "NOT SOURCE_IS_SOURCE_DISTRIBUTION")
 279 option(GMX_COMPILER_WARNINGS
 280     "Enable a default set of compiler warnings"
 281     ${GMX_COMPILER_WARNINGS_DEFAULT})
 282 mark_as_advanced(GMX_COMPILER_WARNINGS)
 283 # Always turn on compiler warnings with a developer build.
 284 gmx_add_cache_dependency(GMX_COMPILER_WARNINGS BOOL "NOT GMX_DEVELOPER_BUILD" ON)
 285
 286 option(GMX_BUILD_SHARED_EXE
 287     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 288     ON)
 289 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 290
 291 option(GMX_PHYSICAL_VALIDATION
 292        "Include physical validation tests in ctest environment. These can then be called using 'make check-phys' or
 293        'make check-all'. Warning: Running the physical validation tests takes significantly more time than other tests!"
 294        OFF)
 295 mark_as_advanced(GMX_PHYSICAL_VALIDATION)
 296
 297 ######################################################################
 298 # Detect OpenMP support
 299 ######################################################################
 300 # The OpenMP detection _must_ come before tests for other CFLAGS.
 301 include(gmxManageOpenMP)
 302
 303
 304
 305 ######################################################################
 306 # Compiler tests
 307 # These need to be done early (before further tests).
 308 #####################################################################
 309
 310 include(gmxCFlags)
 311 gmx_c_flags()
 312
 313 # These variables should be used for CMake-style lists (ie. separated
 314 # by semicolons) of additional compiler flags which are not generated
 315 # in gmxCFlags nor are SIMD or MPI related.
 316 #
 317 # TODO These variables should be consolidated into
 318 # EXTRA_COMPILER_FLAGS so that we we don't perpetrate bugs where
 319 # things that work in C compilation (e.g. merging from old branches)
 320 # might not also work for C++ compilation.
 321 set(EXTRA_C_FLAGS "")
 322 set(EXTRA_CXX_FLAGS "")
 323
 324 # Run through a number of tests for buggy compilers and other issues
 325 include(gmxTestCompilerProblems)
 326 gmx_test_compiler_problems()
 327
 328 # Implement double-precision option. This is complicated because we
 329 # need installed headers to use the precision mode of the build that
 330 # produced the library, but cannot use config.h in that case. We also
 331 # want such variables to always have a definition, because #if is more
 332 # robust than #ifdef. So, we put this value on the compiler command
 333 # line in all cases.
 334 #
 335 # GMX_RELAXED_DOUBLE_PRECISION does not need to be handled here,
 336 # because no installed header needs it
 337 if(GMX_DOUBLE)
 338     set(GMX_DOUBLE_VALUE 1)
 339 else()
 340     set(GMX_DOUBLE_VALUE 0)
 341 endif()
 342 add_definitions(-DGMX_DOUBLE=${GMX_DOUBLE_VALUE})
 343 list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE=${GMX_DOUBLE_VALUE}")
 344
 345 option(GMX_IMD "Enable Interactive Molecular Dynamics (IMD) sessions, e.g. with VMD" ON)
 346 if(GMX_IMD AND WIN32)
 347     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 348 endif()
 349
 350
 351
 352 ########################################################################
 353 # Basic system tests (standard libraries, headers, functions, types)   #
 354 ########################################################################
 355 include(CheckIncludeFiles)
 356 include(CheckIncludeFileCXX)
 357 check_include_files(unistd.h     HAVE_UNISTD_H)
 358 check_include_files(pwd.h        HAVE_PWD_H)
 359 check_include_files(dirent.h     HAVE_DIRENT_H)
 360 check_include_files(time.h       HAVE_TIME_H)
 361 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 362 check_include_files(io.h         HAVE_IO_H)
 363 check_include_files(sched.h      HAVE_SCHED_H)
 364 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 365
 366 include(CheckCXXSymbolExists)
 367 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 368 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 369 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 370 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 371 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 372 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 373 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 374 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 375
 376 # We cannot check for the __builtins as symbols, but check if code compiles
 377 check_cxx_source_compiles("int main(){ return __builtin_clz(1);}"   HAVE_BUILTIN_CLZ)
 378 check_cxx_source_compiles("int main(){ return __builtin_clzll(1);}" HAVE_BUILTIN_CLZLL)
 379 if(MSVC)
 380     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned long i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE)
 381     check_cxx_source_compiles("#include <intrin.h>\n int main(){unsigned long r;unsigned __int64 i=1;_BitScanReverse(&r,i);return r;}" HAVE_BITSCANREVERSE64)
 382 elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 383     check_cxx_source_compiles("int main(){ return __cntlz4(1);}" HAVE_CNTLZ4)
 384     check_cxx_source_compiles("int main(){ return __cntlz8(1);}" HAVE_CNTLZ8)
 385 endif()
 386
 387 include(CheckLibraryExists)
 388 find_library(HAVE_LIBM m)
 389 mark_as_advanced(HAVE_LIBM)
 390 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 391 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 392 check_library_exists(m fedisableexcept "" HAVE_FEDISABLEEXCEPT)
 393
 394 include(TestSchedAffinity)
 395 test_sched_affinity(HAVE_SCHED_AFFINITY)
 396
 397 # Aligned memory allocation. We need to check for both mm_malloc(),
 398 # posix_memalign(), memalign(), and on windows also _aligned_malloc()
 399 include(gmxTestMMMalloc)
 400 gmx_test_mm_malloc(HAVE__MM_MALLOC)
 401 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 402 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 403 if(MSVC)
 404     # No need to waste time on this test on platforms where it will never be true
 405     check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 406 endif()
 407
 408 include(TestBigEndian)
 409 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 410
 411 gmx_set_boolean(GMX_USE_NICE "HAVE_UNISTD_H AND HAVE_NICE")
 412
 413 # Management of GROMACS options for specific toolchains should go
 414 # here. Because the initial settings for some of the main options have
 415 # already happened, but things like library detection and MPI compiler
 416 # feature detection have not, the docstrings for any over-rides of
 417 # GROMACS defaults or user settings will make sense. Also, any
 418 # toolchain-related reasons for choosing whether to detect various
 419 # things can be sorted out now, before the detection takes place.
 420 if(GMX_TARGET_FUJITSU_SPARC64)
 421     include(gmxManageFujitsuSparc64)
 422 endif()
 423
 424 ########################################################################
 425 #Process MPI settings
 426 ########################################################################
 427 include(gmxManageMPI)
 428
 429 ########################################################################
 430 #Process MiMiC settings
 431 ########################################################################
 432 include(gmxManageMimic)
 433
 434 ########################################################################
 435 #Process shared/static library settings
 436 ########################################################################
 437 include(gmxManageSharedLibraries)
 438
 439
 440 ########################################################################
 441 # Find external packages                                               #
 442 ########################################################################
 443
 444 # Unconditionally find the package, as it is also required for unit
 445 # tests. This exports LIBXML2_FOUND, which we should not use because
 446 # it does not tell us that linking will succeed. Instead, we test that
 447 # next.
 448 #if(DEFINED LIBXML2_LIBRARIES)
 449 #  set(LibXml2_FIND_QUIETLY TRUE)
 450 #endif()
 451 #find_package(LibXml2)
 452 #include(gmxTestLibXml2)
 453 #gmx_test_libxml2(HAVE_LIBXML2)
 454 #option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 455 #set(PKG_XML "")
 456 #mark_as_advanced(GMX_XML)
 457 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 458 #if(GMX_XML AND NOT HAVE_LIBXML2)
 459 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 460 #endif()
 461 #if(GMX_XML)
 462 #    include_directories(${LIBXML2_INCLUDE_DIR})
 463 #    set(PKG_XML libxml-2.0)
 464 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 465 #endif()
 466
 467 gmx_option_trivalue(
 468     GMX_HWLOC
 469     "Use hwloc portable hardware locality library"
 470     "AUTO")
 471
 472 if (GMX_HWLOC)
 473     # Find quietly the second time.
 474     if (HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN)
 475         set(HWLOC_FIND_QUIETLY TRUE)
 476     endif()
 477     find_package(HWLOC 1.5)
 478
 479     if (HWLOC_FOUND)
 480         if (HWLOC_LIBRARIES MATCHES ".a$")
 481             set(_STATIC_HWLOC TRUE)
 482         endif()
 483
 484         gmx_check_if_changed(HWLOC_FOUND_CHANGED HWLOC_FOUND)
 485         if (_STATIC_HWLOC AND HWLOC_FOUND_CHANGED AND NOT GMX_HWLOC_FORCE)
 486             message(STATUS "Static hwloc library found, will not attempt using it as it could lead to link-time errors. To use the detected library, manually set GMX_HWLOC=ON and you will likely have to pass appropriate linker flags too to satisfy the link-time dependencies of your hwloc library. Try \"pkg-config --libs --static hwloc\" for suggestions on what you will need.")
 487             set(GMX_USE_HWLOC OFF)
 488         else()
 489             set(GMX_USE_HWLOC ON)
 490         endif()
 491
 492         if (GMX_USE_HWLOC)
 493             include_directories(SYSTEM ${HWLOC_INCLUDE_DIRS})
 494             list(APPEND GMX_EXTRA_LIBRARIES ${HWLOC_LIBRARIES})
 495         endif()
 496     elseif(GMX_HWLOC_FORCE)
 497         message(FATAL_ERROR "HWLOC package support required, but not found.")
 498     endif()
 499
 500     set(HWLOC_FIND_QUIETLY_AFTER_FIRST_RUN TRUE CACHE INTERNAL "Be quiet during future attempts to find HWLOC")
 501 endif()
 502
 503 option(GMX_EXTERNAL_TINYXML2 "Use external TinyXML-2 instead of compiling the version bundled with GROMACS." OFF)
 504 mark_as_advanced(GMX_EXTERNAL_TINYXML2)
 505 if(GMX_EXTERNAL_TINYXML2)
 506     # Find an external TinyXML-2 library.
 507     find_package(TinyXML-2 3.0.0)
 508     set(HAVE_TINYXML2 ${TinyXML2_FOUND})
 509     if(NOT HAVE_TINYXML2)
 510         message(FATAL_ERROR "External TinyXML-2 could not be found, please adjust your search paths")
 511     endif()
 512 endif()
 513
 514 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 515 mark_as_advanced(GMX_EXTRAE)
 516
 517 if (GMX_EXTRAE)
 518   find_package(EXTRAE)
 519   if(EXTRAE_FOUND)
 520     include_directories(SYSTEM ${EXTRAE_INCLUDE_DIR})
 521     set(HAVE_EXTRAE 1)
 522   else()
 523     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 524   endif()
 525 endif()
 526
 527 option(GMX_X11 "Use X window system" OFF)
 528 if (GMX_X11)
 529     find_package(X11)
 530     # X11 includes/libraries are only set in the ngmx subdirectory!
 531     if(NOT X11_FOUND)
 532         message(FATAL_ERROR
 533                 "X11 include files and/or libraries were not found. "
 534                 "Set GMX_X11=OFF to compile without X11 support. "
 535                 "gmx view will not be available.")
 536     endif()
 537     include_directories(SYSTEM ${X11_INCLUDE_DIR})
 538 endif()
 539
 540 include(ThreadMPI)
 541 # Enable core threading facilities
 542 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 543 if(GMX_THREAD_MPI)
 544     # enable MPI functions
 545     tmpi_enable()
 546     set(MPI_IN_PLACE_EXISTS 1)
 547 endif()
 548 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 549 if (TMPI_ATOMICS_DISABLED)
 550    add_definitions(-DTMPI_ATOMICS_DISABLED)
 551 endif()
 552
 553 include(gmxManageTNG)
 554
 555 include(gmxManageLmfit)
 556
 557 if(GMX_GPU)
 558     # now that we have detected the dependencies, do the second configure pass
 559     gmx_gpu_setup()
 560     if (GMX_CLANG_CUDA)
 561         list(APPEND GMX_EXTRA_LIBRARIES ${GMX_CUDA_CLANG_LINK_LIBS})
 562         link_directories("${GMX_CUDA_CLANG_LINK_DIRS}")
 563     endif()
 564 endif()
 565
 566 if(CYGWIN)
 567     set(GMX_CYGWIN 1)
 568 endif()
 569
 570 if(WIN32)
 571     set(GMX_NATIVE_WINDOWS 1)
 572     # This makes windows.h not declare min/max as macros that would break
 573     # C++ code using std::min/std::max.
 574     add_definitions(-DNOMINMAX)
 575 endif()
 576
 577 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING" ON)
 578 mark_as_advanced(GMX_BUILD_UNITTESTS)
 579 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 580
 581 ########################################################################
 582 # Our own GROMACS tests
 583 ########################################################################
 584
 585 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 586 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 587 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 588
 589 include(gmxTestInlineASM)
 590 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 591
 592 include(gmxSetBuildInformation)
 593 gmx_set_build_information()
 594
 595 gmx_option_multichoice(
 596     GMX_USE_RDTSCP
 597     "Use low-latency RDTSCP instruction for CPU-based timers for mdrun execution; might need to be off when compiling for heterogeneous environments)"
 598     "AUTO"
 599     OFF ON AUTO DETECT)
 600 mark_as_advanced(GMX_USE_RDTSCP)
 601
 602 macro(gmx_check_rdtscp)
 603     if (CPU_DETECTION_FEATURES MATCHES "rdtscp")
 604         set(HAVE_RDTSCP 1)
 605         set(RDTSCP_DETECTION_MESSAGE " - detected on the build host")
 606     else()
 607         set(RDTSCP_DETECTION_MESSAGE " - not detected on the build host")
 608     endif()
 609 endmacro()
 610
 611 set(HAVE_RDTSCP 0)
 612 if (GMX_USE_RDTSCP STREQUAL "ON")
 613     set(HAVE_RDTSCP 1)
 614 elseif(GMX_USE_RDTSCP STREQUAL "DETECT")
 615     gmx_check_rdtscp()
 616 elseif(GMX_USE_RDTSCP STREQUAL "AUTO")
 617     # If the user specified automated SIMD selection, that the choice
 618     # is made based on detection on the build host. If so, then RDTSCP
 619     # should be chosen the same way.
 620     #
 621     # If the user specified an AVX SIMD level (e.g. when
 622     # cross-compiling GROMACS) then they will get our best guess, ie
 623     # that in practice AVX mostly correlates with rdtscp (and anyway
 624     # is only relevant in rather old x86 hardware).
 625     if (GMX_SIMD STREQUAL "AUTO")
 626         gmx_check_rdtscp()
 627     elseif (GMX_SIMD MATCHES "AVX")
 628         set(HAVE_RDTSCP 1)
 629     endif()
 630 endif()
 631 gmx_check_if_changed(HAVE_RDTSCP_CHANGED HAVE_RDTSCP)
 632 if (HAVE_RDTSCP_CHANGED)
 633     if (HAVE_RDTSCP)
 634         message(STATUS "Enabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 635     else()
 636         message(STATUS "Disabling RDTSCP support${RDTSCP_DETECTION_MESSAGE}")
 637     endif()
 638 endif()
 639
 640 include(gmxTestLargeFiles)
 641 gmx_test_large_files(GMX_LARGEFILES)
 642
 643 include(gmxTestSignal)
 644 gmx_test_sigusr1(HAVE_SIGUSR1)
 645
 646 include(gmxTestPipes)
 647 gmx_test_pipes(HAVE_PIPES)
 648
 649 include(gmxTestXDR)
 650 gmx_test_xdr(GMX_SYSTEM_XDR)
 651 # Darwin has system XDR, but it uses a three-argument flavour of
 652 # xdrproc_t that it guarantees will still work if you pass the normal
 653 # two-argument xdr filters, but gcc 8 warns about the cast necessary
 654 # to do that, so it's simpler to just use our own XDR library.
 655 #
 656 # TODO It would be better to craft a cmake test which fails if such
 657 # XDR operations cause warnings, and succeeds otherwise, because it is
 658 # generally preferable to use system libraries where possible.
 659 if(NOT GMX_SYSTEM_XDR OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 660     set(GMX_INTERNAL_XDR 1)
 661 endif()
 662
 663
 664 ##################################################
 665 # Process SIMD instruction settings
 666 ##################################################
 667 # This checks what flags to add in order to
 668 # support the SIMD instructions we need, it sets
 669 # correct defines for the SIMD instructions supported,
 670 # and adds advanced options to control accuracy
 671 # for SIMD math operations.
 672 include(gmxManageSimd)
 673 gmx_manage_simd()
 674
 675 include(gmxManageCycleCounters)
 676 gmx_manage_cycle_counters()
 677
 678 # Process QM/MM Settings
 679 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 680     set(GMX_QMMM_GAUSSIAN 1)
 681 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 682     set(GMX_QMMM_MOPAC 1)
 683 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 684     set(GMX_QMMM_GAMESS 1)
 685 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 686     set(GMX_QMMM_ORCA 1)
 687 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 688     # nothing to do
 689 else()
 690     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 691 endif()
 692
 693
 694 ##################################################
 695 # Process FFT library settings
 696 ##################################################
 697 include(gmxManageFFTLibraries)
 698
 699
 700 include(gmxManageLinearAlgebraLibraries)
 701
 702 include(gmxManagePluginSupport)
 703
 704 if (GMX_USE_PLUGINS)
 705     if(NOT GMX_VMD_PLUGIN_PATH)
 706         find_package(VMD)
 707     endif()
 708 endif()
 709
 710 # Link real-time library for POSIX timers. The check for clock_gettime
 711 # confirms the linkability of rt.
 712 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 713     list(APPEND GMX_EXTRA_LIBRARIES rt)
 714 endif()
 715
 716 # Math and thread libraries must often come after all others when linking...
 717 if (HAVE_LIBM)
 718     list(APPEND GMX_PUBLIC_LIBRARIES m)
 719 endif()
 720
 721 option(GMX_NACL "Configure for Native Client builds" OFF)
 722 if (GMX_NACL)
 723   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 724   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 725   # TODO: Is this still necessary with the check for its presence?
 726   set(GMX_USE_NICE 0)
 727   set(GMX_NO_RENAME 1)
 728 endif()
 729 mark_as_advanced(GMX_NACL)
 730
 731 if(GMX_FAHCORE)
 732   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 733       "Path to swindirect.h")
 734   include_directories(${COREWRAP_INCLUDE_DIR})
 735 endif()
 736
 737 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 738 # produce warnings if that fails.
 739 set(build_help_default AUTO)
 740 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 741     set(build_help_default OFF)
 742 endif()
 743 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 744 mark_as_advanced(GMX_BUILD_HELP)
 745 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 746     message(FATAL_ERROR
 747         "Rebuilding shell completions or man pages is not supported for "
 748         "in-source builds from a source distribution. "
 749         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 750 endif()
 751
 752 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 753 # these are set after everything else
 754 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 755     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 756     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 757 else()
 758     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 759     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_C_FLAGS};${GMXC_CFLAGS}")
 760     foreach(build_type ${build_types_with_explicit_flags})
 761         message("CMAKE_C_FLAGS_${build_type}: ${GMXC_CFLAGS_${build_type}}")
 762     endforeach()
 763     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS};${MPI_COMPILE_FLAGS};${EXTRA_CXX_FLAGS};${GMXC_CXXFLAGS}")
 764     foreach(build_type ${build_types_with_explicit_flags})
 765         message("CMAKE_CXX_FLAGS_${build_type}: ${GMXC_CXXFLAGS_${build_type}}")
 766     endforeach()
 767     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 768     message("CMAKE_SHARED_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 769 endif()
 770
 771 ########################################################################
 772 # Specify install locations
 773 ########################################################################
 774 # Use GNUInstallDirs to set paths on multiarch systems.
 775 include(GNUInstallDirs)
 776
 777 set(GMX_INSTALL_DATASUBDIR "gromacs" CACHE STRING "Subdirectory for GROMACS data under CMAKE_INSTALL_DATADIR")
 778 mark_as_advanced(GMX_INSTALL_DATASUBDIR)
 779
 780 # Internal convenience so we do not have to join two path segments in the code
 781 set(GMX_INSTALL_GMXDATADIR ${CMAKE_INSTALL_DATADIR}/${GMX_INSTALL_DATASUBDIR})
 782
 783 # If the nesting level wrt. the installation root is changed,
 784 # gromacs-config.cmake.cmakein needs to be adapted.
 785 set(GMX_INSTALL_CMAKEDIR  ${CMAKE_INSTALL_DATAROOTDIR}/cmake)
 786
 787 # TODO: Make GMXRC adapt if this is changed
 788 set(GMX_INSTALL_PKGCONFIGDIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 789 set(GMX_INSTALL_OCLDIR       ${GMX_INSTALL_GMXDATADIR}/opencl)
 790
 791 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${CMAKE_INSTALL_INCLUDEDIR})
 792
 793 # Binary and library suffix options
 794 include(gmxManageSuffixes)
 795
 796 ################################################################
 797 # Shared library load path settings
 798 ################################################################
 799 if(NOT GMX_BUILD_SHARED_EXE)
 800     # No rpath
 801     set(CMAKE_SKIP_RPATH TRUE)
 802     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 803     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 804 else()
 805     # The build folder always has bin/ and lib/; if we are also going to
 806     # install to lib/, then the installation RPATH works also in the build
 807     # tree.  This makes installation slightly faster (no need to rewrite the
 808     # RPATHs), and makes the binaries in the build tree relocatable.
 809     if(CMAKE_INSTALL_LIBDIR STREQUAL "lib")
 810         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 811         if(POLICY CMP0068)
 812             cmake_policy(SET CMP0068 NEW) # From CMake-3.9
 813             set(CMAKE_BUILD_WITH_INSTALL_NAME_DIR TRUE)
 814         endif()
 815     endif()
 816     # Set the RPATH as relative to the executable location to make the
 817     # binaries relocatable.
 818     if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Assume OS X >=10.5
 819         set(CMAKE_INSTALL_RPATH "@loader_path/../${CMAKE_INSTALL_LIBDIR}")
 820         set(CMAKE_INSTALL_NAME_DIR ${CMAKE_INSTALL_RPATH})
 821     else()
 822         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${CMAKE_INSTALL_LIBDIR}")
 823     endif()
 824     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 825     set(CMAKE_MACOSX_RPATH 1)
 826 endif()
 827
 828 #COPYING file: Only necessary for binary distributions.
 829 #Simpler to always install.
 830 install(FILES COPYING DESTINATION ${GMX_INSTALL_GMXDATADIR} COMPONENT data)
 831
 832 if (GMX_BUILD_FOR_COVERAGE)
 833     # Code heavy with asserts makes conditional coverage close to useless metric,
 834     # as by design most of the false branches are impossible to trigger in
 835     # correctly functioning code.  And the benefit of testing those that could
 836     # be triggered by using an API against its specification isn't usually
 837     # worth the effort.
 838     add_definitions(-DNDEBUG -DGMX_DISABLE_ASSERTS)
 839 endif()
 840
 841 if (BUILD_TESTING)
 842     include(tests/CheckTarget.cmake)
 843 endif()
 844
 845 # TODO: Determine control flow and defaults for package installation and testing use cases.
 846 # Ref: http://redmine.gromacs.org/issues/2896
 847 option(GMX_PYTHON_PACKAGE "Configure gmxapi Python package" OFF)
 848 mark_as_advanced(GMX_PYTHON_PACKAGE)
 849
 850 if (NOT GMX_BUILD_MDRUN_ONLY)
 851     # Note: Though only documented as an output variable, PYTHON_EXECUTABLE is
 852     # also effective as a CMake input variable to effectively hint the location
 853     # of the Python interpreter. This may be helpful in environments with both
 854     # Python 2 and Python 3 on the default PATH.
 855     # Ref: https://cmake.org/cmake/help/latest/module/FindPythonInterp.html
 856     if(FIND_PACKAGE_MESSAGE_DETAILS_PythonInterp)
 857         # Keep quiet on subsequent runs of cmake
 858         set(PythonInterp_FIND_QUIETLY ON)
 859     endif()
 860     # Older CMake versions might not search for Python newer than 3.7.
 861     set(Python_ADDITIONAL_VERSIONS 3.8)
 862     if(GMX_PYTHON_PACKAGE)
 863         find_package(PythonInterp 3.5 REQUIRED)
 864         # Note: PythonLibs will be found later by pybind11.
 865         # TODO: (issue #2998) When CMake >= 3.12 is required, update detection.
 866         # I.e.  find_package(Python3 3.5 COMPONENTS Interpreter Development REQUIRED)
 867     else()
 868         find_package(PythonInterp 3.5)
 869     endif()
 870     find_package(ImageMagick QUIET COMPONENTS convert)
 871     include(gmxTestImageMagick)
 872     GMX_TEST_IMAGEMAGICK(IMAGE_CONVERT_POSSIBLE)
 873     add_subdirectory(docs)
 874     add_subdirectory(share)
 875     add_subdirectory(scripts)
 876 endif()
 877 add_subdirectory(src)
 878
 879 if (BUILD_TESTING)
 880     add_subdirectory(tests)
 881 endif()
 882
 883 if(GMX_PYTHON_PACKAGE AND NOT GMX_BUILD_MDRUN_ONLY)
 884     add_subdirectory(python_packaging)
 885 endif()
 886
 887 gmx_cpack_write_config()
 888
 889 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 890 # Don't bother the user after the first configure pass.
 891 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 892     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 893 endif()
 894 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 895
 896 #######################
 897 ## uninstall target
 898 #######################
 899 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 900                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 901                   IMMEDIATE @ONLY)
 902 ###########################
 903 ADD_CUSTOM_TARGET(uninstall
 904                   "${CMAKE_COMMAND}" -P
 905                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 906 ###########################
 907 set_directory_properties(PROPERTIES
 908             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")