CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.5-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.5-dev")
  67 # The MD5 checksum of the regressiontest tarball. Only used if "-dev"
  68 # is not present in the PROJECT_VERSION
  69 set(REGRESSIONTEST_MD5SUM "81e8ff1600495ce2a57706dca9d73482")
  70 # If this is not a released tarball, "-dev" will be present in
  71 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  72 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  73 # code contains all recent fixes from the corresponding code branch.
  74 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  75
  76 set(CUSTOM_VERSION_STRING ""
  77     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  78 mark_as_advanced(CUSTOM_VERSION_STRING)
  79 if (CUSTOM_VERSION_STRING)
  80     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  81 endif()
  82 set(LIBRARY_SOVERSION 0)
  83 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  84 # It is a bit irritating, but this has to be set separately for now!
  85 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  86 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  87 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  88
  89 # The numerical gromacs version. It is 40600 for 4.6.0.
  90 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  91 math(EXPR NUM_VERSION
  92     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  93 if(CPACK_PACKAGE_VERSION_PATCH)
  94     math(EXPR NUM_VERSION
  95          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  96 endif()
  97
  98 # The API version tracks the numerical Gromacs version (for now).
  99 # It is potentially different from the Gromacs version in the future, if
 100 # the programs/libraries diverge from the presumably more stable API.
 101 # The #define GMX_API_VERSION in version.h is set to this value to
 102 # provide backward compatibility of software written against the Gromacs API.
 103 set(API_VERSION ${NUM_VERSION})
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 106     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 107 endif()
 108
 109 include(gmxBuildTypeReference)
 110 include(gmxBuildTypeTSAN)
 111 include(gmxBuildTypeASAN)
 112 include(gmxBuildTypeReleaseWithAssert)
 113
 114 if(NOT CMAKE_BUILD_TYPE)
 115     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 116     # There's no need to offer a user the choice of ThreadSanitizer
 117     # Set the possible values of build type for cmake-gui
 118     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 119         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 120 endif()
 121 if(CMAKE_CONFIGURATION_TYPES)
 122     # Add appropriate GROMACS-specific build types for the Visual
 123     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 124     # are already present by default).
 125     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 126     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 127     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 128         "List of configuration types"
 129         FORCE)
 130 endif()
 131 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL)
 132
 133 enable_language(C)
 134 enable_language(CXX)
 135 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 136
 137 set(CPACK_PACKAGE_NAME "gromacs")
 138 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 139 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 140 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 141 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 142 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 143 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 144 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 145 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 146 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 147 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 148 # CPack source archives include only the directories we list here.
 149 # This variable is a list of pairs of names of source and destination
 150 # directories. Most of these are used for content GROMACS generates as
 151 # part of the configuration or build.
 152 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/docs/man/man1;docs/man/man1;${CMAKE_BINARY_DIR}/docs/man/man7;docs/man/man7;${CMAKE_BINARY_DIR}/docs/old-html/final;docs/old-html/final;${CMAKE_BINARY_DIR}/docs/install-guide/final;/")
 153 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 154 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 155
 156 #must come after all cpack settings!
 157 include(CPack)
 158
 159 # Set a default valgrind suppression file.
 160 # This unfortunately needs to duplicate information from CTest to work as
 161 # expected...
 162 set(MEMORYCHECK_SUPPRESSIONS_FILE
 163     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 164     CACHE FILEPATH
 165     "File that contains suppressions for the memory checker")
 166 include(CTest)
 167
 168 set(SOURCE_IS_GIT_REPOSITORY OFF)
 169 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 170 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 171     set(SOURCE_IS_GIT_REPOSITORY ON)
 172 endif()
 173 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 174     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 175 endif()
 176
 177 ########################################################################
 178 # Check and warn if cache generated on a different host is being reused
 179 ########################################################################
 180 if(CMAKE_HOST_UNIX)
 181     execute_process(COMMAND hostname
 182                     OUTPUT_VARIABLE TMP_HOSTNAME
 183                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 184     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 185         message(WARNING "
 186             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 187             is being reused! This could lead to inconsistencies; therefore, it is
 188             recommended to regenerate the cache!")
 189     endif()
 190     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 191             "Hostname of the machine where the cache was generated.")
 192 endif()
 193
 194 ########################################################################
 195 # Detect architecture before setting options so we can alter defaults
 196 ########################################################################
 197 # Detect the architecture the compiler is targetting, detect
 198 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 199 # to use if none is specified, and populate the cache option for CPU
 200 # SIMD.
 201 include(gmxDetectTargetArchitecture)
 202 gmx_detect_target_architecture()
 203
 204 ########################################################################
 205 # User input options                                                   #
 206 ########################################################################
 207 include(gmxOptionUtilities)
 208
 209 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 210
 211 if(GMX_TARGET_FUJITSU_SPARC64)
 212     # Fujitsu only has SIMD in double precision, so this will be faster
 213     set(GMX_DOUBLE_DEFAULT ON)
 214 else()
 215     set(GMX_DOUBLE_DEFAULT OFF)
 216 endif()
 217 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 218 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 219 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 220
 221 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 222 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 223 gmx_dependent_option(
 224     GMX_MPI_IN_PLACE
 225     "Enable MPI_IN_PLACE for MPIs that have it defined"
 226     ON
 227     GMX_MPI)
 228 mark_as_advanced(GMX_MPI_IN_PLACE)
 229 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 230 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 231 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 232 mark_as_advanced(GMX_FAHCORE)
 233
 234 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 235 mark_as_advanced(GMX_COOL_QUOTES)
 236 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 237
 238 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 239 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 240 if(MSVC)
 241     set(REQUIRED_CUDA_VERSION 4.1)
 242 else()
 243     set(REQUIRED_CUDA_VERSION 4.0)
 244 endif()
 245 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 246 include(gmxManageGPU)
 247
 248 if(GMX_CPU_ACCELERATION)
 249     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 250     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 251     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 252     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 253 endif()
 254
 255 if(NOT GMX_TARGET_MIC)
 256     include(gmxDetectSimd)
 257     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 258 else()
 259     set(GMX_SUGGESTED_SIMD "None")
 260 endif()
 261
 262 gmx_option_multichoice(
 263     GMX_SIMD
 264     "SIMD instruction set for CPU kernels and compiler optimization"
 265     "${GMX_SUGGESTED_SIMD}"
 266     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 267
 268 gmx_option_multichoice(
 269     GMX_FFT_LIBRARY
 270     "FFT library"
 271     "fftw3"
 272     fftw3 mkl "fftpack[built-in]")
 273 gmx_dependent_option(
 274     GMX_BUILD_OWN_FFTW
 275     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 276     OFF
 277     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 278 gmx_dependent_option(
 279     GMX_DISABLE_FFTW_MEASURE
 280     "Do not optimize FFTW setups (not needed with SSE)"
 281     OFF
 282     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 283 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 284 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 285
 286 gmx_option_multichoice(
 287     GMX_QMMM_PROGRAM
 288     "QM package for QM/MM"
 289     None
 290     none gaussian mopac gamess orca)
 291
 292 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 293 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 294
 295 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 296
 297 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 298 mark_as_advanced(GMX_BROKEN_CALLOC)
 299 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 300 mark_as_advanced(GMX_LOAD_PLUGINS)
 301
 302 option(GMX_GPU  "Enable GPU acceleration" ON)
 303 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 304
 305 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 306
 307 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 308 mark_as_advanced(GMX_GIT_VERSION_INFO)
 309
 310 if(UNIX)
 311     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 312 endif()
 313 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 314
 315 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 316 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 317
 318 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 319 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 320
 321 option(GMX_BUILD_FOR_COVERAGE
 322        "Tune build for better code coverage metrics (e.g., disable asserts)"
 323        OFF)
 324 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 325
 326 option(GMX_DEVELOPER_BUILD
 327     "Enable Developer convenience features: always build unit-tests"
 328     OFF)
 329 mark_as_advanced(GMX_DEVELOPER_BUILD)
 330
 331 ######################################################################
 332 # Detect OpenMP support
 333 ######################################################################
 334 # The OpenMP detection _must_ come before tests for other CFLAGS.
 335 include(gmxManageOpenMP)
 336
 337
 338
 339 ######################################################################
 340 # Compiler tests
 341 # These need to be done early (before further tests).
 342 #####################################################################
 343
 344 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 345 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 346 # invalid options with the Intel Compilers, and we have added a line
 347 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 348 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 349 # a semicolon. Since this is also used as a separator in lists inside CMake,
 350 # that string ends up being split into two separate patterns, and the last
 351 # part is just a single word that also matches other messages. We solved this
 352 # by replacing the semicolon with a period that matches any character.
 353 #
 354 # These files should be removed from the source tree when a CMake version that
 355 # includes the features in question becomes required for building GROMACS.
 356 include(CheckCCompilerFlag)
 357 include(CheckCXXCompilerFlag)
 358
 359 include(gmxCFlags)
 360 gmx_c_flags()
 361
 362 # This variable should be used for additional compiler flags which are not
 363 # generated in gmxCFlags nor are SIMD or MPI related.
 364 set(EXTRA_C_FLAGS "")
 365 set(EXTRA_CXX_FLAGS "")
 366
 367 # Run through a number of tests for buggy compilers and other issues
 368 include(gmxTestCompilerProblems)
 369 gmx_test_compiler_problems()
 370 # GMX_SIMD will not be set automatically until the second
 371 # pass (which is not strictly guaranteed to occur), so putting this
 372 # check here among logically-related tests is inefficient, but the
 373 # potential loss is likely zero.
 374 if(GMX_SIMD STREQUAL "AVX_256"
 375         AND CMAKE_COMPILER_IS_GNUCC
 376         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 377             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 378     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 379     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 380 endif()
 381
 382
 383
 384 set(PKG_CFLAGS "")
 385 if(GMX_DOUBLE)
 386     add_definitions(-DGMX_DOUBLE)
 387     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 388     if(GMX_RELAXED_DOUBLE_PRECISION)
 389         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 390     endif()
 391 endif()
 392 if(GMX_SOFTWARE_INVSQRT)
 393   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 394 endif()
 395
 396 if(WIN32 AND NOT CYGWIN)
 397     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 398     add_definitions(-DGMX_HAVE_WINSOCK)
 399 endif()
 400
 401
 402
 403 ########################################################################
 404 # Basic system tests (standard libraries, headers, functions, types)   #
 405 ########################################################################
 406 include(CheckIncludeFiles)
 407 include(CheckIncludeFileCXX)
 408 check_include_files(unistd.h     HAVE_UNISTD_H)
 409 check_include_files(pwd.h        HAVE_PWD_H)
 410 check_include_files(dirent.h     HAVE_DIRENT_H)
 411 check_include_files(time.h       HAVE_TIME_H)
 412 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 413 check_include_files(io.h         HAVE_IO_H)
 414 check_include_files(sched.h      HAVE_SCHED_H)
 415
 416 check_include_files(regex.h      HAVE_POSIX_REGEX)
 417 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 418 # TODO: It could be nice to inform the user if no regex support is found,
 419 # as selections won't be fully functional.
 420
 421 include(CheckFunctionExists)
 422 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 423 check_function_exists(memalign          HAVE_MEMALIGN)
 424 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 425 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 426 check_function_exists(fsync             HAVE_FSYNC)
 427 check_function_exists(_fileno           HAVE__FILENO)
 428 check_function_exists(fileno            HAVE_FILENO)
 429 check_function_exists(_commit           HAVE__COMMIT)
 430 check_function_exists(sigaction         HAVE_SIGACTION)
 431 check_function_exists(sysconf           HAVE_SYSCONF)
 432 check_function_exists(rsqrt             HAVE_RSQRT)
 433 check_function_exists(rsqrtf            HAVE_RSQRTF)
 434 check_function_exists(sqrtf             HAVE_SQRTF)
 435
 436 include(CheckLibraryExists)
 437 check_library_exists(m sqrt "" HAVE_LIBM)
 438 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 439
 440 include(TestSchedAffinity)
 441 test_sched_affinity(HAVE_SCHED_AFFINITY)
 442
 443 include(TestBigEndian)
 444 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 445
 446 # Management of GROMACS options for specific toolchains should go
 447 # here. Because the initial settings for some of the main options have
 448 # already happened, but things like library detection and MPI compiler
 449 # feature detection have not, the docstrings for any over-rides of
 450 # GROMACS defaults or user settings will make sense. Also, any
 451 # toolchain-related reasons for choosing whether to detect various
 452 # things can be sorted out now, before the detection takes place.
 453 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 454     include(gmxManageBlueGene)
 455 endif()
 456
 457 if(GMX_TARGET_FUJITSU_SPARC64)
 458     include(gmxManageFujitsuSparc64)
 459 endif()
 460
 461 ########################################################################
 462 #Process MPI settings
 463 ########################################################################
 464 include(gmxManageMPI)
 465
 466
 467 ########################################################################
 468 #Process shared/static library settings
 469 ########################################################################
 470 include(gmxManageSharedLibraries)
 471
 472
 473 ########################################################################
 474 # Find external packages                                               #
 475 ########################################################################
 476
 477 # Unconditionally find the package, as it is also required for unit
 478 # tests. This exports LIBXML2_FOUND, which we should not use because
 479 # it does not tell us that linking will succeed. Instead, we test that
 480 # next.
 481 if(DEFINED LIBXML2_LIBRARIES)
 482   set(LibXml2_FIND_QUIETLY TRUE)
 483 endif()
 484 find_package(LibXml2)
 485 include(gmxTestLibXml2)
 486 gmx_test_libxml2(HAVE_LIBXML2)
 487 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 488 set(PKG_XML "")
 489 mark_as_advanced(GMX_XML)
 490 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 491 #if(GMX_XML AND NOT HAVE_LIBXML2)
 492 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 493 #endif()
 494 #if(GMX_XML)
 495 #    include_directories(${LIBXML2_INCLUDE_DIR})
 496 #    set(PKG_XML libxml-2.0)
 497 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 498 #endif()
 499
 500 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 501 mark_as_advanced(GMX_EXTRAE)
 502
 503 if (GMX_EXTRAE)
 504   find_package(EXTRAE)
 505   if(EXTRAE_FOUND)
 506     include_directories(${EXTRAE_INCLUDE_DIR})
 507     set(HAVE_EXTRAE 1)
 508   else()
 509     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 510   endif()
 511 endif()
 512
 513 option(GMX_X11 "Use X window system" OFF)
 514 if (GMX_X11)
 515     find_package(X11)
 516     # X11 includes/libraries are only set in the ngmx subdirectory!
 517     if(NOT X11_FOUND)
 518         message(FATAL_ERROR
 519                 "X11 include files and/or libraries were not found. "
 520                 "Set GMX_X11=OFF to compile without X11 support. "
 521                 "gmx view will not be available.")
 522     endif()
 523     include_directories(${X11_INCLUDE_DIR})
 524 endif()
 525
 526 include(ThreadMPI)
 527 # Enable core threading facilities
 528 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 529 # Enable tMPI C++ support
 530 tmpi_enable_cxx()
 531 if(GMX_THREAD_MPI)
 532     # enable MPI functions
 533     tmpi_enable()
 534     set(GMX_MPI 1)
 535     set(MPI_IN_PLACE_EXISTS 1)
 536 endif()
 537 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 538 if (TMPI_ATOMICS_DISABLED)
 539    add_definitions(-DTMPI_ATOMICS_DISABLED)
 540 endif()
 541
 542 if(GMX_GPU)
 543     # now that we have detected the dependencies, do the second configure pass
 544     gmx_gpu_setup()
 545 endif()
 546
 547 if(CYGWIN)
 548     set(GMX_CYGWIN 1)
 549 endif()
 550
 551 if(WIN32 AND NOT CYGWIN)
 552     set(GMX_NATIVE_WINDOWS 1)
 553     # This makes windows.h not declare min/max as macros that would break
 554     # C++ code using std::min/std::max.
 555     add_definitions(-DNOMINMAX)
 556 endif()
 557
 558 # only bother with finding git and using version.h if the source is a git repo
 559 if(GMX_GIT_VERSION_INFO)
 560     if (NOT SOURCE_IS_GIT_REPOSITORY)
 561         message(FATAL_ERROR
 562             "Cannot generate git version information from source tree not under git. "
 563             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 564     endif()
 565     # We need at least git v1.5.3 be able to parse git's date output. If not
 566     # found or the version is too small, we can't generate version information.
 567     find_package(Git)
 568
 569     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 570         message(FATAL_ERROR
 571             "No compatible git version found (>= 1.5.3 required). "
 572             "Won't be able to generate development version information. "
 573             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 574     endif()
 575 endif()
 576
 577 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 578 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 579 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 580     find_package(Boost 1.44.0)
 581     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 582         set(Boost_FOUND FALSE)
 583     endif()
 584     # Print the notification only on first run, when determining the default
 585     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 586         message("Boost >= 1.44 not found. Using minimal internal version. "
 587                 "This may cause trouble if you plan on compiling/linking other "
 588                 "software that uses Boost against Gromacs.")
 589     endif()
 590 endif()
 591 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 592        ${Boost_FOUND})
 593 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 594     message(FATAL_ERROR
 595         "Boost >= 1.44 not found. "
 596         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 597         "version of Boost included with Gromacs.")
 598 endif()
 599
 600 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 601     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 602 endif()
 603 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 604 mark_as_advanced(GMX_BUILD_UNITTESTS)
 605 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 606 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 607     message(FATAL_ERROR
 608         "Cannot build unit tests without libxml2. "
 609         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 610 endif()
 611
 612 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 613     # TNG wants zlib if it is available
 614     find_package(ZLIB QUIET)
 615     include(gmxTestZLib)
 616     gmx_test_zlib(HAVE_ZLIB)
 617 endif()
 618
 619 ########################################################################
 620 # Generate development version info for cache
 621 ########################################################################
 622 # set(GEN_VERSION_INFO_INTERNAL "ON")
 623 # include(gmxGenerateVersionString)
 624
 625 ########################################################################
 626 # Our own GROMACS tests
 627 ########################################################################
 628
 629 add_definitions( -DHAVE_CONFIG_H )
 630 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 631 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 632 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 633 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 634 # Required for gmx_header_config_gen.h to be found before installation
 635 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 636 # Required for now to make old code compile
 637 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 638
 639 include(gmxTestInlineASM)
 640 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 641
 642 include(gmxSetBuildInformation)
 643 gmx_set_build_information()
 644 # Turn on RDTSCP if:
 645 # - the build system's CPU supports it
 646 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 647 #   at this point means that the user set it).
 648 # Note: it's better to not use the later set value of GMX_SIMD because
 649 # it reflects the system's capability of both compiling and running AVX code.
 650 # TODO: After merge with 5.0 one could implement a cache variable dependency
 651 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 652 # after the first cmake pass.
 653 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 654     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 655 else()
 656     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 657 endif()
 658 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 659 mark_as_advanced(GMX_USE_RDTSCP)
 660 if(GMX_USE_RDTSCP)
 661     set(HAVE_RDTSCP 1)
 662 endif()
 663
 664 include(gmxTestFloatFormat)
 665 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 666                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 667                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 668
 669 include(gmxTestLargeFiles)
 670 gmx_test_large_files(GMX_LARGEFILES)
 671
 672 include(gmxTestSignal)
 673 gmx_test_sigusr1(HAVE_SIGUSR1)
 674
 675 include(gmxTestPipes)
 676 gmx_test_pipes(HAVE_PIPES)
 677
 678 include(gmxTestIsfinite)
 679 gmx_test_isfinite(HAVE_ISFINITE)
 680 gmx_test__isfinite(HAVE__ISFINITE)
 681 gmx_test__finite(HAVE__FINITE)
 682
 683 include(gmxTestCXX11)
 684 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 685 include(CMakeDependentOption)
 686 # clang with some older versions of boost fail to work with C++11
 687 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 688     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 689     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 690 endif()
 691 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 692 # entirely to keep the compilation environment uniform.
 693 cmake_dependent_option(GMX_CXX11
 694     "Use C++11 features"
 695     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 696 mark_as_advanced(GMX_CXX11)
 697 if(GMX_CXX11)
 698     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 699 endif()
 700
 701
 702 include(gmxTestXDR)
 703 gmx_test_xdr(GMX_SYSTEM_XDR)
 704 if(NOT GMX_SYSTEM_XDR)
 705     set(GMX_INTERNAL_XDR 1)
 706 endif()
 707
 708
 709 ##################################################
 710 # Process SIMD instruction settings
 711 ##################################################
 712 # This checks what flags to add in order to
 713 # support the SIMD instructions we need, and sets
 714 # correct defines for the SIMD instructions supported.
 715 include(gmxTestSimd)
 716 gmx_test_simd()
 717
 718
 719 # Process QM/MM Settings
 720 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 721     set(GMX_QMMM_GAUSSIAN 1)
 722 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 723     set(GMX_QMMM_MOPAC 1)
 724 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 725     set(GMX_QMMM_GAMESS 1)
 726 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 727     set(GMX_QMMM_ORCA 1)
 728 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 729     # nothing to do
 730 else()
 731     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 732 endif()
 733
 734
 735 ##################################################
 736 # Process FFT library settings
 737 ##################################################
 738 include(gmxManageFFTLibraries)
 739
 740
 741 include(gmxManageLinearAlgebraLibraries)
 742
 743 # Whether GROMACS will really try to compile support for VMD plugins
 744 set(GMX_USE_PLUGINS OFF)
 745
 746 if(GMX_LOAD_PLUGINS)
 747   if(CYGWIN OR NOT WIN32)
 748     # Native Windows does not have, nor need dlopen
 749     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 750     include(gmxTestdlopen)
 751     gmx_test_dlopen(HAVE_DLOPEN)
 752   endif()
 753
 754   # so, should we use plug-ins?
 755   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 756     if(NOT VMD_QUIETLY)
 757       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 758     endif()
 759     if(NOT GMX_VMD_PLUGIN_PATH)
 760       find_package(VMD)
 761     endif()
 762     set(GMX_USE_PLUGINS ON)
 763     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 764     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 765   else()
 766     set(PKG_DL_LIBS)
 767   endif()
 768 endif()
 769 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 770
 771 # Link real-time library for POSIX timers. The check for clock_gettime
 772 # confirms the linkability of rt.
 773 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 774     list(APPEND GMX_EXTRA_LIBRARIES rt)
 775 endif()
 776
 777 # Math and thread libraries must often come after all others when linking...
 778 if(HAVE_LIBM)
 779     list(APPEND GMX_EXTRA_LIBRARIES m)
 780 endif()
 781
 782 option(GMX_NACL "Configure for Native Client builds" OFF)
 783 if (GMX_NACL)
 784   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 785   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 786   set(GMX_NO_NICE 1)
 787   set(GMX_NO_RENAME 1)
 788 endif()
 789 mark_as_advanced(GMX_NACL)
 790
 791 if(GMX_FAHCORE)
 792   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 793       "Path to swindirect.h")
 794   include_directories(${COREWRAP_INCLUDE_DIR})
 795 endif()
 796
 797 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 798 mark_as_advanced(GMX_BUILD_HELP)
 799 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 800     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 801
 802     message(FATAL_ERROR
 803         "Rebuilding HTML and man pages is not supported for in-source "
 804         "builds from a source distribution. "
 805         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 806 endif()
 807
 808 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 809 # these are set after everything else
 810 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 811     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 812     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 813     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 814     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 815 else()
 816     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 817     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 818     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 819     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 820     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 821     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 822     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 823     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 824     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 825 endif()
 826
 827 if(NOT GMX_OPENMP)
 828     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 829     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 830     unset(OpenMP_C_FLAGS CACHE)
 831     unset(OpenMP_CXX_FLAGS CACHE)
 832 else()
 833     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 834     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 835 endif()
 836 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 837
 838 ########################################################################
 839 # Specify install locations
 840 ########################################################################
 841 # Use GNUInstallDirs to set paths on multiarch systems.
 842 include(GNUInstallDirs)
 843
 844 # Customization for the installation tree paths.
 845 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 846     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 847 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 848     "Data installation directory under share/ (default: gromacs)")
 849 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 850
 851 # These variables are used internally to provide a central location for
 852 # customizing the install locations.
 853 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 854 set(BIN_INSTALL_DIR  bin)
 855 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 856 set(MAN_INSTALL_DIR  share/man)
 857 set(INCL_INSTALL_DIR include)
 858
 859 # These variables get written into config.h for use in finding the data
 860 # directories.
 861 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 862 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 863
 864 # Binary and library suffix options
 865 include(gmxManageSuffixes)
 866
 867 ################################################################
 868 # Shared library load path settings
 869 ################################################################
 870 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 871 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 872 # was added.
 873 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 874    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 875     # The build folder always has bin/ and lib/; if we are also going to
 876     # install to lib/, then the installation RPATH works also in the build
 877     # tree.  This makes installation slightly faster (no need to rewrite the
 878     # RPATHs), and makes the binaries in the build tree relocatable.
 879     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 880         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 881     endif()
 882     # Set the RPATH as relative to the executable location to make the
 883     # binaries relocatable.
 884     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 885         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 886     else()
 887         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 888     endif()
 889     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 890     set(CMAKE_MACOSX_RPATH 1)
 891 else()
 892     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 893     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 894         # Set the RPATH options manually.
 895         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 896         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 897     else()
 898         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 899         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 900     endif()
 901 endif()
 902
 903 #COPYING file: Only necessary for binary distributions.
 904 #Simpler to always install.
 905 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 906
 907 if(GMX_EXTERNAL_BOOST)
 908     include_directories(${Boost_INCLUDE_DIRS})
 909     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 910 else()
 911     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 912     # typeid not supported for minimal internal version
 913     # (would add significant amount of code)
 914     add_definitions(-DBOOST_NO_TYPEID)
 915     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 916     # (from share/template/)
 917     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 918     if (NOT GMX_BUILD_MDRUN_ONLY)
 919         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 920                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 921                 COMPONENT development)
 922     endif()
 923 endif()
 924
 925 if (GMX_BUILD_FOR_COVERAGE)
 926     # Code heavy with asserts makes conditional coverage close to useless metric,
 927     # as by design most of the false branches are impossible to trigger in
 928     # correctly functioning code.  And the benefit of testing those that could
 929     # be triggered by using an API against its specification isn't usually
 930     # worth the effort.
 931     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 932 endif()
 933
 934 if (BUILD_TESTING)
 935     # "tests" target builds all the separate test binaries.
 936     add_custom_target(tests)
 937     # "run-ctest" is an internal target that actually runs the tests.
 938     # This is necessary to be able to add separate targets that execute as part
 939     # of 'make check', but are ensured to be executed after the actual tests.
 940     add_custom_target(run-ctest
 941                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 942                       COMMENT "Running all tests"
 943                       VERBATIM)
 944     add_dependencies(run-ctest tests)
 945     # "check" target builds and runs all tests.
 946     add_custom_target(check DEPENDS run-ctest)
 947 endif()
 948
 949 if (NOT GMX_BUILD_MDRUN_ONLY)
 950     add_subdirectory(docs)
 951     add_subdirectory(share)
 952     add_subdirectory(scripts)
 953 endif()
 954 add_subdirectory(src)
 955
 956 if (BUILD_TESTING)
 957     add_subdirectory(tests)
 958 endif()
 959
 960 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 961 # Don't bother the user after the first configure pass.
 962 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 963     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 964 endif()
 965 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 966
 967 #######################
 968 ## uninstall target
 969 #######################
 970 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 971                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 972                   IMMEDIATE @ONLY)
 973 ###########################
 974 ADD_CUSTOM_TARGET(uninstall
 975                   "${CMAKE_COMMAND}" -P
 976                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 977 ###########################
 978 set_directory_properties(PROPERTIES
 979             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")