cmake/gmxManageSimd.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # include avx test source, used if the AVX flags are set below
  36 include(gmxTestAVXMaskload)
  37 include(gmxFindFlagsForSource)
  38
  39 # Macro that manages setting the respective C and C++ toolchain
  40 # variables so that subsequent tests for SIMD support can work.
  41 macro(prepare_x86_toolchain TOOLCHAIN_C_FLAGS_VARIABLE TOOLCHAIN_CXX_FLAGS_VARIABLE)
  42     # On OS X, we often want to use gcc instead of clang, since gcc
  43     # supports OpenMP (until clang 3.8, or so, plus whenever Apple
  44     # support it in their version). However, by default gcc uses the
  45     # external system assembler, which does not support AVX, so we
  46     # need to tell the linker to use the clang compilers assembler
  47     # instead - and this has to happen before we detect AVX flags.
  48     if(APPLE AND CMAKE_C_COMPILER_ID STREQUAL "GNU")
  49         gmx_test_cflag(GNU_C_USE_CLANG_AS "-Wa,-q" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  50     endif()
  51     if(APPLE AND CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  52         gmx_test_cxxflag(GNU_CXX_USE_CLANG_AS "-Wa,-q" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  53     endif()
  54 endmacro()
  55
  56 # Macro that manages setting the respective C and C++ toolchain
  57 # variables so that subsequent tests for SIMD support can work.
  58 macro(prepare_power_vsx_toolchain TOOLCHAIN_C_FLAGS_VARIABLE TOOLCHAIN_CXX_FLAGS_VARIABLE)
  59     if(${CMAKE_CXX_COMPILER_ID} MATCHES "GNU" OR ${CMAKE_C_COMPILER_ID} MATCHES "GNU")
  60         # VSX uses the same function API as Altivec/VMX, so make sure we tune for the current CPU and not VMX.
  61         # By putting these flags here rather than in the general compiler flags file we can safely assume
  62         # that we are at least on Power7 since that is when VSX appeared.
  63         if(BUILD_CPU_BRAND MATCHES "POWER7")
  64             gmx_test_cflag(GNU_C_VSX_POWER7   "-mcpu=power7 -mtune=power7" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  65             gmx_test_cflag(GNU_CXX_VSX_POWER7 "-mcpu=power7 -mtune=power7" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  66         else()
  67             # Enable power8 vector extensions on all platforms except old Power7.
  68             gmx_test_cflag(GNU_C_VSX_POWER8   "-mcpu=power8 -mpower8-vector -mpower8-fusion -mdirect-move" ${TOOLCHAIN_C_FLAGS_VARIABLE})
  69             gmx_test_cflag(GNU_CXX_VSX_POWER8 "-mcpu=power8 -mpower8-vector -mpower8-fusion -mdirect-move" ${TOOLCHAIN_CXX_FLAGS_VARIABLE})
  70         endif()
  71         # Altivec was originally single-only, and it took a while for compilers
  72         # to support the double-precision features in VSX.
  73         if(GMX_DOUBLE AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.9")
  74             message(FATAL_ERROR "Using VSX SIMD in double precision with GCC requires GCC-4.9 or later.")
  75         endif()
  76     endif()
  77     if(${CMAKE_CXX_COMPILER_ID} MATCHES "XL" OR ${CMAKE_C_COMPILER_ID} MATCHES "XL")
  78         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "13.1.5" OR CMAKE_C_COMPILER_VERSION VERSION_LESS "13.1.5")
  79             message(FATAL_ERROR "Using VSX SIMD requires XL compiler version 13.1.5 or later.")
  80         endif()
  81     endif()
  82 endmacro()
  83
  84 # Issue a fatal error with an appropriate message, when the toolchain
  85 # was not able to compile code for SIMD support.
  86 #
  87 # Inputs:
  88 #  SIMD_STRING              A string describing the kind of SIMD support that didn't work.
  89 #  ALTERNATIVE_SUGGESTION   A string describing anything the user could try other than getting a new compiler.
  90 #  SUGGEST_BINUTILS_UPDATE  True when there's information that the compiler was OK, but something else was not.
  91 function(gmx_give_fatal_error_when_simd_support_not_found SIMD_STRING ALTERNATIVE_SUGGESTION SUGGEST_BINUTILS_UPDATE)
  92     if(SUGGEST_BINUTILS_UPDATE)
  93         set(_msg "Found a compiler flag for ${SIMD_STRING} support, but some other problem exists. Update your assembler and/or linker, e.g. in the binutils package of your distribution.")
  94     else()
  95         set(_msg "Cannot find ${SIMD_STRING} compiler flag. Use a newer compiler, or ${ALTERNATIVE_SUGGESTION}.")
  96     endif()
  97     message(FATAL_ERROR ${_msg})
  98 endfunction()
  99
 100 macro(gmx_manage_simd)
 101
 102 set(GMX_SIMD_ACCURACY_BITS_SINGLE 22 CACHE STRING "Target mantissa bits for SIMD single math")
 103 #
 104 # Note that we typically restrict double precision target accuracy to be twice that
 105 # of single. This means we only need one more N-R iteration for 1/sqrt(x) and 1(x),
 106 # and the first iteration can sometimes be done as a pair in single precision. This should
 107 # be plenty enough for Molecular Dynamics applications. Many of our double precision math
 108 # functions still achieve very close to full double precision, but we do not guarantee that
 109 # they will be able to achieve higher accuracy if you set this beyond 44 bits. GROMACS will
 110 # work - but some unit tests might fail.
 111 #
 112 set(GMX_SIMD_ACCURACY_BITS_DOUBLE 44 CACHE STRING "Target mantissa bits for SIMD double math")
 113 mark_as_advanced(GMX_SIMD_ACCURACY_BITS_SINGLE)
 114 mark_as_advanced(GMX_SIMD_ACCURACY_BITS_DOUBLE)
 115
 116 if(${GMX_SIMD_ACCURACY_BITS_SINGLE} GREATER 22)
 117     message(STATUS "Note: Full mantissa accuracy (including least significant bit) requested for SIMD single math. Presently we cannot get the least significant bit correct since that would require different algorithms - reducing to 22 bits.")
 118     set(GMX_SIMD_ACCURACY_BITS_SINGLE 22 CACHE STRING "Target mantissa bits for SIMD single math" FORCE)
 119 endif()
 120
 121 if(${GMX_SIMD_ACCURACY_BITS_DOUBLE} GREATER 51)
 122     message(STATUS "Note: Full mantissa accuracy (including least significant bit) requested for SIMD double math. Presently we cannot get the least significant bit correct since that would require different algorithms - reducing to 51 bits.")
 123     set(GMX_SIMD_ACCURACY_BITS_DOUBLE 51 CACHE STRING "Target mantissa bits for SIMD double math" FORCE)
 124 endif()
 125
 126 #
 127 # Section to set (and test) compiler flags for SIMD.
 128 #
 129 # The flags will be set based on the GMX_SIMD choice provided by the user.
 130 # Automatic detection of the architecture on the build host is done prior to
 131 # calling this macro.
 132 #
 133
 134 if(GMX_SIMD STREQUAL "NONE")
 135     # nothing to do configuration-wise
 136     set(SIMD_STATUS_MESSAGE "SIMD instructions disabled")
 137 elseif(GMX_SIMD STREQUAL "SSE2")
 138
 139     gmx_find_flags(
 140         "#include<xmmintrin.h>
 141          int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_rsqrt_ps(x);return _mm_movemask_ps(x);}"
 142         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 143         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 144         "-msse2" "/arch:SSE2" "-hgnu")
 145
 146     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 147         gmx_give_fatal_error_when_simd_support_not_found("SSE2" "disable SIMD support (slow)" "${SUGGEST_BINUTILS_UPDATE}")
 148     endif()
 149
 150     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 151     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 152     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 153     set(SIMD_STATUS_MESSAGE "Enabling SSE2 SIMD instructions")
 154
 155 elseif(GMX_SIMD STREQUAL "SSE4.1")
 156
 157     # Note: MSVC enables SSE4.1 with the SSE2 flag, so we include that in testing.
 158     gmx_find_flags(
 159         "#include<smmintrin.h>
 160         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_dp_ps(x,x,0x77);return _mm_movemask_ps(x);}"
 161         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 162         SIMD_SSE_4_1_C_FLAGS SIMD_SSE_4_1_CXX_FLAGS
 163         "-msse4.1" "/arch:SSE4.1" "/arch:SSE2" "-hgnu")
 164
 165     if(NOT SIMD_SSE_4_1_C_FLAGS OR NOT SIMD_SSE_4_1_CXX_FLAGS)
 166         gmx_give_fatal_error_when_simd_support_not_found("SSE4.1" "choose SSE2 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 167     endif()
 168
 169     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 170     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 171     set(GMX_SIMD_X86_SSE4_1 1)
 172     set(SIMD_STATUS_MESSAGE "Enabling SSE4.1 SIMD instructions")
 173
 174 elseif(GMX_SIMD STREQUAL "AVX_128_FMA")
 175
 176     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 177
 178     # We don't have the full compiler version string yet (BUILD_C_COMPILER),
 179     # so we can't distinguish vanilla from Apple clang versions, but catering for a few rare AMD
 180     # hackintoshes is not worth the effort.
 181     if (APPLE AND (CMAKE_C_COMPILER_ID STREQUAL "Clang" OR
 182                 CMAKE_CXX_COMPILER_ID STREQUAL "Clang"))
 183         message(WARNING "Due to a known compiler bug, Clang up to version 3.2 (and Apple Clang up to version 4.1) produces incorrect code with AVX_128_FMA SIMD. As we cannot work around this bug on OS X, you will have to select a different compiler or SIMD instruction set.")
 184     endif()
 185
 186     # clang <=3.2 contains a bug that causes incorrect code to be generated for the
 187     # vfmaddps instruction and therefore the bug is triggered with AVX_128_FMA.
 188     # (see: http://llvm.org/bugs/show_bug.cgi?id=15040).
 189     # We can work around this by not using the integrated assembler (except on OS X
 190     # which has an outdated assembler that does not support AVX instructions).
 191     if (CMAKE_C_COMPILER_ID MATCHES "Clang" AND CMAKE_C_COMPILER_VERSION VERSION_LESS "3.3")
 192         # we assume that we have an external assembler that supports AVX
 193         message(STATUS "Clang ${CMAKE_C_COMPILER_VERSION} detected, enabling FMA bug workaround")
 194         set(TOOLCHAIN_C_FLAGS "${TOOLCHAIN_C_FLAGS} -no-integrated-as")
 195     endif()
 196     if (CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CMAKE_CXX_COMPILER_VERSION VERSION_LESS "3.3")
 197         # we assume that we have an external assembler that supports AVX
 198         message(STATUS "Clang ${CMAKE_CXX_COMPILER_VERSION} detected, enabling FMA bug workaround")
 199         set(TOOLCHAIN_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS} -no-integrated-as")
 200     endif()
 201
 202     # AVX128/FMA on AMD is a bit complicated. We need to do detection in three stages:
 203     # 1) Find the flags required for generic AVX support
 204     # 2) Find the flags necessary to enable fused-multiply add support
 205     # 3) Optional: Find a flag to enable the AMD XOP instructions
 206
 207     ### STAGE 1: Find the generic AVX flag
 208     gmx_find_flags(
 209         "#include<immintrin.h>
 210         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_permute_ps(x,1);return 0;}"
 211         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 212         SIMD_GENERIC_AVX_C_FLAGS SIMD_GENERIC_AVX_CXX_FLAGS
 213         "-mavx" "/arch:AVX" "-hgnu")
 214
 215     ### STAGE 2: Find the fused-multiply add flag.
 216     # GCC requires x86intrin.h for FMA support. MSVC 2010 requires intrin.h for FMA support.
 217     check_include_file(x86intrin.h HAVE_X86INTRIN_H ${SIMD_C_FLAGS})
 218     check_include_file(intrin.h HAVE_INTRIN_H ${SIMD_C_FLAGS})
 219     if(HAVE_X86INTRIN_H)
 220         set(INCLUDE_X86INTRIN_H "#include <x86intrin.h>")
 221     endif()
 222     if(HAVE_INTRIN_H)
 223         set(INCLUDE_INTRIN_H "#include <xintrin.h>")
 224     endif()
 225
 226     gmx_find_flags(
 227         "#include<immintrin.h>
 228         ${INCLUDE_X86INTRIN_H}
 229         ${INCLUDE_INTRIN_H}
 230         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_macc_ps(x,x,x);return _mm_movemask_ps(x);}"
 231         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 232         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 233         "-mfma4" "-hgnu")
 234
 235     # We only need to check the last (FMA) test; that will always fail if the generic AVX test failed
 236     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 237         gmx_give_fatal_error_when_simd_support_not_found("128-bit AVX with FMA support" "choose SSE4.1 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 238     endif()
 239
 240     ### STAGE 3: Optional: Find the XOP instruction flag (No point in yelling if this does not work)
 241     gmx_find_flags(
 242         "#include<immintrin.h>
 243         ${INCLUDE_X86INTRIN_H}
 244         ${INCLUDE_INTRIN_H}
 245         int main(){__m128 x=_mm_set1_ps(0.5);x=_mm_frcz_ps(x);return _mm_movemask_ps(x);}"
 246         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 247         SIMD_AVX_128_XOP_C_FLAGS SIMD_AVX_128_XOP_CXX_FLAGS
 248         "-mxop")
 249
 250     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 251     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 252     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 253     set(SIMD_STATUS_MESSAGE "Enabling 128-bit AVX SIMD GROMACS SIMD (with fused-multiply add)")
 254
 255     gmx_test_avx_gcc_maskload_bug(GMX_SIMD_X86_AVX_GCC_MASKLOAD_BUG "${SIMD_C_FLAGS}")
 256
 257 elseif(GMX_SIMD STREQUAL "AVX_256")
 258
 259     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 260
 261     gmx_find_flags(
 262         "#include<immintrin.h>
 263          int main(){__m256 x=_mm256_set1_ps(0.5);x=_mm256_add_ps(x,x);return _mm256_movemask_ps(x);}"
 264         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 265         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 266         "-mavx" "/arch:AVX" "-hgnu")
 267
 268     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 269         gmx_give_fatal_error_when_simd_support_not_found("AVX" "choose SSE4.1 SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 270     endif()
 271
 272     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 273     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 274     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 275     set(SIMD_STATUS_MESSAGE "Enabling 256-bit AVX SIMD instructions")
 276
 277     gmx_test_avx_gcc_maskload_bug(GMX_SIMD_X86_AVX_GCC_MASKLOAD_BUG "${SIMD_C_FLAGS}")
 278
 279 elseif(GMX_SIMD STREQUAL "AVX2_256")
 280
 281     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 282
 283     gmx_find_flags(
 284         "#include<immintrin.h>
 285          int main(){__m256i x=_mm256_set1_epi32(5);x=_mm256_add_epi32(x,x);return _mm256_movemask_epi8(x);}"
 286         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 287         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 288         "-march=core-avx2" "-mavx2" "/arch:AVX" "-hgnu") # no AVX2-specific flag for MSVC yet
 289
 290     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 291         gmx_give_fatal_error_when_simd_support_not_found("AVX2" "choose AVX SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 292     endif()
 293
 294     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 295     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 296     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 297     set(SIMD_STATUS_MESSAGE "Enabling 256-bit AVX2 SIMD instructions")
 298
 299     # No need to test for Maskload bug - it was fixed before gcc added AVX2 support
 300
 301 elseif(GMX_SIMD STREQUAL "MIC")
 302
 303     # No flags needed. Not testing.
 304     set(GMX_SIMD_X86_MIC 1)
 305     set(SIMD_STATUS_MESSAGE "Enabling MIC (Xeon Phi) SIMD instructions")
 306
 307 elseif(GMX_SIMD STREQUAL "AVX_512")
 308
 309     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 310
 311     gmx_find_flags(
 312         "#include<immintrin.h>
 313          int main(){__m512 y,x=_mm512_set1_ps(0.5);y=_mm512_fmadd_ps(x,x,x);return (int)_mm512_cmp_ps_mask(x,y,_CMP_LT_OS);}"
 314         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 315         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 316         "-xCORE-AVX512" "-mavx512f -mfma" "-mavx512f" "/arch:AVX" "-hgnu") # no AVX_512F flags known for MSVC yet
 317
 318     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 319         gmx_give_fatal_error_when_simd_support_not_found("AVX 512F" "choose a lower level of SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 320     endif()
 321
 322     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 323     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 324     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 325     set(SIMD_STATUS_MESSAGE "Enabling 512-bit AVX-512 SIMD instructions")
 326
 327 elseif(GMX_SIMD STREQUAL "AVX_512_KNL")
 328
 329     prepare_x86_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 330
 331     gmx_find_flags(
 332         "#include<immintrin.h>
 333         int main(){__m512 y,x=_mm512_set1_ps(0.5);y=_mm512_rsqrt28_ps(x);return (int)_mm512_cmp_ps_mask(x,y,_CMP_LT_OS);}"
 334         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 335         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 336         "-xMIC-AVX512" "-mavx512er -mfma" "-mavx512er" "/arch:AVX" "-hgnu") # no AVX_512ER flags known for MSVC yet
 337
 338     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 339         gmx_give_fatal_error_when_simd_support_not_found("AVX 512ER" "choose a lower level of SIMD (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 340     endif()
 341
 342     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 343     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 344     set(GMX_SIMD_X86_${GMX_SIMD} 1)
 345     set(SIMD_STATUS_MESSAGE "Enabling 512-bit AVX-512-KNL SIMD instructions")
 346
 347 elseif(GMX_SIMD STREQUAL "ARM_NEON")
 348
 349     gmx_find_flags(
 350         "#include<arm_neon.h>
 351          int main(){float32x4_t x=vdupq_n_f32(0.5);x=vmlaq_f32(x,x,x);return vgetq_lane_f32(x,0)>0;}"
 352         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 353         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 354         "-mfpu=neon-vfpv4" "-mfpu=neon" "")
 355
 356     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 357         gmx_give_fatal_error_when_simd_support_not_found("ARM NEON" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 358     endif()
 359
 360     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 361     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 362     set(GMX_SIMD_${GMX_SIMD} 1)
 363     set(SIMD_STATUS_MESSAGE "Enabling 32-bit ARM NEON SIMD instructions")
 364
 365 elseif(GMX_SIMD STREQUAL "ARM_NEON_ASIMD")
 366
 367     gmx_find_flags(
 368         "#include<arm_neon.h>
 369          int main(){float64x2_t x=vdupq_n_f64(0.5);x=vfmaq_f64(x,x,x);x=vrndnq_f64(x);return vgetq_lane_f64(x,0)>0;}"
 370         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 371         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 372         "")
 373
 374     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 375         gmx_give_fatal_error_when_simd_support_not_found("ARM (AArch64) NEON Advanced SIMD" "particularly gcc version 4.9 or later, or disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 376     endif()
 377
 378     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 379     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 380     set(GMX_SIMD_${GMX_SIMD} 1)
 381     set(SIMD_STATUS_MESSAGE "Enabling ARM (AArch64) NEON Advanced SIMD instructions")
 382
 383 elseif(GMX_SIMD STREQUAL "IBM_QPX")
 384
 385     try_compile(TEST_QPX ${CMAKE_BINARY_DIR}
 386         "${CMAKE_SOURCE_DIR}/cmake/TestQPX.c")
 387
 388     if (TEST_QPX)
 389         message(WARNING "IBM QPX SIMD instructions selected. This will work, but SIMD kernels are only available for the Verlet cut-off scheme. The plain C kernels that are used for the group cut-off scheme kernels will be slow, so please consider using the Verlet cut-off scheme.")
 390         set(GMX_SIMD_${GMX_SIMD} 1)
 391         set(SIMD_STATUS_MESSAGE "Enabling IBM QPX SIMD instructions")
 392
 393     else()
 394         gmx_give_fatal_error_when_simd_support_not_found("IBM QPX" "or 'cmake .. -DCMAKE_TOOLCHAIN_FILE=Platform/BlueGeneQ-static-XL-CXX' to set up the tool chain" "${SUGGEST_BINUTILS_UPDATE}")
 395     endif()
 396
 397 elseif(GMX_SIMD STREQUAL "IBM_VMX")
 398
 399     gmx_find_flags(
 400         "#include<altivec.h>
 401          int main(){vector float x,y=vec_ctf(vec_splat_s32(1),0);x=vec_madd(y,y,y);return vec_all_ge(y,x);}"
 402         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 403         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 404         "-maltivec -mabi=altivec" "-qarch=auto -qaltivec")
 405
 406     if(NOT SIMD_${GMX_SIMD}_C_FLAGS OR NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 407         gmx_give_fatal_error_when_simd_support_not_found("IBM VMX" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 408     endif()
 409
 410     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 411     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 412     set(GMX_SIMD_${GMX_SIMD} 1)
 413     set(SIMD_STATUS_MESSAGE "Enabling IBM VMX SIMD instructions")
 414
 415 elseif(GMX_SIMD STREQUAL "IBM_VSX")
 416
 417     prepare_power_vsx_toolchain(TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS)
 418
 419     gmx_find_flags(
 420         "#include<altivec.h>
 421          int main(){vector double x,y=vec_splats(1.0);x=vec_madd(y,y,y);return vec_all_ge(y,x);}"
 422         TOOLCHAIN_C_FLAGS TOOLCHAIN_CXX_FLAGS
 423         SIMD_${GMX_SIMD}_C_FLAGS SIMD_${GMX_SIMD}_CXX_FLAGS
 424         "-mvsx" "-maltivec -mabi=altivec" "-qarch=auto -qaltivec")
 425
 426     # Usually we check also for the C compiler here, but a C compiler
 427     # is not required for SIMD support on this platform. cmake through
 428     # at least version 3.7 cannot pass this check with the C compiler
 429     # in the latest xlc 13.1.5, but the C++ compiler has different
 430     # behaviour and is OK. See Redmine #2102.
 431     if(NOT SIMD_${GMX_SIMD}_CXX_FLAGS)
 432         gmx_give_fatal_error_when_simd_support_not_found("IBM VSX" "disable SIMD support (slower)" "${SUGGEST_BINUTILS_UPDATE}")
 433     endif()
 434
 435     set(SIMD_C_FLAGS "${TOOLCHAIN_C_FLAGS}")
 436     set(SIMD_CXX_FLAGS "${TOOLCHAIN_CXX_FLAGS}")
 437     set(GMX_SIMD_${GMX_SIMD} 1)
 438     set(SIMD_STATUS_MESSAGE "Enabling IBM VSX SIMD instructions")
 439
 440 elseif(GMX_SIMD STREQUAL "SPARC64_HPC_ACE")
 441
 442     # Note that GMX_RELAXED_DOUBLE_PRECISION is enabled by default in the top-level CMakeLists.txt
 443
 444     set(GMX_SIMD_${GMX_SIMD} 1)
 445     set(SIMD_STATUS_MESSAGE "Enabling Sparc64 HPC-ACE SIMD instructions")
 446
 447 elseif(GMX_SIMD STREQUAL "REFERENCE")
 448
 449     # NB: This file handles settings for the SIMD module, so in the interest
 450     # of proper modularization, please do NOT put any verlet kernel settings in this file.
 451
 452     if(GMX_SIMD_REF_FLOAT_WIDTH)
 453         add_definitions(-DGMX_SIMD_REF_FLOAT_WIDTH=${GMX_SIMD_REF_FLOAT_WIDTH})
 454     endif()
 455     if(GMX_SIMD_REF_DOUBLE_WIDTH)
 456         add_definitions(-DGMX_SIMD_REF_DOUBLE_WIDTH=${GMX_SIMD_REF_DOUBLE_WIDTH})
 457     endif()
 458
 459     set(GMX_SIMD_${GMX_SIMD} 1)
 460     set(SIMD_STATUS_MESSAGE "Enabling reference (emulated) SIMD instructions.")
 461
 462 else()
 463     gmx_invalid_option_value(GMX_SIMD)
 464 endif()
 465
 466
 467 gmx_check_if_changed(SIMD_CHANGED GMX_SIMD)
 468 if (SIMD_CHANGED AND DEFINED SIMD_STATUS_MESSAGE)
 469     message(STATUS "${SIMD_STATUS_MESSAGE}")
 470 endif()
 471
 472 # By default, 32-bit windows cannot pass SIMD (SSE/AVX) arguments in registers,
 473 # and even on 64-bit (all platforms) it is only used for a handful of arguments.
 474 # The __vectorcall (MSVC, from MSVC2013) or __regcall (ICC) calling conventions
 475 # enable this, which is critical to enable 32-bit SIMD and improves performance
 476 # for 64-bit SIMD.
 477 # Check if the compiler supports one of these, and in that case set gmx_simdcall
 478 # to that string. If we do not have any such calling convention modifier, set it
 479 # to an empty string.
 480 #
 481 # Update 2015-11-04: As of version 3.6, clang has added support for __vectorcall
 482 # (also on Linux). This appears to be buggy for the reference SIMD
 483 # implementation when using the Debug build (when functions are not inlined)
 484 # while it seems works fine for the actual SIMD implementations. This is likely
 485 # because the reference build ends up passing lots of structures with arrays
 486 # rather than actual vector data. For now we disable __vectorcall with clang
 487 # when using the reference build.
 488 #
 489 # xlc 13.1.5 does not seem recognize any attribute, and warns about invalid ones
 490 # so we avoid searching for any.
 491 #
 492 if(NOT DEFINED GMX_SIMD_CALLING_CONVENTION)
 493     if(GMX_TARGET_BGQ)
 494         set(CALLCONV_LIST " ")
 495     elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND GMX_SIMD STREQUAL "REFERENCE")
 496         set(CALLCONV_LIST __regcall " ")
 497    elseif(CMAKE_CXX_COMPILER_ID MATCHES "XL")
 498         set(CALLCONV_LIST " ")
 499     else()
 500         set(CALLCONV_LIST __vectorcall __regcall " ")
 501     endif()
 502     foreach(callconv ${CALLCONV_LIST})
 503         set(callconv_compile_var "_callconv_${callconv}")
 504         check_c_source_compiles("int ${callconv} f(int i) {return i;} int main(void) {return f(0);}" ${callconv_compile_var})
 505         if(${callconv_compile_var})
 506             set(GMX_SIMD_CALLING_CONVENTION "${callconv}" CACHE INTERNAL "Calling convention for SIMD routines" FORCE)
 507             break()
 508         endif()
 509     endforeach()
 510 endif()
 511
 512 endmacro()
 513