CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 189 # to use if none is specified, and populate the cache option for CPU
 190 # SIMD.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectSimd)
 194 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 195 if("${GMX_SUGGESTED_SIMD}" STREQUAL "AVX2_256")
 196     message(STATUS "Changing acceleration from AVX2 to AVX (until AVX2 patches commited).")
 197     set(GMX_SUGGESTED_SIMD "AVX_256")
 198 endif()
 199
 200 gmx_option_multichoice(
 201     GMX_SIMD
 202     "SIMD instruction set for CPU kernels and compiler optimization"
 203     "${GMX_SUGGESTED_SIMD}"
 204     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 205
 206 gmx_option_multichoice(
 207     GMX_FFT_LIBRARY
 208     "FFT library"
 209     "fftw3"
 210     fftw3 mkl "fftpack[built-in]")
 211 gmx_dependent_option(
 212     GMX_BUILD_OWN_FFTW
 213     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 214     OFF
 215     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 216 gmx_dependent_option(
 217     GMX_DISABLE_FFTW_MEASURE
 218     "Do not optimize FFTW setups (not needed with SSE)"
 219     OFF
 220     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 221 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 222 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 223
 224 gmx_option_multichoice(
 225     GMX_QMMM_PROGRAM
 226     "QM package for QM/MM"
 227     None
 228     none gaussian mopac gamess orca)
 229
 230 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_TYPE "Reference kernel type (4xn or 2xnn)" STRING "4xn" "GMX_SIMD STREQUAL REFERENCE")
 231 gmx_dependent_cache_variable(GMX_NBNXN_REF_KERNEL_WIDTH "Reference kernel width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 232
 233 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 234 mark_as_advanced(GMX_BROKEN_CALLOC)
 235 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 236 mark_as_advanced(GMX_LOAD_PLUGINS)
 237
 238 option(GMX_GPU  "Enable GPU acceleration" ON)
 239 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 240
 241 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 242
 243 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 244 mark_as_advanced(GMX_GIT_VERSION_INFO)
 245
 246 if(UNIX)
 247     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 248 endif()
 249 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 250
 251 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 252 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 253
 254 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 255 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 256
 257 option(GMX_BUILD_FOR_COVERAGE
 258        "Tune build for better code coverage metrics (e.g., disable asserts)"
 259        OFF)
 260 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 261
 262
 263 ######################################################################
 264 # Detect OpenMP support
 265 ######################################################################
 266 # The OpenMP detection _must_ come before tests for other CFLAGS.
 267 include(gmxManageOpenMP)
 268
 269
 270
 271 ######################################################################
 272 # Compiler tests
 273 # These need to be done early (before further tests).
 274 #####################################################################
 275
 276 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 277 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 278 # invalid options with the Intel Compilers.
 279 # These files should be removed from the source tree when a CMake version that
 280 # includes the features in question becomes required for building GROMACS.
 281 include(CheckCCompilerFlag)
 282 include(CheckCXXCompilerFlag)
 283
 284
 285 include(gmxCFlags)
 286 gmx_c_flags()
 287
 288 # This variable should be used for additional compiler flags which are not
 289 # generated in gmxCFlags nor are SIMD or MPI related.
 290 set(EXTRA_C_FLAGS "")
 291 set(EXTRA_CXX_FLAGS "")
 292
 293 # Run through a number of tests for buggy compilers and other issues
 294 include(gmxTestCompilerProblems)
 295 gmx_test_compiler_problems()
 296
 297
 298 set(PKG_CFLAGS "")
 299 if(GMX_DOUBLE)
 300     add_definitions(-DGMX_DOUBLE)
 301     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 302 endif(GMX_DOUBLE)
 303 if(GMX_SOFTWARE_INVSQRT)
 304   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 305 endif(GMX_SOFTWARE_INVSQRT)
 306
 307
 308
 309 ########################################################################
 310 # Basic system tests (standard libraries, headers, functions, types)   #
 311 ########################################################################
 312 include(CheckIncludeFiles)
 313 include(CheckIncludeFileCXX)
 314 check_include_files(unistd.h     HAVE_UNISTD_H)
 315 check_include_files(pwd.h        HAVE_PWD_H)
 316 check_include_files(dirent.h     HAVE_DIRENT_H)
 317 check_include_files(time.h       HAVE_TIME_H)
 318 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 319 check_include_files(io.h         HAVE_IO_H)
 320 check_include_files(sched.h      HAVE_SCHED_H)
 321
 322 check_include_files(regex.h      HAVE_POSIX_REGEX)
 323 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 324 # TODO: It could be nice to inform the user if no regex support is found,
 325 # as selections won't be fully functional.
 326
 327 include(CheckFunctionExists)
 328 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 329 check_function_exists(memalign          HAVE_MEMALIGN)
 330 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 331 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 332 check_function_exists(fsync             HAVE_FSYNC)
 333 check_function_exists(_fileno           HAVE__FILENO)
 334 check_function_exists(fileno            HAVE_FILENO)
 335 check_function_exists(_commit           HAVE__COMMIT)
 336 check_function_exists(sigaction         HAVE_SIGACTION)
 337 check_function_exists(sysconf           HAVE_SYSCONF)
 338 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 339 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 340 check_function_exists(rsqrt             HAVE_RSQRT)
 341 check_function_exists(rsqrtf            HAVE_RSQRTF)
 342 check_function_exists(sqrtf             HAVE_SQRTF)
 343
 344 include(CheckLibraryExists)
 345 check_library_exists(m sqrt "" HAVE_LIBM)
 346 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 347
 348 include(TestBigEndian)
 349 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 350
 351 # Management of GROMACS options for specific toolchains should go
 352 # here. Because the initial settings for some of the main options have
 353 # already happened, but things like library detection and MPI compiler
 354 # feature detection have not, the docstrings for any over-rides of
 355 # GROMACS defaults or user settings will make sense. Also, any
 356 # toolchain-related reasons for choosing whether to detect various
 357 # things can be sorted out now, before the detection takes place.
 358 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 359     include(gmxManageBlueGene)
 360 endif()
 361
 362 ########################################################################
 363 #Process MPI settings
 364 ########################################################################
 365 include(gmxManageMPI)
 366
 367
 368 ########################################################################
 369 #Process shared/static library settings
 370 ########################################################################
 371 include(gmxManageSharedLibraries)
 372
 373
 374 ########################################################################
 375 # Find external packages                                               #
 376 ########################################################################
 377
 378 # Unconditionally find the package, as it is also required for unit
 379 # tests. This exports LIBXML2_FOUND, which we should not use because
 380 # it does not tell us that linking will succeed. Instead, we test that
 381 # next.
 382 find_package(LibXml2)
 383 include(gmxTestLibXml2)
 384 gmx_test_libxml2(HAVE_LIBXML2)
 385 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 386 set(PKG_XML "")
 387 mark_as_advanced(GMX_XML)
 388 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 389 #if(GMX_XML AND NOT HAVE_LIBXML2)
 390 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 391 #endif()
 392 #if(GMX_XML)
 393 #    include_directories(${LIBXML2_INCLUDE_DIR})
 394 #    set(PKG_XML libxml-2.0)
 395 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 396 #endif(GMX_XML)
 397
 398 option(GMX_GSL "Add support for gsl" OFF)
 399 if (GMX_GSL)
 400   find_package(GSL)
 401   set(PKG_GSL "")
 402   if(GSL_FOUND)
 403     include_directories(${GSL_INCLUDE_DIR})
 404     set(PKG_GSL gsl)
 405     set(HAVE_LIBGSL 1)
 406   endif(GSL_FOUND)
 407 endif (GMX_GSL)
 408
 409 option(GMX_X11 "Use X window system" OFF)
 410 if (GMX_X11)
 411     find_package(X11)
 412     # X11 includes/libraries are only set in the ngmx subdirectory!
 413     if(NOT X11_FOUND)
 414         message(FATAL_ERROR
 415                 "X11 include files and/or libraries were not found. "
 416                 "Set GMX_X11=OFF to compile without X11 support. "
 417                 "gmx view will not be available.")
 418     endif()
 419     include_directories(${X11_INCLUDE_DIR})
 420 endif(GMX_X11)
 421
 422 include(ThreadMPI)
 423 set(THREAD_MPI_LIB thread_mpi)
 424 # Enable core threading facilities
 425 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 426 # Enable tMPI C++ support
 427 tmpi_enable_cxx()
 428 if(GMX_THREAD_MPI)
 429     # enable MPI functions
 430     tmpi_enable()
 431     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 432     set(GMX_MPI 1)
 433     set(MPI_IN_PLACE_EXISTS 1)
 434 endif(GMX_THREAD_MPI)
 435 tmpi_get_source_list(THREAD_MPI_SRC)
 436
 437 if(GMX_GPU)
 438     # now that we have detected the dependencies, do the second configure pass
 439     gmx_gpu_setup()
 440 endif(GMX_GPU)
 441
 442 if(CYGWIN)
 443     set(GMX_CYGWIN 1)
 444 endif(CYGWIN)
 445
 446 if(WIN32 AND NOT CYGWIN)
 447     set(GMX_NATIVE_WINDOWS 1)
 448     # This makes windows.h not declare min/max as macros that would break
 449     # C++ code using std::min/std::max.
 450     add_definitions(-DNOMINMAX)
 451 endif()
 452
 453 # only bother with finding git and using version.h if the source is a git repo
 454 if(GMX_GIT_VERSION_INFO)
 455     if (NOT SOURCE_IS_GIT_REPOSITORY)
 456         message(FATAL_ERROR
 457             "Cannot generate git version information from source tree not under git. "
 458             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 459     endif ()
 460     # We need at least git v1.5.3 be able to parse git's date output. If not
 461     # found or the version is too small, we can't generate version information.
 462     find_package(Git)
 463
 464     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 465         message(FATAL_ERROR
 466             "No compatible git version found (>= 1.5.3 required). "
 467             "Won't be able to generate development version information. "
 468             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 469     endif()
 470 endif()
 471
 472 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 473 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 474 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 475     find_package(Boost 1.44.0)
 476     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 477         set(Boost_FOUND FALSE)
 478     endif()
 479     # Print the notification only on first run, when determining the default
 480     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 481         message("Boost >= 1.44 not found. Using minimal internal version. "
 482                 "This may cause trouble if you plan on compiling/linking other "
 483                 "software that uses Boost against Gromacs.")
 484     endif()
 485 endif()
 486 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 487        ${Boost_FOUND})
 488 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 489     message(FATAL_ERROR
 490         "Boost >= 1.44 not found. "
 491         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 492         "version of Boost included with Gromacs.")
 493 endif()
 494
 495 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 496 mark_as_advanced(GMX_BUILD_UNITTESTS)
 497 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 498 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 499     message(FATAL_ERROR
 500         "Cannot build unit tests without libxml2. "
 501         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 502 endif()
 503
 504 ########################################################################
 505 # Generate development version info for cache
 506 ########################################################################
 507 # set(GEN_VERSION_INFO_INTERNAL "ON")
 508 # include(gmxGenerateVersionString)
 509
 510 ########################################################################
 511 # Our own GROMACS tests
 512 ########################################################################
 513
 514 add_definitions( -DHAVE_CONFIG_H )
 515 include_directories(${CMAKE_SOURCE_DIR}/src)
 516 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 517 include_directories(${CMAKE_BINARY_DIR}/src)
 518 # Required for gmx_header_config_gen.h to be found before installation
 519 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 520 # Required for now to make old code compile
 521 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 522
 523 include(gmxTestInlineASM)
 524 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 525
 526 include(gmxSetBuildInformation)
 527 gmx_set_build_information()
 528 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 529     set(HAVE_RDTSCP 1)
 530 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 531
 532 include(gmxTestFloatFormat)
 533 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 534                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 535                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 536
 537 include(gmxTestLargeFiles)
 538 gmx_test_large_files(GMX_LARGEFILES)
 539
 540 include(gmxTestSignal)
 541 gmx_test_sigusr1(HAVE_SIGUSR1)
 542
 543 include(gmxTestInline)
 544 gmx_test_inline(INLINE_KEYWORD)
 545
 546 include(gmxTestRestrict)
 547 gmx_test_restrict(RESTRICT_KEYWORD)
 548
 549 include(gmxTestPipes)
 550 gmx_test_pipes(HAVE_PIPES)
 551
 552 include(gmxTestIsfinite)
 553 gmx_test_isfinite(HAVE_ISFINITE)
 554 gmx_test__isfinite(HAVE__ISFINITE)
 555 gmx_test__finite(HAVE__FINITE)
 556
 557 include(gmxTestCXX11)
 558 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 559 include(CMakeDependentOption)
 560 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 561 # entirely to keep the compilation environment uniform.
 562 cmake_dependent_option(GMX_CXX11
 563     "Use C++11 features"
 564     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 565 mark_as_advanced(GMX_CXX11)
 566 if(GMX_CXX11)
 567     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 568 endif()
 569
 570
 571 include(gmxTestXDR)
 572 gmx_test_xdr(GMX_SYSTEM_XDR)
 573 if(NOT GMX_SYSTEM_XDR)
 574     set(GMX_INTERNAL_XDR 1)
 575 endif(NOT GMX_SYSTEM_XDR)
 576
 577
 578 ##################################################
 579 # Process SIMD instruction settings
 580 ##################################################
 581 # This checks what flags to add in order to
 582 # support the SIMD instructions we need, and sets
 583 # correct defines for the SIMD instructions supported.
 584 include(gmxTestSimd)
 585 gmx_test_simd()
 586
 587
 588 # Process QM/MM Settings
 589 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 590     set(GMX_QMMM_GAUSSIAN 1)
 591 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 592     set(GMX_QMMM_MOPAC 1)
 593 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 594     set(GMX_QMMM_GAMESS 1)
 595 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 596     set(GMX_QMMM_ORCA 1)
 597 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 598     # nothing to do
 599 else()
 600     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 601 endif()
 602
 603
 604 ##################################################
 605 # Process FFT library settings
 606 ##################################################
 607 include(gmxManageFFTLibraries)
 608
 609
 610 include(gmxManageLinearAlgebraLibraries)
 611
 612 # Whether GROMACS will really try to compile support for VMD plugins
 613 set(GMX_USE_PLUGINS OFF)
 614
 615 if(GMX_LOAD_PLUGINS)
 616   if(CYGWIN OR NOT WIN32)
 617     # Native Windows does not have, nor need dlopen
 618     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 619     include(gmxTestdlopen)
 620     gmx_test_dlopen(HAVE_DLOPEN)
 621   endif()
 622
 623   # so, should we use plug-ins?
 624   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 625     if(NOT VMD_QUIETLY)
 626       MESSAGE(STATUS
 627           "Found the ability to use plug-ins when building shared libaries, "
 628           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 629           "formats).")
 630     endif()
 631     if(NOT GMX_VMD_PLUGIN_PATH)
 632       find_package(VMD)
 633     endif()
 634     set(GMX_USE_PLUGINS ON)
 635     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 636     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 637   else()
 638     set(PKG_DL_LIBS)
 639   endif()
 640 endif(GMX_LOAD_PLUGINS)
 641 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 642
 643 # Link real-time library for POSIX timers. The check for clock_gettime
 644 # confirms the linkability of rt.
 645 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 646     list(APPEND GMX_EXTRA_LIBRARIES rt)
 647 endif()
 648
 649 # Math and thread libraries must often come after all others when linking...
 650 if(HAVE_LIBM)
 651     list(APPEND GMX_EXTRA_LIBRARIES m)
 652 endif(HAVE_LIBM)
 653 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 654     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 655     if(HAVE_MASS_SIMD)
 656         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 657     else()
 658         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 659     endif()
 660 endif()
 661
 662
 663 option(GMX_NACL "Configure for Native Client builds" OFF)
 664 if (GMX_NACL)
 665   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 666   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 667   set(GMX_NO_NICE 1)
 668   set(GMX_NO_RENAME 1)
 669 endif()
 670 mark_as_advanced(GMX_NACL)
 671
 672 if(GMX_FAHCORE)
 673   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 674       "Path to swindirect.h")
 675   include_directories(${COREWRAP_INCLUDE_DIR})
 676 endif(GMX_FAHCORE)
 677
 678 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 679 mark_as_advanced(GMX_BUILD_HELP)
 680 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 681     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 682
 683     message(FATAL_ERROR
 684         "Rebuilding HTML and man pages is not supported for in-source "
 685         "builds from a source distribution. "
 686         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 687 endif()
 688
 689 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 690 # these are set after everything else
 691 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 692     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 693     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 694     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 695     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 696 else()
 697     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 698     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 699     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 700     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 701     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 702     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 703     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 704     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 705     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 706 endif()
 707
 708 if(NOT GMX_OPENMP)
 709     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 710     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 711     unset(OpenMP_C_FLAGS CACHE)
 712     unset(OpenMP_CXX_FLAGS CACHE)
 713 else()
 714     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 715     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 716 endif()
 717 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 718
 719 ########################################################################
 720 # Specify install locations
 721 ########################################################################
 722 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 723     "Library installation directory (default: lib)")
 724 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 725     "Data installation directory under share/ (default: gromacs)")
 726 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 727
 728 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 729 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 730 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 731 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 732 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 733
 734 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 735 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 736
 737 # Binary and library suffix options
 738 include(gmxManageSuffixes)
 739
 740 ##################################################################
 741 # Shared library settings
 742 ##################################################################
 743 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 744     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 745         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 746     endif()
 747     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 748     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 749 else()
 750     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 751         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 752         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 753     else()
 754         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 755     endif()
 756 endif()
 757
 758 #COPYING file: Only necessary for binary distributions.
 759 #Simpler to always install.
 760 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 761
 762 if(GMX_EXTERNAL_BOOST)
 763     include_directories(${Boost_INCLUDE_DIRS})
 764     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 765 else()
 766     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 767     # typeid not supported for minimal internal version
 768     # (would add significant amount of code)
 769     add_definitions(-DBOOST_NO_TYPEID)
 770     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 771     # (from share/template/)
 772     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 773     if (NOT GMX_BUILD_MDRUN_ONLY)
 774         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 775                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 776                 COMPONENT development)
 777     endif ()
 778 endif()
 779
 780 if(GMX_USE_TNG)
 781     find_package(ZLIB)
 782     set(TNG_BUILD_FORTRAN OFF CACHE BOOL "Build Fortran compatible TNG library and examples for testing")
 783     set(TNG_BUILD_EXAMPLES OFF CACHE BOOL "Build examples showing usage of the TNG API")
 784     set(TNG_BUILD_COMPRESSION_TESTS OFF CACHE BOOL "Build tests of the TNG compression library")
 785     # TODO reconsider use of OpenMP in TNG if/when trajectory writing is not serial in mdrun
 786     set(TNG_USE_OPENMP ${GMX_OPENMP} CACHE BOOL "Try to use the OpenMP library (if available) with TNG")
 787     set(TNG_BUILD_DOCUMENTATION OFF CACHE BOOL "Use Doxygen to create the HTML based TNG API documentation")
 788     set(TNG_BUILD_TEST OFF CACHE BOOL "Build TNG testing binary.")
 789     add_subdirectory(${CMAKE_SOURCE_DIR}/src/external/tng_io)
 790     set(GMX_TNG_LIBRARIES tng_io)
 791 endif()
 792 mark_as_advanced(TNG_BUILD_FORTRAN)
 793 mark_as_advanced(TNG_BUILD_EXAMPLES)
 794 mark_as_advanced(TNG_BUILD_COMPRESSION_TESTS)
 795 mark_as_advanced(TNG_USE_OPENMP)
 796 mark_as_advanced(TNG_BUILD_DOCUMENTATION)
 797 mark_as_advanced(TNG_BUILD_TEST)
 798 mark_as_advanced(TNG_EXAMPLE_FILES_DIR)
 799
 800 if (GMX_BUILD_FOR_COVERAGE)
 801     # Code heavy with asserts makes conditional coverage close to useless metric,
 802     # as by design most of the false branches are impossible to trigger in
 803     # correctly functioning code.  And the benefit of testing those that could
 804     # be triggered by using an API against its specification isn't usually
 805     # worth the effort.
 806     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 807 endif ()
 808
 809 if (BUILD_TESTING)
 810     # "tests" target builds all the separate test binaries.
 811     add_custom_target(tests)
 812     # "run-ctest" is an internal target that actually runs the tests.
 813     # This is necessary to be able to add separate targets that execute as part
 814     # of 'make check', but are ensured to be executed after the actual tests.
 815     add_custom_target(run-ctest
 816                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 817                       COMMENT "Running all tests"
 818                       VERBATIM)
 819     add_dependencies(run-ctest tests)
 820     # "check" target builds and runs all tests.
 821     add_custom_target(check DEPENDS run-ctest)
 822 endif()
 823
 824 if (NOT GMX_BUILD_MDRUN_ONLY)
 825     add_subdirectory(doxygen)
 826     add_subdirectory(share)
 827     add_subdirectory(scripts)
 828 endif ()
 829 add_subdirectory(src)
 830
 831 if (BUILD_TESTING)
 832     add_subdirectory(tests)
 833 endif()
 834
 835 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 836 # Don't bother the user after the first configure pass.
 837 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 838     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 839 endif()
 840 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 841
 842 #######################
 843 ## uninstall target
 844 #######################
 845     CONFIGURE_FILE(
 846                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 847                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 848                    IMMEDIATE @ONLY)
 849 ###########################
 850 ADD_CUSTOM_TARGET(uninstall
 851                   "${CMAKE_COMMAND}" -P
 852                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 853 ###########################
 854
 855 ########################################################################
 856 # Manual                                                               #
 857 ########################################################################
 858
 859 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 860 mark_as_advanced(GMX_BUILD_MANUAL)
 861 if(GMX_BUILD_MANUAL)
 862     # Make sure we only do detection of manual-building dependencies
 863     # when the user opted in for that.
 864     add_subdirectory(manual)
 865 endif()