src/testutils/TestMacros.cmake

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2011,2012,2013,2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 include(CMakeParseArguments)
  36
  37 function (gmx_add_unit_test_object_library NAME)
  38     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  39         include_directories(BEFORE SYSTEM ${GMOCK_INCLUDE_DIRS})
  40         add_library(${NAME} OBJECT ${UNITTEST_TARGET_OPTIONS} ${ARGN})
  41         set_property(TARGET ${NAME} APPEND PROPERTY COMPILE_DEFINITIONS "${GMOCK_COMPILE_DEFINITIONS}")
  42         set_property(TARGET ${NAME} APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  43     endif()
  44 endfunction ()
  45
  46 function (gmx_add_gtest_executable EXENAME)
  47     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  48         set(_options MPI)
  49         cmake_parse_arguments(ARG "${_options}" "" "" ${ARGN})
  50         set(_source_files ${ARG_UNPARSED_ARGUMENTS})
  51
  52         file(RELATIVE_PATH _input_files_path ${CMAKE_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  53         set(_temporary_files_path "${CMAKE_CURRENT_BINARY_DIR}/Testing/Temporary")
  54         file(MAKE_DIRECTORY ${_temporary_files_path})
  55         # Note that the quotation marks in the next line form part of
  56         # the defined symbol, so that the macro replacement in the
  57         # source file is as a string.
  58         # These are only needed for unittest_main.cpp, but for simplicity used
  59         # for the whole target (since there may be multiple executables in the
  60         # same directory, it is not straightforward to use a source file
  61         # property).
  62         set(EXTRA_COMPILE_DEFINITIONS
  63             TEST_DATA_PATH="${_input_files_path}"
  64             TEST_TEMP_PATH="${_temporary_files_path}")
  65         if (ARG_MPI)
  66             list(APPEND EXTRA_COMPILE_DEFINITIONS
  67                  TEST_USES_MPI=true)
  68         endif()
  69
  70         include_directories(BEFORE SYSTEM ${GMOCK_INCLUDE_DIRS})
  71         add_executable(${EXENAME} ${UNITTEST_TARGET_OPTIONS}
  72             ${_source_files} ${TESTUTILS_DIR}/unittest_main.cpp)
  73         target_link_libraries(${EXENAME}
  74             ${TESTUTILS_LIBS} libgromacs ${GMOCK_LIBRARIES} ${GMX_EXE_LINKER_FLAGS} ${GMX_STDLIB_LIBRARIES})
  75         set_property(TARGET ${EXENAME}
  76             APPEND PROPERTY COMPILE_FLAGS "${GMOCK_COMPILE_FLAGS}")
  77         set_property(TARGET ${EXENAME}
  78             APPEND PROPERTY COMPILE_DEFINITIONS "${GMOCK_COMPILE_DEFINITIONS}")
  79         set_property(TARGET ${EXENAME}
  80             APPEND PROPERTY COMPILE_DEFINITIONS "${EXTRA_COMPILE_DEFINITIONS}")
  81     endif()
  82 endfunction()
  83
  84 # Use this function with MPI_RANKS <N> INTEGRATION_TEST to register a test
  85 # binary as an integration test that requires MPI. The intended number of MPI
  86 # ranks is also passed
  87 #
  88 # TODO When a test case needs it, generalize the MPI_RANKS mechanism so
  89 # that ctest can run the test binary over a range of numbers of MPI
  90 # ranks.
  91 function (gmx_register_gtest_test NAME EXENAME)
  92     if (GMX_BUILD_UNITTESTS AND BUILD_TESTING)
  93         set(_options INTEGRATION_TEST)
  94         set(_one_value_args MPI_RANKS)
  95         cmake_parse_arguments(ARG "${_options}" "${_one_value_args}" "" ${ARGN})
  96         set(_xml_path ${CMAKE_BINARY_DIR}/Testing/Temporary/${NAME}.xml)
  97         set(_cmd ${EXENAME})
  98         set(_labels GTest)
  99         set(_timeout 30)
 100         if (ARG_INTEGRATION_TEST)
 101             list(APPEND _labels IntegrationTest)
 102             set(_timeout 120)
 103
 104             # GMX_EXTRA_LIBRARIES might be needed for mdrun integration tests at
 105             # some point.
 106             # target_link_libraries(${EXENAME} ${GMX_EXTRA_LIBRARIES} ${GMX_STDLIB_LIBRARIES})
 107         else()
 108             list(APPEND _labels UnitTest)
 109         endif()
 110         if (ARG_MPI_RANKS)
 111             if (NOT GMX_CAN_RUN_MPI_TESTS)
 112                 return()
 113             endif()
 114             list(APPEND _labels MpiTest)
 115             if (GMX_MPI)
 116                 set(_cmd
 117                     ${MPIEXEC} ${MPIEXEC_NUMPROC_FLAG} ${ARG_MPI_RANKS}
 118                     ${MPIEXEC_PREFLAGS} $<TARGET_FILE:${EXENAME}> ${MPIEXEC_POSTFLAGS})
 119             elseif (GMX_THREAD_MPI)
 120                 list(APPEND _cmd -ntmpi ${ARG_MPI_RANKS})
 121             endif()
 122         endif()
 123         add_test(NAME ${NAME}
 124                  COMMAND ${_cmd} --gtest_output=xml:${_xml_path})
 125         set_tests_properties(${NAME} PROPERTIES LABELS "${_labels}")
 126         set_tests_properties(${NAME} PROPERTIES TIMEOUT ${_timeout})
 127         add_dependencies(tests ${EXENAME})
 128     endif()
 129 endfunction ()
 130
 131 function (gmx_add_unit_test NAME EXENAME)
 132     gmx_add_gtest_executable(${EXENAME} ${ARGN})
 133     gmx_register_gtest_test(${NAME} ${EXENAME})
 134 endfunction()
 135
 136 function (gmx_add_mpi_unit_test NAME EXENAME RANKS)
 137     if (GMX_MPI OR (GMX_THREAD_MPI AND GTEST_IS_THREADSAFE))
 138         gmx_add_gtest_executable(${EXENAME} MPI ${ARGN})
 139         gmx_register_gtest_test(${NAME} ${EXENAME} MPI_RANKS ${RANKS})
 140     endif()
 141 endfunction()