cmake/gmxTestCXX11.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016,2017, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CheckCXXSourceCompiles)
  36
  37 # Check whether both a suitable C++11-compatible compiler and standard
  38 # library is available, and give a fatal error if not.
  39 #
  40 # Any required compiler flag for C++11 support is returned in
  41 # ${FLAG}. The other parameters are only inputs, naming variables that
  42 # contain flags that may have been detected, or set by the user.
  43 function(GMX_TEST_CXX11 CXX11_CXX_FLAG_NAME STDLIB_CXX_FLAG_NAME STDLIB_LIBRARIES_NAME)
  44
  45     # First check that the compiler is OK, and find the appropriate flag.
  46
  47     if(WIN32 AND NOT MINGW)
  48         set(CXX11_CXX_FLAG "/Qstd=c++11")
  49     elseif(CYGWIN)
  50         set(CXX11_CXX_FLAG "-std=gnu++11") #required for strdup
  51     else()
  52         set(CXX11_CXX_FLAG "-std=c++11")
  53     endif()
  54     CHECK_CXX_COMPILER_FLAG("${CXX11_CXX_FLAG}" CXXFLAG_STD_CXX0X)
  55     if(NOT CXXFLAG_STD_CXX0X)
  56         set(CXX11_CXX_FLAG "")
  57     endif()
  58     set(CMAKE_REQUIRED_FLAGS "${CXX11_CXX_FLAG}")
  59     check_cxx_source_compiles(
  60 "// Test that a subclass has a proper copy constructor
  61 struct a {
  62   a() {};
  63   a(const a&) {};
  64   a(a&&) = delete;
  65 };
  66 class b: public a
  67 {
  68 };
  69 b bTest() {
  70   return b();
  71 }
  72 // ICC requires that a suitable GCC is available. It is using its standard library and emulates
  73 // GCC behaviour based on its version. Relevant here it emulates the implementation of the move
  74 // constructor. This compiler check should only fail based on the compiler not GCC. The GCC version
  75 // is checked by the following STL check. It is known that all ICC>=15 have the proper move
  76 // constructor. Thus this check is disabled for ICC.
  77 #if !((defined __INTEL_COMPILER && __INTEL_COMPILER >= 1500) || (defined __ICL && __ICL >= 1500))
  78 // Test that a subclass has a proper move constructor
  79 struct c {
  80   c() {};
  81   c(const c&) = delete;
  82   c(c&&) {};
  83 };
  84 struct d : public c {
  85 };
  86 d dTest() {
  87   return d();
  88 }
  89 #endif
  90 // Test that operator bool() works
  91 struct e {
  92   explicit operator bool() {return true;}
  93 };
  94 // Test that constexpr works
  95 constexpr int factorial(int n)
  96 {
  97     return n <= 1? 1 : (n * factorial(n - 1));
  98 }
  99 // Test that r-value references work
 100 void checkRvalueReference(int &&);
 101 // Test that extern templates work
 102 template <typename T> void someFunction();
 103 extern template void someFunction<int>();
 104 int main() {
 105   // Test nullptr
 106   double *x = nullptr;
 107   (void)x; // Suppressing unused variable warning
 108   // Test range-based for loops
 109   int array[5] = { 1, 2, 3, 4, 5 };
 110   for (int& x : array)
 111     x *= 2;
 112   // Test alignas
 113   alignas(4*sizeof(int)) int y;
 114 }" CXX11_SUPPORTED)
 115     if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
 116         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.8.1")
 117             message(FATAL_ERROR "GROMACS requires version 4.8.1 or later of the GNU C++ compiler for complete C++11 support")
 118         endif()
 119     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
 120         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "3.3")
 121             message(FATAL_ERROR "GROMACS requires version 3.3 or later of the Clang C++ compiler for complete C++11 support")
 122         endif()
 123     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
 124         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "15.0")
 125             message(FATAL_ERROR "GROMACS requires version 15.0 or later of the Intel C++ compiler for complete C++11 support")
 126         endif()
 127     elseif("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
 128         if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "19.0.23026")
 129             message(FATAL_ERROR "GROMACS requires version 2015 (19.0.23026) or later of the MSVC C++ compiler for complete C++11 support")
 130         endif()
 131     endif()
 132     if(CXX11_SUPPORTED)
 133         set(${CXX11_CXX_FLAG_NAME} ${CXX11_CXX_FLAG} PARENT_SCOPE)
 134     else()
 135         message(FATAL_ERROR "This version of GROMACS requires a C++11 compiler. Please use a newer compiler or use the GROMACS 5.1.x release. See the installation guide for details.")
 136     endif()
 137
 138     # Now check the standard library is OK
 139
 140     set(CMAKE_REQUIRED_FLAGS "${CXX11_CXX_FLAG} ${${STDLIB_CXX_FLAG_NAME}}")
 141     set(CMAKE_REQUIRED_LIBRARIES "${${STDLIB_LIBRARIES_NAME}}")
 142     check_cxx_source_compiles(
 143 "#include <chrono>
 144 #include <map>
 145 #include <memory>
 146 #include <thread>
 147 #include <utility>
 148 int main() {
 149   typedef std::unique_ptr<int> intPointer;
 150   intPointer p(new int(10));
 151   std::map<int, std::unique_ptr<int>> m;
 152   m.insert(std::make_pair(5, std::move(p)));
 153   auto start = std::chrono::steady_clock::now();
 154   if (std::chrono::steady_clock::now() - start < std::chrono::seconds(2))
 155   {
 156       std::thread t;
 157   }
 158 }" CXX11_STDLIB_PRESENT)
 159     if(NOT CXX11_STDLIB_PRESENT)
 160         message(FATAL_ERROR "This version of GROMACS requires C++11-compatible standard library. Several compilers (e.g. Clang and Intel) use GCC. For those make sure to have GCC 4.8.1 or later. Please use a newer compiler, or a newer standard library, or use the GROMACS 5.1.x release. See the installation guide for details.")
 161     endif()
 162 endfunction()