CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014,2015, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # PROJECT_VERSION should have the following structure:
  52 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
  53 #
  54 # The "-dev" suffix is important to keep because it makes possible to distinguish
  55 # between a build from official release and a build from git release branch on a
  56 # machine with no git.
  57 #
  58 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  59 # REGRESSIONTEST_VERSION and REGRESSIONTEST_BRANCH should always be
  60 # defined.
  61 set(PROJECT_VERSION "5.0.7-dev")
  62 # If this is a released tarball, "-dev" will not be present in
  63 # PROJECT_VERSION, and REGRESSIONTEST_VERSION specifies the version
  64 # number of the regressiontest tarball against which the code tarball
  65 # can be tested. This will be the version of the last patch release.
  66 set(REGRESSIONTEST_VERSION "5.0.7-dev")
  67 # The MD5 checksum of the regressiontest tarball. Only used if "-dev"
  68 # is not present in the PROJECT_VERSION
  69 set(REGRESSIONTEST_MD5SUM "0f3b41e7a0fbb43efd6793d2b2fedacc")
  70 # If this is not a released tarball, "-dev" will be present in
  71 # PROJECT_VERSION, and REGRESSIONTEST_BRANCH specifies the name of the
  72 # gerrit.gromacs.org branch whose HEAD can test this code, *if* this
  73 # code contains all recent fixes from the corresponding code branch.
  74 set(REGRESSIONTEST_BRANCH "refs/heads/release-5-0")
  75
  76 set(CUSTOM_VERSION_STRING ""
  77     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  78 mark_as_advanced(CUSTOM_VERSION_STRING)
  79 if (CUSTOM_VERSION_STRING)
  80     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  81 endif()
  82 set(LIBRARY_SOVERSION 0)
  83 set(LIBRARY_VERSION ${LIBRARY_SOVERSION}.0.0)
  84 # It is a bit irritating, but this has to be set separately for now!
  85 SET(CPACK_PACKAGE_VERSION_MAJOR "5")
  86 SET(CPACK_PACKAGE_VERSION_MINOR "0")
  87 #SET(CPACK_PACKAGE_VERSION_PATCH "0")
  88
  89 # The numerical gromacs version. It is 40600 for 4.6.0.
  90 # The #define GMX_VERSION in gromacs/version.h is set to this value.
  91 math(EXPR NUM_VERSION
  92     "${CPACK_PACKAGE_VERSION_MAJOR}*10000 + ${CPACK_PACKAGE_VERSION_MINOR}*100")
  93 if(CPACK_PACKAGE_VERSION_PATCH)
  94     math(EXPR NUM_VERSION
  95          "${NUM_VERSION} + ${CPACK_PACKAGE_VERSION_PATCH}")
  96 endif()
  97
  98 # The API version tracks the numerical Gromacs version (for now).
  99 # It is potentially different from the Gromacs version in the future, if
 100 # the programs/libraries diverge from the presumably more stable API.
 101 # The #define GMX_API_VERSION in version.h is set to this value to
 102 # provide backward compatibility of software written against the Gromacs API.
 103 set(API_VERSION ${NUM_VERSION})
 104
 105 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
 106     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
 107 endif()
 108 if("${CMAKE_INSTALL_PREFIX}" STREQUAL "${CMAKE_BINARY_DIR}")
 109     message(FATAL_ERROR "GROMACS cannot be installed into the build tree, choose a different location for CMAKE_INSTALL_PREFIX")
 110 endif()
 111
 112 include(gmxBuildTypeReference)
 113 include(gmxBuildTypeTSAN)
 114 include(gmxBuildTypeASAN)
 115 include(gmxBuildTypeReleaseWithAssert)
 116
 117 if(NOT CMAKE_BUILD_TYPE)
 118     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert." FORCE)
 119     # There's no need to offer a user the choice of ThreadSanitizer
 120     # Set the possible values of build type for cmake-gui
 121     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
 122         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert")
 123 endif()
 124 if(CMAKE_CONFIGURATION_TYPES)
 125     # Add appropriate GROMACS-specific build types for the Visual
 126     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
 127     # are already present by default).
 128     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
 129     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
 130     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
 131         "List of configuration types"
 132         FORCE)
 133 endif()
 134 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBINFO RELWITHASSERT MINSIZEREL)
 135
 136 enable_language(C)
 137 enable_language(CXX)
 138 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
 139
 140 set(CPACK_PACKAGE_NAME "gromacs")
 141 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
 142 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 143 set(CPACK_PACKAGE_VENDOR "gromacs.org")
 144 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
 145 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
 146 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
 147 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
 148 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
 149 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 150 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 151 # CPack source archives include only the directories we list here.
 152 # This variable is a list of pairs of names of source and destination
 153 # directories. Most of these are used for content GROMACS generates as
 154 # part of the configuration or build.
 155 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/docs/man/man1;docs/man/man1;${CMAKE_BINARY_DIR}/docs/man/man7;docs/man/man7;${CMAKE_BINARY_DIR}/docs/old-html/final;docs/old-html/final;${CMAKE_BINARY_DIR}/docs/install-guide/final;/")
 156 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 157 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 158
 159 #must come after all cpack settings!
 160 include(CPack)
 161
 162 # Set a default valgrind suppression file.
 163 # This unfortunately needs to duplicate information from CTest to work as
 164 # expected...
 165 set(MEMORYCHECK_SUPPRESSIONS_FILE
 166     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 167     CACHE FILEPATH
 168     "File that contains suppressions for the memory checker")
 169 include(CTest)
 170
 171 set(SOURCE_IS_GIT_REPOSITORY OFF)
 172 set(SOURCE_IS_SOURCE_DISTRIBUTION OFF)
 173 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 174     set(SOURCE_IS_GIT_REPOSITORY ON)
 175 endif()
 176 if(NOT EXISTS "${CMAKE_SOURCE_DIR}/admin/.isreposource")
 177     set(SOURCE_IS_SOURCE_DISTRIBUTION ON)
 178 endif()
 179
 180 ########################################################################
 181 # Check and warn if cache generated on a different host is being reused
 182 ########################################################################
 183 if(CMAKE_HOST_UNIX)
 184     execute_process(COMMAND hostname
 185                     OUTPUT_VARIABLE TMP_HOSTNAME
 186                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 187     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 188         message(WARNING "
 189             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 190             is being reused! This could lead to inconsistencies; therefore, it is
 191             recommended to regenerate the cache!")
 192     endif()
 193     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 194             "Hostname of the machine where the cache was generated.")
 195 endif()
 196
 197 ########################################################################
 198 # Detect architecture before setting options so we can alter defaults
 199 ########################################################################
 200 # Detect the architecture the compiler is targetting, detect
 201 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 202 # to use if none is specified, and populate the cache option for CPU
 203 # SIMD.
 204 include(gmxDetectTargetArchitecture)
 205 gmx_detect_target_architecture()
 206
 207 ########################################################################
 208 # User input options                                                   #
 209 ########################################################################
 210 include(gmxOptionUtilities)
 211
 212 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 213
 214 if(GMX_TARGET_FUJITSU_SPARC64)
 215     # Fujitsu only has SIMD in double precision, so this will be faster
 216     set(GMX_DOUBLE_DEFAULT ON)
 217 else()
 218     set(GMX_DOUBLE_DEFAULT OFF)
 219 endif()
 220 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 221 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 222 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 223
 224 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 225 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 226 gmx_dependent_option(
 227     GMX_MPI_IN_PLACE
 228     "Enable MPI_IN_PLACE for MPIs that have it defined"
 229     ON
 230     GMX_MPI)
 231 mark_as_advanced(GMX_MPI_IN_PLACE)
 232 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 233 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 234 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 235 mark_as_advanced(GMX_FAHCORE)
 236
 237 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 238 mark_as_advanced(GMX_COOL_QUOTES)
 239 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 240
 241 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 242 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 243 if(MSVC)
 244     set(REQUIRED_CUDA_VERSION 4.1)
 245 else()
 246     set(REQUIRED_CUDA_VERSION 4.0)
 247 endif()
 248 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 249 include(gmxManageGPU)
 250
 251 if(GMX_CPU_ACCELERATION)
 252     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 253     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 254     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 255     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 256 endif()
 257
 258 if(NOT GMX_TARGET_MIC)
 259     include(gmxDetectSimd)
 260     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 261 else()
 262     set(GMX_SUGGESTED_SIMD "None")
 263 endif()
 264
 265 gmx_option_multichoice(
 266     GMX_SIMD
 267     "SIMD instruction set for CPU kernels and compiler optimization"
 268     "${GMX_SUGGESTED_SIMD}"
 269     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 270
 271 if(GMX_TARGET_MIC)
 272     set(GMX_FFT_LIBRARY_DEFAULT "mkl")
 273 else()
 274     set(GMX_FFT_LIBRARY_DEFAULT "fftw3")
 275 endif()
 276
 277 gmx_option_multichoice(
 278     GMX_FFT_LIBRARY
 279     "FFT library"
 280     "${GMX_FFT_LIBRARY_DEFAULT}"
 281     fftw3 mkl "fftpack[built-in]")
 282 gmx_dependent_option(
 283     GMX_BUILD_OWN_FFTW
 284     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 285     OFF
 286     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 287 gmx_dependent_option(
 288     GMX_DISABLE_FFTW_MEASURE
 289     "Do not optimize FFTW setups (not needed with SSE)"
 290     OFF
 291     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 292 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 293 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 294
 295 gmx_option_multichoice(
 296     GMX_QMMM_PROGRAM
 297     "QM package for QM/MM"
 298     None
 299     none gaussian mopac gamess orca)
 300
 301 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 302 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 303
 304 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 305
 306 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 307 mark_as_advanced(GMX_BROKEN_CALLOC)
 308 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 309 mark_as_advanced(GMX_LOAD_PLUGINS)
 310
 311 option(GMX_GPU  "Enable GPU acceleration" ON)
 312 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 313
 314 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 315
 316 option(GMX_GIT_VERSION_INFO "Generate git version information" ${SOURCE_IS_GIT_REPOSITORY})
 317 mark_as_advanced(GMX_GIT_VERSION_INFO)
 318
 319 if(UNIX)
 320     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 321 endif()
 322 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 323
 324 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 325 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 326
 327 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 328 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 329
 330 option(GMX_BUILD_FOR_COVERAGE
 331        "Tune build for better code coverage metrics (e.g., disable asserts)"
 332        OFF)
 333 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 334
 335 option(GMX_DEVELOPER_BUILD
 336     "Enable Developer convenience features: always build unit-tests"
 337     OFF)
 338 mark_as_advanced(GMX_DEVELOPER_BUILD)
 339
 340 option(GMX_BUILD_SHARED_EXE
 341     "Build exectuables as shared binaries. If not set, this disables rpath and dynamic linker flags in an attempt to build a static binary, but this may require setting up the toolchain properly and making appropriate libraries available."
 342     ON)
 343 mark_as_advanced(GMX_BUILD_SHARED_EXE)
 344
 345 ######################################################################
 346 # Detect OpenMP support
 347 ######################################################################
 348 # The OpenMP detection _must_ come before tests for other CFLAGS.
 349 include(gmxManageOpenMP)
 350
 351
 352
 353 ######################################################################
 354 # Compiler tests
 355 # These need to be done early (before further tests).
 356 #####################################################################
 357
 358 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 359 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 360 # invalid options with the Intel Compilers, and we have added a line
 361 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 362 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 363 # a semicolon. Since this is also used as a separator in lists inside CMake,
 364 # that string ends up being split into two separate patterns, and the last
 365 # part is just a single word that also matches other messages. We solved this
 366 # by replacing the semicolon with a period that matches any character.
 367 #
 368 # These files should be removed from the source tree when a CMake version that
 369 # includes the features in question becomes required for building GROMACS.
 370 include(CheckCCompilerFlag)
 371 include(CheckCXXCompilerFlag)
 372
 373 include(gmxCFlags)
 374 gmx_c_flags()
 375
 376 # This variable should be used for additional compiler flags which are not
 377 # generated in gmxCFlags nor are SIMD or MPI related.
 378 set(EXTRA_C_FLAGS "")
 379 set(EXTRA_CXX_FLAGS "")
 380
 381 # Run through a number of tests for buggy compilers and other issues
 382 include(gmxTestCompilerProblems)
 383 gmx_test_compiler_problems()
 384 # GMX_SIMD will not be set automatically until the second
 385 # pass (which is not strictly guaranteed to occur), so putting this
 386 # check here among logically-related tests is inefficient, but the
 387 # potential loss is likely zero.
 388 if(GMX_SIMD STREQUAL "AVX_256"
 389         AND CMAKE_COMPILER_IS_GNUCC
 390         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 391             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 392     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 393     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 394 endif()
 395
 396
 397
 398 set(PKG_CFLAGS "")
 399 if(GMX_DOUBLE)
 400     add_definitions(-DGMX_DOUBLE)
 401     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 402     if(GMX_RELAXED_DOUBLE_PRECISION)
 403         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 404     endif()
 405 endif()
 406 if(GMX_SOFTWARE_INVSQRT)
 407   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 408 endif()
 409
 410 if(WIN32 AND NOT CYGWIN)
 411     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 412     add_definitions(-DGMX_HAVE_WINSOCK)
 413 endif()
 414
 415
 416
 417 ########################################################################
 418 # Basic system tests (standard libraries, headers, functions, types)   #
 419 ########################################################################
 420 include(CheckIncludeFiles)
 421 include(CheckIncludeFileCXX)
 422 check_include_files(unistd.h     HAVE_UNISTD_H)
 423 check_include_files(pwd.h        HAVE_PWD_H)
 424 check_include_files(dirent.h     HAVE_DIRENT_H)
 425 check_include_files(time.h       HAVE_TIME_H)
 426 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 427 check_include_files(io.h         HAVE_IO_H)
 428 check_include_files(sched.h      HAVE_SCHED_H)
 429
 430 check_include_files(regex.h      HAVE_POSIX_REGEX)
 431 # TODO: It could be nice to inform the user if no regex support is found,
 432 # as selections won't be fully functional.
 433
 434 include(CheckFunctionExists)
 435 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 436 check_function_exists(memalign          HAVE_MEMALIGN)
 437 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 438 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 439 check_function_exists(fsync             HAVE_FSYNC)
 440 check_function_exists(_fileno           HAVE__FILENO)
 441 check_function_exists(fileno            HAVE_FILENO)
 442 check_function_exists(_commit           HAVE__COMMIT)
 443 check_function_exists(sigaction         HAVE_SIGACTION)
 444 check_function_exists(sysconf           HAVE_SYSCONF)
 445 check_function_exists(rsqrt             HAVE_RSQRT)
 446 check_function_exists(rsqrtf            HAVE_RSQRTF)
 447 check_function_exists(sqrtf             HAVE_SQRTF)
 448
 449 include(CheckLibraryExists)
 450 check_library_exists(m sqrt "" HAVE_LIBM)
 451 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 452
 453 include(TestSchedAffinity)
 454 test_sched_affinity(HAVE_SCHED_AFFINITY)
 455
 456 include(TestBigEndian)
 457 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 458
 459 # Management of GROMACS options for specific toolchains should go
 460 # here. Because the initial settings for some of the main options have
 461 # already happened, but things like library detection and MPI compiler
 462 # feature detection have not, the docstrings for any over-rides of
 463 # GROMACS defaults or user settings will make sense. Also, any
 464 # toolchain-related reasons for choosing whether to detect various
 465 # things can be sorted out now, before the detection takes place.
 466 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 467     include(gmxManageBlueGene)
 468 endif()
 469
 470 if(GMX_TARGET_FUJITSU_SPARC64)
 471     include(gmxManageFujitsuSparc64)
 472 endif()
 473
 474 ########################################################################
 475 #Process MPI settings
 476 ########################################################################
 477 include(gmxManageMPI)
 478
 479
 480 ########################################################################
 481 #Process shared/static library settings
 482 ########################################################################
 483 include(gmxManageSharedLibraries)
 484
 485
 486 ########################################################################
 487 # Find external packages                                               #
 488 ########################################################################
 489
 490 # TNG wants zlib if it is available. And static libxml2 might have a dependency
 491 find_package(ZLIB QUIET)
 492 include(gmxTestZLib)
 493 gmx_test_zlib(HAVE_ZLIB)
 494
 495 # Unconditionally find the package, as it is also required for unit
 496 # tests. This exports LIBXML2_FOUND, which we should not use because
 497 # it does not tell us that linking will succeed. Instead, we test that
 498 # next.
 499 if(DEFINED LIBXML2_LIBRARIES)
 500   set(LibXml2_FIND_QUIETLY TRUE)
 501 endif()
 502 find_package(LibXml2)
 503 include(gmxTestLibXml2)
 504 gmx_test_libxml2(HAVE_LIBXML2)
 505 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 506 set(PKG_XML "")
 507 mark_as_advanced(GMX_XML)
 508 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 509 #if(GMX_XML AND NOT HAVE_LIBXML2)
 510 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 511 #endif()
 512 #if(GMX_XML)
 513 #    include_directories(${LIBXML2_INCLUDE_DIR})
 514 #    set(PKG_XML libxml-2.0)
 515 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 516 #endif()
 517
 518 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 519 mark_as_advanced(GMX_EXTRAE)
 520
 521 if (GMX_EXTRAE)
 522   find_package(EXTRAE)
 523   if(EXTRAE_FOUND)
 524     include_directories(${EXTRAE_INCLUDE_DIR})
 525     set(HAVE_EXTRAE 1)
 526   else()
 527     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 528   endif()
 529 endif()
 530
 531 option(GMX_X11 "Use X window system" OFF)
 532 if (GMX_X11)
 533     find_package(X11)
 534     # X11 includes/libraries are only set in the ngmx subdirectory!
 535     if(NOT X11_FOUND)
 536         message(FATAL_ERROR
 537                 "X11 include files and/or libraries were not found. "
 538                 "Set GMX_X11=OFF to compile without X11 support. "
 539                 "gmx view will not be available.")
 540     endif()
 541     include_directories(${X11_INCLUDE_DIR})
 542 endif()
 543
 544 include(ThreadMPI)
 545 # Enable core threading facilities
 546 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 547 # Enable tMPI C++ support
 548 tmpi_enable_cxx()
 549 if(GMX_THREAD_MPI)
 550     # enable MPI functions
 551     tmpi_enable()
 552     set(GMX_MPI 1)
 553     set(MPI_IN_PLACE_EXISTS 1)
 554 endif()
 555 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 556 if (TMPI_ATOMICS_DISABLED)
 557    add_definitions(-DTMPI_ATOMICS_DISABLED)
 558 endif()
 559
 560 if(GMX_GPU)
 561     # now that we have detected the dependencies, do the second configure pass
 562     gmx_gpu_setup()
 563 endif()
 564
 565 if(CYGWIN)
 566     set(GMX_CYGWIN 1)
 567 endif()
 568
 569 if(WIN32 AND NOT CYGWIN)
 570     set(GMX_NATIVE_WINDOWS 1)
 571     # This makes windows.h not declare min/max as macros that would break
 572     # C++ code using std::min/std::max.
 573     add_definitions(-DNOMINMAX)
 574 endif()
 575
 576 # only bother with finding git and using version.h if the source is a git repo
 577 if(GMX_GIT_VERSION_INFO)
 578     if (NOT SOURCE_IS_GIT_REPOSITORY)
 579         message(FATAL_ERROR
 580             "Cannot generate git version information from source tree not under git. "
 581             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 582     endif()
 583     # We need at least git v1.5.3 be able to parse git's date output. If not
 584     # found or the version is too small, we can't generate version information.
 585     find_package(Git)
 586
 587     if(NOT GIT_FOUND OR GIT_VERSION_STRING VERSION_LESS "1.5.3")
 588         message(FATAL_ERROR
 589             "No compatible git version found (>= 1.5.3 required). "
 590             "Won't be able to generate development version information. "
 591             "Set GMX_GIT_VERSION_INFO=OFF to proceed.")
 592     endif()
 593 endif()
 594
 595 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 596 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 597 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 598     find_package(Boost 1.44.0)
 599     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 600         set(Boost_FOUND FALSE)
 601     endif()
 602     # Print the notification only on first run, when determining the default
 603     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 604         message("Boost >= 1.44 not found. Using minimal internal version. "
 605                 "This may cause trouble if you plan on compiling/linking other "
 606                 "software that uses Boost against Gromacs.")
 607     endif()
 608 endif()
 609 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 610        ${Boost_FOUND})
 611 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 612     message(FATAL_ERROR
 613         "Boost >= 1.44 not found. "
 614         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 615         "version of Boost included with Gromacs.")
 616 endif()
 617
 618 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 619     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 620 endif()
 621 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 622 mark_as_advanced(GMX_BUILD_UNITTESTS)
 623 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 624 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 625     message(FATAL_ERROR
 626         "Cannot build unit tests without libxml2. "
 627         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 628 endif()
 629
 630 ########################################################################
 631 # Generate development version info for cache
 632 ########################################################################
 633 # set(GEN_VERSION_INFO_INTERNAL "ON")
 634 # include(gmxGenerateVersionString)
 635
 636 ########################################################################
 637 # Our own GROMACS tests
 638 ########################################################################
 639
 640 add_definitions( -DHAVE_CONFIG_H )
 641 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 642 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 643 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 644 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 645 # Required for gmx_header_config_gen.h to be found before installation
 646 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src/gromacs/utility)
 647 # Required for now to make old code compile
 648 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/gromacs/legacyheaders)
 649
 650 include(gmxTestInlineASM)
 651 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 652
 653 include(gmxSetBuildInformation)
 654 gmx_set_build_information()
 655 # Turn on RDTSCP if:
 656 # - the build system's CPU supports it
 657 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 658 #   at this point means that the user set it).
 659 # Note: it's better to not use the later set value of GMX_SIMD because
 660 # it reflects the system's capability of both compiling and running AVX code.
 661 # TODO: After merge with 5.0 one could implement a cache variable dependency
 662 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 663 # after the first cmake pass.
 664 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 665     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 666 else()
 667     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 668 endif()
 669 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 670 mark_as_advanced(GMX_USE_RDTSCP)
 671 if(GMX_USE_RDTSCP)
 672     set(HAVE_RDTSCP 1)
 673 endif()
 674
 675 include(gmxTestFloatFormat)
 676 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 677                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 678                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 679
 680 include(gmxTestLargeFiles)
 681 gmx_test_large_files(GMX_LARGEFILES)
 682
 683 include(gmxTestSignal)
 684 gmx_test_sigusr1(HAVE_SIGUSR1)
 685
 686 include(gmxTestPipes)
 687 gmx_test_pipes(HAVE_PIPES)
 688
 689 include(gmxTestIsfinite)
 690 gmx_test_isfinite(HAVE_ISFINITE)
 691 gmx_test__isfinite(HAVE__ISFINITE)
 692 gmx_test__finite(HAVE__FINITE)
 693
 694 include(gmxTestCXX11)
 695 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 696 include(CMakeDependentOption)
 697 # clang with some older versions of boost fail to work with C++11
 698 if(CMAKE_CXX_COMPILER_ID MATCHES Clang AND
 699     (Boost_VERSION VERSION_EQUAL 104601 OR Boost_VERSION VERSION_EQUAL 104700))
 700     set(CLANG_AND_OLD_EXTERNAL_BOOST TRUE)
 701 endif()
 702 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 703 # entirely to keep the compilation environment uniform.
 704 cmake_dependent_option(GMX_CXX11
 705     "Use C++11 features"
 706     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU AND NOT CLANG_AND_OLD_EXTERNAL_BOOST" OFF)
 707 mark_as_advanced(GMX_CXX11)
 708 if(GMX_CXX11)
 709     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 710 endif()
 711
 712 # Now we can test for CXX11_REGEX include file
 713 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 714
 715 include(gmxTestXDR)
 716 gmx_test_xdr(GMX_SYSTEM_XDR)
 717 if(NOT GMX_SYSTEM_XDR)
 718     set(GMX_INTERNAL_XDR 1)
 719 endif()
 720
 721
 722 ##################################################
 723 # Process SIMD instruction settings
 724 ##################################################
 725 # This checks what flags to add in order to
 726 # support the SIMD instructions we need, and sets
 727 # correct defines for the SIMD instructions supported.
 728 include(gmxTestSimd)
 729 gmx_test_simd()
 730
 731
 732 # Process QM/MM Settings
 733 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 734     set(GMX_QMMM_GAUSSIAN 1)
 735 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 736     set(GMX_QMMM_MOPAC 1)
 737 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 738     set(GMX_QMMM_GAMESS 1)
 739 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 740     set(GMX_QMMM_ORCA 1)
 741 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 742     # nothing to do
 743 else()
 744     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 745 endif()
 746
 747
 748 ##################################################
 749 # Process FFT library settings
 750 ##################################################
 751 include(gmxManageFFTLibraries)
 752
 753
 754 include(gmxManageLinearAlgebraLibraries)
 755
 756 # Whether GROMACS will really try to compile support for VMD plugins
 757 set(GMX_USE_PLUGINS OFF)
 758
 759 if(GMX_LOAD_PLUGINS)
 760   if(CYGWIN OR NOT WIN32)
 761     # Native Windows does not have, nor need dlopen
 762     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 763     include(gmxTestdlopen)
 764     gmx_test_dlopen(HAVE_DLOPEN)
 765   endif()
 766
 767   # so, should we use plug-ins?
 768   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 769     if(NOT VMD_QUIETLY)
 770       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 771     endif()
 772     if(NOT GMX_VMD_PLUGIN_PATH)
 773       find_package(VMD)
 774     endif()
 775     set(GMX_USE_PLUGINS ON)
 776     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 777     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 778   else()
 779     set(PKG_DL_LIBS)
 780   endif()
 781 endif()
 782 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 783
 784 # Link real-time library for POSIX timers. The check for clock_gettime
 785 # confirms the linkability of rt.
 786 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 787     list(APPEND GMX_EXTRA_LIBRARIES rt)
 788 endif()
 789
 790 # Math and thread libraries must often come after all others when linking...
 791 if(HAVE_LIBM)
 792     list(APPEND GMX_EXTRA_LIBRARIES m)
 793 endif()
 794
 795 option(GMX_NACL "Configure for Native Client builds" OFF)
 796 if (GMX_NACL)
 797   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 798   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 799   set(GMX_NO_NICE 1)
 800   set(GMX_NO_RENAME 1)
 801 endif()
 802 mark_as_advanced(GMX_NACL)
 803
 804 if(GMX_FAHCORE)
 805   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 806       "Path to swindirect.h")
 807   include_directories(${COREWRAP_INCLUDE_DIR})
 808 endif()
 809
 810 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 811 mark_as_advanced(GMX_BUILD_HELP)
 812 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 813     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 814
 815     message(FATAL_ERROR
 816         "Rebuilding HTML and man pages is not supported for in-source "
 817         "builds from a source distribution. "
 818         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 819 endif()
 820
 821 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 822 # these are set after everything else
 823 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 824     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 825     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 826     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 827     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 828 else()
 829     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 830     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 831     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 832     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 833     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 834     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 835     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 836     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 837     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 838 endif()
 839
 840 if(NOT GMX_OPENMP)
 841     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 842     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 843     unset(OpenMP_C_FLAGS CACHE)
 844     unset(OpenMP_CXX_FLAGS CACHE)
 845 else()
 846     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 847     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 848 endif()
 849 set(PKG_CFLAGS "${PKG_CFLAGS} ${OpenMP_C_FLAGS}")
 850
 851 ########################################################################
 852 # Specify install locations
 853 ########################################################################
 854 # Use GNUInstallDirs to set paths on multiarch systems.
 855 include(GNUInstallDirs)
 856
 857 # Customization for the installation tree paths.
 858 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 859     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 860 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 861     "Data installation directory under share/ (default: gromacs)")
 862 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 863
 864 # These variables are used internally to provide a central location for
 865 # customizing the install locations.
 866 set(LIB_INSTALL_DIR  ${GMX_LIB_INSTALL_DIR})
 867 set(BIN_INSTALL_DIR  bin)
 868 set(DATA_INSTALL_DIR share/${GMX_DATA_INSTALL_DIR})
 869 set(MAN_INSTALL_DIR  share/man)
 870 set(INCL_INSTALL_DIR include)
 871
 872 # These variables get written into config.h for use in finding the data
 873 # directories.
 874 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 875 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 876
 877 # Binary and library suffix options
 878 include(gmxManageSuffixes)
 879
 880 ################################################################
 881 # Shared library load path settings
 882 ################################################################
 883 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 884 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 885 # was added.
 886
 887 if(NOT GMX_BUILD_SHARED_EXE)
 888     # No rpath
 889     set(CMAKE_SKIP_RPATH TRUE)
 890     set(CMAKE_EXE_LINK_DYNAMIC_C_FLAGS) # remove -Wl,-Bdynamic
 891     set(CMAKE_EXE_LINK_DYNAMIC_CXX_FLAGS)
 892 elseif((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 893    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 894     # The build folder always has bin/ and lib/; if we are also going to
 895     # install to lib/, then the installation RPATH works also in the build
 896     # tree.  This makes installation slightly faster (no need to rewrite the
 897     # RPATHs), and makes the binaries in the build tree relocatable.
 898     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 899         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 900     endif()
 901     # Set the RPATH as relative to the executable location to make the
 902     # binaries relocatable.
 903     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 904         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 905     else()
 906         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 907     endif()
 908     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 909     set(CMAKE_MACOSX_RPATH 1)
 910 else()
 911     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 912     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 913         # Set the RPATH options manually.
 914         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 915         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 916     else()
 917         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 918         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 919     endif()
 920 endif()
 921
 922 #COPYING file: Only necessary for binary distributions.
 923 #Simpler to always install.
 924 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 925
 926 if(GMX_EXTERNAL_BOOST)
 927     include_directories(${Boost_INCLUDE_DIRS})
 928     set(PKG_CFLAGS "${PKG_CFLAGS} -I${Boost_INCLUDE_DIRS}")
 929 else()
 930     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 931     # typeid not supported for minimal internal version
 932     # (would add significant amount of code)
 933     add_definitions(-DBOOST_NO_TYPEID)
 934     # TODO: Propagate the above settings to the installed CMakeFiles.txt template
 935     # (from share/template/)
 936     set(PKG_CFLAGS "${PKG_CFLAGS} -DBOOST_NO_TYPEID -I${CMAKE_INSTALL_PREFIX}/${INCL_INSTALL_DIR}/gromacs/external/boost")
 937     if (NOT GMX_BUILD_MDRUN_ONLY)
 938         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 939                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 940                 COMPONENT development)
 941     endif()
 942 endif()
 943
 944 if (GMX_BUILD_FOR_COVERAGE)
 945     # Code heavy with asserts makes conditional coverage close to useless metric,
 946     # as by design most of the false branches are impossible to trigger in
 947     # correctly functioning code.  And the benefit of testing those that could
 948     # be triggered by using an API against its specification isn't usually
 949     # worth the effort.
 950     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 951 endif()
 952
 953 if (BUILD_TESTING)
 954     # "tests" target builds all the separate test binaries.
 955     add_custom_target(tests)
 956     # "run-ctest" is an internal target that actually runs the tests.
 957     # This is necessary to be able to add separate targets that execute as part
 958     # of 'make check', but are ensured to be executed after the actual tests.
 959     add_custom_target(run-ctest
 960                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 961                       COMMENT "Running all tests"
 962                       VERBATIM)
 963     add_dependencies(run-ctest tests)
 964     # "check" target builds and runs all tests.
 965     add_custom_target(check DEPENDS run-ctest)
 966 endif()
 967
 968 if (NOT GMX_BUILD_MDRUN_ONLY)
 969     add_subdirectory(docs)
 970     add_subdirectory(share)
 971     add_subdirectory(scripts)
 972 endif()
 973 add_subdirectory(src)
 974
 975 if (BUILD_TESTING)
 976     add_subdirectory(tests)
 977 endif()
 978
 979 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 980 # Don't bother the user after the first configure pass.
 981 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 982     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 983 endif()
 984 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 985
 986 #######################
 987 ## uninstall target
 988 #######################
 989 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 990                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 991                   IMMEDIATE @ONLY)
 992 ###########################
 993 ADD_CUSTOM_TARGET(uninstall
 994                   "${CMAKE_COMMAND}" -P
 995                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 996 ###########################
 997 set_directory_properties(PROPERTIES
 998             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")