tests/CheckTarget.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # "tests" target builds all the separate test binaries.
  36 add_custom_target(tests)
  37 # "run-ctest" is an internal target that actually runs the tests.
  38 # This is necessary to be able to add separate targets that execute as part
  39 # of 'make check', but are ensured to be executed after the actual tests.
  40 add_custom_target(run-ctest
  41                   COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
  42                   COMMENT "Running all tests"
  43                   USES_TERMINAL VERBATIM)
  44 add_dependencies(run-ctest tests)
  45 # "check" target builds and runs all tests.
  46 add_custom_target(check DEPENDS run-ctest)
  47
  48 # Global property for collecting notices to show at the end of the "check"
  49 # target.
  50 set_property(GLOBAL PROPERTY GMX_TESTS_NOTICE)
  51
  52 function (gmx_add_missing_tests_notice TEXT)
  53     set_property(GLOBAL APPEND PROPERTY GMX_TESTS_NOTICE ${TEXT})
  54 endfunction()
  55
  56 function (gmx_create_missing_tests_notice_target)
  57     get_property(_text GLOBAL PROPERTY GMX_TESTS_NOTICE)
  58     set(_cmds)
  59     foreach (_line ${_text})
  60         list(APPEND _cmds COMMAND ${CMAKE_COMMAND} -E echo "NOTE: ${_line}")
  61     endforeach()
  62     add_custom_target(missing-tests-notice
  63         ${_cmds}
  64         DEPENDS run-ctest
  65         COMMENT "Some tests not available" VERBATIM)
  66     add_dependencies(check missing-tests-notice)
  67 endfunction()