cmake/FindCUDA/run_nvcc.cmake

   1 #  James Bigler, NVIDIA Corp (nvidia.com - jbigler)
   2 #
   3 #  Copyright (c) 2008 - 2009 NVIDIA Corporation.  All rights reserved.
   4 #
   5 #  This code is licensed under the MIT License.  See the FindCUDA.cmake script
   6 #  for the text of the license.
   7
   8 # The MIT License
   9 #
  10 # License for the specific language governing rights and limitations under
  11 # Permission is hereby granted, free of charge, to any person obtaining a
  12 # copy of this software and associated documentation files (the "Software"),
  13 # to deal in the Software without restriction, including without limitation
  14 # the rights to use, copy, modify, merge, publish, distribute, sublicense,
  15 # and/or sell copies of the Software, and to permit persons to whom the
  16 # Software is furnished to do so, subject to the following conditions:
  17 #
  18 # The above copyright notice and this permission notice shall be included
  19 # in all copies or substantial portions of the Software.
  20 #
  21 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  22 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  23 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
  24 # THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  25 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  26 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  27 # DEALINGS IN THE SOFTWARE.
  28
  29
  30 ##########################################################################
  31 # This file runs the nvcc commands to produce the desired output file along with
  32 # the dependency file needed by CMake to compute dependencies.  In addition the
  33 # file checks the output of each command and if the command fails it deletes the
  34 # output files.
  35
  36 # Input variables
  37 #
  38 # verbose:BOOL=<>          OFF: Be as quiet as possible (default)
  39 #                          ON : Describe each step
  40 #
  41 # build_configuration:STRING=<> Typically one of Debug, MinSizeRel, Release, or
  42 #                               RelWithDebInfo, but it should match one of the
  43 #                               entries in CUDA_HOST_FLAGS. This is the build
  44 #                               configuration used when compiling the code.  If
  45 #                               blank or unspecified Debug is assumed as this is
  46 #                               what CMake does.
  47 #
  48 # generated_file:STRING=<> File to generate.  This argument must be passed in.
  49 #
  50 # generated_cubin_file:STRING=<> File to generate.  This argument must be passed
  51 #                                                   in if build_cubin is true.
  52
  53 if(NOT generated_file)
  54   message(FATAL_ERROR "You must specify generated_file on the command line")
  55 endif()
  56
  57 # Set these up as variables to make reading the generated file easier
  58 set(CMAKE_COMMAND "@CMAKE_COMMAND@") # path
  59 set(source_file "@source_file@") # path
  60 set(NVCC_generated_dependency_file "@NVCC_generated_dependency_file@") # path
  61 set(cmake_dependency_file "@cmake_dependency_file@") # path
  62 set(CUDA_make2cmake "@CUDA_make2cmake@") # path
  63 set(CUDA_parse_cubin "@CUDA_parse_cubin@") # path
  64 set(build_cubin @build_cubin@) # bool
  65 set(CUDA_HOST_COMPILER "@CUDA_HOST_COMPILER@") # path
  66 # We won't actually use these variables for now, but we need to set this, in
  67 # order to force this file to be run again if it changes.
  68 set(generated_file_path "@generated_file_path@") # path
  69 set(generated_file_internal "@generated_file@") # path
  70 set(generated_cubin_file_internal "@generated_cubin_file@") # path
  71
  72 set(CUDA_NVCC_EXECUTABLE "@CUDA_NVCC_EXECUTABLE@") # path
  73 set(CUDA_NVCC_FLAGS @CUDA_NVCC_FLAGS@ ;; @CUDA_WRAP_OPTION_NVCC_FLAGS@) # list
  74 @CUDA_NVCC_FLAGS_CONFIG@
  75 set(nvcc_flags @nvcc_flags@) # list
  76 set(CUDA_NVCC_INCLUDE_ARGS "@CUDA_NVCC_INCLUDE_ARGS@") # list (needs to be in quotes to handle spaces properly).
  77 set(format_flag "@format_flag@") # string
  78 set(cuda_language_flag @cuda_language_flag@) # list
  79
  80 if(build_cubin AND NOT generated_cubin_file)
  81   message(FATAL_ERROR "You must specify generated_cubin_file on the command line")
  82 endif()
  83
  84 # This is the list of host compilation flags.  It C or CXX should already have
  85 # been chosen by FindCUDA.cmake.
  86 @CUDA_HOST_FLAGS@
  87
  88 # Take the compiler flags and package them up to be sent to the compiler via -Xcompiler
  89 set(nvcc_host_compiler_flags "")
  90 # If we weren't given a build_configuration, use Debug.
  91 if(NOT build_configuration)
  92   set(build_configuration Debug)
  93 endif()
  94 string(TOUPPER "${build_configuration}" build_configuration)
  95 #message("CUDA_NVCC_HOST_COMPILER_FLAGS = ${CUDA_NVCC_HOST_COMPILER_FLAGS}")
  96 foreach(flag ${CMAKE_HOST_FLAGS} ${CMAKE_HOST_FLAGS_${build_configuration}})
  97   # Extra quotes are added around each flag to help nvcc parse out flags with spaces.
  98   set(nvcc_host_compiler_flags "${nvcc_host_compiler_flags},\"${flag}\"")
  99 endforeach()
 100 if (nvcc_host_compiler_flags)
 101   set(nvcc_host_compiler_flags "-Xcompiler" ${nvcc_host_compiler_flags})
 102 endif()
 103 #message("nvcc_host_compiler_flags = \"${nvcc_host_compiler_flags}\"")
 104 # Add the build specific configuration flags
 105 list(APPEND CUDA_NVCC_FLAGS ${CUDA_NVCC_FLAGS_${build_configuration}})
 106
 107 # Any -ccbin existing in CUDA_NVCC_FLAGS gets highest priority
 108 list( FIND CUDA_NVCC_FLAGS "-ccbin" ccbin_found0 )
 109 list( FIND CUDA_NVCC_FLAGS "--compiler-bindir" ccbin_found1 )
 110 if( ccbin_found0 LESS 0 AND ccbin_found1 LESS 0 AND CUDA_HOST_COMPILER )
 111   if (CUDA_HOST_COMPILER STREQUAL "$(VCInstallDir)bin" AND DEFINED CCBIN)
 112     set(CCBIN -ccbin "${CCBIN}")
 113   else()
 114     set(CCBIN -ccbin "${CUDA_HOST_COMPILER}")
 115   endif()
 116 endif()
 117
 118 # cuda_execute_process - Executes a command with optional command echo and status message.
 119 #
 120 #   status  - Status message to print if verbose is true
 121 #   command - COMMAND argument from the usual execute_process argument structure
 122 #   ARGN    - Remaining arguments are the command with arguments
 123 #
 124 #   CUDA_result - return value from running the command
 125 #
 126 # Make this a macro instead of a function, so that things like RESULT_VARIABLE
 127 # and other return variables are present after executing the process.
 128 macro(cuda_execute_process status command)
 129   set(_command ${command})
 130   if(NOT "x${_command}" STREQUAL "xCOMMAND")
 131     message(FATAL_ERROR "Malformed call to cuda_execute_process.  Missing COMMAND as second argument. (command = ${command})")
 132   endif()
 133   if(verbose)
 134     execute_process(COMMAND "${CMAKE_COMMAND}" -E echo -- ${status})
 135     # Now we need to build up our command string.  We are accounting for quotes
 136     # and spaces, anything else is left up to the user to fix if they want to
 137     # copy and paste a runnable command line.
 138     set(cuda_execute_process_string)
 139     foreach(arg ${ARGN})
 140       # If there are quotes, excape them, so they come through.
 141       string(REPLACE "\"" "\\\"" arg ${arg})
 142       # Args with spaces need quotes around them to get them to be parsed as a single argument.
 143       if(arg MATCHES " ")
 144         list(APPEND cuda_execute_process_string "\"${arg}\"")
 145       else()
 146         list(APPEND cuda_execute_process_string ${arg})
 147       endif()
 148     endforeach()
 149     # Echo the command
 150     execute_process(COMMAND ${CMAKE_COMMAND} -E echo ${cuda_execute_process_string})
 151   endif()
 152   # Run the command
 153   execute_process(COMMAND ${ARGN} RESULT_VARIABLE CUDA_result )
 154 endmacro()
 155
 156 # Delete the target file
 157 cuda_execute_process(
 158   "Removing ${generated_file}"
 159   COMMAND "${CMAKE_COMMAND}" -E remove "${generated_file}"
 160   )
 161
 162 # For CUDA 2.3 and below, -G -M doesn't work, so remove the -G flag
 163 # for dependency generation and hope for the best.
 164 set(depends_CUDA_NVCC_FLAGS "${CUDA_NVCC_FLAGS}")
 165 set(CUDA_VERSION @CUDA_VERSION@)
 166 if(CUDA_VERSION VERSION_LESS "3.0")
 167   cmake_policy(PUSH)
 168   # CMake policy 0007 NEW states that empty list elements are not
 169   # ignored.  I'm just setting it to avoid the warning that's printed.
 170   cmake_policy(SET CMP0007 NEW)
 171   # Note that this will remove all occurances of -G.
 172   list(REMOVE_ITEM depends_CUDA_NVCC_FLAGS "-G")
 173   cmake_policy(POP)
 174 endif()
 175
 176 # nvcc doesn't define __CUDACC__ for some reason when generating dependency files.  This
 177 # can cause incorrect dependencies when #including files based on this macro which is
 178 # defined in the generating passes of nvcc invokation.  We will go ahead and manually
 179 # define this for now until a future version fixes this bug.
 180 set(CUDACC_DEFINE -D__CUDACC__)
 181
 182 # Generate the dependency file
 183 cuda_execute_process(
 184   "Generating dependency file: ${NVCC_generated_dependency_file}"
 185   COMMAND "${CUDA_NVCC_EXECUTABLE}"
 186   -M
 187   ${CUDACC_DEFINE}
 188   "${source_file}"
 189   -o "${NVCC_generated_dependency_file}"
 190   ${CCBIN}
 191   ${nvcc_flags}
 192   ${nvcc_host_compiler_flags}
 193   ${depends_CUDA_NVCC_FLAGS}
 194   -DNVCC
 195   ${CUDA_NVCC_INCLUDE_ARGS}
 196   )
 197
 198 if(CUDA_result)
 199   message(FATAL_ERROR "Error generating ${generated_file}")
 200 endif()
 201
 202 # Generate the cmake readable dependency file to a temp file.  Don't put the
 203 # quotes just around the filenames for the input_file and output_file variables.
 204 # CMake will pass the quotes through and not be able to find the file.
 205 cuda_execute_process(
 206   "Generating temporary cmake readable file: ${cmake_dependency_file}.tmp"
 207   COMMAND "${CMAKE_COMMAND}"
 208   -D "input_file:FILEPATH=${NVCC_generated_dependency_file}"
 209   -D "output_file:FILEPATH=${cmake_dependency_file}.tmp"
 210   -P "${CUDA_make2cmake}"
 211   )
 212
 213 if(CUDA_result)
 214   message(FATAL_ERROR "Error generating ${generated_file}")
 215 endif()
 216
 217 # Copy the file if it is different
 218 cuda_execute_process(
 219   "Copy if different ${cmake_dependency_file}.tmp to ${cmake_dependency_file}"
 220   COMMAND "${CMAKE_COMMAND}" -E copy_if_different "${cmake_dependency_file}.tmp" "${cmake_dependency_file}"
 221   )
 222
 223 if(CUDA_result)
 224   message(FATAL_ERROR "Error generating ${generated_file}")
 225 endif()
 226
 227 # Delete the temporary file
 228 cuda_execute_process(
 229   "Removing ${cmake_dependency_file}.tmp and ${NVCC_generated_dependency_file}"
 230   COMMAND "${CMAKE_COMMAND}" -E remove "${cmake_dependency_file}.tmp" "${NVCC_generated_dependency_file}"
 231   )
 232
 233 if(CUDA_result)
 234   message(FATAL_ERROR "Error generating ${generated_file}")
 235 endif()
 236
 237 # Generate the code
 238 cuda_execute_process(
 239   "Generating ${generated_file}"
 240   COMMAND "${CUDA_NVCC_EXECUTABLE}"
 241   "${source_file}"
 242   ${cuda_language_flag}
 243   ${format_flag} -o "${generated_file}"
 244   ${CCBIN}
 245   ${nvcc_flags}
 246   ${nvcc_host_compiler_flags}
 247   ${CUDA_NVCC_FLAGS}
 248   -DNVCC
 249   ${CUDA_NVCC_INCLUDE_ARGS}
 250   )
 251
 252 if(CUDA_result)
 253   # Since nvcc can sometimes leave half done files make sure that we delete the output file.
 254   cuda_execute_process(
 255     "Removing ${generated_file}"
 256     COMMAND "${CMAKE_COMMAND}" -E remove "${generated_file}"
 257     )
 258   message(FATAL_ERROR "Error generating file ${generated_file}")
 259 else()
 260   if(verbose)
 261     message("Generated ${generated_file} successfully.")
 262   endif()
 263 endif()
 264
 265 # Cubin resource report commands.
 266 if( build_cubin )
 267   # Run with -cubin to produce resource usage report.
 268   cuda_execute_process(
 269     "Generating ${generated_cubin_file}"
 270     COMMAND "${CUDA_NVCC_EXECUTABLE}"
 271     "${source_file}"
 272     ${CUDA_NVCC_FLAGS}
 273     ${nvcc_flags}
 274     ${CCBIN}
 275     ${nvcc_host_compiler_flags}
 276     -DNVCC
 277     -cubin
 278     -o "${generated_cubin_file}"
 279     ${CUDA_NVCC_INCLUDE_ARGS}
 280     )
 281
 282   # Execute the parser script.
 283   cuda_execute_process(
 284     "Executing the parser script"
 285     COMMAND  "${CMAKE_COMMAND}"
 286     -D "input_file:STRING=${generated_cubin_file}"
 287     -P "${CUDA_parse_cubin}"
 288     )
 289
 290 endif()