CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsitencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 if(GMX_CPU_ACCELERATION)
 176     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 177     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 178     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 179     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 180 endif()
 181
 182 if(NOT GMX_TARGET_MIC)
 183     include(gmxDetectSimd)
 184     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 185 else()
 186     set(GMX_SUGGESTED_SIMD "None")
 187 endif()
 188
 189 gmx_option_multichoice(
 190     GMX_SIMD
 191     "SIMD instruction set for CPU kernels and compiler optimization"
 192     "${GMX_SUGGESTED_SIMD}"
 193     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 194
 195 gmx_option_multichoice(
 196     GMX_FFT_LIBRARY
 197     "FFT library"
 198     "fftw3"
 199     fftw3 mkl "fftpack[built-in]")
 200 gmx_dependent_option(
 201     GMX_BUILD_OWN_FFTW
 202     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 203     OFF
 204     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 205 gmx_dependent_option(
 206     GMX_DISABLE_FFTW_MEASURE
 207     "Do not optimize FFTW setups (not needed with SSE)"
 208     OFF
 209     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 210 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 211 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 212
 213 gmx_option_multichoice(
 214     GMX_QMMM_PROGRAM
 215     "QM package for QM/MM"
 216     None
 217     none gaussian mopac gamess orca)
 218
 219 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 220 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 221
 222 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 223
 224 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 225 mark_as_advanced(GMX_BROKEN_CALLOC)
 226 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 227 mark_as_advanced(GMX_LOAD_PLUGINS)
 228
 229 option(GMX_GPU  "Enable GPU acceleration" ON)
 230 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 231
 232 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 233
 234 if(UNIX)
 235     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 236 endif()
 237 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 238
 239 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 240 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 241
 242 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 243 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 244
 245 option(GMX_BUILD_FOR_COVERAGE
 246        "Tune build for better code coverage metrics (e.g., disable asserts)"
 247        OFF)
 248 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 249
 250 option(GMX_DEVELOPER_BUILD
 251     "Enable Developer convenience features: always build unit-tests"
 252     OFF)
 253 mark_as_advanced(GMX_DEVELOPER_BUILD)
 254
 255 ######################################################################
 256 # Detect OpenMP support
 257 ######################################################################
 258 # The OpenMP detection _must_ come before tests for other CFLAGS.
 259 include(gmxManageOpenMP)
 260
 261
 262
 263 ######################################################################
 264 # Compiler tests
 265 # These need to be done early (before further tests).
 266 #####################################################################
 267
 268 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 269 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 270 # invalid options with the Intel Compilers, and we have added a line
 271 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 272 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 273 # a semicolon. Since this is also used as a separator in lists inside CMake,
 274 # that string ends up being split into two separate patterns, and the last
 275 # part is just a single word that also matches other messages. We solved this
 276 # by replacing the semicolon with a period that matches any character.
 277 #
 278 # These files should be removed from the source tree when a CMake version that
 279 # includes the features in question becomes required for building GROMACS.
 280 include(CheckCCompilerFlag)
 281 include(CheckCXXCompilerFlag)
 282
 283 include(gmxCFlags)
 284 gmx_c_flags()
 285
 286 # This variable should be used for additional compiler flags which are not
 287 # generated in gmxCFlags nor are SIMD or MPI related.
 288 set(EXTRA_C_FLAGS "")
 289 set(EXTRA_CXX_FLAGS "")
 290
 291 # Run through a number of tests for buggy compilers and other issues
 292 include(gmxTestCompilerProblems)
 293 gmx_test_compiler_problems()
 294 # GMX_SIMD will not be set automatically until the second
 295 # pass (which is not strictly guaranteed to occur), so putting this
 296 # check here among logically-related tests is inefficient, but the
 297 # potential loss is likely zero.
 298 if(GMX_SIMD STREQUAL "AVX_256"
 299         AND CMAKE_COMPILER_IS_GNUCC
 300         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 301             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 302     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 303     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 304 endif()
 305
 306
 307 if(GMX_DOUBLE)
 308     add_definitions(-DGMX_DOUBLE)
 309     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 310     if(GMX_RELAXED_DOUBLE_PRECISION)
 311         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 312     endif()
 313 endif()
 314 if(GMX_SOFTWARE_INVSQRT)
 315     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 316 endif()
 317
 318 if(WIN32)
 319     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 320     add_definitions(-DGMX_HAVE_WINSOCK)
 321 endif()
 322
 323
 324
 325 ########################################################################
 326 # Basic system tests (standard libraries, headers, functions, types)   #
 327 ########################################################################
 328 include(CheckIncludeFiles)
 329 include(CheckIncludeFileCXX)
 330 check_include_files(unistd.h     HAVE_UNISTD_H)
 331 check_include_files(pwd.h        HAVE_PWD_H)
 332 check_include_files(dirent.h     HAVE_DIRENT_H)
 333 check_include_files(time.h       HAVE_TIME_H)
 334 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 335 check_include_files(io.h         HAVE_IO_H)
 336 check_include_files(sched.h      HAVE_SCHED_H)
 337
 338 check_include_files(regex.h      HAVE_POSIX_REGEX)
 339 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 340 # TODO: It could be nice to inform the user if no regex support is found,
 341 # as selections won't be fully functional.
 342
 343 include(CheckFunctionExists)
 344 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 345 check_function_exists(memalign          HAVE_MEMALIGN)
 346 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 347 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 348 check_function_exists(fsync             HAVE_FSYNC)
 349 check_function_exists(_fileno           HAVE__FILENO)
 350 check_function_exists(fileno            HAVE_FILENO)
 351 check_function_exists(_commit           HAVE__COMMIT)
 352 check_function_exists(sigaction         HAVE_SIGACTION)
 353 check_function_exists(sysconf           HAVE_SYSCONF)
 354 check_function_exists(rsqrt             HAVE_RSQRT)
 355 check_function_exists(rsqrtf            HAVE_RSQRTF)
 356 check_function_exists(sqrtf             HAVE_SQRTF)
 357
 358 include(CheckLibraryExists)
 359 check_library_exists(m sqrt "" HAVE_LIBM)
 360 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 361
 362 include(TestSchedAffinity)
 363 test_sched_affinity(HAVE_SCHED_AFFINITY)
 364
 365 include(TestBigEndian)
 366 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 367
 368 # Management of GROMACS options for specific toolchains should go
 369 # here. Because the initial settings for some of the main options have
 370 # already happened, but things like library detection and MPI compiler
 371 # feature detection have not, the docstrings for any over-rides of
 372 # GROMACS defaults or user settings will make sense. Also, any
 373 # toolchain-related reasons for choosing whether to detect various
 374 # things can be sorted out now, before the detection takes place.
 375 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 376     include(gmxManageBlueGene)
 377 endif()
 378
 379 if(GMX_TARGET_FUJITSU_SPARC64)
 380     include(gmxManageFujitsuSparc64)
 381 endif()
 382
 383 ########################################################################
 384 #Process MPI settings
 385 ########################################################################
 386 include(gmxManageMPI)
 387
 388
 389 ########################################################################
 390 #Process shared/static library settings
 391 ########################################################################
 392 include(gmxManageSharedLibraries)
 393
 394
 395 ########################################################################
 396 # Find external packages                                               #
 397 ########################################################################
 398
 399 # Unconditionally find the package, as it is also required for unit
 400 # tests. This exports LIBXML2_FOUND, which we should not use because
 401 # it does not tell us that linking will succeed. Instead, we test that
 402 # next.
 403 if(DEFINED LIBXML2_LIBRARIES)
 404   set(LibXml2_FIND_QUIETLY TRUE)
 405 endif()
 406 find_package(LibXml2)
 407 include(gmxTestLibXml2)
 408 gmx_test_libxml2(HAVE_LIBXML2)
 409 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 410 set(PKG_XML "")
 411 mark_as_advanced(GMX_XML)
 412 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 413 #if(GMX_XML AND NOT HAVE_LIBXML2)
 414 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 415 #endif()
 416 #if(GMX_XML)
 417 #    include_directories(${LIBXML2_INCLUDE_DIR})
 418 #    set(PKG_XML libxml-2.0)
 419 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 420 #endif()
 421
 422 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 423 mark_as_advanced(GMX_EXTRAE)
 424
 425 if (GMX_EXTRAE)
 426   find_package(EXTRAE)
 427   if(EXTRAE_FOUND)
 428     include_directories(${EXTRAE_INCLUDE_DIR})
 429     set(HAVE_EXTRAE 1)
 430   else()
 431     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 432   endif()
 433 endif()
 434
 435 option(GMX_X11 "Use X window system" OFF)
 436 if (GMX_X11)
 437     find_package(X11)
 438     # X11 includes/libraries are only set in the ngmx subdirectory!
 439     if(NOT X11_FOUND)
 440         message(FATAL_ERROR
 441                 "X11 include files and/or libraries were not found. "
 442                 "Set GMX_X11=OFF to compile without X11 support. "
 443                 "gmx view will not be available.")
 444     endif()
 445     include_directories(${X11_INCLUDE_DIR})
 446 endif()
 447
 448 include(ThreadMPI)
 449 # Enable core threading facilities
 450 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 451 # Enable tMPI C++ support
 452 tmpi_enable_cxx()
 453 if(GMX_THREAD_MPI)
 454     # enable MPI functions
 455     tmpi_enable()
 456     set(GMX_MPI 1)
 457     set(MPI_IN_PLACE_EXISTS 1)
 458 endif()
 459 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 460 if (TMPI_ATOMICS_DISABLED)
 461    add_definitions(-DTMPI_ATOMICS_DISABLED)
 462 endif()
 463
 464 if(GMX_GPU)
 465     # now that we have detected the dependencies, do the second configure pass
 466     gmx_gpu_setup()
 467 endif()
 468
 469 if(CYGWIN)
 470     set(GMX_CYGWIN 1)
 471 endif()
 472
 473 if(WIN32)
 474     set(GMX_NATIVE_WINDOWS 1)
 475     # This makes windows.h not declare min/max as macros that would break
 476     # C++ code using std::min/std::max.
 477     add_definitions(-DNOMINMAX)
 478 endif()
 479
 480 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 481 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 482 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 483     find_package(Boost 1.44.0)
 484     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 485         set(Boost_FOUND FALSE)
 486     endif()
 487     # Print the notification only on first run, when determining the default
 488     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 489         message("Boost >= 1.44 not found. Using minimal internal version. "
 490                 "This may cause trouble if you plan on compiling/linking other "
 491                 "software that uses Boost against Gromacs.")
 492     endif()
 493 endif()
 494 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 495        ${Boost_FOUND})
 496 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 497     message(FATAL_ERROR
 498         "Boost >= 1.44 not found. "
 499         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 500         "version of Boost included with Gromacs.")
 501 endif()
 502
 503 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 504     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 505 endif()
 506 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 507 mark_as_advanced(GMX_BUILD_UNITTESTS)
 508 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 509 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 510     message(FATAL_ERROR
 511         "Cannot build unit tests without libxml2. "
 512         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 513 endif()
 514
 515 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 516     # TNG wants zlib if it is available
 517     find_package(ZLIB QUIET)
 518     include(gmxTestZLib)
 519     gmx_test_zlib(HAVE_ZLIB)
 520 endif()
 521
 522 ########################################################################
 523 # Our own GROMACS tests
 524 ########################################################################
 525
 526 add_definitions( -DHAVE_CONFIG_H )
 527 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 528 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 529 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 530 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 531
 532 include(gmxTestInlineASM)
 533 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 534
 535 include(gmxSetBuildInformation)
 536 gmx_set_build_information()
 537 # Turn on RDTSCP if:
 538 # - the build system's CPU supports it
 539 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 540 #   at this point means that the user set it).
 541 # Note: it's better to not use the later set value of GMX_SIMD because
 542 # it reflects the system's capability of both compiling and running AVX code.
 543 # TODO: After merge with 5.0 one could implement a cache variable dependency
 544 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 545 # after the first cmake pass.
 546 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 547     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 548 else()
 549     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 550 endif()
 551 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 552 mark_as_advanced(GMX_USE_RDTSCP)
 553 if(GMX_USE_RDTSCP)
 554     set(HAVE_RDTSCP 1)
 555 endif()
 556
 557 include(gmxTestFloatFormat)
 558 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 559                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 560                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 561
 562 include(gmxTestLargeFiles)
 563 gmx_test_large_files(GMX_LARGEFILES)
 564
 565 include(gmxTestSignal)
 566 gmx_test_sigusr1(HAVE_SIGUSR1)
 567
 568 include(gmxTestPipes)
 569 gmx_test_pipes(HAVE_PIPES)
 570
 571 include(gmxTestIsfinite)
 572 gmx_test_isfinite(HAVE_ISFINITE)
 573 gmx_test__isfinite(HAVE__ISFINITE)
 574 gmx_test__finite(HAVE__FINITE)
 575
 576 include(gmxTestCXX11)
 577 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 578 include(CMakeDependentOption)
 579 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 580 # entirely to keep the compilation environment uniform.
 581 cmake_dependent_option(GMX_CXX11
 582     "Use C++11 features"
 583     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 584 mark_as_advanced(GMX_CXX11)
 585 if(GMX_CXX11)
 586     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 587 endif()
 588
 589
 590 include(gmxTestXDR)
 591 gmx_test_xdr(GMX_SYSTEM_XDR)
 592 if(NOT GMX_SYSTEM_XDR)
 593     set(GMX_INTERNAL_XDR 1)
 594 endif()
 595
 596
 597 ##################################################
 598 # Process SIMD instruction settings
 599 ##################################################
 600 # This checks what flags to add in order to
 601 # support the SIMD instructions we need, and sets
 602 # correct defines for the SIMD instructions supported.
 603 include(gmxTestSimd)
 604 gmx_test_simd()
 605
 606
 607 # Process QM/MM Settings
 608 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 609     set(GMX_QMMM_GAUSSIAN 1)
 610 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 611     set(GMX_QMMM_MOPAC 1)
 612 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 613     set(GMX_QMMM_GAMESS 1)
 614 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 615     set(GMX_QMMM_ORCA 1)
 616 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 617     # nothing to do
 618 else()
 619     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 620 endif()
 621
 622
 623 ##################################################
 624 # Process FFT library settings
 625 ##################################################
 626 include(gmxManageFFTLibraries)
 627
 628
 629 include(gmxManageLinearAlgebraLibraries)
 630
 631 # Whether GROMACS will really try to compile support for VMD plugins
 632 set(GMX_USE_PLUGINS OFF)
 633
 634 if(GMX_LOAD_PLUGINS)
 635   if(NOT WIN32)
 636     # Native Windows does not have, nor need dlopen
 637     include(gmxTestdlopen)
 638     gmx_test_dlopen(HAVE_DLOPEN)
 639   endif()
 640
 641   # so, should we use plug-ins?
 642   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 643     if(NOT VMD_QUIETLY)
 644       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 645     endif()
 646     if(NOT GMX_VMD_PLUGIN_PATH)
 647       find_package(VMD)
 648     endif()
 649     set(GMX_USE_PLUGINS ON)
 650     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 651     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 652   else()
 653     set(PKG_DL_LIBS)
 654   endif()
 655 endif()
 656 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 657
 658 # Link real-time library for POSIX timers. The check for clock_gettime
 659 # confirms the linkability of rt.
 660 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 661     list(APPEND GMX_EXTRA_LIBRARIES rt)
 662 endif()
 663
 664 # Math and thread libraries must often come after all others when linking...
 665 if(HAVE_LIBM)
 666     list(APPEND GMX_EXTRA_LIBRARIES m)
 667 endif()
 668
 669 option(GMX_NACL "Configure for Native Client builds" OFF)
 670 if (GMX_NACL)
 671   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 672   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 673   set(GMX_NO_NICE 1)
 674   set(GMX_NO_RENAME 1)
 675 endif()
 676 mark_as_advanced(GMX_NACL)
 677
 678 if(GMX_FAHCORE)
 679   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 680       "Path to swindirect.h")
 681   include_directories(${COREWRAP_INCLUDE_DIR})
 682 endif()
 683
 684 # Value of AUTO tries to generate things, but will only produce warnings if
 685 # that fails.
 686 set(build_help_default AUTO)
 687 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 688     set(build_help_default OFF)
 689 endif()
 690 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 691 mark_as_advanced(GMX_BUILD_HELP)
 692 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 693     message(FATAL_ERROR
 694         "Rebuilding HTML and man pages or shell completions is not supported "
 695         "for in-source builds from a source distribution. "
 696         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 697 endif()
 698
 699 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 700 # these are set after everything else
 701 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 702     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 703     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 704     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 705     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 706 else()
 707     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 708     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 709     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 710     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 711     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 712     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 713     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 714     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 715     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 716 endif()
 717
 718 if(NOT GMX_OPENMP)
 719     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 720     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 721     unset(OpenMP_C_FLAGS CACHE)
 722     unset(OpenMP_CXX_FLAGS CACHE)
 723 else()
 724     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 725     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 726 endif()
 727
 728 ########################################################################
 729 # Specify install locations
 730 ########################################################################
 731 # Use GNUInstallDirs to set paths on multiarch systems.
 732 include(GNUInstallDirs)
 733
 734 # Customization for the installation tree paths.
 735 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 736     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 737 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 738     "Data installation directory under share/ (default: gromacs)")
 739 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 740
 741 # These variables are used internally to provide a central location for
 742 # customizing the install locations.
 743 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 744 set(BIN_INSTALL_DIR       bin)
 745 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 746 set(MAN_INSTALL_DIR       share/man)
 747 # If the nesting level wrt. the installation root is changed,
 748 # gromacs-config.cmake.cmakein needs to be adapted.
 749 set(CMAKE_INSTALL_DIR     share/cmake)
 750 # TODO: Make GMXRC adapt if this is changed
 751 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 752 set(INCL_INSTALL_DIR      include)
 753
 754 # These variables get written into config.h for use in finding the data
 755 # directories.
 756 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 757 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 758
 759 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 760
 761 # Binary and library suffix options
 762 include(gmxManageSuffixes)
 763
 764 ################################################################
 765 # Shared library load path settings
 766 ################################################################
 767 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 768 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 769 # was added.
 770 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 771    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 772     # The build folder always has bin/ and lib/; if we are also going to
 773     # install to lib/, then the installation RPATH works also in the build
 774     # tree.  This makes installation slightly faster (no need to rewrite the
 775     # RPATHs), and makes the binaries in the build tree relocatable.
 776     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 777         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 778     endif()
 779     # Set the RPATH as relative to the executable location to make the
 780     # binaries relocatable.
 781     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 782         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 783     else()
 784         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 785     endif()
 786     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 787     set(CMAKE_MACOSX_RPATH 1)
 788 else()
 789     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 790     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 791         # Set the RPATH options manually.
 792         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 793         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 794     else()
 795         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 796         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 797     endif()
 798 endif()
 799
 800 #COPYING file: Only necessary for binary distributions.
 801 #Simpler to always install.
 802 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 803
 804 if(GMX_EXTERNAL_BOOST)
 805     include_directories(${Boost_INCLUDE_DIRS})
 806     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 807 else()
 808     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 809     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 810     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 811     # typeid not supported for minimal internal version
 812     # (would add significant amount of code)
 813     add_definitions(-DBOOST_NO_TYPEID)
 814     if (NOT GMX_BUILD_MDRUN_ONLY)
 815         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 816                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 817                 COMPONENT development)
 818     endif()
 819 endif()
 820
 821 if (GMX_BUILD_FOR_COVERAGE)
 822     # Code heavy with asserts makes conditional coverage close to useless metric,
 823     # as by design most of the false branches are impossible to trigger in
 824     # correctly functioning code.  And the benefit of testing those that could
 825     # be triggered by using an API against its specification isn't usually
 826     # worth the effort.
 827     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 828 endif()
 829
 830 if (BUILD_TESTING)
 831     # "tests" target builds all the separate test binaries.
 832     add_custom_target(tests)
 833     # "run-ctest" is an internal target that actually runs the tests.
 834     # This is necessary to be able to add separate targets that execute as part
 835     # of 'make check', but are ensured to be executed after the actual tests.
 836     add_custom_target(run-ctest
 837                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 838                       COMMENT "Running all tests"
 839                       VERBATIM)
 840     add_dependencies(run-ctest tests)
 841     # "check" target builds and runs all tests.
 842     add_custom_target(check DEPENDS run-ctest)
 843 endif()
 844
 845 if (NOT GMX_BUILD_MDRUN_ONLY)
 846     add_subdirectory(docs)
 847     add_subdirectory(share)
 848     add_subdirectory(scripts)
 849 endif()
 850 add_subdirectory(src)
 851
 852 if (BUILD_TESTING)
 853     add_subdirectory(tests)
 854 endif()
 855
 856 gmx_cpack_write_config()
 857
 858 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 859 # Don't bother the user after the first configure pass.
 860 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 861     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 862 endif()
 863 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 864
 865 #######################
 866 ## uninstall target
 867 #######################
 868 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 869                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 870                   IMMEDIATE @ONLY)
 871 ###########################
 872 ADD_CUSTOM_TARGET(uninstall
 873                   "${CMAKE_COMMAND}" -P
 874                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 875 ###########################
 876 set_directory_properties(PROPERTIES
 877             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")