cmake/gmxManageGPU.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # If the user did not set GMX_GPU we'll consider this option to be
  36 # in "auto" mode meaning that we will:
  37 # - search for CUDA and set GMX_GPU=ON we find it
  38 # - check whether GPUs are present
  39 # - if CUDA is not found but GPUs were detected issue a warning
  40 if (NOT DEFINED GMX_GPU)
  41     set(GMX_GPU_AUTO TRUE CACHE INTERNAL "GPU acceleration will be selected automatically")
  42 endif()
  43 option(GMX_GPU "Enable GPU acceleration" OFF)
  44
  45 if(GMX_GPU AND GMX_DOUBLE)
  46     message(FATAL_ERROR "GPU acceleration is not available in double precision!")
  47 endif()
  48 if(GMX_GPU_AUTO AND GMX_DOUBLE)
  49     message(WARNING "GPU acceleration is not available in double precision, disabled!")
  50     set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
  51     set_property(CACHE GMX_GPU_AUTO PROPERTY VALUE OFF)
  52 endif()
  53
  54 # detect GPUs in the build host machine
  55 if ((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  56     include(gmxDetectGpu)
  57     gmx_detect_gpu()
  58 endif()
  59
  60 # We need to call find_package even when we've already done the detection/setup
  61 if(GMX_GPU OR GMX_GPU_AUTO)
  62     if(NOT GMX_GPU AND NOT GMX_DETECT_GPU_AVAILABLE)
  63         # Stay quiet when detection has occured and found no GPU.
  64         # Noise is acceptable when there is a GPU or the user required one.
  65         set(FIND_CUDA_QUIETLY QUIET)
  66     endif()
  67
  68     # Cmake tries to use the static cuda runtime by default,
  69     # but this leads to unusable GPU builds on OS X.
  70     if(APPLE)
  71         set(CUDA_USE_STATIC_CUDA_RUNTIME OFF CACHE STRING "Use the static version of the CUDA runtime library if available")
  72     endif()
  73
  74     find_package(CUDA ${REQUIRED_CUDA_VERSION} ${FIND_CUDA_QUIETLY})
  75 endif()
  76
  77 # Depending on the current vale of GMX_GPU and GMX_GPU_AUTO:
  78 # - OFF, FALSE: Will skip this detection/setup.
  79 # - OFF, TRUE : Will keep GMX_GPU=OFF if no CUDA is detected, but will assemble
  80 #               a warning message which will be issued at the end of the
  81 #               configuration if GPU(s) were found in the build system.
  82 # - ON , FALSE: The user requested GPU build and this requires CUDA, so we will
  83 #               fail if it is not available.
  84 # - ON , TRUE : Can't happen (GMX_GPU=ON can only be user-set at this point)
  85 if((GMX_GPU OR GMX_GPU_AUTO) AND NOT GMX_GPU_DETECTION_DONE)
  86     if (EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
  87         set(CUDA_FOUND TRUE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  88     else()
  89         set(CUDA_FOUND FALSE CACHE INTERNAL "Whether the CUDA toolkit was found" FORCE)
  90     endif()
  91
  92     # assemble warning/error message
  93     if (GMX_DETECT_GPU_AVAILABLE)
  94         set(_msg "${GMX_DETECT_GPU_COUNT} NVIDIA GPU(s) found in the system")
  95
  96         # append GPU names
  97         if (NOT GMX_DETECT_GPU_INFO STREQUAL "")
  98             set(_msg "${_msg}:")
  99             foreach(gpu ${GMX_DETECT_GPU_INFO})
 100                 set(_msg "${_msg}
 101 ${gpu}")
 102             endforeach()
 103         endif()
 104
 105         # TODO remove the second part of the message when we'll have compute
 106         # capability information from the detection.
 107         set(_msg "${_msg}
 108 Compute capability information not available, consult the NVIDIA website:
 109 https://developer.nvidia.com/cuda-gpus")
 110     endif()
 111
 112         set(CUDA_NOTFOUND_MESSAGE "mdrun supports native GPU acceleration on NVIDIA hardware with compute capability >= ${REQUIRED_CUDA_COMPUTE_CAPABILITY} (Fermi or later). This requires the NVIDIA CUDA toolkit, which was not found. Its location can be hinted by setting the CUDA_TOOLKIT_ROOT_DIR CMake option (does not work as an environment variable). The typical location would be /usr/local/cuda[-version]. Note that CPU or GPU acceleration can be selected at runtime.
 113
 114 ${_msg}")
 115         unset(_msg)
 116
 117     if (NOT CUDA_FOUND)
 118         if (GMX_GPU_AUTO)
 119             # Disable GPU acceleration in auto mode
 120             message(STATUS "No compatible CUDA toolkit found (v5.0+), disabling native GPU acceleration")
 121             set_property(CACHE GMX_GPU PROPERTY VALUE OFF)
 122             set(CUDA_NOTFOUND_AUTO ON)
 123         else()
 124             # the user requested CUDA, but it wasn't found
 125             message(FATAL_ERROR "${CUDA_NOTFOUND_MESSAGE}")
 126         endif()
 127     else()
 128         if (GMX_GPU_AUTO)
 129             message(STATUS "Enabling native GPU acceleration")
 130             set_property(CACHE GMX_GPU PROPERTY VALUE ON)
 131         endif()
 132     endif() # NOT CUDA_FOUND
 133 endif()
 134
 135 # Try to find NVML if a GPU accelerated binary should be build.
 136 if (GMX_GPU)
 137     if (DEFINED NVML_LIBRARY)
 138         set(NVML_FIND_QUIETLY TRUE)
 139     endif()
 140     find_package(NVML)
 141     option(GMX_USE_NVML "Use NVML support for better CUDA performance" ${NVML_FOUND})
 142     mark_as_advanced(GMX_USE_NVML)
 143     if(GMX_USE_NVML)
 144         if(NVML_FOUND)
 145             include_directories(SYSTEM ${NVML_INCLUDE_DIR})
 146             set(HAVE_NVML 1)
 147             list(APPEND GMX_EXTRA_LIBRARIES ${NVML_LIBRARY})
 148         else()
 149             message(FATAL_ERROR "NVML support was required, but was not detected. Please consult the install guide.")
 150         endif()
 151     endif()
 152 endif()
 153
 154 # Annoyingly enough, FindCUDA leaves a few variables behind as non-advanced.
 155 # We need to mark these advanced outside the conditional, otherwise, if the
 156 # user turns GMX_GPU=OFF after a failed cmake pass, these variables will be
 157 # left behind in the cache.
 158 mark_as_advanced(CUDA_SDK_ROOT_DIR
 159                  CUDA_USE_STATIC_CUDA_RUNTIME
 160                  CUDA_dl_LIBRARY CUDA_rt_LIBRARY
 161                  )
 162 if(NOT GMX_GPU)
 163     mark_as_advanced(CUDA_TOOLKIT_ROOT_DIR)
 164     mark_as_advanced(CUDA_HOST_COMPILER)
 165 endif()
 166
 167 # Try to execute ${CUDA_NVCC_EXECUTABLE} --version and set the output
 168 # (or an error string) in the argument variable.
 169 # Note that semicolon is used as separator for nvcc.
 170 #
 171 # Parameters:
 172 #   COMPILER_INFO   - [output variable] string with compiler path, ID and
 173 #                     some compiler-provided information
 174 #   COMPILER_FLAGS  - [output variable] flags for the compiler
 175 #
 176 macro(get_cuda_compiler_info COMPILER_INFO COMPILER_FLAGS)
 177     if(CUDA_NVCC_EXECUTABLE)
 178
 179         # Get the nvcc version string. This is multi-line, but since it is only 4 lines
 180         # and might change in the future it is better to store than trying to parse out
 181         # the version from the current format.
 182         execute_process(COMMAND ${CUDA_NVCC_EXECUTABLE} --version
 183             RESULT_VARIABLE _nvcc_version_res
 184             OUTPUT_VARIABLE _nvcc_version_out
 185             ERROR_VARIABLE  _nvcc_version_err
 186             OUTPUT_STRIP_TRAILING_WHITESPACE)
 187         if (${_nvcc_version_res} EQUAL 0)
 188             # Fix multi-line mess: Replace newline with ";" so we can use it in a define
 189             string(REPLACE "\n" ";" _nvcc_info_singleline ${_nvcc_version_out})
 190             SET(${COMPILER_INFO} "${CUDA_NVCC_EXECUTABLE} ${_nvcc_info_singleline}")
 191             string(TOUPPER ${CMAKE_BUILD_TYPE} _build_type)
 192             SET(_compiler_flags "${CUDA_NVCC_FLAGS_${_build_type}}")
 193             if(CUDA_PROPAGATE_HOST_FLAGS)
 194                 string(REGEX REPLACE "[ ]+" ";" _cxx_flags_nospace "${BUILD_CXXFLAGS}")
 195             endif()
 196             SET(${COMPILER_FLAGS} "${CUDA_NVCC_FLAGS}${CUDA_NVCC_FLAGS_${_build_type}}; ${_cxx_flags_nospace}")
 197         else()
 198             SET(${COMPILER_INFO} "N/A")
 199             SET(${COMPILER_FLAGS} "N/A")
 200         endif()
 201     endif()
 202 endmacro ()
 203
 204 include(CMakeDependentOption)
 205 include(gmxOptionUtilities)
 206 macro(gmx_gpu_setup)
 207     if(GMX_GPU)
 208         if(NOT CUDA_NVCC_EXECUTABLE)
 209             message(FATAL_ERROR "nvcc is required for a CUDA build, please set CUDA_TOOLKIT_ROOT_DIR appropriately")
 210         endif()
 211
 212         # set up nvcc options
 213         include(gmxManageNvccConfig)
 214
 215         gmx_check_if_changed(_cuda_version_changed CUDA_VERSION)
 216
 217         # Generate CUDA RT API version string which will end up in config.h
 218         # We do this because nvcc is silly enough to not define its own version
 219         # (which should match the CUDA runtime API version AFAICT) and we want to
 220         # avoid creating the fragile dependency on cuda_runtime_api.h.
 221         #
 222         # NOTE: CUDA v7.5 is expected to have nvcc define it own version, so in the
 223         # future we should switch to using that version string instead of our own.
 224         if (NOT GMX_CUDA_VERSION OR _cuda_version_changed)
 225             MATH(EXPR GMX_CUDA_VERSION "${CUDA_VERSION_MAJOR}*1000 + ${CUDA_VERSION_MINOR}*10")
 226         endif()
 227
 228         if (_cuda_version_changed)
 229             # check the generated CUDA API version against the one present in cuda_runtime_api.h
 230             try_compile(_get_cuda_version_compile_res
 231                 ${CMAKE_BINARY_DIR}
 232                 ${CMAKE_SOURCE_DIR}/cmake/TestCUDAVersion.c
 233                 COMPILE_DEFINITIONS "-DGMX_CUDA_VERSION=${GMX_CUDA_VERSION}"
 234                 CMAKE_FLAGS "-DINCLUDE_DIRECTORIES=${CUDA_TOOLKIT_INCLUDE}"
 235                 OUTPUT_VARIABLE _get_cuda_version_compile_out)
 236
 237             if (NOT _get_cuda_version_compile_res)
 238                 if (_get_cuda_version_compile_out MATCHES "CUDA version mismatch")
 239                     message(FATAL_ERROR "The CUDA API version generated internally from the compiler version does not match the version reported by cuda.h. This means either that the CUDA detection picked up mismatching nvcc and the CUDA headers (likely not part of the same toolkit installation) or that there is an error in the internal version generation. If you are sure that it is not the former causing the error (check the relevant cache variables), define the GMX_CUDA_VERSION cache variable to work around the error.")
 240                 else()
 241                     message(FATAL_ERROR "Could not detect CUDA runtime API version")
 242                 endif()
 243             endif()
 244         endif()
 245
 246         # no OpenMP is no good!
 247         if(NOT GMX_OPENMP)
 248             message(WARNING "To use GPU acceleration efficiently, mdrun requires OpenMP multi-threading. Without OpenMP a single CPU core can be used with a GPU which is not optimal. Note that with MPI multiple processes can be forced to use a single GPU, but this is typically inefficient. You need to set both C and C++ compilers that support OpenMP (CC and CXX environment variables, respectively) when using GPUs.")
 249         endif()
 250     endif() # GMX_GPU
 251
 252     cmake_dependent_option(GMX_CUDA_NB_SINGLE_COMPILATION_UNIT
 253         "Whether to compile the CUDA non-bonded module using a single compilation unit." ON
 254         "GMX_GPU" ON)
 255     mark_as_advanced(GMX_CUDA_NB_SINGLE_COMPILATION_UNIT)
 256
 257     if (GMX_GPU)
 258         # We need to use single compilation unit for kernels:
 259         # - when compiling for CC 2.x devices where buggy kernel code is generated
 260         gmx_check_if_changed(_gmx_cuda_target_changed GMX_CUDA_TARGET_SM GMX_CUDA_TARGET_COMPUTE CUDA_NVCC_FLAGS)
 261         if(_gmx_cuda_target_changed OR NOT GMX_GPU_DETECTION_DONE)
 262             if((NOT GMX_CUDA_TARGET_SM AND NOT GMX_CUDA_TARGET_COMPUTE) OR
 263                (GMX_CUDA_TARGET_SM MATCHES "2[01]" OR GMX_CUDA_TARGET_COMPUTE MATCHES "2[01]"))
 264                message(STATUS "Enabling single compilation unit for the CUDA non-bonded module. Multiple compilation units are not compatible with CC 2.x devices, to enable the feature specify only CC >=3.0 target architectures in GMX_CUDA_TARGET_SM/GMX_CUDA_TARGET_COMPUTE.")
 265                 set_property(CACHE GMX_CUDA_NB_SINGLE_COMPILATION_UNIT PROPERTY VALUE ON)
 266             else()
 267                 message(STATUS "Enabling multiple compilation units for the CUDA non-bonded module.")
 268                 set_property(CACHE GMX_CUDA_NB_SINGLE_COMPILATION_UNIT PROPERTY VALUE OFF)
 269             endif()
 270         endif()
 271     endif()
 272 endmacro()