CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
  61     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
  62 endif()
  63
  64 include(gmxBuildTypeReference)
  65 include(gmxBuildTypeProfile)
  66 include(gmxBuildTypeTSAN)
  67 include(gmxBuildTypeASAN)
  68 include(gmxBuildTypeMSAN)
  69 include(gmxBuildTypeReleaseWithAssert)
  70
  71 if(NOT CMAKE_BUILD_TYPE)
  72     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  73     # There's no need to offer a user the choice of ThreadSanitizer
  74     # Set the possible values of build type for cmake-gui
  75     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  76         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  77 endif()
  78 if(CMAKE_CONFIGURATION_TYPES)
  79     # Add appropriate GROMACS-specific build types for the Visual
  80     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  81     # are already present by default).
  82     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  83     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  84     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  85         "List of configuration types"
  86         FORCE)
  87 endif()
  88 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  89
  90 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  91
  92 # Set a default valgrind suppression file.
  93 # This unfortunately needs to duplicate information from CTest to work as
  94 # expected...
  95 set(MEMORYCHECK_SUPPRESSIONS_FILE
  96     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  97     CACHE FILEPATH
  98     "File that contains suppressions for the memory checker")
  99 include(CTest)
 100
 101 include(gmxCPackUtilities)
 102 gmx_cpack_init()
 103
 104 # Variables that accumulate stuff influencing the installed headers
 105 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 106 set(INSTALLED_HEADER_DEFINITIONS "")
 107
 108 ########################################################################
 109 # Check and warn if cache generated on a different host is being reused
 110 ########################################################################
 111 if(CMAKE_HOST_UNIX)
 112     execute_process(COMMAND hostname
 113                     OUTPUT_VARIABLE TMP_HOSTNAME
 114                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 116         message(WARNING "
 117             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 118             is being reused! This could lead to inconsistencies; therefore, it is
 119             recommended to regenerate the cache!")
 120     endif()
 121     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 122             "Hostname of the machine where the cache was generated.")
 123 endif()
 124
 125 ########################################################################
 126 # Detect architecture before setting options so we can alter defaults
 127 ########################################################################
 128 # Detect the architecture the compiler is targetting, detect
 129 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 130 # to use if none is specified, and populate the cache option for CPU
 131 # SIMD.
 132 include(gmxDetectTargetArchitecture)
 133 gmx_detect_target_architecture()
 134
 135 ########################################################################
 136 # User input options                                                   #
 137 ########################################################################
 138 include(gmxOptionUtilities)
 139
 140 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 141
 142 if(GMX_TARGET_FUJITSU_SPARC64)
 143     # Fujitsu only has SIMD in double precision, so this will be faster
 144     set(GMX_DOUBLE_DEFAULT ON)
 145 else()
 146     set(GMX_DOUBLE_DEFAULT OFF)
 147 endif()
 148 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 149 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 150 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 151
 152 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 153 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 154 gmx_dependent_option(
 155     GMX_MPI_IN_PLACE
 156     "Enable MPI_IN_PLACE for MPIs that have it defined"
 157     ON
 158     GMX_MPI)
 159 mark_as_advanced(GMX_MPI_IN_PLACE)
 160 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 161 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 162 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 163 mark_as_advanced(GMX_FAHCORE)
 164
 165 option(GMX_COOL_QUOTES "Enable GROMACS cool quotes" ON)
 166 mark_as_advanced(GMX_COOL_QUOTES)
 167 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 168
 169 option(GMX_USE_OPENCL "Enable OpenCL acceleration" OFF)
 170
 171 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 172 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 173 if(MSVC)
 174     set(REQUIRED_CUDA_VERSION 4.1)
 175 else()
 176     set(REQUIRED_CUDA_VERSION 4.0)
 177 endif()
 178 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 179
 180 # OpenCL required version: 1.1 or newer
 181 set(REQUIRED_OPENCL_MIN_VERSION 1.1)
 182
 183 if(NOT GMX_USE_OPENCL)
 184     # CUDA detection is done only if GMX_USE_OPENCL is OFF
 185     include(gmxManageGPU)
 186 else()
 187     #Now the OpenCL path
 188     if(GMX_GPU)
 189         include(gmxManageOpenCL)
 190     else(GMX_GPU)
 191         message(FATAL_ERROR "OpenCL requested but GPU option is not enabled (try -DGMX_GPU=on) ")
 192     endif(GMX_GPU)
 193 endif()
 194
 195 include(gmxDetectSimd)
 196 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 197
 198 gmx_option_multichoice(
 199     GMX_SIMD
 200     "SIMD instruction set for CPU kernels and compiler optimization"
 201     "${GMX_SUGGESTED_SIMD}"
 202     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 AVX_512F AVX_512ER MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 203
 204 if(GMX_TARGET_MIC)
 205     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 206 else()
 207     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 208 endif()
 209
 210 gmx_option_multichoice(
 211     GMX_FFT_LIBRARY
 212     "FFT library"
 213     "${GMX_FFT_LIBRARY_DEFAULT}"
 214     fftw3 mkl "fftpack[built-in]")
 215 gmx_dependent_option(
 216     GMX_BUILD_OWN_FFTW
 217     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 218     OFF
 219     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 220 gmx_dependent_option(
 221     GMX_DISABLE_FFTW_MEASURE
 222     "Do not optimize FFTW setups (not needed with SSE)"
 223     OFF
 224     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 225 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 226 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 227
 228 gmx_option_multichoice(
 229     GMX_QMMM_PROGRAM
 230     "QM package for QM/MM"
 231     None
 232     none gaussian mopac gamess orca)
 233
 234 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 235 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 236
 237 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 238
 239 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 240 mark_as_advanced(GMX_BROKEN_CALLOC)
 241 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 242 mark_as_advanced(GMX_LOAD_PLUGINS)
 243
 244 option(GMX_GPU  "Enable GPU acceleration" ON)
 245 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 246
 247 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 248
 249 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 250
 251 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 252 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 253
 254 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 255 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 256
 257 option(GMX_BUILD_FOR_COVERAGE
 258        "Tune build for better code coverage metrics (e.g., disable asserts)"
 259        OFF)
 260 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 261
 262 option(GMX_DEVELOPER_BUILD
 263     "Enable Developer convenience features: always build unit-tests"
 264     OFF)
 265 mark_as_advanced(GMX_DEVELOPER_BUILD)
 266
 267 option(GMX_BUILD_SHARED_EXE
 268     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 269     ON)
 270 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 271
 272 ######################################################################
 273 # Detect OpenMP support
 274 ######################################################################
 275 # The OpenMP detection _must_ come before tests for other CFLAGS.
 276 include(gmxManageOpenMP)
 277
 278
 279
 280 ######################################################################
 281 # Compiler tests
 282 # These need to be done early (before further tests).
 283 #####################################################################
 284
 285 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 286 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 287 # invalid options with the Intel Compilers, and we have added a line
 288 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 289 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 290 # a semicolon. Since this is also used as a separator in lists inside CMake,
 291 # that string ends up being split into two separate patterns, and the last
 292 # part is just a single word that also matches other messages. We solved this
 293 # by replacing the semicolon with a period that matches any character.
 294 #
 295 # These files should be removed from the source tree when a CMake version that
 296 # includes the features in question becomes required for building GROMACS.
 297 include(CheckCCompilerFlag)
 298 include(CheckCXXCompilerFlag)
 299
 300 include(gmxCFlags)
 301 gmx_c_flags()
 302
 303 # This variable should be used for additional compiler flags which are not
 304 # generated in gmxCFlags nor are SIMD or MPI related.
 305 set(EXTRA_C_FLAGS "")
 306 set(EXTRA_CXX_FLAGS "")
 307
 308 # Run through a number of tests for buggy compilers and other issues
 309 include(gmxTestCompilerProblems)
 310 gmx_test_compiler_problems()
 311 # GMX_SIMD will not be set automatically until the second
 312 # pass (which is not strictly guaranteed to occur), so putting this
 313 # check here among logically-related tests is inefficient, but the
 314 # potential loss is likely zero.
 315 if(GMX_SIMD STREQUAL "AVX_256"
 316         AND CMAKE_COMPILER_IS_GNUCC
 317         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 318             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 319     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 320     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 321 endif()
 322
 323
 324 if(GMX_DOUBLE)
 325     add_definitions(-DGMX_DOUBLE)
 326     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 327     if(GMX_RELAXED_DOUBLE_PRECISION)
 328         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 329     endif()
 330 endif()
 331 if(GMX_SOFTWARE_INVSQRT)
 332     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 333 endif()
 334
 335 if(WIN32)
 336     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 337     add_definitions(-DGMX_HAVE_WINSOCK)
 338 endif()
 339
 340
 341
 342 ########################################################################
 343 # Basic system tests (standard libraries, headers, functions, types)   #
 344 ########################################################################
 345 include(CheckIncludeFiles)
 346 include(CheckIncludeFileCXX)
 347 check_include_files(unistd.h     HAVE_UNISTD_H)
 348 check_include_files(pwd.h        HAVE_PWD_H)
 349 check_include_files(dirent.h     HAVE_DIRENT_H)
 350 check_include_files(time.h       HAVE_TIME_H)
 351 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 352 check_include_files(io.h         HAVE_IO_H)
 353 check_include_files(sched.h      HAVE_SCHED_H)
 354
 355 check_include_files(regex.h      HAVE_POSIX_REGEX)
 356 # TODO: It could be nice to inform the user if no regex support is found,
 357 # as selections won't be fully functional.
 358
 359 include(CheckCXXSymbolExists)
 360 check_cxx_symbol_exists(posix_memalign    stdlib.h     HAVE_POSIX_MEMALIGN)
 361 check_cxx_symbol_exists(memalign          stdlib.h     HAVE_MEMALIGN)
 362 check_cxx_symbol_exists(_aligned_malloc   stdlib.h     HAVE__ALIGNED_MALLOC)
 363 check_cxx_symbol_exists(gettimeofday      sys/time.h   HAVE_GETTIMEOFDAY)
 364 check_cxx_symbol_exists(sysconf           unistd.h     HAVE_SYSCONF)
 365 check_cxx_symbol_exists(nice              unistd.h     HAVE_NICE)
 366 check_cxx_symbol_exists(fsync             unistd.h     HAVE_FSYNC)
 367 check_cxx_symbol_exists(_fileno           stdio.h      HAVE__FILENO)
 368 check_cxx_symbol_exists(fileno            stdio.h      HAVE_FILENO)
 369 check_cxx_symbol_exists(_commit           io.h         HAVE__COMMIT)
 370 check_cxx_symbol_exists(sigaction         signal.h     HAVE_SIGACTION)
 371 check_cxx_symbol_exists(rsqrt             math.h       HAVE_RSQRT)
 372 check_cxx_symbol_exists(rsqrtf            math.h       HAVE_RSQRTF)
 373 check_cxx_symbol_exists(sqrtf             math.h       HAVE_SQRTF)
 374
 375 include(CheckLibraryExists)
 376 find_library(HAVE_LIBM m)
 377 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 378 check_library_exists(m feenableexcept "" HAVE_FEENABLEEXCEPT)
 379
 380 include(TestSchedAffinity)
 381 test_sched_affinity(HAVE_SCHED_AFFINITY)
 382
 383 include(TestBigEndian)
 384 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 385
 386 set(GMX_USE_NICE 0)
 387 if (HAVE_UNISTD_H AND HAVE_NICE)
 388     set(GMX_USE_NICE 1)
 389 endif()
 390
 391 # Management of GROMACS options for specific toolchains should go
 392 # here. Because the initial settings for some of the main options have
 393 # already happened, but things like library detection and MPI compiler
 394 # feature detection have not, the docstrings for any over-rides of
 395 # GROMACS defaults or user settings will make sense. Also, any
 396 # toolchain-related reasons for choosing whether to detect various
 397 # things can be sorted out now, before the detection takes place.
 398 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 399     include(gmxManageBlueGene)
 400 endif()
 401
 402 if(GMX_TARGET_FUJITSU_SPARC64)
 403     include(gmxManageFujitsuSparc64)
 404 endif()
 405
 406 ########################################################################
 407 #Process MPI settings
 408 ########################################################################
 409 include(gmxManageMPI)
 410
 411
 412 ########################################################################
 413 #Process shared/static library settings
 414 ########################################################################
 415 include(gmxManageSharedLibraries)
 416
 417
 418 ########################################################################
 419 # Find external packages                                               #
 420 ########################################################################
 421
 422 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 423 find_package(ZLIB QUIET)
 424 include(gmxTestZLib)
 425 gmx_test_zlib(HAVE_ZLIB)
 426
 427 # Unconditionally find the package, as it is also required for unit
 428 # tests. This exports LIBXML2_FOUND, which we should not use because
 429 # it does not tell us that linking will succeed. Instead, we test that
 430 # next.
 431 if(DEFINED LIBXML2_LIBRARIES)
 432   set(LibXml2_FIND_QUIETLY TRUE)
 433 endif()
 434 find_package(LibXml2)
 435 include(gmxTestLibXml2)
 436 gmx_test_libxml2(HAVE_LIBXML2)
 437 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 438 set(PKG_XML "")
 439 mark_as_advanced(GMX_XML)
 440 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 441 #if(GMX_XML AND NOT HAVE_LIBXML2)
 442 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 443 #endif()
 444 #if(GMX_XML)
 445 #    include_directories(${LIBXML2_INCLUDE_DIR})
 446 #    set(PKG_XML libxml-2.0)
 447 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 448 #endif()
 449
 450 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 451 mark_as_advanced(GMX_EXTRAE)
 452
 453 if (GMX_EXTRAE)
 454   find_package(EXTRAE)
 455   if(EXTRAE_FOUND)
 456     include_directories(${EXTRAE_INCLUDE_DIR})
 457     set(HAVE_EXTRAE 1)
 458   else()
 459     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 460   endif()
 461 endif()
 462
 463 option(GMX_X11 "Use X window system" OFF)
 464 if (GMX_X11)
 465     find_package(X11)
 466     # X11 includes/libraries are only set in the ngmx subdirectory!
 467     if(NOT X11_FOUND)
 468         message(FATAL_ERROR
 469                 "X11 include files and/or libraries were not found. "
 470                 "Set GMX_X11=OFF to compile without X11 support. "
 471                 "gmx view will not be available.")
 472     endif()
 473     include_directories(${X11_INCLUDE_DIR})
 474 endif()
 475
 476 include(ThreadMPI)
 477 # Enable core threading facilities
 478 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 479 # Enable tMPI C++ support
 480 tmpi_enable_cxx()
 481 if(GMX_THREAD_MPI)
 482     # enable MPI functions
 483     tmpi_enable()
 484     set(MPI_IN_PLACE_EXISTS 1)
 485 endif()
 486 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 487 if (TMPI_ATOMICS_DISABLED)
 488    add_definitions(-DTMPI_ATOMICS_DISABLED)
 489 endif()
 490
 491 if(GMX_GPU)
 492     # now that we have detected the dependencies, do the second configure pass
 493     gmx_gpu_setup()
 494 endif()
 495
 496 if(CYGWIN)
 497     set(GMX_CYGWIN 1)
 498 endif()
 499
 500 if(WIN32)
 501     set(GMX_NATIVE_WINDOWS 1)
 502     # This makes windows.h not declare min/max as macros that would break
 503     # C++ code using std::min/std::max.
 504     add_definitions(-DNOMINMAX)
 505 endif()
 506
 507 if(CMAKE_SYSTEM_NAME STREQUAL "Darwin") #Work-around for cmake bug #10837
 508     if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Intel" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 509         set(CMAKE_INCLUDE_SYSTEM_FLAG_C "-isystem ")
 510     endif()
 511     if (CMAKE_COMPILER_IS_GNUCXX OR CMAKE_CXX_COMPILER_ID MATCHES "Intel" OR CMAKE_CXX_COMPILER_ID MATCHES "Clang")
 512         set(CMAKE_INCLUDE_SYSTEM_FLAG_CXX "-isystem ")
 513     endif()
 514 endif()
 515
 516 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 517 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 518 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 519     if(DEFINED Boost_INCLUDE_DIR)
 520         set(Boost_FIND_QUIETLY TRUE)
 521     endif()
 522     find_package(Boost 1.44.0)
 523     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 524         set(Boost_FOUND FALSE)
 525     endif()
 526     # Print the notification only on first run, when determining the default
 527     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 528         message("Boost >= 1.44 not found. Using minimal internal version. "
 529                 "This may cause trouble if you plan on compiling/linking other "
 530                 "software that uses Boost against GROMACS.")
 531     endif()
 532 endif()
 533 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 534        ${Boost_FOUND})
 535 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 536     message(FATAL_ERROR
 537         "Boost >= 1.44 not found. "
 538         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 539         "version of Boost included with GROMACS.")
 540 endif()
 541
 542 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 543     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 544 endif()
 545 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 546 mark_as_advanced(GMX_BUILD_UNITTESTS)
 547 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 548 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 549     message(FATAL_ERROR
 550         "Cannot build unit tests without libxml2. "
 551         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 552 endif()
 553
 554 ########################################################################
 555 # Our own GROMACS tests
 556 ########################################################################
 557
 558 add_definitions( -DHAVE_CONFIG_H )
 559 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 560 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 561 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 562 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 563
 564 include(gmxTestInlineASM)
 565 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 566
 567 include(gmxSetBuildInformation)
 568 gmx_set_build_information()
 569 # Turn on RDTSCP if:
 570 # - the build system's CPU supports it
 571 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 572 #   at this point means that the user set it).
 573 # Note: it's better to not use the later set value of GMX_SIMD because
 574 # it reflects the system's capability of both compiling and running AVX code.
 575 # TODO: After merge with 5.0 one could implement a cache variable dependency
 576 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 577 # after the first cmake pass.
 578 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 579     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 580 else()
 581     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 582 endif()
 583 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 584 mark_as_advanced(GMX_USE_RDTSCP)
 585 if(GMX_USE_RDTSCP)
 586     set(HAVE_RDTSCP 1)
 587 endif()
 588
 589 include(gmxTestFloatFormat)
 590 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 591                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 592                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 593
 594 include(gmxTestLargeFiles)
 595 gmx_test_large_files(GMX_LARGEFILES)
 596
 597 include(gmxTestSignal)
 598 gmx_test_sigusr1(HAVE_SIGUSR1)
 599
 600 include(gmxTestPipes)
 601 gmx_test_pipes(HAVE_PIPES)
 602
 603 include(gmxTestIsfinite)
 604 gmx_test_isfinite(HAVE_ISFINITE)
 605 gmx_test__isfinite(HAVE__ISFINITE)
 606 gmx_test__finite(HAVE__FINITE)
 607
 608 include(gmxTestCXX11)
 609 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 610 include(CMakeDependentOption)
 611 # clang with some older versions of boost fail to work with C++11
 612 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 613     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 614     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 615 endif()
 616 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 617 # entirely to keep the compilation environment uniform.
 618 cmake_dependent_option(GMX_CXX11
 619     "Use C++11 features"
 620     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 621 mark_as_advanced(GMX_CXX11)
 622 if(GMX_CXX11)
 623     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 624 endif()
 625
 626 # Now we can test for CXX11_REGEX include file
 627 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 628
 629 include(gmxTestXDR)
 630 gmx_test_xdr(GMX_SYSTEM_XDR)
 631 if(NOT GMX_SYSTEM_XDR)
 632     set(GMX_INTERNAL_XDR 1)
 633 endif()
 634
 635
 636 ##################################################
 637 # Process SIMD instruction settings
 638 ##################################################
 639 # This checks what flags to add in order to
 640 # support the SIMD instructions we need, it sets
 641 # correct defines for the SIMD instructions supported,
 642 # and adds advanced options to control accuracy
 643 # for SIMD math operations.
 644 include(gmxManageSimd)
 645 gmx_manage_simd()
 646
 647 # Process QM/MM Settings
 648 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 649     set(GMX_QMMM_GAUSSIAN 1)
 650 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 651     set(GMX_QMMM_MOPAC 1)
 652 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 653     set(GMX_QMMM_GAMESS 1)
 654 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 655     set(GMX_QMMM_ORCA 1)
 656 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 657     # nothing to do
 658 else()
 659     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 660 endif()
 661
 662
 663 ##################################################
 664 # Process FFT library settings
 665 ##################################################
 666 include(gmxManageFFTLibraries)
 667
 668
 669 include(gmxManageLinearAlgebraLibraries)
 670
 671 # Whether GROMACS will really try to compile support for VMD plugins
 672 set(GMX_USE_PLUGINS OFF)
 673
 674 if(GMX_LOAD_PLUGINS)
 675   if(NOT WIN32)
 676     # Native Windows does not have, nor need dlopen
 677     include(gmxTestdlopen)
 678     gmx_test_dlopen(HAVE_DLOPEN)
 679   endif()
 680
 681   # so, should we use plug-ins?
 682   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 683     if(NOT VMD_QUIETLY)
 684       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 685     endif()
 686     if(NOT GMX_VMD_PLUGIN_PATH)
 687       find_package(VMD)
 688     endif()
 689     set(GMX_USE_PLUGINS ON)
 690     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 691     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 692   else()
 693     set(PKG_DL_LIBS)
 694   endif()
 695 endif()
 696 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 697
 698 # Link real-time library for POSIX timers. The check for clock_gettime
 699 # confirms the linkability of rt.
 700 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 701     list(APPEND GMX_EXTRA_LIBRARIES rt)
 702 endif()
 703
 704 # Math and thread libraries must often come after all others when linking...
 705 if(HAVE_LIBM)
 706     list(APPEND GMX_EXTRA_LIBRARIES m)
 707 endif()
 708
 709 option(GMX_NACL "Configure for Native Client builds" OFF)
 710 if (GMX_NACL)
 711   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 712   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 713   # TODO: Is this still necessary with the check for its presence?
 714   set(GMX_USE_NICE 0)
 715   set(GMX_NO_RENAME 1)
 716 endif()
 717 mark_as_advanced(GMX_NACL)
 718
 719 if(GMX_FAHCORE)
 720   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 721       "Path to swindirect.h")
 722   include_directories(${COREWRAP_INCLUDE_DIR})
 723 endif()
 724
 725 # Value of GMX_BUILD_HELP=AUTO tries to generate things, but will only
 726 # produce warnings if that fails.
 727 set(build_help_default AUTO)
 728 if (SOURCE_IS_SOURCE_DISTRIBUTION OR CMAKE_CROSSCOMPILING)
 729     set(build_help_default OFF)
 730 endif()
 731 gmx_option_trivalue(GMX_BUILD_HELP "Build completions automatically (requires that compiled binaries can be executed on the build host) and install man pages if built (requires building the 'man' target manually)" ${build_help_default})
 732 mark_as_advanced(GMX_BUILD_HELP)
 733 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 734     message(FATAL_ERROR
 735         "Rebuilding shell completions or man pages is not supported for "
 736         "in-source builds from a source distribution. "
 737         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 738 endif()
 739
 740 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 741 # these are set after everything else
 742 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 743     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 744     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 745     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 746     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 747 else()
 748     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 749     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 750     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 751     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 752     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 753     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 754     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 755     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 756     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 757 endif()
 758
 759 if(NOT GMX_OPENMP)
 760     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 761     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 762     unset(OpenMP_C_FLAGS CACHE)
 763     unset(OpenMP_CXX_FLAGS CACHE)
 764 else()
 765     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 766     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 767 endif()
 768
 769 ########################################################################
 770 # Specify install locations
 771 ########################################################################
 772 # Use GNUInstallDirs to set paths on multiarch systems.
 773 include(GNUInstallDirs)
 774
 775 # Customization for the installation tree paths.
 776 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 777     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 778 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 779     "Data installation directory under share/ (default: gromacs)")
 780 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 781
 782 # These variables are used internally to provide a central location for
 783 # customizing the install locations.
 784 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 785 set(BIN_INSTALL_DIR       bin)
 786 # This variable also gets written into config.h for use in finding the data
 787 # directories.
 788 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 789 set(MAN_INSTALL_DIR       share/man)
 790 # If the nesting level wrt. the installation root is changed,
 791 # gromacs-config.cmake.cmakein needs to be adapted.
 792 set(CMAKE_INSTALL_DIR     share/cmake)
 793 # TODO: Make GMXRC adapt if this is changed
 794 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 795 set(OCL_INSTALL_DIR       ${DATA_INSTALL_DIR}/opencl)
 796 set(INCL_INSTALL_DIR      include)
 797
 798 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 799
 800 # Binary and library suffix options
 801 include(gmxManageSuffixes)
 802
 803 ################################################################
 804 # Shared library load path settings
 805 ################################################################
 806 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 807 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 808 # was added.
 809
 810 if(NOT GMX_BUILD_SHARED_EXE)
 811     # No rpath
 812     set(CMAKE_SKIP_RPATH TRUE)
 813     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 814     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 815 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 816    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 817     # The build folder always has bin/ and lib/; if we are also going to
 818     # install to lib/, then the installation RPATH works also in the build
 819     # tree.  This makes installation slightly faster (no need to rewrite the
 820     # RPATHs), and makes the binaries in the build tree relocatable.
 821     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 822         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 823     endif()
 824     # Set the RPATH as relative to the executable location to make the
 825     # binaries relocatable.
 826     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 827         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 828     else()
 829         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 830     endif()
 831     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 832     set(CMAKE_MACOSX_RPATH 1)
 833 else()
 834     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 835     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 836         # Set the RPATH options manually.
 837         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 838         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 839     else()
 840         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 841         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 842     endif()
 843 endif()
 844
 845 #COPYING file: Only necessary for binary distributions.
 846 #Simpler to always install.
 847 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 848
 849 if(GMX_EXTERNAL_BOOST)
 850     include_directories(SYSTEM ${Boost_INCLUDE_DIRS})
 851     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 852 else()
 853     include_directories(BEFORE SYSTEM ${CMAKE_SOURCE_DIR}/src/external/boost)
 854     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 855     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 856     # typeid not supported for minimal internal version
 857     # (would add significant amount of code)
 858     add_definitions(-DBOOST_NO_TYPEID)
 859     if (NOT GMX_BUILD_MDRUN_ONLY)
 860         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 861                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 862                 COMPONENT development)
 863     endif()
 864 endif()
 865
 866 if (GMX_BUILD_FOR_COVERAGE)
 867     # Code heavy with asserts makes conditional coverage close to useless metric,
 868     # as by design most of the false branches are impossible to trigger in
 869     # correctly functioning code.  And the benefit of testing those that could
 870     # be triggered by using an API against its specification isn't usually
 871     # worth the effort.
 872     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 873 endif()
 874
 875 if (BUILD_TESTING)
 876     # "tests" target builds all the separate test binaries.
 877     add_custom_target(tests)
 878     # "run-ctest" is an internal target that actually runs the tests.
 879     # This is necessary to be able to add separate targets that execute as part
 880     # of 'make check', but are ensured to be executed after the actual tests.
 881     add_custom_target(run-ctest
 882                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 883                       COMMENT "Running all tests"
 884                       VERBATIM)
 885     add_dependencies(run-ctest tests)
 886     # "check" target builds and runs all tests.
 887     add_custom_target(check DEPENDS run-ctest)
 888 endif()
 889
 890 if (NOT GMX_BUILD_MDRUN_ONLY)
 891     add_subdirectory(docs)
 892     add_subdirectory(share)
 893     add_subdirectory(scripts)
 894 endif()
 895 add_subdirectory(src)
 896
 897 if (BUILD_TESTING)
 898     add_subdirectory(tests)
 899 endif()
 900
 901 gmx_cpack_write_config()
 902
 903 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 904 # Don't bother the user after the first configure pass.
 905 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 906     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 907 endif()
 908 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 909
 910 #######################
 911 ## uninstall target
 912 #######################
 913 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 914                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 915                   IMMEDIATE @ONLY)
 916 ###########################
 917 ADD_CUSTOM_TARGET(uninstall
 918                   "${CMAKE_COMMAND}" -P
 919                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 920 ###########################
 921 set_directory_properties(PROPERTIES
 922             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")