CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2009,2010,2011,2012,2013,2014, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 cmake_minimum_required(VERSION 2.8.8)
  36 # When we require cmake >= 2.8.12, it will provide
  37 # CMAKE_MINIMUM_REQUIRED_VERSION automatically, but in the meantime we
  38 # need to set a variable, and it must have a different name.
  39 set(GMX_CMAKE_MINIMUM_REQUIRED_VERSION "2.8.8")
  40
  41 # CMake modules/macros are in a subdirectory to keep this file cleaner
  42 # This needs to be set before project() in order to pick up toolchain files
  43 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${CMAKE_CURRENT_SOURCE_DIR}/cmake/Platform)
  44
  45 project(Gromacs)
  46
  47 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  48 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
  49 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
  50
  51 # Set up common version variables, as well as general information about
  52 # the build tree (whether the build is from a source package or from a git
  53 # repository).  Also declares a few functions that will be used for generating
  54 # version info files later.
  55 include(gmxVersionInfo)
  56
  57 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND UNIX)
  58     set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  59 endif()
  60
  61 include(gmxBuildTypeReference)
  62 include(gmxBuildTypeProfile)
  63 include(gmxBuildTypeTSAN)
  64 include(gmxBuildTypeASAN)
  65 include(gmxBuildTypeReleaseWithAssert)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel Reference RelWithAssert Profile." FORCE)
  69     # There's no need to offer a user the choice of ThreadSanitizer
  70     # Set the possible values of build type for cmake-gui
  71     set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release"
  72         "MinSizeRel" "RelWithDebInfo" "Reference" "RelWithAssert" "Profile")
  73 endif()
  74 if(CMAKE_CONFIGURATION_TYPES)
  75     # Add appropriate GROMACS-specific build types for the Visual
  76     # Studio generator (Debug, Release, MinSizeRel and RelWithDebInfo
  77     # are already present by default).
  78     list(APPEND CMAKE_CONFIGURATION_TYPES "RelWithAssert" "Reference")
  79     list(REMOVE_DUPLICATES CMAKE_CONFIGURATION_TYPES)
  80     set(CMAKE_CONFIGURATION_TYPES "${CMAKE_CONFIGURATION_TYPES}" CACHE STRING
  81         "List of configuration types"
  82         FORCE)
  83 endif()
  84 set(build_types_with_explicit_flags RELEASE DEBUG RELWITHDEBUGINFO RELWITHASSERT MINSIZEREL PROFILE)
  85
  86 set_property(GLOBAL PROPERTY FIND_LIBRARY_USE_LIB64_PATHS ON)
  87 set(CPACK_PACKAGE_NAME "gromacs")
  88 set(CPACK_PACKAGE_VERSION_MAJOR ${GMX_VERSION_MAJOR})
  89 set(CPACK_PACKAGE_VERSION_MINOR ${GMX_VERSION_MINOR})
  90 set(CPACK_PACKAGE_VERSION_PATCH ${GMX_VERSION_PATCH})
  91 set(CPACK_PACKAGE_VERSION       ${GMX_VERSION_STRING})
  92 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  93 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  94 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  95 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  96 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  97 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/COPYING")
  98 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  99 set(CPACK_SOURCE_IGNORE_FILES "\\\\.isreposource$;\\\\.git/;\\\\.gitignore$;\\\\.gitattributes;")
 100 set(CPACK_PROJECT_CONFIG_FILE "${CMAKE_SOURCE_DIR}/CPackInit.cmake")
 101 # CPack source archives include only the directories we list here.
 102 # This variable is a list of pairs of names of source and destination
 103 # directories. Most of these are used for content GROMACS generates as
 104 # part of the configuration or build.
 105 set(CPACK_SOURCE_INSTALLED_DIRECTORIES "${CMAKE_SOURCE_DIR};/;${CMAKE_BINARY_DIR}/src/programs/completion;src/programs/completion;${CMAKE_BINARY_DIR}/docs/man/man1;docs/man/man1;${CMAKE_BINARY_DIR}/docs/man/man7;docs/man/man7;${CMAKE_BINARY_DIR}/docs/old-html/final;docs/old-html/final;${CMAKE_BINARY_DIR}/docs/install-guide/final;/")
 106 set(CPACK_PACKAGE_CONTACT "gmx-users@gromacs.org")
 107 set(CPACK_GMX_BUILD_HELP "${GMX_BUILD_HELP}") #Works even though GMX_BUILD_HELP is defined later because it is off by default.
 108
 109 #must come after all cpack settings!
 110 include(CPack)
 111
 112 # Set a default valgrind suppression file.
 113 # This unfortunately needs to duplicate information from CTest to work as
 114 # expected...
 115 set(MEMORYCHECK_SUPPRESSIONS_FILE
 116     "${CMAKE_SOURCE_DIR}/cmake/legacy_and_external.supp"
 117     CACHE FILEPATH
 118     "File that contains suppressions for the memory checker")
 119 include(CTest)
 120
 121 # Variables that accumulate stuff influencing the installed headers
 122 set(INSTALLED_HEADER_INCLUDE_DIRS "")
 123 set(INSTALLED_HEADER_DEFINITIONS "")
 124
 125 ########################################################################
 126 # Check and warn if cache generated on a different host is being reused
 127 ########################################################################
 128 if(CMAKE_HOST_UNIX)
 129     execute_process(COMMAND hostname
 130                     OUTPUT_VARIABLE TMP_HOSTNAME
 131                     OUTPUT_STRIP_TRAILING_WHITESPACE)
 132     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
 133         message(WARNING "
 134             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
 135             is being reused! This could lead to inconsitencies; therefore, it is
 136             recommended to regenerate the cache!")
 137     endif()
 138     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
 139             "Hostname of the machine where the cache was generated.")
 140 endif()
 141
 142 ########################################################################
 143 # Detect architecture before setting options so we can alter defaults
 144 ########################################################################
 145 # Detect the architecture the compiler is targetting, detect
 146 # SIMD instructions possibilities on that hardware, suggest SIMD instruction set
 147 # to use if none is specified, and populate the cache option for CPU
 148 # SIMD.
 149 include(gmxDetectTargetArchitecture)
 150 gmx_detect_target_architecture()
 151
 152 ########################################################################
 153 # User input options                                                   #
 154 ########################################################################
 155 include(gmxOptionUtilities)
 156
 157 set(CMAKE_PREFIX_PATH "" CACHE STRING "Extra locations to search for external libraries and tools (give directory without lib, bin, or include)")
 158
 159 if(GMX_TARGET_FUJITSU_SPARC64)
 160     # Fujitsu only has SIMD in double precision, so this will be faster
 161     set(GMX_DOUBLE_DEFAULT ON)
 162 else()
 163     set(GMX_DOUBLE_DEFAULT OFF)
 164 endif()
 165 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" ${GMX_DOUBLE_DEFAULT})
 166 option(GMX_RELAXED_DOUBLE_PRECISION "Accept single precision 1/sqrt(x) when using Fujitsu HPC-ACE SIMD" OFF)
 167 mark_as_advanced(GMX_RELAXED_DOUBLE_PRECISION)
 168
 169 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 170 option(GMX_THREAD_MPI  "Build a thread-MPI-based multithreaded version of GROMACS (not compatible with MPI)" ON)
 171 gmx_dependent_option(
 172     GMX_MPI_IN_PLACE
 173     "Enable MPI_IN_PLACE for MPIs that have it defined"
 174     ON
 175     GMX_MPI)
 176 mark_as_advanced(GMX_MPI_IN_PLACE)
 177 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 178 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 179 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 180 mark_as_advanced(GMX_FAHCORE)
 181
 182 option(GMX_COOL_QUOTES "Enable Gromacs cool quotes" ON)
 183 mark_as_advanced(GMX_COOL_QUOTES)
 184 gmx_add_cache_dependency(GMX_COOL_QUOTES BOOL "NOT GMX_FAHCORE" OFF)
 185
 186 # Decide on GPU settings based on user-settings and GPU/CUDA detection.
 187 # We support CUDA >=v4.0 on *nix, but <= v4.1 doesn't work with MSVC
 188 if(MSVC)
 189     set(REQUIRED_CUDA_VERSION 4.1)
 190 else()
 191     set(REQUIRED_CUDA_VERSION 4.0)
 192 endif()
 193 set(REQUIRED_CUDA_COMPUTE_CAPABILITY 2.0)
 194 include(gmxManageGPU)
 195
 196 if(GMX_CPU_ACCELERATION)
 197     # Stay compatible with old Jenkins command line options for specific SIMD acceleration
 198     set(GMX_SIMD "${GMX_CPU_ACCELERATION}" CACHE STRING "SIMD instruction set level and compiler optimization" FORCE)
 199     message("You set GMX_CPU_ACCELERATION, which is deprecated, and will be removed in a later version of GROMACS. It is replaced by GMX_SIMD. For now, copying the value from GMX_CPU_ACCELERATION to GMX_SIMD.")
 200     # TODO remove all references to GMX_CPU_ACCELERATION in master branch
 201 endif()
 202
 203 if(NOT GMX_TARGET_MIC)
 204     include(gmxDetectSimd)
 205     gmx_detect_simd(GMX_SUGGESTED_SIMD)
 206 else()
 207     set(GMX_SUGGESTED_SIMD "None")
 208 endif()
 209
 210 gmx_option_multichoice(
 211     GMX_SIMD
 212     "SIMD instruction set for CPU kernels and compiler optimization"
 213     "${GMX_SUGGESTED_SIMD}"
 214     None SSE2 SSE4.1 AVX_128_FMA AVX_256 AVX2_256 IBM_QPX Sparc64_HPC_ACE Reference)
 215
 216 gmx_option_multichoice(
 217     GMX_FFT_LIBRARY
 218     "FFT library"
 219     "fftw3"
 220     fftw3 mkl "fftpack[built-in]")
 221 gmx_dependent_option(
 222     GMX_BUILD_OWN_FFTW
 223     "Download and build FFTW 3 during the GROMACS build process, rather than fall back on the really slow fftpack."
 224     OFF
 225     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 226 gmx_dependent_option(
 227     GMX_DISABLE_FFTW_MEASURE
 228     "Do not optimize FFTW setups (not needed with SSE)"
 229     OFF
 230     "GMX_FFT_LIBRARY STREQUAL FFTW3")
 231 mark_as_advanced(GMX_BUILD_OWN_FFTW)
 232 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 233
 234 gmx_option_multichoice(
 235     GMX_QMMM_PROGRAM
 236     "QM package for QM/MM"
 237     None
 238     none gaussian mopac gamess orca)
 239
 240 gmx_dependent_cache_variable(GMX_SIMD_REF_FLOAT_WIDTH  "Reference SIMD single precision width" STRING "4" "GMX_SIMD STREQUAL REFERENCE")
 241 gmx_dependent_cache_variable(GMX_SIMD_REF_DOUBLE_WIDTH "Reference SIMD double precision width" STRING "2" "GMX_SIMD STREQUAL REFERENCE")
 242
 243 # This should be moved to a separate NBNXN cmake module when that code is cleaned up and modularized
 244
 245 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 246 mark_as_advanced(GMX_BROKEN_CALLOC)
 247 option(GMX_LOAD_PLUGINS "Compile with plugin support, needed to read VMD supported file formats" ON)
 248 mark_as_advanced(GMX_LOAD_PLUGINS)
 249
 250 option(GMX_GPU  "Enable GPU acceleration" ON)
 251 option(GMX_OPENMP "Enable OpenMP-based multithreading" ON)
 252
 253 option(GMX_USE_TNG "Use the TNG library for trajectory I/O" ON)
 254
 255 if(UNIX)
 256     option(GMX_SYMLINK_OLD_BINARY_NAMES "Create symbolic links for pre-5.0 binary names" ON)
 257 endif()
 258 option(GMX_BUILD_MDRUN_ONLY "Build and install only the mdrun binary" OFF)
 259
 260 option(GMX_CYCLE_SUBCOUNTERS "Enable cycle subcounters to get a more detailed cycle timings" OFF)
 261 mark_as_advanced(GMX_CYCLE_SUBCOUNTERS)
 262
 263 option(GMX_SKIP_DEFAULT_CFLAGS "Don't automatically add suggested/required Compiler flags." OFF)
 264 mark_as_advanced(GMX_SKIP_DEFAULT_CFLAGS)
 265
 266 option(GMX_BUILD_FOR_COVERAGE
 267        "Tune build for better code coverage metrics (e.g., disable asserts)"
 268        OFF)
 269 mark_as_advanced(GMX_BUILD_FOR_COVERAGE)
 270
 271 option(GMX_DEVELOPER_BUILD
 272     "Enable Developer convenience features: always build unit-tests"
 273     OFF)
 274 mark_as_advanced(GMX_DEVELOPER_BUILD)
 275
 276 ######################################################################
 277 # Detect OpenMP support
 278 ######################################################################
 279 # The OpenMP detection _must_ come before tests for other CFLAGS.
 280 include(gmxManageOpenMP)
 281
 282
 283
 284 ######################################################################
 285 # Compiler tests
 286 # These need to be done early (before further tests).
 287 #####################################################################
 288
 289 # The cmake/Check{C,CXX}CompilerFlag.cmake files in the GROMACS distribution
 290 # are used with permission from CMake v3.0.0 so that GROMACS can detect
 291 # invalid options with the Intel Compilers, and we have added a line
 292 # to detect warnings with the Fujitsu compilers on K computer and ICC.
 293 # CMake-3.0 also has a bug where the FAIL_REGEX pattern for AIX contains
 294 # a semicolon. Since this is also used as a separator in lists inside CMake,
 295 # that string ends up being split into two separate patterns, and the last
 296 # part is just a single word that also matches other messages. We solved this
 297 # by replacing the semicolon with a period that matches any character.
 298 #
 299 # These files should be removed from the source tree when a CMake version that
 300 # includes the features in question becomes required for building GROMACS.
 301 include(CheckCCompilerFlag)
 302 include(CheckCXXCompilerFlag)
 303
 304 include(gmxCFlags)
 305 gmx_c_flags()
 306
 307 # This variable should be used for additional compiler flags which are not
 308 # generated in gmxCFlags nor are SIMD or MPI related.
 309 set(EXTRA_C_FLAGS "")
 310 set(EXTRA_CXX_FLAGS "")
 311
 312 # Run through a number of tests for buggy compilers and other issues
 313 include(gmxTestCompilerProblems)
 314 gmx_test_compiler_problems()
 315 # GMX_SIMD will not be set automatically until the second
 316 # pass (which is not strictly guaranteed to occur), so putting this
 317 # check here among logically-related tests is inefficient, but the
 318 # potential loss is likely zero.
 319 if(GMX_SIMD STREQUAL "AVX_256"
 320         AND CMAKE_COMPILER_IS_GNUCC
 321         AND (C_COMPILER_VERSION VERSION_EQUAL "4.6.1"
 322             OR CXX_COMPILER_VERSION VERSION_EQUAL "4.6.1"))
 323     message(FATAL_ERROR "gcc 4.6.1 has buggy support for AVX, and GROMACS mdrun will not work. If you want simulation performance, use a more recent compiler. Otherwise, use GMX_SIMD=SSE4.1")
 324     # See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=49002
 325 endif()
 326
 327
 328 if(GMX_DOUBLE)
 329     add_definitions(-DGMX_DOUBLE)
 330     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_DOUBLE")
 331     if(GMX_RELAXED_DOUBLE_PRECISION)
 332         add_definitions(-DGMX_RELAXED_DOUBLE_PRECISION)
 333     endif()
 334 endif()
 335 if(GMX_SOFTWARE_INVSQRT)
 336     list(APPEND INSTALLED_HEADER_DEFINITIONS "-DGMX_SOFTWARE_INVSQRT")
 337 endif()
 338
 339 if(WIN32 AND NOT CYGWIN)
 340     list(APPEND GMX_EXTRA_LIBRARIES "wsock32")
 341     add_definitions(-DGMX_HAVE_WINSOCK)
 342 endif()
 343
 344
 345
 346 ########################################################################
 347 # Basic system tests (standard libraries, headers, functions, types)   #
 348 ########################################################################
 349 include(CheckIncludeFiles)
 350 include(CheckIncludeFileCXX)
 351 check_include_files(unistd.h     HAVE_UNISTD_H)
 352 check_include_files(pwd.h        HAVE_PWD_H)
 353 check_include_files(dirent.h     HAVE_DIRENT_H)
 354 check_include_files(time.h       HAVE_TIME_H)
 355 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 356 check_include_files(io.h         HAVE_IO_H)
 357 check_include_files(sched.h      HAVE_SCHED_H)
 358
 359 check_include_files(regex.h      HAVE_POSIX_REGEX)
 360 check_include_file_cxx(regex     HAVE_CXX11_REGEX)
 361 # TODO: It could be nice to inform the user if no regex support is found,
 362 # as selections won't be fully functional.
 363
 364 include(CheckFunctionExists)
 365 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 366 check_function_exists(memalign          HAVE_MEMALIGN)
 367 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 368 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 369 check_function_exists(fsync             HAVE_FSYNC)
 370 check_function_exists(_fileno           HAVE__FILENO)
 371 check_function_exists(fileno            HAVE_FILENO)
 372 check_function_exists(_commit           HAVE__COMMIT)
 373 check_function_exists(sigaction         HAVE_SIGACTION)
 374 check_function_exists(sysconf           HAVE_SYSCONF)
 375 check_function_exists(rsqrt             HAVE_RSQRT)
 376 check_function_exists(rsqrtf            HAVE_RSQRTF)
 377 check_function_exists(sqrtf             HAVE_SQRTF)
 378
 379 include(CheckLibraryExists)
 380 check_library_exists(m sqrt "" HAVE_LIBM)
 381 check_library_exists(rt clock_gettime "" HAVE_CLOCK_GETTIME)
 382
 383 include(TestSchedAffinity)
 384 test_sched_affinity(HAVE_SCHED_AFFINITY)
 385
 386 include(TestBigEndian)
 387 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 388
 389 # Management of GROMACS options for specific toolchains should go
 390 # here. Because the initial settings for some of the main options have
 391 # already happened, but things like library detection and MPI compiler
 392 # feature detection have not, the docstrings for any over-rides of
 393 # GROMACS defaults or user settings will make sense. Also, any
 394 # toolchain-related reasons for choosing whether to detect various
 395 # things can be sorted out now, before the detection takes place.
 396 if(${CMAKE_SYSTEM_NAME} MATCHES BlueGene)
 397     include(gmxManageBlueGene)
 398 endif()
 399
 400 if(GMX_TARGET_FUJITSU_SPARC64)
 401     include(gmxManageFujitsuSparc64)
 402 endif()
 403
 404 ########################################################################
 405 #Process MPI settings
 406 ########################################################################
 407 include(gmxManageMPI)
 408
 409
 410 ########################################################################
 411 #Process shared/static library settings
 412 ########################################################################
 413 include(gmxManageSharedLibraries)
 414
 415
 416 ########################################################################
 417 # Find external packages                                               #
 418 ########################################################################
 419
 420 # Unconditionally find the package, as it is also required for unit
 421 # tests. This exports LIBXML2_FOUND, which we should not use because
 422 # it does not tell us that linking will succeed. Instead, we test that
 423 # next.
 424 if(DEFINED LIBXML2_LIBRARIES)
 425   set(LibXml2_FIND_QUIETLY TRUE)
 426 endif()
 427 find_package(LibXml2)
 428 include(gmxTestLibXml2)
 429 gmx_test_libxml2(HAVE_LIBXML2)
 430 option(GMX_XML "Use libxml2 to parse xml files (currently has no effect)" ${HAVE_LIBXML2})
 431 set(PKG_XML "")
 432 mark_as_advanced(GMX_XML)
 433 # Don't actually do anything, since libxml2 is currently not used by libgromacs
 434 #if(GMX_XML AND NOT HAVE_LIBXML2)
 435 #    message(FATAL_ERROR "libxml2 not found. Set GMX_XML=OFF to compile without XML support")
 436 #endif()
 437 #if(GMX_XML)
 438 #    include_directories(${LIBXML2_INCLUDE_DIR})
 439 #    set(PKG_XML libxml-2.0)
 440 #    set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 441 #endif()
 442
 443 option(GMX_EXTRAE "Add support for tracing using EXTRAE" OFF)
 444 mark_as_advanced(GMX_EXTRAE)
 445
 446 if (GMX_EXTRAE)
 447   find_package(EXTRAE)
 448   if(EXTRAE_FOUND)
 449     include_directories(${EXTRAE_INCLUDE_DIR})
 450     set(HAVE_EXTRAE 1)
 451   else()
 452     message(FATAL_ERROR "EXTRAE library was not found. Please add the correct path to CMAKE_PREFIX_PATH")
 453   endif()
 454 endif()
 455
 456 option(GMX_X11 "Use X window system" OFF)
 457 if (GMX_X11)
 458     find_package(X11)
 459     # X11 includes/libraries are only set in the ngmx subdirectory!
 460     if(NOT X11_FOUND)
 461         message(FATAL_ERROR
 462                 "X11 include files and/or libraries were not found. "
 463                 "Set GMX_X11=OFF to compile without X11 support. "
 464                 "gmx view will not be available.")
 465     endif()
 466     include_directories(${X11_INCLUDE_DIR})
 467 endif()
 468
 469 include(ThreadMPI)
 470 # Enable core threading facilities
 471 tmpi_enable_core("${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include")
 472 # Enable tMPI C++ support
 473 tmpi_enable_cxx()
 474 if(GMX_THREAD_MPI)
 475     # enable MPI functions
 476     tmpi_enable()
 477     set(GMX_MPI 1)
 478     set(MPI_IN_PLACE_EXISTS 1)
 479 endif()
 480 # If atomics are manually disabled a define is needed because atomics.h doesn't depend on config.h
 481 if (TMPI_ATOMICS_DISABLED)
 482    add_definitions(-DTMPI_ATOMICS_DISABLED)
 483 endif()
 484
 485 if(GMX_GPU)
 486     # now that we have detected the dependencies, do the second configure pass
 487     gmx_gpu_setup()
 488 endif()
 489
 490 if(CYGWIN)
 491     set(GMX_CYGWIN 1)
 492 endif()
 493
 494 if(WIN32 AND NOT CYGWIN)
 495     set(GMX_NATIVE_WINDOWS 1)
 496     # This makes windows.h not declare min/max as macros that would break
 497     # C++ code using std::min/std::max.
 498     add_definitions(-DNOMINMAX)
 499 endif()
 500
 501 # Detect boost unless GMX_EXTERNAL_BOOST is explicitly OFF
 502 # Used for default if GMX_EXTERNAL_BOOST is not defined (first CMake pass)
 503 if(NOT DEFINED GMX_EXTERNAL_BOOST OR GMX_EXTERNAL_BOOST)
 504     find_package(Boost 1.44.0)
 505     if(Boost_FOUND AND Boost_VERSION VERSION_LESS "104400")
 506         set(Boost_FOUND FALSE)
 507     endif()
 508     # Print the notification only on first run, when determining the default
 509     if(NOT DEFINED GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 510         message("Boost >= 1.44 not found. Using minimal internal version. "
 511                 "This may cause trouble if you plan on compiling/linking other "
 512                 "software that uses Boost against Gromacs.")
 513     endif()
 514 endif()
 515 option(GMX_EXTERNAL_BOOST "Use external Boost instead of minimal built-in version"
 516        ${Boost_FOUND})
 517 if(GMX_EXTERNAL_BOOST AND NOT Boost_FOUND)
 518     message(FATAL_ERROR
 519         "Boost >= 1.44 not found. "
 520         "You can set GMX_EXTERNAL_BOOST=OFF to compile against minimal "
 521         "version of Boost included with Gromacs.")
 522 endif()
 523
 524 if(NOT DEFINED GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 525     message(WARNING "libxml2 not found. Will build GROMACS without unit-tests. This is not recommended, because the unit-tests help to verify that GROMACS functions correctly. Most likely you are missing the libxml2-dev(el) package. After you installed it, set GMX_BUILD_UNITTESTS=ON.")
 526 endif()
 527 option(GMX_BUILD_UNITTESTS "Build unit tests with BUILD_TESTING (uses Google C++ Testing and Mocking Frameworks, requires libxml2)" ${HAVE_LIBXML2})
 528 mark_as_advanced(GMX_BUILD_UNITTESTS)
 529 gmx_add_cache_dependency(GMX_BUILD_UNITTESTS BOOL BUILD_TESTING OFF)
 530 if (GMX_BUILD_UNITTESTS AND NOT HAVE_LIBXML2)
 531     message(FATAL_ERROR
 532         "Cannot build unit tests without libxml2. "
 533         "Either set GMX_BUILD_UNITTESTS=OFF or tell CMake how to find a working version of libxml2.")
 534 endif()
 535
 536 if(GMX_USE_TNG AND NOT GMX_EXTERNAL_TNG)
 537     # TNG wants zlib if it is available
 538     find_package(ZLIB QUIET)
 539     include(gmxTestZLib)
 540     gmx_test_zlib(HAVE_ZLIB)
 541 endif()
 542
 543 ########################################################################
 544 # Our own GROMACS tests
 545 ########################################################################
 546
 547 add_definitions( -DHAVE_CONFIG_H )
 548 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src)
 549 include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/thread_mpi/include)
 550 # Required for config.h, maybe should only be set in src/CMakeLists.txt
 551 include_directories(BEFORE ${CMAKE_BINARY_DIR}/src)
 552
 553 include(gmxTestInlineASM)
 554 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 555
 556 include(gmxSetBuildInformation)
 557 gmx_set_build_information()
 558 # Turn on RDTSCP if:
 559 # - the build system's CPU supports it
 560 # - the acceleration is set to AVX as all AVX-capable CPUs support AVX (which
 561 #   at this point means that the user set it).
 562 # Note: it's better to not use the later set value of GMX_SIMD because
 563 # it reflects the system's capability of both compiling and running AVX code.
 564 # TODO: After merge with 5.0 one could implement a cache variable dependency
 565 # such that GMX_USE_RDTSCP can change if GMX_SIMD is changed to AVX
 566 # after the first cmake pass.
 567 if (BUILD_CPU_FEATURES MATCHES "rdtscp" OR GMX_SIMD MATCHES "AVX")
 568     set(GMX_USE_RDTSCP_DEFAULT_VALUE ON)
 569 else()
 570     set(GMX_USE_RDTSCP_DEFAULT_VALUE OFF)
 571 endif()
 572 option(GMX_USE_RDTSCP "Use RDTSCP for better CPU-based timers (available on recent x86 CPUs; might need to be off when compiling for heterogeneous environments)" ${GMX_USE_RDTSCP_DEFAULT_VALUE})
 573 mark_as_advanced(GMX_USE_RDTSCP)
 574 if(GMX_USE_RDTSCP)
 575     set(HAVE_RDTSCP 1)
 576 endif()
 577
 578 include(gmxTestFloatFormat)
 579 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 580                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 581                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 582
 583 include(gmxTestLargeFiles)
 584 gmx_test_large_files(GMX_LARGEFILES)
 585
 586 include(gmxTestSignal)
 587 gmx_test_sigusr1(HAVE_SIGUSR1)
 588
 589 include(gmxTestPipes)
 590 gmx_test_pipes(HAVE_PIPES)
 591
 592 include(gmxTestIsfinite)
 593 gmx_test_isfinite(HAVE_ISFINITE)
 594 gmx_test__isfinite(HAVE__ISFINITE)
 595 gmx_test__finite(HAVE__FINITE)
 596
 597 include(gmxTestCXX11)
 598 gmx_test_cxx11(GMX_CXX11_SUPPORTED GMX_CXX11_FLAGS)
 599 include(CMakeDependentOption)
 600 # nvcc does not support C++11 flags, so with GPUs we prefer to skip C++11 flags
 601 # entirely to keep the compilation environment uniform.
 602 cmake_dependent_option(GMX_CXX11
 603     "Use C++11 features"
 604     ON "GMX_CXX11_SUPPORTED AND NOT GMX_GPU" OFF)
 605 mark_as_advanced(GMX_CXX11)
 606 if(GMX_CXX11)
 607     set(EXTRA_CXX_FLAGS "${EXTRA_CXX_FLAGS} ${GMX_CXX11_FLAGS}")
 608 endif()
 609
 610
 611 include(gmxTestXDR)
 612 gmx_test_xdr(GMX_SYSTEM_XDR)
 613 if(NOT GMX_SYSTEM_XDR)
 614     set(GMX_INTERNAL_XDR 1)
 615 endif()
 616
 617
 618 ##################################################
 619 # Process SIMD instruction settings
 620 ##################################################
 621 # This checks what flags to add in order to
 622 # support the SIMD instructions we need, and sets
 623 # correct defines for the SIMD instructions supported.
 624 include(gmxTestSimd)
 625 gmx_test_simd()
 626
 627
 628 # Process QM/MM Settings
 629 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 630     set(GMX_QMMM_GAUSSIAN 1)
 631 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 632     set(GMX_QMMM_MOPAC 1)
 633 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 634     set(GMX_QMMM_GAMESS 1)
 635 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 636     set(GMX_QMMM_ORCA 1)
 637 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 638     # nothing to do
 639 else()
 640     gmx_invalid_option_value(GMX_QMMM_PROGRAM)
 641 endif()
 642
 643
 644 ##################################################
 645 # Process FFT library settings
 646 ##################################################
 647 include(gmxManageFFTLibraries)
 648
 649
 650 include(gmxManageLinearAlgebraLibraries)
 651
 652 # Whether GROMACS will really try to compile support for VMD plugins
 653 set(GMX_USE_PLUGINS OFF)
 654
 655 if(GMX_LOAD_PLUGINS)
 656   if(CYGWIN OR NOT WIN32)
 657     # Native Windows does not have, nor need dlopen
 658     # Note that WIN32 is set with Cygwin, but Cygwin needs dlopen to use plug-ins
 659     include(gmxTestdlopen)
 660     gmx_test_dlopen(HAVE_DLOPEN)
 661   endif()
 662
 663   # so, should we use plug-ins?
 664   if((WIN32 AND NOT CYGWIN) OR (HAVE_DLOPEN AND BUILD_SHARED_LIBS))
 665     if(NOT VMD_QUIETLY)
 666       MESSAGE(STATUS "Using dynamic plugins (e.g VMD-supported file formats)")
 667     endif()
 668     if(NOT GMX_VMD_PLUGIN_PATH)
 669       find_package(VMD)
 670     endif()
 671     set(GMX_USE_PLUGINS ON)
 672     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS}) # magic cross-platform pre-set variable for dlopen library
 673     set(PKG_DL_LIBS "-l${CMAKE_DL_LIBS}")
 674   else()
 675     set(PKG_DL_LIBS)
 676   endif()
 677 endif()
 678 set(VMD_QUIETLY TRUE CACHE INTERNAL "")
 679
 680 # Link real-time library for POSIX timers. The check for clock_gettime
 681 # confirms the linkability of rt.
 682 if(HAVE_TIME_H AND HAVE_UNISTD_H AND HAVE_CLOCK_GETTIME)
 683     list(APPEND GMX_EXTRA_LIBRARIES rt)
 684 endif()
 685
 686 # Math and thread libraries must often come after all others when linking...
 687 if(HAVE_LIBM)
 688     list(APPEND GMX_EXTRA_LIBRARIES m)
 689 endif()
 690
 691 option(GMX_NACL "Configure for Native Client builds" OFF)
 692 if (GMX_NACL)
 693   list(APPEND GMX_EXTRA_LIBRARIES nosys)
 694   set(GMX_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -lnosys")
 695   set(GMX_NO_NICE 1)
 696   set(GMX_NO_RENAME 1)
 697 endif()
 698 mark_as_advanced(GMX_NACL)
 699
 700 if(GMX_FAHCORE)
 701   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 702       "Path to swindirect.h")
 703   include_directories(${COREWRAP_INCLUDE_DIR})
 704 endif()
 705
 706 option(GMX_BUILD_HELP "Build man pages, HTML help, and completions automatically (requires that compiled binaries can be executed on the build host)" OFF)
 707 mark_as_advanced(GMX_BUILD_HELP)
 708 if (GMX_BUILD_HELP AND SOURCE_IS_SOURCE_DISTRIBUTION AND
 709     "${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 710
 711     message(FATAL_ERROR
 712         "Rebuilding HTML and man pages is not supported for in-source "
 713         "builds from a source distribution. "
 714         "Set GMX_BUILD_HELP=OFF or do an out-of-source build to proceed.")
 715 endif()
 716
 717 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 718 # these are set after everything else
 719 if (NOT GMX_SKIP_DEFAULT_CFLAGS)
 720     set(CMAKE_C_FLAGS "${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${CMAKE_C_FLAGS}")
 721     set(CMAKE_CXX_FLAGS "${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${CMAKE_CXX_FLAGS}")
 722     set(CMAKE_EXE_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}")
 723     set(CMAKE_SHARED_LINKER_FLAGS "${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS}")
 724 else()
 725     message("Recommended flags which are not added because GMX_SKIP_DEFAULT_CFLAGS=yes:")
 726     message("CMAKE_C_FLAGS: ${SIMD_C_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_C_FLAGS} ${GMXC_CFLAGS}")
 727     message("CMAKE_C_FLAGS_RELEASE: ${GMXC_CFLAGS_RELEASE}")
 728     message("CMAKE_C_FLAGS_DEBUG: ${GMXC_CFLAGS_DEBUG}")
 729     message("CMAKE_CXX_FLAGS: ${SIMD_CXX_FLAGS} ${MPI_COMPILE_FLAGS} ${EXTRA_CXX_FLAGS} ${GMXC_CXXFLAGS}")
 730     message("CMAKE_CXX_FLAGS_RELEASE: ${GMXC_CXXFLAGS_RELEASE}")
 731     message("CMAKE_CXX_FLAGS_DEBUG: ${GMXC_CXXFLAGS_DEBUG}")
 732     message("CMAKE_EXE_LINKER_FLAGS: ${FFT_LINKER_FLAGS} ${MPI_LINKER_FLAGS}")
 733     message("CMAKE_SHARED_LINKER_FLAGS: ${MPI_LINKER_FLAGS}")
 734 endif()
 735
 736 if(NOT GMX_OPENMP)
 737     #Unset all OpenMP flags in case OpenMP was disabled either by the user
 738     #or because it was only partially detected (e.g. only for C but not C++ compiler)
 739     unset(OpenMP_C_FLAGS CACHE)
 740     unset(OpenMP_CXX_FLAGS CACHE)
 741 else()
 742     set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} ${OpenMP_LINKER_FLAGS})
 743     set(GMX_SHARED_LINKER_FLAGS ${GMX_SHARED_LINKER_FLAGS} ${OpenMP_SHARED_LINKER_FLAGS})
 744 endif()
 745
 746 ########################################################################
 747 # Specify install locations
 748 ########################################################################
 749 # Use GNUInstallDirs to set paths on multiarch systems.
 750 include(GNUInstallDirs)
 751
 752 # Customization for the installation tree paths.
 753 set(GMX_LIB_INSTALL_DIR ${CMAKE_INSTALL_LIBDIR} CACHE STRING
 754     "Library installation directory (default: ${CMAKE_INSTALL_LIBDIR})")
 755 set(GMX_DATA_INSTALL_DIR gromacs CACHE STRING
 756     "Data installation directory under share/ (default: gromacs)")
 757 mark_as_advanced(GMX_LIB_INSTALL_DIR GMX_DATA_INSTALL_DIR)
 758
 759 # These variables are used internally to provide a central location for
 760 # customizing the install locations.
 761 set(LIB_INSTALL_DIR       ${GMX_LIB_INSTALL_DIR})
 762 set(BIN_INSTALL_DIR       bin)
 763 set(DATA_INSTALL_DIR      share/${GMX_DATA_INSTALL_DIR})
 764 set(MAN_INSTALL_DIR       share/man)
 765 # If the nesting level wrt. the installation root is changed,
 766 # gromacs-config.cmake.cmakein needs to be adapted.
 767 set(CMAKE_INSTALL_DIR     share/cmake)
 768 # TODO: Make GMXRC adapt if this is changed
 769 set(PKGCONFIG_INSTALL_DIR ${LIB_INSTALL_DIR}/pkgconfig)
 770 set(INCL_INSTALL_DIR      include)
 771
 772 # These variables get written into config.h for use in finding the data
 773 # directories.
 774 set(GMXLIB_SEARCH_DIR share/${GMX_DATA_INSTALL_DIR}/top)
 775 set(GMXLIB_FALLBACK   ${CMAKE_INSTALL_PREFIX}/${DATA_INSTALL_DIR}/top)
 776
 777 list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR})
 778
 779 # Binary and library suffix options
 780 include(gmxManageSuffixes)
 781
 782 ################################################################
 783 # Shared library load path settings
 784 ################################################################
 785 # CMake supports RPATH on OS X only from 2.8.12 upwards.
 786 # CMAKE_SYSTEM_VERSION > 8.0 matches OS X 10.5 and above, where RPATH support
 787 # was added.
 788 if((NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin") OR
 789    ((CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0) AND (NOT CMAKE_VERSION VERSION_LESS 2.8.12)))
 790     # The build folder always has bin/ and lib/; if we are also going to
 791     # install to lib/, then the installation RPATH works also in the build
 792     # tree.  This makes installation slightly faster (no need to rewrite the
 793     # RPATHs), and makes the binaries in the build tree relocatable.
 794     if(GMX_LIB_INSTALL_DIR STREQUAL "lib")
 795         set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 796     endif()
 797     # Set the RPATH as relative to the executable location to make the
 798     # binaries relocatable.
 799     if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 800         set(CMAKE_INSTALL_RPATH "\$ORIGIN/../${GMX_LIB_INSTALL_DIR}")
 801     else()
 802         set(CMAKE_INSTALL_RPATH "@executable_path/../${GMX_LIB_INSTALL_DIR}")
 803     endif()
 804     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 805     set(CMAKE_MACOSX_RPATH 1)
 806 else()
 807     # We are on Darwin/OSX, and CMake cannot handle RPATHs automatically.
 808     if(CMAKE_SYSTEM_VERSION VERSION_GREATER 8.0)
 809         # Set the RPATH options manually.
 810         set(CMAKE_INSTALL_NAME_DIR "@rpath")
 811         set(GMX_EXE_LINKER_FLAGS ${GMX_EXE_LINKER_FLAGS} "-Wl,-rpath,@executable_path/../${GMX_LIB_INSTALL_DIR}")
 812     else()
 813         # Use the old INSTALL_NAME_DIR mechanism if RPATH is not supported.
 814         set(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}")
 815     endif()
 816 endif()
 817
 818 #COPYING file: Only necessary for binary distributions.
 819 #Simpler to always install.
 820 install(FILES COPYING DESTINATION ${DATA_INSTALL_DIR} COMPONENT data)
 821
 822 if(GMX_EXTERNAL_BOOST)
 823     include_directories(${Boost_INCLUDE_DIRS})
 824     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${Boost_INCLUDE_DIRS})
 825 else()
 826     include_directories(BEFORE ${CMAKE_SOURCE_DIR}/src/external/boost)
 827     list(APPEND INSTALLED_HEADER_INCLUDE_DIRS ${INCL_INSTALL_DIR}/gromacs/external/boost)
 828     list(APPEND INSTALLED_HEADED_DEFINITIONS "-DBOOST_NO_TYPEID")
 829     # typeid not supported for minimal internal version
 830     # (would add significant amount of code)
 831     add_definitions(-DBOOST_NO_TYPEID)
 832     if (NOT GMX_BUILD_MDRUN_ONLY)
 833         install(DIRECTORY ${CMAKE_SOURCE_DIR}/src/external/boost/boost
 834                 DESTINATION ${INCL_INSTALL_DIR}/gromacs/external/boost
 835                 COMPONENT development)
 836     endif()
 837 endif()
 838
 839 if (GMX_BUILD_FOR_COVERAGE)
 840     # Code heavy with asserts makes conditional coverage close to useless metric,
 841     # as by design most of the false branches are impossible to trigger in
 842     # correctly functioning code.  And the benefit of testing those that could
 843     # be triggered by using an API against its specification isn't usually
 844     # worth the effort.
 845     add_definitions(-DNDEBUG -DBOOST_DISABLE_ASSERTS -DGMX_DISABLE_ASSERTS)
 846 endif()
 847
 848 if (BUILD_TESTING)
 849     # "tests" target builds all the separate test binaries.
 850     add_custom_target(tests)
 851     # "run-ctest" is an internal target that actually runs the tests.
 852     # This is necessary to be able to add separate targets that execute as part
 853     # of 'make check', but are ensured to be executed after the actual tests.
 854     add_custom_target(run-ctest
 855                       COMMAND ${CMAKE_CTEST_COMMAND} --output-on-failure
 856                       COMMENT "Running all tests"
 857                       VERBATIM)
 858     add_dependencies(run-ctest tests)
 859     # "check" target builds and runs all tests.
 860     add_custom_target(check DEPENDS run-ctest)
 861 endif()
 862
 863 if (NOT GMX_BUILD_MDRUN_ONLY)
 864     add_subdirectory(docs)
 865     add_subdirectory(share)
 866     add_subdirectory(scripts)
 867 endif()
 868 add_subdirectory(src)
 869
 870 if (BUILD_TESTING)
 871     add_subdirectory(tests)
 872 endif()
 873
 874 # Issue a warning if NVIDIA GPUs were detected, but CUDA was not found.
 875 # Don't bother the user after the first configure pass.
 876 if ((CUDA_NOTFOUND_AUTO AND GMX_DETECT_GPU_AVAILABLE) AND NOT GMX_GPU_DETECTION_DONE)
 877     message(WARNING "${CUDA_NOTFOUND_MESSAGE}")
 878 endif()
 879 set(GMX_GPU_DETECTION_DONE TRUE CACHE INTERNAL "Whether GPU detection has already been done")
 880
 881 #######################
 882 ## uninstall target
 883 #######################
 884 CONFIGURE_FILE(   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 885                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 886                   IMMEDIATE @ONLY)
 887 ###########################
 888 ADD_CUSTOM_TARGET(uninstall
 889                   "${CMAKE_COMMAND}" -P
 890                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 891 ###########################
 892 set_directory_properties(PROPERTIES
 893             ADDITIONAL_MAKE_CLEAN_FILES "install_manifest.txt")