CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87
  88 # Set a default valgrind suppression file.
  89 # This unfortunately needs to duplicate information from CTest to work as
  90 # expected...
  91 set(MEMORYCHECK_SUPPRESSIONS_FILE
  92     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
  93     CACHE FILEPATH
  94     "File that contains suppressions for the memory checker")
  95 include(CTest)
  96
  97 include(gmxCPackUtilities)
  98 gmx_cpack_init()
  99
 100 # Variables that accumulate stuff influencing the installed headers
 101 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 102 set(INSTALLED_HEADER_DEFINITIONS "")
 103
 104 ########################################################################
 105 # Check and warn if cache generated on a different host is being reused
 106 ########################################################################
 107 if(CMAKE_HOST_UNIX)
 108     execute_process(COMMAND hostname
 109                     OUTPUT_VARIABLE TMP_HOSTNAME
 110                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 111     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 112         message(WARNING "
 113             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 114             is being reused! This could lead to inconsistencies; therefore, it is
 115             recommended to regenerate the cache!")
 116     endif()
 117     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 118             "Hostname of the machine where the cache was generated.")
 119 endif()
 120
 121 ########################################################################
 122 # Detect architecture before setting options so we can alter defaults
 123 ########################################################################
 124 # Detect the architecture the compiler is targetting, detect
 125 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 126 # to use if none is specified, and populate the cache option for CPU
 127 # SIMD.
 128 include(gmxDetectTargetArchitecture)
 129 gmx_detect_target_architecture()
 130
 131 ########################################################################
 132 # User input options                                                   #
 133 ########################################################################
 134 include(gmxOptionUtilities)
 135
 136 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 137
 138 if(GMX_TARGET_FUJITSU_SPARC64)
 139     # Fujitsu only has SIMD in double precision, so this will be faster
 140     set(GMX_DOUBLE_DEFAULT ON)
 141 else()
 142     set(GMX_DOUBLE_DEFAULT OFF)
 143 endif()
 144 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 145 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 146 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 147
 148 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 149 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 150 gmx_dependent_option(
 151     GMX_MPI_IN_PLACE
 152     "Enable MPI_IN_PLACE for MPIs that have it defined"
 153     ON
 154     GMX_MPI)
 155 mark_as_advanced(GMX_MPI_IN_PLACE)
 156 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 157 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 158 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 159 mark_as_advanced(GMX_FAHCORE)
 160
 161 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 162 mark_as_advanced(GMX_COOL_QUOTES)
 163 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 164
 165 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 166 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 167 if(MSVC)
 168     set(REQUIRED_CUDA_VERSION 4.1)
 169 else()
 170     set(REQUIRED_CUDA_VERSION 4.0)
 171 endif()
 172 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 173 include(gmxManageGPU)
 174
 175 if(GMX_CPU_ACCELERATION)
 176     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 177     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 178     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 179     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 180 endif()
 181
 182 include(gmxDetectSimd)
 183 gmx_detect_simd(GMX_SUGGESTED_SIMD)
 184
 185 gmx_option_multichoice(
 186     GMX_SIMD
 187     "SIMD instruction set for CPU kernels and compiler optimization"
 188     "${GMX_SUGGESTED_SIMD}"
 189     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 MIC ARM_NEON ARM_NEON_ASIMD IBM_QPX IBM_VMX IBM_VSX Sparc64_HPC_ACE Reference)
 190
 191 gmx_option_multichoice(
 192     GMX_FFT_LIBRARY
 193     "FFT library"
 194     "fftw3"
 195     fftw3 mkl "fftpack[built-in]")
 196 gmx_dependent_option(
 197     GMX_BUILD_OWN_FFTW
 198     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 199     OFF
 200     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 201 gmx_dependent_option(
 202     GMX_DISABLE_FFTW_MEASURE
 203     "Do not optimize FFTW setups (not needed with SSE)"
 204     OFF
 205     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 206 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 207 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 208
 209 gmx_option_multichoice(
 210     GMX_QMMM_PROGRAM
 211     "QM package for QM/MM"
 212     None
 213     none gaussian mopac gamess orca)
 214
 215 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 216 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 217
 218 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 219
 220 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 221 mark_as_advanced(GMX_BROKEN_CALLOC)
 222 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 223 mark_as_advanced(GMX_LOAD_PLUGINS)
 224
 225 option(GMX_GPU  "Enable GPU acceleration" ON)
 226 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 227
 228 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 229
 230 if(UNIX)
 231     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 232 endif()
 233 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 234
 235 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 236 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 237
 238 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 239 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 240
 241 option(GMX_BUILD_FOR_COVERAGE
 242        "Tune build for better code coverage metrics (e.g., disable asserts)"
 243        OFF)
 244 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 245
 246 option(GMX_DEVELOPER_BUILD
 247     "Enable Developer convenience features: always build unit-tests"
 248     OFF)
 249 mark_as_advanced(GMX_DEVELOPER_BUILD)
 250
 251 ######################################################################
 252 # Detect OpenMP support
 253 ######################################################################
 254 # The OpenMP detection _must_ come before tests for other CFLAGS.
 255 include(gmxManageOpenMP)
 256
 257
 258
 259 ######################################################################
 260 # Compiler tests
 261 # These need to be done early (before further tests).
 262 #####################################################################
 263
 264 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 265 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 266 # invalid options with the Intel Compilers, and we have added a line
 267 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 268 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 269 # a semicolon. Since this is also used as a separator in lists inside CMake,
 270 # that string ends up being split into two separate patterns, and the last
 271 # part is just a single word that also matches other messages. We solved this
 272 # by replacing the semicolon with a period that matches any character.
 273 #
 274 # These files should be removed from the source tree when a CMake version that
 275 # includes the features in question becomes required for building GROMACS.
 276 include(CheckCCompilerFlag)
 277 include(CheckCXXCompilerFlag)
 278
 279 include(gmxCFlags)
 280 gmx_c_flags()
 281
 282 # This variable should be used for additional compiler flags which are not
 283 # generated in gmxCFlags nor are SIMD or MPI related.
 284 set(EXTRA_C_FLAGS "")
 285 set(EXTRA_CXX_FLAGS "")
 286
 287 # Run through a number of tests for buggy compilers and other issues
 288 include(gmxTestCompilerProblems)
 289 gmx_test_compiler_problems()
 290 # GMX_SIMD will not be set automatically until the second
 291 # pass (which is not strictly guaranteed to occur), so putting this
 292 # check here among logically-related tests is inefficient, but the
 293 # potential loss is likely zero.
 294 if(GMX_SIMD STREQUAL "AVX_256"
 295         AND CMAKE_COMPILER_IS_GNUCC
 296         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 297             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 298     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 299     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 300 endif()
 301
 302
 303 if(GMX_DOUBLE)
 304     add_definitions(-DGMX_DOUBLE)
 305     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 306     if(GMX_RELAXED_DOUBLE_PRECISION)
 307         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 308     endif()
 309 endif()
 310 if(GMX_SOFTWARE_INVSQRT)
 311     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 312 endif()
 313
 314 if(WIN32)
 315     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 316     add_definitions(-DGMX_HAVE_WINSOCK)
 317 endif()
 318
 319
 320
 321 ########################################################################
 322 # Basic system tests (standard libraries, headers, functions, types)   #
 323 ########################################################################
 324 include(CheckIncludeFiles)
 325 include(CheckIncludeFileCXX)
 326 check_include_files(unistd.h     HAVE_UNISTD_H)
 327 check_include_files(pwd.h        HAVE_PWD_H)
 328 check_include_files(dirent.h     HAVE_DIRENT_H)
 329 check_include_files(time.h       HAVE_TIME_H)
 330 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 331 check_include_files(io.h         HAVE_IO_H)
 332 check_include_files(sched.h      HAVE_SCHED_H)
 333
 334 check_include_files(regex.h      HAVE_POSIX_REGEX)
 335 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 336 # TODO: It could be nice to inform the user if no regex support is found,
 337 # as selections won't be fully functional.
 338
 339 include(CheckFunctionExists)
 340 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 341 check_function_exists(memalign          HAVE_MEMALIGN)
 342 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 343 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 344 check_function_exists(fsync             HAVE_FSYNC)
 345 check_function_exists(_fileno           HAVE__FILENO)
 346 check_function_exists(fileno            HAVE_FILENO)
 347 check_function_exists(_commit           HAVE__COMMIT)
 348 check_function_exists(sigaction         HAVE_SIGACTION)
 349 check_function_exists(sysconf           HAVE_SYSCONF)
 350 check_function_exists(rsqrt             HAVE_RSQRT)
 351 check_function_exists(rsqrtf            HAVE_RSQRTF)
 352 check_function_exists(sqrtf             HAVE_SQRTF)
 353 check_function_exists(nice              HAVE_NICE)
 354
 355 include(CheckLibraryExists)
 356 check_library_exists(m sqrt "" HAVE_LIBM)
 357 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 358
 359 include(TestSchedAffinity)
 360 test_sched_affinity(HAVE_SCHED_AFFINITY)
 361
 362 include(TestBigEndian)
 363 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 364
 365 set(GMX_USE_NICE 0)
 366 if (HAVE_UNISTD_H AND HAVE_NICE)
 367     set(GMX_USE_NICE 1)
 368 endif()
 369
 370 # Management of GROMACS options for specific toolchains should go
 371 # here. Because the initial settings for some of the main options have
 372 # already happened, but things like library detection and MPI compiler
 373 # feature detection have not, the docstrings for any over-rides of
 374 # GROMACS defaults or user settings will make sense. Also, any
 375 # toolchain-related reasons for choosing whether to detect various
 376 # things can be sorted out now, before the detection takes place.
 377 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 378     include(gmxManageBlueGene)
 379 endif()
 380
 381 if(GMX_TARGET_FUJITSU_SPARC64)
 382     include(gmxManageFujitsuSparc64)
 383 endif()
 384
 385 ########################################################################
 386 #Process MPI settings
 387 ########################################################################
 388 include(gmxManageMPI)
 389
 390
 391 ########################################################################
 392 #Process shared/static library settings
 393 ########################################################################
 394 include(gmxManageSharedLibraries)
 395
 396
 397 ########################################################################
 398 # Find external packages                                               #
 399 ########################################################################
 400
 401 # Unconditionally find the package, as it is also required for unit
 402 # tests. This exports LIBXML2_FOUND, which we should not use because
 403 # it does not tell us that linking will succeed. Instead, we test that
 404 # next.
 405 if(DEFINED LIBXML2_LIBRARIES)
 406   set(LibXml2_FIND_QUIETLY TRUE)
 407 endif()
 408 find_package(LibXml2)
 409 include(gmxTestLibXml2)
 410 gmx_test_libxml2(HAVE_LIBXML2)
 411 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 412 set(PKG_XML "")
 413 mark_as_advanced(GMX_XML)
 414 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 415 #if(GMX_XML AND NOT HAVE_LIBXML2)
 416 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 417 #endif()
 418 #if(GMX_XML)
 419 #    include_directories(${LIBXML2_INCLUDE_DIR})
 420 #    set(PKG_XML libxml-2.0)
 421 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 422 #endif()
 423
 424 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 425 mark_as_advanced(GMX_EXTRAE)
 426
 427 if (GMX_EXTRAE)
 428   find_package(EXTRAE)
 429   if(EXTRAE_FOUND)
 430     include_directories(${EXTRAE_INCLUDE_DIR})
 431     set(HAVE_EXTRAE 1)
 432   else()
 433     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 434   endif()
 435 endif()
 436
 437 option(GMX_X11 "Use X window system" OFF)
 438 if (GMX_X11)
 439     find_package(X11)
 440     # X11 includes/libraries are only set in the ngmx subdirectory!
 441     if(NOT X11_FOUND)
 442         message(FATAL_ERROR
 443                 "X11 include files and/or libraries were not found. "
 444                 "Set GMX_X11=OFF to compile without X11 support. "
 445                 "gmx view will not be available.")
 446     endif()
 447     include_directories(${X11_INCLUDE_DIR})
 448 endif()
 449
 450 include(ThreadMPI)
 451 # Enable core threading facilities
 452 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 453 # Enable tMPI C++ support
 454 tmpi_enable_cxx()
 455 if(GMX_THREAD_MPI)
 456     # enable MPI functions
 457     tmpi_enable()
 458     set(GMX_MPI 1)
 459     set(MPI_IN_PLACE_EXISTS 1)
 460 endif()
 461 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 462 if (TMPI_ATOMICS_DISABLED)
 463    add_definitions(-DTMPI_ATOMICS_DISABLED)
 464 endif()
 465
 466 if(GMX_GPU)
 467     # now that we have detected the dependencies, do the second configure pass
 468     gmx_gpu_setup()
 469 endif()
 470
 471 if(CYGWIN)
 472     set(GMX_CYGWIN 1)
 473 endif()
 474
 475 if(WIN32)
 476     set(GMX_NATIVE_WINDOWS 1)
 477     # This makes windows.h not declare min/max as macros that would break
 478     # C++ code using std::min/std::max.
 479     add_definitions(-DNOMINMAX)
 480 endif()
 481
 482 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 483 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 484 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 485     find_package(Boost 1.44.0)
 486     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 487         set(Boost_FOUND FALSE)
 488     endif()
 489     # Print the notification only on first run, when determining the default
 490     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 491         message("Boost >= 1.44 not found. Using minimal internal version. "
 492                 "This may cause trouble if you plan on compiling/linking other "
 493                 "software that uses Boost against Gromacs.")
 494     endif()
 495 endif()
 496 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 497        ${Boost_FOUND})
 498 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 499     message(FATAL_ERROR
 500         "Boost >= 1.44 not found. "
 501         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 502         "version of Boost included with Gromacs.")
 503 endif()
 504
 505 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 506     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 507 endif()
 508 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 509 mark_as_advanced(GMX_BUILD_UNITTESTS)
 510 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 511 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 512     message(FATAL_ERROR
 513         "Cannot build unit tests without libxml2. "
 514         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 515 endif()
 516
 517 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 518     # TNG wants zlib if it is available
 519     find_package(ZLIB QUIET)
 520     include(gmxTestZLib)
 521     gmx_test_zlib(HAVE_ZLIB)
 522 endif()
 523
 524 ########################################################################
 525 # Our own GROMACS tests
 526 ########################################################################
 527
 528 add_definitions( -DHAVE_CONFIG_H )
 529 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 530 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 531 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 532 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 533
 534 include(gmxTestInlineASM)
 535 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 536
 537 include(gmxSetBuildInformation)
 538 gmx_set_build_information()
 539 # Turn on RDTSCP if:
 540 # - the build system's CPU supports it
 541 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 542 #   at this point means that the user set it).
 543 # Note: it's better to not use the later set value of GMX_SIMD because
 544 # it reflects the system's capability of both compiling and running AVX code.
 545 # TODO: After merge with 5.0 one could implement a cache variable dependency
 546 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 547 # after the first cmake pass.
 548 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 549     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 550 else()
 551     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 552 endif()
 553 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 554 mark_as_advanced(GMX_USE_RDTSCP)
 555 if(GMX_USE_RDTSCP)
 556     set(HAVE_RDTSCP 1)
 557 endif()
 558
 559 include(gmxTestFloatFormat)
 560 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 561                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 562                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 563
 564 include(gmxTestLargeFiles)
 565 gmx_test_large_files(GMX_LARGEFILES)
 566
 567 include(gmxTestSignal)
 568 gmx_test_sigusr1(HAVE_SIGUSR1)
 569
 570 include(gmxTestPipes)
 571 gmx_test_pipes(HAVE_PIPES)
 572
 573 include(gmxTestIsfinite)
 574 gmx_test_isfinite(HAVE_ISFINITE)
 575 gmx_test__isfinite(HAVE__ISFINITE)
 576 gmx_test__finite(HAVE__FINITE)
 577
 578 include(gmxTestCXX11)
 579 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 580 include(CMakeDependentOption)
 581 # clang with some older versions of boost fail to work with C++11
 582 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 583     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 584     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 585 endif()
 586 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 587 # entirely to keep the compilation environment uniform.
 588 cmake_dependent_option(GMX_CXX11
 589     "Use C++11 features"
 590     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 591 mark_as_advanced(GMX_CXX11)
 592 if(GMX_CXX11)
 593     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 594 endif()
 595
 596
 597 include(gmxTestXDR)
 598 gmx_test_xdr(GMX_SYSTEM_XDR)
 599 if(NOT GMX_SYSTEM_XDR)
 600     set(GMX_INTERNAL_XDR 1)
 601 endif()
 602
 603
 604 ##################################################
 605 # Process SIMD instruction settings
 606 ##################################################
 607 # This checks what flags to add in order to
 608 # support the SIMD instructions we need, and sets
 609 # correct defines for the SIMD instructions supported.
 610 include(gmxTestSimd)
 611 gmx_test_simd()
 612
 613
 614 # Process QM/MM Settings
 615 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 616     set(GMX_QMMM_GAUSSIAN 1)
 617 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 618     set(GMX_QMMM_MOPAC 1)
 619 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 620     set(GMX_QMMM_GAMESS 1)
 621 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 622     set(GMX_QMMM_ORCA 1)
 623 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 624     # nothing to do
 625 else()
 626     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 627 endif()
 628
 629
 630 ##################################################
 631 # Process FFT library settings
 632 ##################################################
 633 include(gmxManageFFTLibraries)
 634
 635
 636 include(gmxManageLinearAlgebraLibraries)
 637
 638 # Whether GROMACS will really try to compile support for VMD plugins
 639 set(GMX_USE_PLUGINS OFF)
 640
 641 if(GMX_LOAD_PLUGINS)
 642   if(NOT WIN32)
 643     # Native Windows does not have, nor need dlopen
 644     include(gmxTestdlopen)
 645     gmx_test_dlopen(HAVE_DLOPEN)
 646   endif()
 647
 648   # so, should we use plug-ins?
 649   if(WIN32 OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 650     if(NOT VMD_QUIETLY)
 651       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 652     endif()
 653     if(NOT GMX_VMD_PLUGIN_PATH)
 654       find_package(VMD)
 655     endif()
 656     set(GMX_USE_PLUGINS ON)
 657     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 658     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 659   else()
 660     set(PKG_DL_LIBS)
 661   endif()
 662 endif()
 663 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 664
 665 # Link real-time library for POSIX timers. The check for clock_gettime
 666 # confirms the linkability of rt.
 667 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 668     list(APPEND GMX_EXTRA_LIBRARIES rt)
 669 endif()
 670
 671 # Math and thread libraries must often come after all others when linking...
 672 if(HAVE_LIBM)
 673     list(APPEND GMX_EXTRA_LIBRARIES m)
 674 endif()
 675
 676 option(GMX_NACL "Configure for Native Client builds" OFF)
 677 if (GMX_NACL)
 678   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 679   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 680   # TODO: Is this still necessary with the check for its presence?
 681   set(GMX_USE_NICE 0)
 682   set(GMX_NO_RENAME 1)
 683 endif()
 684 mark_as_advanced(GMX_NACL)
 685
 686 if(GMX_FAHCORE)
 687   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 688       "Path to swindirect.h")
 689   include_directories(${COREWRAP_INCLUDE_DIR})
 690 endif()
 691
 692 # Value of AUTO tries to generate things, but will only produce warnings if
 693 # that fails.
 694 set(build_help_default AUTO)
 695 if (SOURCE_IS_SOURCE_DISTRIBUTION)
 696     set(build_help_default OFF)
 697 endif()
 698 gmx_option_trivalue(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" ${build_help_default})
 699 mark_as_advanced(GMX_BUILD_HELP)
 700 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND BUILD_IS_INSOURCE)
 701     message(FATAL_ERROR
 702         "Rebuilding HTML and man pages or shell completions is not supported "
 703         "for in-source builds from a source distribution. "
 704         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 705 endif()
 706
 707 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 708 # these are set after everything else
 709 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 710     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 711     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 712     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 713     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 714 else()
 715     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 716     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 717     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 718     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 719     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 720     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 721     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 722     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 723     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 724 endif()
 725
 726 if(NOT GMX_OPENMP)
 727     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 728     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 729     unset(OpenMP_C_FLAGS CACHE)
 730     unset(OpenMP_CXX_FLAGS CACHE)
 731 else()
 732     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 733     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 734 endif()
 735
 736 ########################################################################
 737 # Specify install locations
 738 ########################################################################
 739 # Use GNUInstallDirs to set paths on multiarch systems.
 740 include(GNUInstallDirs)
 741
 742 # Customization for the installation tree paths.
 743 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 744     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 745 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 746     "Data installation directory under share/ (default: gromacs)")
 747 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 748
 749 # These variables are used internally to provide a central location for
 750 # customizing the install locations.
 751 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 752 set(BIN_INSTALL_DIR       bin)
 753 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 754 set(MAN_INSTALL_DIR       share/man)
 755 # If the nesting level wrt. the installation root is changed,
 756 # gromacs-config.cmake.cmakein needs to be adapted.
 757 set(CMAKE_INSTALL_DIR     share/cmake)
 758 # TODO: Make GMXRC adapt if this is changed
 759 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 760 set(INCL_INSTALL_DIR      include)
 761
 762 # These variables get written into config.h for use in finding the data
 763 # directories.
 764 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 765 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 766
 767 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 768
 769 # Binary and library suffix options
 770 include(gmxManageSuffixes)
 771
 772 ################################################################
 773 # Shared library load path settings
 774 ################################################################
 775 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 776 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 777 # was added.
 778 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 779    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 780     # The build folder always has bin/ and lib/; if we are also going to
 781     # install to lib/, then the installation RPATH works also in the build
 782     # tree.  This makes installation slightly faster (no need to rewrite the
 783     # RPATHs), and makes the binaries in the build tree relocatable.
 784     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 785         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 786     endif()
 787     # Set the RPATH as relative to the executable location to make the
 788     # binaries relocatable.
 789     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 790         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 791     else()
 792         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 793     endif()
 794     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 795     set(CMAKE_MACOSX_RPATH 1)
 796 else()
 797     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 798     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 799         # Set the RPATH options manually.
 800         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 801         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 802     else()
 803         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 804         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 805     endif()
 806 endif()
 807
 808 #COPYING file: Only necessary for binary distributions.
 809 #Simpler to always install.
 810 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 811
 812 if(GMX_EXTERNAL_BOOST)
 813     include_directories(${Boost_INCLUDE_DIRS})
 814     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 815 else()
 816     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 817     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 818     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 819     # typeid not supported for minimal internal version
 820     # (would add significant amount of code)
 821     add_definitions(-DBOOST_NO_TYPEID)
 822     if (NOT GMX_BUILD_MDRUN_ONLY)
 823         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 824                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 825                 COMPONENT development)
 826     endif()
 827 endif()
 828
 829 if (GMX_BUILD_FOR_COVERAGE)
 830     # Code heavy with asserts makes conditional coverage close to useless metric,
 831     # as by design most of the false branches are impossible to trigger in
 832     # correctly functioning code.  And the benefit of testing those that could
 833     # be triggered by using an API against its specification isn't usually
 834     # worth the effort.
 835     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 836 endif()
 837
 838 if (BUILD_TESTING)
 839     # "tests" target builds all the separate test binaries.
 840     add_custom_target(tests)
 841     # "run-ctest" is an internal target that actually runs the tests.
 842     # This is necessary to be able to add separate targets that execute as part
 843     # of 'make check', but are ensured to be executed after the actual tests.
 844     add_custom_target(run-ctest
 845                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 846                       COMMENT "Running all tests"
 847                       VERBATIM)
 848     add_dependencies(run-ctest tests)
 849     # "check" target builds and runs all tests.
 850     add_custom_target(check DEPENDS run-ctest)
 851 endif()
 852
 853 if (NOT GMX_BUILD_MDRUN_ONLY)
 854     add_subdirectory(docs)
 855     add_subdirectory(share)
 856     add_subdirectory(scripts)
 857 endif()
 858 add_subdirectory(src)
 859
 860 if (BUILD_TESTING)
 861     add_subdirectory(tests)
 862 endif()
 863
 864 gmx_cpack_write_config()
 865
 866 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 867 # Don't bother the user after the first configure pass.
 868 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 869     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 870 endif()
 871 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 872
 873 #######################
 874 ## uninstall target
 875 #######################
 876 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 877                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 878                   IMMEDIATE @ONLY)
 879 ###########################
 880 ADD_CUSTOM_TARGET(uninstall
 881                   "${CMAKE_COMMAND}" -P
 882                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 883 ###########################
 884 set_directory_properties(PROPERTIES
 885             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")