CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.1-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.1-dev")
  67 # The MD5 checksum of the regressiontest tarball. Only used if "-dev"
  68 # is not present in the PROJECT_VERSION
  69 set(REGRESSIONTEST_MD5SUM "a07524afebca5013540d4f2f72df2dce")
  70 # If this is not a released tarball, "-dev" will be present in
  71 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  72 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  73 # code contains all recent fixes from the corresponding code branch.
  74 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  75
  76 set(CUSTOM_VERSION_STRING ""
  77     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  78 mark_as_advanced(CUSTOM_VERSION_STRING)
  79 if (CUSTOM_VERSION_STRING)
  80     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  81 endif()
  82 set(LIBRARY_SOVERSION 0)
  83 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  84 # It is a bit irritating, but this has to be set separately for now!
  85 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  86 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  87 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  88
  89 # The numerical gromacs version. It is 40600 for 4.6.0.
  90 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  91 math(EXPR NUM_VERSION
  92     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  93 if(CPACK_PACKAGE_VERSION_PATCH)
  94     math(EXPR NUM_VERSION
  95          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  96 endif()
  97
  98 # The API version tracks the numerical Gromacs version (for now).
  99 # It is potentially different from the Gromacs version in the future, if
 100 # the programs/libraries diverge from the presumably more stable API.
 101 # The #define GMX_API_VERSION in version.h is set to this value to
 102 # provide backward compatibility of software written against the Gromacs API.
 103 set(API_VERSION ${NUM_VERSION})
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 106     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 107 endif()
 108
 109 include(gmxBuildTypeReference)
 110 include(gmxBuildTypeTSAN)
 111 include(gmxBuildTypeASAN)
 112 include(gmxBuildTypeReleaseWithAssert)
 113
 114 if(NOT CMAKE_BUILD_TYPE)
 115     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 116     # There's no need to offer a user the choice of ThreadSanitizer
 117     # Set the possible values of build type for cmake-gui
 118     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 119         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 120 endif()
 121 if(CMAKE_CONFIGURATION_TYPES)
 122     # Add appropriate GROMACS-specific build types for the Visual
 123     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 124     # are already present by default).
 125     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 126     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 127     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 128         "List of configuration types"
 129         FORCE)
 130 endif()
 131 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL)
 132
 133 enable_language(C)
 134 enable_language(CXX)
 135
 136 set(CPACK_PACKAGE_NAME "gromacs")
 137 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 138 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 139 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 140 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 141 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 142 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 143 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 144 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 145 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 146 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 147 # CPack source archives include only the directories we list here.
 148 # This variable is a list of pairs of names of source and destination
 149 # directories. Most of these are used for content GROMACS generates as
 150 # part of the configuration or build.
 151 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/share/man/man1;share/man/man1;${CMAKE_BINARY_DIR}/share/man/man7;share/man/man7;${CMAKE_BINARY_DIR}/share/html/final;share/html/final;${CMAKE_BINARY_DIR}/install-guide/final;/")
 152 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 153 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 154
 155 #must come after all cpack settings!
 156 include(CPack)
 157
 158 # Set a default valgrind suppression file.
 159 # This unfortunately needs to duplicate information from CTest to work as
 160 # expected...
 161 set(MEMORYCHECK_SUPPRESSIONS_FILE
 162     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 163     CACHE FILEPATH
 164     "File that contains suppressions for the memory checker")
 165 include(CTest)
 166
 167 set(SOURCE_IS_GIT_REPOSITORY OFF)
 168 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 169 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 170     set(SOURCE_IS_GIT_REPOSITORY ON)
 171 endif()
 172 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 173     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 174 endif()
 175
 176 ########################################################################
 177 # Check and warn if cache generated on a different host is being reused
 178 ########################################################################
 179 if(CMAKE_HOST_UNIX)
 180     execute_process(COMMAND hostname
 181                     OUTPUT_VARIABLE TMP_HOSTNAME
 182                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 183     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 184         message(WARNING "
 185             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 186             is being reused! This could lead to inconsitencies; therefore, it is
 187             recommended to regenerate the cache!")
 188     endif()
 189     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 190             "Hostname of the machine where the cache was generated.")
 191 endif()
 192
 193 ########################################################################
 194 # User input options                                                   #
 195 ########################################################################
 196 include(gmxOptionUtilities)
 197
 198 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 199
 200 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 201 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 202 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 203 gmx_dependent_option(
 204     GMX_MPI_IN_PLACE
 205     "Enable MPI_IN_PLACE for MPIs that have it defined"
 206     ON
 207     GMX_MPI)
 208 mark_as_advanced(GMX_MPI_IN_PLACE)
 209 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 210 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 211 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 212 mark_as_advanced(GMX_FAHCORE)
 213
 214 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 215 mark_as_advanced(GMX_COOL_QUOTES)
 216 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 217
 218 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 219 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 220 if(MSVC)
 221     set(REQUIRED_CUDA_VERSION 4.1)
 222 else()
 223     set(REQUIRED_CUDA_VERSION 4.0)
 224 endif()
 225 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 226 include(gmxManageGPU)
 227
 228 # Detect the architecture the compiler is targetting, detect
 229 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 230 # to use if none is specified, and populate the cache option for CPU
 231 # SIMD.
 232 include(gmxDetectTargetArchitecture)
 233 gmx_detect_target_architecture()
 234
 235 if(GMX_CPU_ACCELERATION)
 236     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 237     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 238     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 239     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 240 endif()
 241
 242 if(NOT GMX_TARGET_MIC)
 243     include(gmxDetectSimd)
 244     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 245 else()
 246     set(GMX_SUGGESTED_SIMD "None")
 247 endif()
 248
 249 gmx_option_multichoice(
 250     GMX_SIMD
 251     "SIMD instruction set for CPU kernels and compiler optimization"
 252     "${GMX_SUGGESTED_SIMD}"
 253     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 254
 255 gmx_option_multichoice(
 256     GMX_FFT_LIBRARY
 257     "FFT library"
 258     "fftw3"
 259     fftw3 mkl "fftpack[built-in]")
 260 gmx_dependent_option(
 261     GMX_BUILD_OWN_FFTW
 262     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 263     OFF
 264     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 265 gmx_dependent_option(
 266     GMX_DISABLE_FFTW_MEASURE
 267     "Do not optimize FFTW setups (not needed with SSE)"
 268     OFF
 269     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 270 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 271 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 272
 273 gmx_option_multichoice(
 274     GMX_QMMM_PROGRAM
 275     "QM package for QM/MM"
 276     None
 277     none gaussian mopac gamess orca)
 278
 279 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 280 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 281
 282 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 283
 284 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 285 mark_as_advanced(GMX_BROKEN_CALLOC)
 286 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 287 mark_as_advanced(GMX_LOAD_PLUGINS)
 288
 289 option(GMX_GPU  "Enable GPU acceleration" ON)
 290 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 291
 292 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 293
 294 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 295 mark_as_advanced(GMX_GIT_VERSION_INFO)
 296
 297 if(UNIX)
 298     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 299 endif()
 300 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 301
 302 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 303 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 304
 305 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 306 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 307
 308 option(GMX_BUILD_FOR_COVERAGE
 309        "Tune build for better code coverage metrics (e.g., disable asserts)"
 310        OFF)
 311 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 312
 313
 314 ######################################################################
 315 # Detect OpenMP support
 316 ######################################################################
 317 # The OpenMP detection _must_ come before tests for other CFLAGS.
 318 include(gmxManageOpenMP)
 319
 320
 321
 322 ######################################################################
 323 # Compiler tests
 324 # These need to be done early (before further tests).
 325 #####################################################################
 326
 327 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 328 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 329 # invalid options with the Intel Compilers, and we have added a line
 330 # to detect warnings with the Fujitsu compilers on K computer.
 331 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 332 # a semicolon. Since this is also used as a separator in lists inside CMake,
 333 # that string ends up being split into two separate patterns, and the last
 334 # part is just a single word that also matches other messages. We solved this
 335 # by replacing the semicolon with a period that matches any character.
 336 #
 337 # These files should be removed from the source tree when a CMake version that
 338 # includes the features in question becomes required for building GROMACS.
 339 include(CheckCCompilerFlag)
 340 include(CheckCXXCompilerFlag)
 341
 342 include(gmxCFlags)
 343 gmx_c_flags()
 344
 345 # This variable should be used for additional compiler flags which are not
 346 # generated in gmxCFlags nor are SIMD or MPI related.
 347 set(EXTRA_C_FLAGS "")
 348 set(EXTRA_CXX_FLAGS "")
 349
 350 # Run through a number of tests for buggy compilers and other issues
 351 include(gmxTestCompilerProblems)
 352 gmx_test_compiler_problems()
 353 # GMX_SIMD will not be set automatically until the second
 354 # pass (which is not strictly guaranteed to occur), so putting this
 355 # check here among logically-related tests is inefficient, but the
 356 # potential loss is likely zero.
 357 if(GMX_SIMD STREQUAL "AVX_256"
 358         AND CMAKE_COMPILER_IS_GNUCC
 359         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 360             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 361     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 362     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 363 endif()
 364
 365
 366
 367 set(PKG_CFLAGS "")
 368 if(GMX_DOUBLE)
 369     add_definitions(-DGMX_DOUBLE)
 370     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 371 endif()
 372 if(GMX_SOFTWARE_INVSQRT)
 373   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 374 endif()
 375
 376 if(WIN32 AND NOT CYGWIN)
 377     set(GMX_WSOCKLIB_PATH CACHE PATH "Path to winsock (wsock32.lib) library.")
 378     mark_as_advanced(GMX_WSOCKLIB_PATH)
 379     find_library(WSOCK32_LIBRARY NAMES wsock32 PATHS ${GMX_WSOCKLIB_PATH})
 380     if(WSOCK32_LIBRARY)
 381         list(APPEND GMX_EXTRA_LIBRARIES ${WSOCK32_LIBRARY})
 382         add_definitions(-DGMX_HAVE_WINSOCK)
 383     else()
 384         message(STATUS "No winsock found. Cannot use interactive molecular dynamics (IMD).")
 385     endif(WSOCK32_LIBRARY)
 386 endif()
 387
 388
 389
 390 ########################################################################
 391 # Basic system tests (standard libraries, headers, functions, types)   #
 392 ########################################################################
 393 include(CheckIncludeFiles)
 394 include(CheckIncludeFileCXX)
 395 check_include_files(unistd.h     HAVE_UNISTD_H)
 396 check_include_files(pwd.h        HAVE_PWD_H)
 397 check_include_files(dirent.h     HAVE_DIRENT_H)
 398 check_include_files(time.h       HAVE_TIME_H)
 399 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 400 check_include_files(io.h         HAVE_IO_H)
 401 check_include_files(sched.h      HAVE_SCHED_H)
 402
 403 check_include_files(regex.h      HAVE_POSIX_REGEX)
 404 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 405 # TODO: It could be nice to inform the user if no regex support is found,
 406 # as selections won't be fully functional.
 407
 408 include(CheckFunctionExists)
 409 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 410 check_function_exists(memalign          HAVE_MEMALIGN)
 411 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 412 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 413 check_function_exists(fsync             HAVE_FSYNC)
 414 check_function_exists(_fileno           HAVE__FILENO)
 415 check_function_exists(fileno            HAVE_FILENO)
 416 check_function_exists(_commit           HAVE__COMMIT)
 417 check_function_exists(sigaction         HAVE_SIGACTION)
 418 check_function_exists(sysconf           HAVE_SYSCONF)
 419 check_function_exists(rsqrt             HAVE_RSQRT)
 420 check_function_exists(rsqrtf            HAVE_RSQRTF)
 421 check_function_exists(sqrtf             HAVE_SQRTF)
 422
 423 include(CheckLibraryExists)
 424 check_library_exists(m sqrt "" HAVE_LIBM)
 425 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 426
 427 include(TestSchedAffinity)
 428 test_sched_affinity(HAVE_SCHED_AFFINITY)
 429
 430 include(TestBigEndian)
 431 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 432
 433 # Management of GROMACS options for specific toolchains should go
 434 # here. Because the initial settings for some of the main options have
 435 # already happened, but things like library detection and MPI compiler
 436 # feature detection have not, the docstrings for any over-rides of
 437 # GROMACS defaults or user settings will make sense. Also, any
 438 # toolchain-related reasons for choosing whether to detect various
 439 # things can be sorted out now, before the detection takes place.
 440 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 441     include(gmxManageBlueGene)
 442 endif()
 443
 444 ########################################################################
 445 #Process MPI settings
 446 ########################################################################
 447 include(gmxManageMPI)
 448
 449
 450 ########################################################################
 451 #Process shared/static library settings
 452 ########################################################################
 453 include(gmxManageSharedLibraries)
 454
 455
 456 ########################################################################
 457 # Find external packages                                               #
 458 ########################################################################
 459
 460 # Unconditionally find the package, as it is also required for unit
 461 # tests. This exports LIBXML2_FOUND, which we should not use because
 462 # it does not tell us that linking will succeed. Instead, we test that
 463 # next.
 464 if(DEFINED LIBXML2_LIBRARIES)
 465   set(LibXml2_FIND_QUIETLY TRUE)
 466 endif()
 467 find_package(LibXml2)
 468 include(gmxTestLibXml2)
 469 gmx_test_libxml2(HAVE_LIBXML2)
 470 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 471 set(PKG_XML "")
 472 mark_as_advanced(GMX_XML)
 473 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 474 #if(GMX_XML AND NOT HAVE_LIBXML2)
 475 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 476 #endif()
 477 #if(GMX_XML)
 478 #    include_directories(${LIBXML2_INCLUDE_DIR})
 479 #    set(PKG_XML libxml-2.0)
 480 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 481 #endif()
 482
 483 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 484 mark_as_advanced(GMX_EXTRAE)
 485
 486 if (GMX_EXTRAE)
 487   find_package(EXTRAE)
 488   if(EXTRAE_FOUND)
 489     include_directories(${EXTRAE_INCLUDE_DIR})
 490     set(HAVE_EXTRAE 1)
 491   else()
 492     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 493   endif()
 494 endif()
 495
 496 option(GMX_X11 "Use X window system" OFF)
 497 if (GMX_X11)
 498     find_package(X11)
 499     # X11 includes/libraries are only set in the ngmx subdirectory!
 500     if(NOT X11_FOUND)
 501         message(FATAL_ERROR
 502                 "X11 include files and/or libraries were not found. "
 503                 "Set GMX_X11=OFF to compile without X11 support. "
 504                 "gmx view will not be available.")
 505     endif()
 506     include_directories(${X11_INCLUDE_DIR})
 507 endif()
 508
 509 include(ThreadMPI)
 510 # Enable core threading facilities
 511 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 512 # Enable tMPI C++ support
 513 tmpi_enable_cxx()
 514 if(GMX_THREAD_MPI)
 515     # enable MPI functions
 516     tmpi_enable()
 517     set(GMX_MPI 1)
 518     set(MPI_IN_PLACE_EXISTS 1)
 519 endif()
 520 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 521 if (TMPI_ATOMICS_DISABLED)
 522    add_definitions(-DTMPI_ATOMICS_DISABLED)
 523 endif()
 524
 525 if(GMX_GPU)
 526     # now that we have detected the dependencies, do the second configure pass
 527     gmx_gpu_setup()
 528 endif()
 529
 530 if(CYGWIN)
 531     set(GMX_CYGWIN 1)
 532 endif()
 533
 534 if(WIN32 AND NOT CYGWIN)
 535     set(GMX_NATIVE_WINDOWS 1)
 536     # This makes windows.h not declare min/max as macros that would break
 537     # C++ code using std::min/std::max.
 538     add_definitions(-DNOMINMAX)
 539 endif()
 540
 541 # only bother with finding git and using version.h if the source is a git repo
 542 if(GMX_GIT_VERSION_INFO)
 543     if (NOT SOURCE_IS_GIT_REPOSITORY)
 544         message(FATAL_ERROR
 545             "Cannot generate git version information from source tree not under git. "
 546             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 547     endif()
 548     # We need at least git v1.5.3 be able to parse git's date output. If not
 549     # found or the version is too small, we can't generate version information.
 550     find_package(Git)
 551
 552     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 553         message(FATAL_ERROR
 554             "No compatible git version found (>= 1.5.3 required). "
 555             "Won't be able to generate development version information. "
 556             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 557     endif()
 558 endif()
 559
 560 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 561 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 562 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 563     find_package(Boost 1.44.0)
 564     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 565         set(Boost_FOUND FALSE)
 566     endif()
 567     # Print the notification only on first run, when determining the default
 568     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 569         message("Boost >= 1.44 not found. Using minimal internal version. "
 570                 "This may cause trouble if you plan on compiling/linking other "
 571                 "software that uses Boost against Gromacs.")
 572     endif()
 573 endif()
 574 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 575        ${Boost_FOUND})
 576 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 577     message(FATAL_ERROR
 578         "Boost >= 1.44 not found. "
 579         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 580         "version of Boost included with Gromacs.")
 581 endif()
 582
 583 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 584     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 585 endif()
 586 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 587 mark_as_advanced(GMX_BUILD_UNITTESTS)
 588 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 589 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 590     message(FATAL_ERROR
 591         "Cannot build unit tests without libxml2. "
 592         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 593 endif()
 594
 595 ########################################################################
 596 # Generate development version info for cache
 597 ########################################################################
 598 # set(GEN_VERSION_INFO_INTERNAL "ON")
 599 # include(gmxGenerateVersionString)
 600
 601 ########################################################################
 602 # Our own GROMACS tests
 603 ########################################################################
 604
 605 add_definitions( -DHAVE_CONFIG_H )
 606 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 607 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 608 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 609 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 610 # Required for gmx_header_config_gen.h to be found before installation
 611 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 612 # Required for now to make old code compile
 613 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 614
 615 include(gmxTestInlineASM)
 616 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 617
 618 include(gmxSetBuildInformation)
 619 gmx_set_build_information()
 620 # Turn on RDTSCP if:
 621 # - the build system's CPU supports it
 622 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 623 #   at this point means that the user set it).
 624 # Note: it's better to not use the later set value of GMX_SIMD because
 625 # it reflects the system's capability of both compiling and running AVX code.
 626 # TODO: After merge with 5.0 one could implement a cache variable dependency
 627 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 628 # after the first cmake pass.
 629 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 630     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 631 else()
 632     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 633 endif()
 634 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 635 mark_as_advanced(GMX_USE_RDTSCP)
 636 if(GMX_USE_RDTSCP)
 637     set(HAVE_RDTSCP 1)
 638 endif()
 639
 640 include(gmxTestFloatFormat)
 641 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 642                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 643                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 644
 645 include(gmxTestLargeFiles)
 646 gmx_test_large_files(GMX_LARGEFILES)
 647
 648 include(gmxTestSignal)
 649 gmx_test_sigusr1(HAVE_SIGUSR1)
 650
 651 include(gmxTestPipes)
 652 gmx_test_pipes(HAVE_PIPES)
 653
 654 include(gmxTestIsfinite)
 655 gmx_test_isfinite(HAVE_ISFINITE)
 656 gmx_test__isfinite(HAVE__ISFINITE)
 657 gmx_test__finite(HAVE__FINITE)
 658
 659 include(gmxTestCXX11)
 660 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 661 include(CMakeDependentOption)
 662 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 663 # entirely to keep the compilation environment uniform.
 664 cmake_dependent_option(GMX_CXX11
 665     "Use C++11 features"
 666     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 667 mark_as_advanced(GMX_CXX11)
 668 if(GMX_CXX11)
 669     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 670 endif()
 671
 672
 673 include(gmxTestXDR)
 674 gmx_test_xdr(GMX_SYSTEM_XDR)
 675 if(NOT GMX_SYSTEM_XDR)
 676     set(GMX_INTERNAL_XDR 1)
 677 endif()
 678
 679
 680 ##################################################
 681 # Process SIMD instruction settings
 682 ##################################################
 683 # This checks what flags to add in order to
 684 # support the SIMD instructions we need, and sets
 685 # correct defines for the SIMD instructions supported.
 686 include(gmxTestSimd)
 687 gmx_test_simd()
 688
 689
 690 # Process QM/MM Settings
 691 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 692     set(GMX_QMMM_GAUSSIAN 1)
 693 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 694     set(GMX_QMMM_MOPAC 1)
 695 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 696     set(GMX_QMMM_GAMESS 1)
 697 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 698     set(GMX_QMMM_ORCA 1)
 699 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 700     # nothing to do
 701 else()
 702     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 703 endif()
 704
 705
 706 ##################################################
 707 # Process FFT library settings
 708 ##################################################
 709 include(gmxManageFFTLibraries)
 710
 711
 712 include(gmxManageLinearAlgebraLibraries)
 713
 714 # Whether GROMACS will really try to compile support for VMD plugins
 715 set(GMX_USE_PLUGINS OFF)
 716
 717 if(GMX_LOAD_PLUGINS)
 718   if(CYGWIN OR NOT WIN32)
 719     # Native Windows does not have, nor need dlopen
 720     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 721     include(gmxTestdlopen)
 722     gmx_test_dlopen(HAVE_DLOPEN)
 723   endif()
 724
 725   # so, should we use plug-ins?
 726   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 727     if(NOT VMD_QUIETLY)
 728       MESSAGE(STATUS
 729           "Found the ability to use plug-ins when building shared libaries, "
 730           "so will compile to use plug-ins (e.g. to read VMD-supported file "
 731           "formats).")
 732     endif()
 733     if(NOT GMX_VMD_PLUGIN_PATH)
 734       find_package(VMD)
 735     endif()
 736     set(GMX_USE_PLUGINS ON)
 737     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 738     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 739   else()
 740     set(PKG_DL_LIBS)
 741   endif()
 742 endif()
 743 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 744
 745 # Link real-time library for POSIX timers. The check for clock_gettime
 746 # confirms the linkability of rt.
 747 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 748     list(APPEND GMX_EXTRA_LIBRARIES rt)
 749 endif()
 750
 751 # Math and thread libraries must often come after all others when linking...
 752 if(HAVE_LIBM)
 753     list(APPEND GMX_EXTRA_LIBRARIES m)
 754 endif()
 755
 756 option(GMX_NACL "Configure for Native Client builds" OFF)
 757 if (GMX_NACL)
 758   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 759   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 760   set(GMX_NO_NICE 1)
 761   set(GMX_NO_RENAME 1)
 762 endif()
 763 mark_as_advanced(GMX_NACL)
 764
 765 if(GMX_FAHCORE)
 766   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 767       "Path to swindirect.h")
 768   include_directories(${COREWRAP_INCLUDE_DIR})
 769 endif()
 770
 771 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 772 mark_as_advanced(GMX_BUILD_HELP)
 773 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 774     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 775
 776     message(FATAL_ERROR
 777         "Rebuilding HTML and man pages is not supported for in-source "
 778         "builds from a source distribution. "
 779         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 780 endif()
 781
 782 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 783 # these are set after everything else
 784 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 785     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 786     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 787     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 788     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 789 else()
 790     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 791     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 792     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 793     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 794     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 795     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 796     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 797     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 798     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 799 endif()
 800
 801 if(NOT GMX_OPENMP)
 802     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 803     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 804     unset(OpenMP_C_FLAGS CACHE)
 805     unset(OpenMP_CXX_FLAGS CACHE)
 806 else()
 807     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 808     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 809 endif()
 810 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 811
 812 ########################################################################
 813 # Specify install locations
 814 ########################################################################
 815 # Use GNUInstallDirs to set paths on multiarch systems.
 816 include(GNUInstallDirs)
 817
 818 # Customization for the installation tree paths.
 819 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 820     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 821 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 822     "Data installation directory under share/ (default: gromacs)")
 823 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 824
 825 # These variables are used internally to provide a central location for
 826 # customizing the install locations.
 827 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 828 set(BIN_INSTALL_DIR  bin)
 829 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 830 set(MAN_INSTALL_DIR  share/man)
 831 set(INCL_INSTALL_DIR include)
 832
 833 # These variables get written into config.h for use in finding the data
 834 # directories.
 835 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 836 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 837
 838 # Binary and library suffix options
 839 include(gmxManageSuffixes)
 840
 841 ################################################################
 842 # Shared library load path settings
 843 ################################################################
 844 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 845 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 846 # was added.
 847 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 848    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 849     # The build folder always has bin/ and lib/; if we are also going to
 850     # install to lib/, then the installation RPATH works also in the build
 851     # tree.  This makes installation slightly faster (no need to rewrite the
 852     # RPATHs), and makes the binaries in the build tree relocatable.
 853     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 854         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 855     endif()
 856     # Set the RPATH as relative to the executable location to make the
 857     # binaries relocatable.
 858     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 859         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 860     else()
 861         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 862     endif()
 863     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 864     set(CMAKE_MACOSX_RPATH 1)
 865 else()
 866     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 867     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 868         # Set the RPATH options manually.
 869         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 870         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 871     else()
 872         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 873         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 874     endif()
 875 endif()
 876
 877 #COPYING file: Only necessary for binary distributions.
 878 #Simpler to always install.
 879 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 880
 881 if(GMX_EXTERNAL_BOOST)
 882     include_directories(${Boost_INCLUDE_DIRS})
 883     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 884 else()
 885     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 886     # typeid not supported for minimal internal version
 887     # (would add significant amount of code)
 888     add_definitions(-DBOOST_NO_TYPEID)
 889     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 890     # (from share/template/)
 891     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 892     if (NOT GMX_BUILD_MDRUN_ONLY)
 893         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 894                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 895                 COMPONENT development)
 896     endif()
 897 endif()
 898
 899 if (GMX_BUILD_FOR_COVERAGE)
 900     # Code heavy with asserts makes conditional coverage close to useless metric,
 901     # as by design most of the false branches are impossible to trigger in
 902     # correctly functioning code.  And the benefit of testing those that could
 903     # be triggered by using an API against its specification isn't usually
 904     # worth the effort.
 905     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 906 endif()
 907
 908 if (BUILD_TESTING)
 909     # "tests" target builds all the separate test binaries.
 910     add_custom_target(tests)
 911     # "run-ctest" is an internal target that actually runs the tests.
 912     # This is necessary to be able to add separate targets that execute as part
 913     # of 'make check', but are ensured to be executed after the actual tests.
 914     add_custom_target(run-ctest
 915                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 916                       COMMENT "Running all tests"
 917                       VERBATIM)
 918     add_dependencies(run-ctest tests)
 919     # "check" target builds and runs all tests.
 920     add_custom_target(check DEPENDS run-ctest)
 921 endif()
 922
 923 if (NOT GMX_BUILD_MDRUN_ONLY)
 924     add_subdirectory(doxygen)
 925     add_subdirectory(install-guide)
 926     add_subdirectory(share)
 927     add_subdirectory(scripts)
 928 endif()
 929 add_subdirectory(src)
 930
 931 if (BUILD_TESTING)
 932     add_subdirectory(tests)
 933 endif()
 934
 935 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 936 # Don't bother the user after the first configure pass.
 937 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 938     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 939 endif()
 940 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 941
 942 #######################
 943 ## uninstall target
 944 #######################
 945 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 946                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 947                   IMMEDIATE @ONLY)
 948 ###########################
 949 ADD_CUSTOM_TARGET(uninstall
 950                   "${CMAKE_COMMAND}" -P
 951                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 952 ###########################
 953 set_directory_properties(PROPERTIES
 954             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")
 955
 956 ########################################################################
 957 # Manual                                                               #
 958 ########################################################################
 959
 960 option(GMX_BUILD_MANUAL "Whether to try to configure to build the PDF manual" OFF)
 961 mark_as_advanced(GMX_BUILD_MANUAL)
 962 if(GMX_BUILD_MANUAL)
 963     # Make sure we only do detection of manual-building dependencies
 964     # when the user opted in for that.
 965     add_subdirectory(manual)
 966 endif()