CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36
  37 # CMake modules/macros are in a subdirectory to keep this file cleaner
  38 # This needs to be set before project() in order to pick up toolchain files
  39 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  40
  41 project(Gromacs)
  42
  43 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  44 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  45 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  46
  47 # PROJECT_VERSION should have the following structure:
  48 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  49 #
  50 # The "-dev" suffix is important to keep because it makes possible to distinguish
  51 # between a build from official release and a build from git release branch on a
  52 # machine with no git.
  53 #
  54 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  55 set(PROJECT_VERSION "5.0-beta2-dev")
  56 # The version number of the regressiontest tarball against which this
  57 # git branch can be tested. Normally, this will be the version of the
  58 # last patch release. Comment the next line out for branches leading
  59 # to a major/minor release.
  60 set(REGRESSIONTEST_VERSION "5.0-beta1")
  61 set(CUSTOM_VERSION_STRING ""
  62     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  63 mark_as_advanced(CUSTOM_VERSION_STRING)
  64 if (CUSTOM_VERSION_STRING)
  65     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  66 endif (CUSTOM_VERSION_STRING)
  67 set(LIBRARY_SOVERSION 0)
  68 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  69 # It is a bit irritating, but this has to be set separately for now!
  70 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  71 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  72 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  73
  74 # The numerical gromacs version. It is 40600 for 4.6.0.
  75 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  76 math(EXPR NUM_VERSION
  77     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  78 if(CPACK_PACKAGE_VERSION_PATCH)
  79     math(EXPR NUM_VERSION
  80          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  81 endif()
  82
  83 # The API version tracks the numerical Gromacs version (for now).
  84 # It is potentially different from the Gromacs version in the future, if
  85 # the programs/libraries diverge from the presumably more stable API.
  86 # The #define GMX_API_VERSION in version.h is set to this value to
  87 # provide backward compatibility of software written against the Gromacs API.
  88 set(API_VERSION ${NUM_VERSION})
  89
  90 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  91     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  92 endif()
  93
  94 set(GMX_INSTALL_PREFIX "" CACHE STRING "Prefix gets appended to CMAKE_INSTALL_PREFIX. For cpack it sets the root folder of the archive.")
  95 mark_as_advanced(GMX_INSTALL_PREFIX)
  96
  97 include(gmxBuildTypeReference)
  98
  99 if(NOT CMAKE_BUILD_TYPE)
 100     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference." FORCE)
 101     # Set the possible values of build type for cmake-gui
 102     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 103         "MinSizeRel" "RelWithDebInfo")
 104 endif(NOT CMAKE_BUILD_TYPE)
 105
 106 enable_language(C)
 107 enable_language(CXX)
 108
 109 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 110 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 111 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 112 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 113 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 114 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 115 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 116 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$")
 117 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 118 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final")
 119 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 120
 121 #must come after all cpack settings!
 122 include(CPack)
 123
 124 # Set a default valgrind suppression file.
 125 # This unfortunately needs to duplicate information from CTest to work as
 126 # expected...
 127 set(MEMORYCHECK_SUPPRESSIONS_FILE
 128     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 129     CACHE FILEPATH
 130     "File that contains suppressions for the memory checker")
 131 include(CTest)
 132
 133 set(SOURCE_IS_GIT_REPOSITORY OFF)
 134 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 135 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 136     set(SOURCE_IS_GIT_REPOSITORY ON)
 137 endif()
 138 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 139     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 140 endif()
 141
 142 ########################################################################
 143 # Check and warn if cache generated on a different host is being reused
 144 ########################################################################
 145 if(CMAKE_HOST_UNIX)
 146     execute_process(COMMAND hostname
 147                     OUTPUT_VARIABLE TMP_HOSTNAME
 148                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 149     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 150         message(WARNING "
 151             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 152             is being reused! This could lead to inconsitencies; therefore, it is
 153             recommended to regenerate the cache!")
 154     endif()
 155     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 156             "Hostname of the machine where the cache was generated.")
 157 endif()
 158
 159 ########################################################################
 160 # User input options                                                   #
 161 ########################################################################
 162 include(gmxOptionUtilities)
 163
 164 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 165
 166 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 167 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 168 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 169 gmx_dependent_option(
 170     GMX_MPI_IN_PLACE
 171     "Enable MPI_IN_PLACE for MPIs that have it defined"
 172     ON
 173     GMX_MPI)
 174 mark_as_advanced(GMX_MPI_IN_PLACE)
 175 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 176 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 177 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 178 mark_as_advanced(GMX_FAHCORE)
 179
 180 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 181 mark_as_advanced(GMX_COOL_QUOTES)
 182 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 183
 184 # decide on GPU settings based on user-settings and GPU/CUDA detection
 185 include(gmxManageGPU)
 186
 187 # Detect the architecture the compiler is targetting, detect
 188 # acceleration possibilities on that hardware, suggest an acceleration
 189 # to use if none is specified, and populate the cache option for CPU
 190 # accleration.
 191 include(gmxDetectTargetArchitecture)
 192 gmx_detect_target_architecture()
 193 include(gmxDetectAcceleration)
 194 gmx_detect_acceleration(GMX_SUGGESTED_CPU_ACCELERATION)
 195
 196 gmx_option_multichoice(
 197     GMX_CPU_ACCELERATION
 198     "Acceleration for CPU kernels and compiler optimization"
 199     "${GMX_SUGGESTED_CPU_ACCELERATION}"
 200     None SSE2 SSE4.1 AVX_128_FMA AVX_256 IBM_QPX Sparc64_HPC_ACE)
 201
 202 gmx_option_multichoice(
 203     GMX_FFT_LIBRARY
 204     "FFT library"
 205     "fftw3"
 206     fftw3 mkl "fftpack[built-in]")
 207 gmx_dependent_option(
 208     GMX_BUILD_OWN_FFTW
 209     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 210     OFF
 211     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 212 gmx_dependent_option(
 213     GMX_DISABLE_FFTW_MEASURE
 214     "Do not optimize FFTW setups (not needed with SSE)"
 215     OFF
 216     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 217 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 218 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 219
 220 gmx_option_multichoice(
 221     GMX_QMMM_PROGRAM
 222     "QM package for QM/MM"
 223     None
 224     none gaussian mopac gamess orca)
 225
 226 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 227 mark_as_advanced(GMX_BROKEN_CALLOC)
 228 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 229 mark_as_advanced(GMX_LOAD_PLUGINS)
 230
 231 option(GMX_GPU  "Enable GPU acceleration" ON)
 232 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 233
 234 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 235 mark_as_advanced(GMX_GIT_VERSION_INFO)
 236
 237 if(UNIX)
 238     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 239 endif()
 240 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 241
 242 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 243 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 244
 245 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 246 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 247
 248 option(GMX_BUILD_FOR_COVERAGE
 249        "Tune build for better code coverage metrics (e.g., disable asserts)"
 250        OFF)
 251 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 252
 253
 254 ######################################################################
 255 # Detect OpenMP support
 256 ######################################################################
 257 # The OpenMP detection _must_ come before tests for other CFLAGS.
 258 include(gmxManageOpenMP)
 259
 260
 261
 262 ######################################################################
 263 # Compiler tests
 264 # These need to be done early (before further tests).
 265 #####################################################################
 266
 267 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 268 # are used with permission from CMake v2.8.9 so that GROMACS can detect
 269 # invalid options with the Intel Compilers.
 270 # These files should be removed from the source tree when a CMake version that
 271 # includes the features in question becomes required for building GROMACS.
 272 include(CheckCCompilerFlag)
 273 include(CheckCXXCompilerFlag)
 274
 275
 276 include(gmxCFlags)
 277 gmx_c_flags()
 278
 279 # This variable should be used for additional compiler flags which are not
 280 # generated in gmxCFlags nor are acceleration or MPI related.
 281 set(EXTRA_C_FLAGS "")
 282 set(EXTRA_CXX_FLAGS "")
 283
 284 # Run through a number of tests for buggy compilers and other issues
 285 include(gmxTestCompilerProblems)
 286 gmx_test_compiler_problems()
 287
 288
 289 set(PKG_CFLAGS "")
 290 if(GMX_DOUBLE)
 291     add_definitions(-DGMX_DOUBLE)
 292     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 293 endif(GMX_DOUBLE)
 294 if(GMX_SOFTWARE_INVSQRT)
 295   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 296 endif(GMX_SOFTWARE_INVSQRT)
 297
 298
 299
 300 ########################################################################
 301 # Basic system tests (standard libraries, headers, functions, types)   #
 302 ########################################################################
 303 include(CheckIncludeFiles)
 304 include(CheckIncludeFileCXX)
 305 check_include_files(unistd.h     HAVE_UNISTD_H)
 306 check_include_files(pwd.h        HAVE_PWD_H)
 307 check_include_files(dirent.h     HAVE_DIRENT_H)
 308 check_include_files(time.h       HAVE_TIME_H)
 309 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 310 check_include_files(io.h         HAVE_IO_H)
 311 check_include_files(sched.h      HAVE_SCHED_H)
 312
 313 check_include_files(regex.h      HAVE_POSIX_REGEX)
 314 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 315 # TODO: It could be nice to inform the user if no regex support is found,
 316 # as selections won't be fully functional.
 317
 318 include(CheckFunctionExists)
 319 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 320 check_function_exists(memalign          HAVE_MEMALIGN)
 321 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 322 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 323 check_function_exists(fsync             HAVE_FSYNC)
 324 check_function_exists(_fileno           HAVE__FILENO)
 325 check_function_exists(fileno            HAVE_FILENO)
 326 check_function_exists(_commit           HAVE__COMMIT)
 327 check_function_exists(sigaction         HAVE_SIGACTION)
 328 check_function_exists(sysconf           HAVE_SYSCONF)
 329 check_function_exists(sched_setaffinity HAVE_SCHED_SETAFFINITY)
 330 check_function_exists(sched_getaffinity HAVE_SCHED_GETAFFINITY)
 331 check_function_exists(rsqrt             HAVE_RSQRT)
 332 check_function_exists(rsqrtf            HAVE_RSQRTF)
 333 check_function_exists(sqrtf             HAVE_SQRTF)
 334
 335 include(CheckLibraryExists)
 336 check_library_exists(m sqrt "" HAVE_LIBM)
 337 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 338
 339 include(TestBigEndian)
 340 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 341
 342 # Management of GROMACS options for specific toolchains should go
 343 # here. Because the initial settings for some of the main options have
 344 # already happened, but things like library detection and MPI compiler
 345 # feature detection have not, the docstrings for any over-rides of
 346 # GROMACS defaults or user settings will make sense. Also, any
 347 # toolchain-related reasons for choosing whether to detect various
 348 # things can be sorted out now, before the detection takes place.
 349 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 350     include(gmxManageBlueGene)
 351 endif()
 352
 353 ########################################################################
 354 #Process MPI settings
 355 ########################################################################
 356 include(gmxManageMPI)
 357
 358
 359 ########################################################################
 360 #Process shared/static library settings
 361 ########################################################################
 362 include(gmxManageSharedLibraries)
 363
 364
 365 ########################################################################
 366 # Find external packages                                               #
 367 ########################################################################
 368
 369 # Unconditionally find the package, as it is also required for unit tests
 370 find_package(LibXml2)
 371 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${LIBXML2_FOUND})
 372 set(PKG_XML "")
 373 mark_as_advanced(GMX_XML)
 374 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 375 #if(GMX_XML AND NOT LIBXML2_FOUND)
 376 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 377 #endif()
 378 #if(GMX_XML)
 379 #    include_directories(${LIBXML2_INCLUDE_DIR})
 380 #    set(PKG_XML libxml-2.0)
 381 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 382 #endif(GMX_XML)
 383
 384 option(GMX_GSL "Add support for gsl" OFF)
 385 if (GMX_GSL)
 386   find_package(GSL)
 387   set(PKG_GSL "")
 388   if(GSL_FOUND)
 389     include_directories(${GSL_INCLUDE_DIR})
 390     set(PKG_GSL gsl)
 391     set(HAVE_LIBGSL 1)
 392   endif(GSL_FOUND)
 393 endif (GMX_GSL)
 394
 395 option(GMX_X11 "Use X window system" OFF)
 396 if (GMX_X11)
 397     find_package(X11)
 398     # X11 includes/libraries are only set in the ngmx subdirectory!
 399     if(NOT X11_FOUND)
 400         message(FATAL_ERROR
 401                 "X11 include files and/or libraries were not found. "
 402                 "Set GMX_X11=OFF to compile without X11 support. "
 403                 "gmx view will not be available.")
 404     endif()
 405     include_directories(${X11_INCLUDE_DIR})
 406 endif(GMX_X11)
 407
 408 include(ThreadMPI)
 409 set(THREAD_MPI_LIB thread_mpi)
 410 # Enable core threading facilities
 411 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders")
 412 # Enable tMPI C++ support
 413 tmpi_enable_cxx()
 414 if(GMX_THREAD_MPI)
 415     # enable MPI functions
 416     tmpi_enable()
 417     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREAD_MPI")
 418     set(GMX_MPI 1)
 419     set(MPI_IN_PLACE_EXISTS 1)
 420 endif(GMX_THREAD_MPI)
 421 tmpi_get_source_list(THREAD_MPI_SRC)
 422
 423 if(GMX_GPU)
 424     # now that we have detected the dependencies, do the second configure pass
 425     gmx_gpu_setup()
 426 endif(GMX_GPU)
 427
 428 if(CYGWIN)
 429     set(GMX_CYGWIN 1)
 430 endif(CYGWIN)
 431
 432 if(WIN32 AND NOT CYGWIN)
 433     set(GMX_NATIVE_WINDOWS 1)
 434     # This makes windows.h not declare min/max as macros that would break
 435     # C++ code using std::min/std::max.
 436     add_definitions(-DNOMINMAX)
 437 endif()
 438
 439 # only bother with finding git and using version.h if the source is a git repo
 440 if(GMX_GIT_VERSION_INFO)
 441     if (NOT SOURCE_IS_GIT_REPOSITORY)
 442         message(FATAL_ERROR
 443             "Cannot generate git version information from source tree not under git. "
 444             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 445     endif ()
 446     # We need at least git v1.5.3 be able to parse git's date output. If not
 447     # found or the version is too small, we can't generate version information.
 448     find_package(Git)
 449
 450     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 451         message(FATAL_ERROR
 452             "No compatible git version found (>= 1.5.3 required). "
 453             "Won't be able to generate development version information. "
 454             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 455     endif()
 456 endif()
 457
 458 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 459 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 460 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 461     find_package(Boost 1.44.0)
 462     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 463         set(Boost_FOUND FALSE)
 464     endif()
 465     # Print the notification only on first run, when determining the default
 466     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 467         message("Boost >= 1.44 not found. Using minimal internal version. "
 468                 "This may cause trouble if you plan on compiling/linking other "
 469                 "software that uses Boost against Gromacs.")
 470     endif()
 471 endif()
 472 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 473        ${Boost_FOUND})
 474 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 475     message(FATAL_ERROR
 476         "Boost >= 1.44 not found. "
 477         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 478         "version of Boost included with Gromacs.")
 479 endif()
 480
 481 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${LIBXML2_FOUND})
 482 mark_as_advanced(GMX_BUILD_UNITTESTS)
 483 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 484 if (GMX_BUILD_UNITTESTS AND NOT LIBXML2_FOUND)
 485     message(FATAL_ERROR
 486         "Cannot build unit tests without libxml2. "
 487         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find libxml2.")
 488 endif()
 489
 490 ########################################################################
 491 # Generate development version info for cache
 492 ########################################################################
 493 # set(GEN_VERSION_INFO_INTERNAL "ON")
 494 # include(gmxGenerateVersionString)
 495
 496 ########################################################################
 497 # Our own GROMACS tests
 498 ########################################################################
 499
 500 add_definitions( -DHAVE_CONFIG_H )
 501 include_directories(${CMAKE_SOURCE_DIR}/src)
 502 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 503 include_directories(${CMAKE_BINARY_DIR}/src)
 504 # Required for gmx_header_config_gen.h to be found before installation
 505 include_directories(${CMAKE_BINARY_DIR}/src/gromacs/utility)
 506 # Required for now to make old code compile
 507 include_directories(${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 508
 509 include(gmxTestInlineASM)
 510 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 511
 512 include(gmxSetBuildInformation)
 513 gmx_set_build_information()
 514 if(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 515     set(HAVE_RDTSCP 1)
 516 endif(BUILD_CPU_FEATURES MATCHES "rdtscp" AND NOT GMX_DISTRIBUTABLE_BUILD)
 517
 518 include(gmxTestFloatFormat)
 519 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 520                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 521                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 522
 523 include(gmxTestLargeFiles)
 524 gmx_test_large_files(GMX_LARGEFILES)
 525
 526 include(gmxTestSignal)
 527 gmx_test_sigusr1(HAVE_SIGUSR1)
 528
 529 include(gmxTestInline)
 530 gmx_test_inline(INLINE_KEYWORD)
 531
 532 include(gmxTestRestrict)
 533 gmx_test_restrict(RESTRICT_KEYWORD)
 534
 535 include(gmxTestPipes)
 536 gmx_test_pipes(HAVE_PIPES)
 537
 538 include(gmxTestIsfinite)
 539 gmx_test_isfinite(HAVE_ISFINITE)
 540 gmx_test__isfinite(HAVE__ISFINITE)
 541 gmx_test__finite(HAVE__FINITE)
 542
 543 include(gmxTestCXX11)
 544 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 545 include(CMakeDependentOption)
 546 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 547 # entirely to keep the compilation environment uniform.
 548 cmake_dependent_option(GMX_CXX11
 549     "Use C++11 features"
 550     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 551 mark_as_advanced(GMX_CXX11)
 552 if(GMX_CXX11)
 553     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 554 endif()
 555
 556
 557 include(gmxTestXDR)
 558 gmx_test_xdr(GMX_SYSTEM_XDR)
 559 if(NOT GMX_SYSTEM_XDR)
 560     set(GMX_INTERNAL_XDR 1)
 561 endif(NOT GMX_SYSTEM_XDR)
 562
 563 # include avx test source, used if the AVX flags are set below
 564 include(gmxTestAVXMaskload)
 565
 566 # Process nonbonded accelerated kernels settings
 567 #
 568 # Note that for the backward-compatible x86 SIMD architectures, the
 569 # GMX_CPU_ACCELERATION determines the maximum level of the instruction
 570 # set used (e.g. GMX_CPU_ACCLERATION=SSE4.1 implies
 571 # SSE2). Accordingly, there are a set of CMake variables
 572 # GMX_<arch>_<feature-set> that are exported to the C code to specify
 573 # CPU features that should be used. This means that the logic for
 574 # requiring such backward compatibility is all located here.
 575 if(${GMX_CPU_ACCELERATION} STREQUAL "NONE")
 576     # nothing to do
 577     set(ACCELERATION_STATUS_MESSAGE "CPU acceleration disabled")
 578
 579 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE2")
 580
 581     GMX_TEST_CFLAG(GNU_SSE2_CFLAG "-msse2" ACCELERATION_C_FLAGS)
 582     if(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 583         GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 584     endif(NOT GNU_SSE2_CFLAG AND GMX_NATIVE_WINDOWS)
 585
 586     GMX_TEST_CXXFLAG(GNU_SSE2_CXXFLAG "-msse2" ACCELERATION_CXX_FLAGS)
 587     if(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 588         GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 589     endif(NOT GNU_SSE2_CXXFLAG AND GMX_NATIVE_WINDOWS)
 590
 591     # We dont warn for lacking SSE2 flag support, since that is probably standard today.
 592
 593     # Only test the include after we have tried to add the correct flag for SSE2 support
 594     check_include_file(emmintrin.h  HAVE_EMMINTRIN_H ${ACCELERATION_C_FLAGS})
 595
 596     if(NOT HAVE_EMMINTRIN_H)
 597         message(FATAL_ERROR "Cannot find emmintrin.h, which is required for SSE2 intrinsics support.")
 598     endif(NOT HAVE_EMMINTRIN_H)
 599
 600     set(GMX_CPU_ACCELERATION_X86_SSE2 1)
 601     # The user should not be able to set this orthogonally to the acceleration
 602     set(GMX_X86_SSE2 1)
 603     set(ACCELERATION_STATUS_MESSAGE
 604         "Enabling SSE2 Gromacs acceleration")
 605
 606 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SSE4.1")
 607
 608     GMX_TEST_CFLAG(GNU_SSE4_CFLAG "-msse4.1" ACCELERATION_C_FLAGS)
 609     if (NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 610         GMX_TEST_CFLAG(MSVC_SSE4_CFLAG "/arch:SSE4.1" ACCELERATION_C_FLAGS)
 611     endif(NOT GNU_SSE4_CFLAG AND GMX_NATIVE_WINDOWS)
 612     if (NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 613         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 614         # intrinsics when SSE2 support is enabled, so we try that instead first.
 615         if (GMX_NATIVE_WINDOWS)
 616             GMX_TEST_CFLAG(MSVC_SSE2_CFLAG "/arch:SSE2" ACCELERATION_C_FLAGS)
 617             message(WARNING "Neither SSE4.1 or SSE2 seems to be supported by your Windows compiler. Something is likely broken.")
 618         else()
 619             message(WARNING "No C SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance")
 620         endif()
 621     endif(NOT GNU_SSE4_CFLAG AND NOT MSVC_SSE4_CFLAG)
 622
 623     GMX_TEST_CXXFLAG(GNU_SSE4_CXXFLAG "-msse4.1" ACCELERATION_CXX_FLAGS)
 624     if (NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 625         GMX_TEST_CXXFLAG(MSVC_SSE4_CXXFLAG "/arch:SSE4.1" ACCELERATION_CXX_FLAGS)
 626     endif(NOT GNU_SSE4_CXXFLAG AND GMX_NATIVE_WINDOWS)
 627     if (NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 628         message(WARNING "No C++ SSE4.1 flag found. Consider a newer compiler, or use SSE2 for slightly lower performance.")
 629         # Not surprising if we end up here! MSVC current does not support the SSE4.1 flag. However, it appears to accept SSE4.1
 630         # intrinsics when SSE2 support is enabled, so we try that instead.
 631         if (GMX_NATIVE_WINDOWS)
 632             GMX_TEST_CXXFLAG(MSVC_SSE2_CXXFLAG "/arch:SSE2" ACCELERATION_CXX_FLAGS)
 633         endif()
 634     endif(NOT GNU_SSE4_CXXFLAG AND NOT MSVC_SSE4_CXXFLAG)
 635
 636     # This must come after we have added the -msse4.1 flag on some platforms.
 637     check_include_file(smmintrin.h  HAVE_SMMINTRIN_H ${ACCELERATION_C_FLAGS})
 638
 639     if(NOT HAVE_SMMINTRIN_H)
 640         message(FATAL_ERROR "Cannot find smmintrin.h, which is required for SSE4.1 intrinsics support.")
 641     endif(NOT HAVE_SMMINTRIN_H)
 642
 643     if(CMAKE_C_COMPILER_ID MATCHES "Intel" AND CMAKE_C_COMPILER_VERSION VERSION_EQUAL "11.1")
 644         message(FATAL_ERROR "You are using Intel compiler version 11.1, and that compiler is known to produce incorrect results with SSE4.1 acceleration. You need to use another compiler (e.g. icc 12 or newer) or different acceleration (probably slower simulations).")
 645     endif()
 646
 647     set(GMX_CPU_ACCELERATION_X86_SSE4_1 1)
 648     # The user should not be able to set this orthogonally to the acceleration
 649     set(GMX_X86_SSE4_1 1)
 650     set(GMX_X86_SSE2   1)
 651     set(ACCELERATION_STATUS_MESSAGE
 652         "Enabling SSE4.1 Gromacs acceleration")
 653
 654 elseif(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" OR ${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 655
 656     # Set the AVX compiler flag for both these choices!
 657
 658     GMX_TEST_CFLAG(GNU_AVX_CFLAG "-mavx" ACCELERATION_C_FLAGS)
 659     if (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 660         GMX_TEST_CFLAG(MSVC_AVX_CFLAG "/arch:AVX" ACCELERATION_C_FLAGS)
 661     endif (NOT GNU_AVX_CFLAG AND GMX_NATIVE_WINDOWS)
 662     if (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 663         message(WARNING "No C AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 664     endif (NOT GNU_AVX_CFLAG AND NOT MSVC_AVX_CFLAG)
 665
 666     GMX_TEST_CXXFLAG(GNU_AVX_CXXFLAG "-mavx" ACCELERATION_CXX_FLAGS)
 667     if (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 668         GMX_TEST_CXXFLAG(MSVC_AVX_CXXFLAG "/arch:AVX" ACCELERATION_CXX_FLAGS)
 669     endif (NOT GNU_AVX_CXXFLAG AND GMX_NATIVE_WINDOWS)
 670     if (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 671         message(WARNING "No C++ AVX flag found. Consider a newer compiler, or try SSE4.1 (lower performance) giving the -DGMX_CPU_ACCELERATION=SSE4.1 to cmake.")
 672     endif (NOT GNU_AVX_CXXFLAG AND NOT MSVC_AVX_CXXFLAG)
 673
 674     # Set the FMA4 flags (MSVC doesn't require any)
 675     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA" AND NOT MSVC)
 676         GMX_TEST_CFLAG(GNU_FMA_CFLAG "-mfma4" ACCELERATION_C_FLAGS)
 677         if (NOT GNU_FMA_CFLAG)
 678             message(WARNING "No C FMA4 flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 679         endif(NOT GNU_FMA_CFLAG)
 680         GMX_TEST_CFLAG(GNU_XOP_CFLAG "-mxop" ACCELERATION_C_FLAGS)
 681         # No big deal if we do not have xop, so no point yelling warnings about it.
 682         GMX_TEST_CXXFLAG(GNU_FMA_CXXFLAG "-mfma4" ACCELERATION_CXX_FLAGS)
 683         if (NOT GNU_FMA_CXXFLAG)
 684             message(WARNING "No C++ FMA flag found. Consider a newer compiler, or try SSE4.1 (lower performance).")
 685         endif (NOT GNU_FMA_CXXFLAG)
 686         GMX_TEST_CXXFLAG(GNU_XOP_CXXFLAG "-mxop" ACCELERATION_CXX_FLAGS)
 687         # No big deal if we do not have xop, so no point yelling warnings about it.
 688     endif()
 689
 690     # Only test the header after we have tried to add the flag for AVX support
 691     check_include_file(immintrin.h  HAVE_IMMINTRIN_H ${ACCELERATION_C_FLAGS})
 692
 693     if(NOT HAVE_IMMINTRIN_H)
 694         message(FATAL_ERROR "Cannot find immintrin.h, which is required for AVX intrinsics support. Consider switching compiler.")
 695     endif(NOT HAVE_IMMINTRIN_H)
 696
 697     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_256")
 698         try_compile(TEST_AVX ${CMAKE_BINARY_DIR}
 699             "${CMAKE_SOURCE_DIR}/cmake/TestAVX.c"
 700             COMPILE_DEFINITIONS "${ACCELERATION_C_FLAGS}")
 701         if(NOT TEST_AVX)
 702             message(FATAL_ERROR "Cannot compile AVX intrinsics. Consider switching compiler.")
 703         endif()
 704     endif()
 705
 706     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 707     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${ACCELERATION_C_FLAGS})
 708     check_include_file(intrin.h HAVE_INTRIN_H ${ACCELERATION_C_FLAGS})
 709
 710     # The user should not be able to set this orthogonally to the acceleration
 711     set(GMX_X86_SSE4_1 1)
 712     set(GMX_X86_SSE2   1)
 713
 714     # But just enable one of the choices internally...
 715     if(${GMX_CPU_ACCELERATION} STREQUAL "AVX_128_FMA")
 716         # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 717         # so we can't distinguish vanilla and Apple clang, but catering for AMD
 718         # hackintoshes is not worth the effort.
 719         if (APPLE AND (${CMAKE_C_COMPILER_ID} STREQUAL "Clang" OR
 720                     ${CMAKE_CXX_COMPILER_ID} STREQUAL "Clang"))
 721             message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA acceleration. As we can not work around this bug on OS X, you will have to select a different compiler or CPU acceleration.")
 722         endif()
 723
 724         if (GMX_USE_CLANG_C_FMA_BUG_WORKAROUND)
 725             # we assume that we have an external assembler that supports AVX
 726             message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 727             set(EXTRA_C_FLAGS "${EXTRA_C_FLAGS} -no-integrated-as")
 728         endif()
 729         if (GMX_USE_CLANG_CXX_FMA_BUG_WORKAROUND)
 730             # we assume that we have an external assembler that supports AVX
 731             message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 732             set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} -no-integrated-as")
 733         endif()
 734
 735         set(GMX_CPU_ACCELERATION_X86_AVX_128_FMA 1)
 736         set(GMX_X86_AVX_128_FMA 1)
 737         set(ACCELERATION_STATUS_MESSAGE
 738             "Enabling 128-bit AVX Gromacs acceleration (with fused-multiply add)")
 739
 740     else()
 741         # If we are not doing AVX_128, it must be AVX_256...
 742         set(GMX_CPU_ACCELERATION_X86_AVX_256 1)
 743         set(GMX_X86_AVX_256 1)
 744         set(ACCELERATION_STATUS_MESSAGE
 745             "Enabling 256-bit AVX Gromacs acceleration")
 746     endif()
 747
 748     # Unfortunately gcc-4.5.2 and gcc-4.6.0 has a bug where they use the wrong datatype for the formal
 749     # parameter of the mask for maskload/maskstore arguments. Check if this is present, since we can work around it.
 750     gmx_test_avx_gcc_maskload_bug(${ACCELERATION_C_FLAGS} GMX_X86_AVX_GCC_MASKLOAD_BUG)
 751
 752 elseif(${GMX_CPU_ACCELERATION} STREQUAL "IBM_QPX")
 753     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 754         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 755
 756     if (TEST_QPX)
 757         message(WARNING "IBM QPX acceleration was selected. This will work, but SIMD-accelerated kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 758         set(GMX_CPU_ACCELERATION_IBM_QPX 1)
 759     else()
 760         message(FATAL_ERROR "Cannot compile the requested IBM QPX intrinsics. If you are compiling for BlueGene/Q with the XL compilers, use 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-C' to set up the tool chain.")
 761     endif()
 762 elseif(${GMX_CPU_ACCELERATION} STREQUAL "SPARC64_HPC_ACE")
 763     set(GMX_CPU_ACCELERATION_SPARC64_HPC_ACE 1)
 764 else()
 765     gmx_invalid_option_value(GMX_CPU_ACCELERATION)
 766 endif()
 767 gmx_check_if_changed(ACCELERATION_CHANGED GMX_CPU_ACCELERATION)
 768 if (ACCELERATION_CHANGED AND DEFINED ACCELERATION_STATUS_MESSAGE)
 769     message(STATUS "${ACCELERATION_STATUS_MESSAGE}")
 770 endif()
 771
 772 # Process QM/MM Settings
 773 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 774     set(GMX_QMMM_GAUSSIAN 1)
 775 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 776     set(GMX_QMMM_MOPAC 1)
 777 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 778     set(GMX_QMMM_GAMESS 1)
 779 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 780     set(GMX_QMMM_ORCA 1)
 781 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 782     # nothing to do
 783 else()
 784     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 785 endif()
 786
 787
 788 ##################################################
 789 # Process FFT library settings
 790 ##################################################
 791 include(gmxManageFFTLibraries)
 792
 793
 794 include(gmxManageLinearAlgebraLibraries)
 795
 796 # Whether GROMACS will really try to compile support for VMD plugins
 797 set(GMX_USE_PLUGINS OFF)
 798
 799 if(GMX_LOAD_PLUGINS)
 800   if(CYGWIN OR NOT WIN32)
 801     # Native Windows does not have, nor need dlopen
 802     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 803     include(gmxTestdlopen)
 804     gmx_test_dlopen(HAVE_DLOPEN)
 805   endif()
 806
 807   # so, should we use plug-ins?
 808   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 809     if(NOT VMD_QUIETLY)
 810       MESSAGE(STATUS
 811           "Found the ability to use plug-ins when building shared libaries, "
 812           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 813           "formats).")
 814     endif()
 815     if(NOT GMX_VMD_PLUGIN_PATH)
 816       find_package(VMD)
 817     endif()
 818     set(GMX_USE_PLUGINS ON)
 819     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 820     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 821   else()
 822     set(PKG_DL_LIBS)
 823   endif()
 824 endif(GMX_LOAD_PLUGINS)
 825 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 826
 827 # Link real-time library for POSIX timers. The check for clock_gettime
 828 # confirms the linkability of rt.
 829 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 830     list(APPEND GMX_EXTRA_LIBRARIES rt)
 831 endif()
 832
 833 # Math and thread libraries must often come after all others when linking...
 834 if(HAVE_LIBM)
 835     list(APPEND GMX_EXTRA_LIBRARIES m)
 836 endif(HAVE_LIBM)
 837 if (${CMAKE_SYSTEM_NAME} MATCHES "BlueGene")
 838     check_library_exists(mass_simd atan2f4 "" HAVE_MASS_SIMD)
 839     if(HAVE_MASS_SIMD)
 840         list(APPEND GMX_EXTRA_LIBRARIES mass_simd)
 841     else()
 842         message(FATAL_ERROR "Could not link to the SIMD version of the IBM MASS library. Please adjust your CMAKE_PREFIX_PATH to contain it")
 843     endif()
 844 endif()
 845
 846
 847 option(GMX_NACL "Configure for Native Client builds" OFF)
 848 if (GMX_NACL)
 849   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 850   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 851   set(GMX_NO_NICE 1)
 852   set(GMX_NO_RENAME 1)
 853 endif()
 854 mark_as_advanced(GMX_NACL)
 855
 856 if(GMX_FAHCORE)
 857   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 858       "Path to swindirect.h")
 859   include_directories(${COREWRAP_INCLUDE_DIR})
 860 endif(GMX_FAHCORE)
 861
 862 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 863 # these are set after everything else
 864 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 865     set(CMAKE_C_FLAGS "${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 866     set(CMAKE_CXX_FLAGS "${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 867     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 868     set(CMAKE_SHARED_LINKER_FLAGS "${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 869 else()
 870     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 871     message("CMAKE_C_FLAGS: ${ACCELERATION_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 872     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 873     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 874     message("CMAKE_CXX_FLAGS: ${ACCELERATION_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 875     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 876     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 877     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 878     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 879 endif()
 880
 881 if(NOT GMX_OPENMP)
 882     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 883     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 884     unset(OpenMP_C_FLAGS CACHE)
 885     unset(OpenMP_CXX_FLAGS CACHE)
 886 else()
 887     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 888     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 889 endif()
 890 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 891
 892 ########################################################################
 893 # Specify install locations
 894 ########################################################################
 895 set(GMX_LIB_INSTALL_DIR lib CACHE STRING
 896     "Library installation directory (default: lib)")
 897 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 898     "Data installation directory under share/ (default: gromacs)")
 899 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 900
 901 set(LIB_INSTALL_DIR  ${GMX_INSTALL_PREFIX}${GMX_LIB_INSTALL_DIR})
 902 set(BIN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}bin)
 903 set(DATA_INSTALL_DIR ${GMX_INSTALL_PREFIX}share/${GMX_DATA_INSTALL_DIR})
 904 set(MAN_INSTALL_DIR  ${GMX_INSTALL_PREFIX}share/man)
 905 set(INCL_INSTALL_DIR ${GMX_INSTALL_PREFIX}include)
 906
 907 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 908 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 909
 910 # Binary and library suffix options
 911 include(gmxManageSuffixes)
 912
 913 ##################################################################
 914 # Shared library settings
 915 ##################################################################
 916 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 917     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 918     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 919     set(CMAKE_INSTALL_RPATH "\\\$ORIGIN/../${GMXLIB}")
 920     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 921 else()
 922     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) #rpath supported for >10.4
 923         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 924         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../lib")
 925     else()
 926         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 927     endif()
 928 endif()
 929
 930 #COPYING file: Only necessary for binary distributions.
 931 #Simpler to always install.
 932 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 933
 934 if(GMX_EXTERNAL_BOOST)
 935     include_directories(${Boost_INCLUDE_DIRS})
 936 else()
 937     include_directories(${CMAKE_SOURCE_DIR}/src/external/boost)
 938     # typeid not supported for minimal internal version
 939     # (would add significant amount of code)
 940     add_definitions(-DBOOST_NO_TYPEID)
 941     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 942     # (from share/template/)
 943     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 944     if (NOT GMX_BUILD_MDRUN_ONLY)
 945         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 946                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 947                 COMPONENT development)
 948     endif ()
 949 endif()
 950
 951 if (GMX_BUILD_FOR_COVERAGE)
 952     # Code heavy with asserts makes conditional coverage close to useless metric,
 953     # as by design most of the false branches are impossible to trigger in
 954     # correctly functioning code.  And the benefit of testing those that could
 955     # be triggered by using an API against its specification isn't usually
 956     # worth the effort.
 957     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 958 endif ()
 959
 960 if (BUILD_TESTING)
 961     # "tests" target builds all the separate test binaries.
 962     add_custom_target(tests)
 963     # "run-ctest" is an internal target that actually runs the tests.
 964     # This is necessary to be able to add separate targets that execute as part
 965     # of 'make check', but are ensured to be executed after the actual tests.
 966     add_custom_target(run-ctest
 967                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 968                       COMMENT "Running all tests"
 969                       VERBATIM)
 970     add_dependencies(run-ctest tests)
 971     # "check" target builds and runs all tests.
 972     add_custom_target(check DEPENDS run-ctest)
 973 endif()
 974
 975 if (NOT GMX_BUILD_MDRUN_ONLY)
 976     add_subdirectory(doxygen)
 977     add_subdirectory(share)
 978     add_subdirectory(scripts)
 979 endif ()
 980 add_subdirectory(src)
 981
 982 if (BUILD_TESTING)
 983     add_subdirectory(tests)
 984 endif()
 985
 986 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 987 # Don't bother the user after the first configure pass.
 988 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 989     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 990 endif()
 991 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 992
 993 #######################
 994 ## uninstall target
 995 #######################
 996     CONFIGURE_FILE(
 997                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 998                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 999                    IMMEDIATE @ONLY)
1000 ###########################
1001 ADD_CUSTOM_TARGET(uninstall
1002                   "${CMAKE_COMMAND}" -P
1003                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
1004 ###########################
1005
1006 ########################################################################
1007 # Manual                                                               #
1008 ########################################################################
1009
1010 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
1011 mark_as_advanced(GMX_BUILD_MANUAL)
1012 if(GMX_BUILD_MANUAL)
1013     # Make sure we only do detection of manual-building dependencies
1014     # when the user opted in for that.
1015     add_subdirectory(manual)
1016 endif()