docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 set(EXPECTED_SPHINX_VERSION 1.4.1)
  62
  63 if (DEFINED PYTHON_EXECUTABLE)
  64     # Keep quiet on subsequent runs of cmake
  65     set(PythonInterp_FIND_QUIETLY ON)
  66 endif()
  67 find_package(PythonInterp 2.7)
  68 find_package(Sphinx ${EXPECTED_SPHINX_VERSION} QUIET COMPONENTS pygments)
  69
  70 # Even if we aren't going to make the full webpage, set up to put all
  71 # the documentation output in the same place, for convenience
  72 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  73 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  74
  75 # The directory from which man pages will be installed; if it remains
  76 # empty, they will be silently skipped.
  77 set(MAN_PAGE_DIR)
  78 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  79     # When building from the tarball, install the bundled man pages
  80     # (unless overridden).
  81     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  82 endif()
  83
  84 add_subdirectory(doxygen)
  85 add_subdirectory(manual)
  86
  87 if (SPHINX_FOUND)
  88     # We need to have all the Sphinx input files in a single directory, and
  89     # since some of them are generated, we copy everything into the build tree,
  90     # to this directory.
  91     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/doxygen.rst
 108         dev-manual/formatting.rst
 109         dev-manual/gmxtree.rst
 110         dev-manual/includestyle.rst
 111         dev-manual/jenkins.rst
 112         dev-manual/language-features.rst
 113         dev-manual/naming.rst
 114         dev-manual/overview.rst
 115         dev-manual/relocatable-binaries.rst
 116         dev-manual/style.rst
 117         dev-manual/testutils.rst
 118         dev-manual/tools.rst
 119         dev-manual/uncrustify.rst
 120         fragments/doxygen-links.rst
 121         install-guide/index.rst
 122         user-guide/index.rst
 123         user-guide/getting-started.rst
 124         user-guide/flow.rst
 125         user-guide/floating-point.rst
 126         user-guide/system-preparation.rst
 127         user-guide/cutoff-schemes.rst
 128         user-guide/managing-simulations.rst
 129         user-guide/mdrun-features.rst
 130         user-guide/mdrun-performance.rst
 131         user-guide/mdp-options.rst
 132         user-guide/run-time-errors.rst
 133         user-guide/file-formats.rst
 134         user-guide/cmdline.rst
 135         user-guide/environment-variables.rst
 136         user-guide/terminology.rst
 137         user-guide/plotje.gif
 138         user-guide/xvgr.gif
 139         conf.py
 140         links.dat
 141         )
 142
 143     include(SphinxMacros.cmake)
 144     gmx_init_sphinx_setup(${SPHINX_INPUT_DIR})
 145
 146     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
 147     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 148         EXTRA_VARS
 149             SPHINX_EXTENSION_PATH RELENG_PATH
 150             EXPECTED_DOXYGEN_VERSION
 151             EXPECTED_SPHINX_VERSION
 152             CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 153             REQUIRED_OPENCL_MIN_VERSION
 154             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 155             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 156             GMX_TNG_MINIMUM_REQUIRED_VERSION
 157             GMX_LMFIT_MINIMUM_REQUIRED_VERSION
 158         COMMENT "Configuring Sphinx configuration file")
 159     gmx_add_sphinx_input_file(${SPHINX_CONFIG_VARS_FILE})
 160     gmx_add_sphinx_source_files(FILES ${SPHINX_SOURCE_FILES})
 161     if (EXISTS ${RELENG_PATH}/docs/FileList.cmake)
 162         include(${RELENG_PATH}/docs/FileList.cmake)
 163         gmx_add_sphinx_source_files(
 164             FROM ${RELENG_PATH}/docs TO dev-manual/releng PREFIX releng/docs/
 165             FILES ${RELENG_SPHINX_FILES})
 166     else()
 167         gmx_add_sphinx_source_files(FILES
 168             dev-manual/releng/index.rst
 169             dev-manual/releng/jenkins-howto.rst
 170             dev-manual/releng/jenkins-ui.rst
 171             )
 172     endif()
 173     gmx_add_sphinx_input_target(sphinx-input)
 174     # Remove other rst files from the build tree, since they confuse Sphinx.
 175     # Skip generated files in onlinehelp/, and fragments.
 176     # The latter do not cause issues with obsolete files, as they
 177     # are not considered as Sphinx input files, but will only be
 178     # included using an explicit .. include::.
 179     gmx_remove_obsolete_sphinx_input_files("^(onlinehelp|fragments)/.*\\\\.rst$")
 180
 181     # TODO: Make this remove obsolete .rst files.
 182     # TODO: This does not work in cross-compilation scenarios; disable up to
 183     # the necessary level.
 184     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 185         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 186         COMMAND gmx -quiet help -export rst
 187         DEPENDS gmx
 188         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 189         COMMENT "Generating reStructuredText help")
 190     # This dependency ensures that the directories exist before the
 191     # executable tries to write things there.
 192     add_dependencies(sphinx-programs sphinx-input)
 193
 194     # Make the INSTALL file for CPack for the tarball. This gets put
 195     # into the tarball via the CPack rules below, which requires that
 196     # the INSTALL file is in a separate directory by itself.
 197     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 198     add_custom_target(install-guide
 199         COMMAND
 200             ${SPHINX_EXECUTABLE}
 201             -q -b text
 202             -w sphinx-install.log
 203             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 204             -c ${SPHINX_INPUT_DIR}
 205             "${SPHINX_INPUT_DIR}/install-guide"
 206             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 207         COMMAND
 208             ${CMAKE_COMMAND} -E rename
 209             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 210             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 211         WORKING_DIRECTORY
 212             ${CMAKE_CURRENT_BINARY_DIR}
 213         COMMENT "Building INSTALL with Sphinx"
 214         VERBATIM
 215         )
 216     add_dependencies(install-guide sphinx-input)
 217     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 218
 219     # Sphinx cache with pickled ReST documents
 220     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 221
 222     add_custom_target(webpage-sphinx
 223         COMMAND
 224             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 225         COMMAND
 226             ${SPHINX_EXECUTABLE}
 227             -q -b html
 228             -w sphinx-html.log
 229             -d "${SPHINX_CACHE_DIR}"
 230             "${SPHINX_INPUT_DIR}"
 231             "${HTML_OUTPUT_DIR}"
 232         WORKING_DIRECTORY
 233             ${CMAKE_CURRENT_BINARY_DIR}
 234         COMMENT "Building HTML documentation with Sphinx"
 235         VERBATIM
 236         )
 237     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 238
 239     add_custom_target(man
 240         COMMAND
 241             ${SPHINX_EXECUTABLE}
 242             -q -b man
 243             -w sphinx-man.log
 244             -d ${SPHINX_CACHE_DIR}
 245             -t do_man
 246             ${SPHINX_INPUT_DIR}
 247             ${CMAKE_CURRENT_BINARY_DIR}/man
 248         COMMENT "Building man pages with Sphinx"
 249         VERBATIM)
 250     add_dependencies(man sphinx-input sphinx-programs)
 251     if (GMX_BUILD_HELP)
 252         # If requested, install the man pages built by the 'man' target
 253         # created above.  Nothing will be installed if the user did not
 254         # manually build the target.
 255         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 256     endif()
 257 else()
 258     add_custom_target(webpage-sphinx
 259         COMMAND ${CMAKE_COMMAND} -E echo
 260             "HTML pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 261         VERBATIM)
 262     add_custom_target(install-guide
 263         COMMAND ${CMAKE_COMMAND} -E echo
 264             "INSTALL cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 265         VERBATIM)
 266     add_custom_target(man
 267         COMMAND ${CMAKE_COMMAND} -E echo
 268             "man pages cannot be built because Sphinx version ${EXPECTED_SPHINX_VERSION} is not available"
 269         VERBATIM)
 270 endif()
 271
 272 if (MAN_PAGE_DIR)
 273     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 274     # Trailing slash on directory is significant for
 275     # install(DIRECTORY). See CMake docs.
 276     install(DIRECTORY ${MAN_PAGE_DIR}/
 277         DESTINATION ${MAN_INSTALL_DIR}/man1
 278         COMPONENT man OPTIONAL
 279         FILES_MATCHING PATTERN "*.1")
 280 endif()
 281 gmx_cpack_add_generated_source_directory(man)
 282
 283 # Determine whether we can build all the HTML pages and content linked from
 284 # there.  If not, construct an informative message if the user tries to
 285 # build the target; most people never need to know, unless they've asked for
 286 # the webpage build.
 287 set(HTML_BUILD_IS_POSSIBLE ON)
 288 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 289 set(HTML_BUILD_WARNINGS)
 290
 291 # Next, turn it off if any of the preconditions are unsatisified
 292 if (NOT PYTHON_EXECUTABLE)
 293     set(HTML_BUILD_IS_POSSIBLE OFF)
 294     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 295 elseif (NOT SPHINX_FOUND)
 296     # Hardly anything gets built if Sphinx is not available, so don't bother.
 297     set(HTML_BUILD_IS_POSSIBLE OFF)
 298     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx version ${EXPECTED_SPHINX_VERSION} is required")
 299 endif()
 300 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 301     list(APPEND HTML_BUILD_WARNINGS
 302          "Reference PDF manual was not built, so links to it do not work")
 303 endif()
 304 if (NOT DOXYGEN_EXECUTABLE)
 305     list(APPEND HTML_BUILD_WARNINGS
 306         "Doxygen was not available, so links to Doxygen do not work")
 307 endif()
 308 if (NOT DOXYGEN_DOT_EXECUTABLE)
 309     list(APPEND HTML_BUILD_WARNINGS
 310         "dot/graphviz was not found, so some graphs are missing")
 311 endif()
 312
 313 if (HTML_BUILD_IS_POSSIBLE)
 314     set(_webpage_target_properties)
 315     if (HTML_BUILD_WARNINGS)
 316         list(APPEND _webpage_target_properties
 317              COMMAND ${CMAKE_COMMAND} -E echo
 318                  "webpage was built, but with the following limitations:")
 319         foreach(_warning ${HTML_BUILD_WARNINGS})
 320         list(APPEND _webpage_target_properties
 321              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 322         endforeach()
 323     endif()
 324
 325     if (MANUAL_BUILD_IS_POSSIBLE)
 326         # Make the PDF reference guide
 327         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 328         # TODO Make this depend on the output of the manual build, so that the
 329         # file actually gets copied multiple times.
 330         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 331         add_custom_command(
 332             OUTPUT ${_manual_target_location}
 333             COMMAND ${CMAKE_COMMAND}
 334                 -E remove -f ${_manual_target_location}
 335             COMMAND ${CMAKE_COMMAND}
 336                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 337             DEPENDS manual
 338             VERBATIM)
 339         list(APPEND _webpage_target_properties
 340              DEPENDS ${_manual_target_location})
 341     endif()
 342
 343     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 344     # makes all the Doxygen output directly in
 345     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 346     # to).
 347
 348     # Add a top-level target that builds everything related to the webpage,
 349     # for Jenkins (and possibly others) to use
 350     add_custom_target(webpage ${_webpage_target_properties}
 351         COMMENT "Building webpage"
 352         VERBATIM)
 353     add_dependencies(webpage webpage-sphinx doxygen-all)
 354 else()
 355     add_custom_target(webpage
 356         COMMAND ${CMAKE_COMMAND} -E echo
 357             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 358         COMMENT "Webpage build not possible"
 359         VERBATIM)
 360 endif()