docs/CMakeLists.txt

   1 #
   2 # This file is part of the GROMACS molecular simulation package.
   3 #
   4 # Copyright (c) 2014,2015,2016, by the GROMACS development team, led by
   5 # Mark Abraham, David van der Spoel, Berk Hess, and Erik Lindahl,
   6 # and including many others, as listed in the AUTHORS file in the
   7 # top-level source directory and at http://www.gromacs.org.
   8 #
   9 # GROMACS is free software; you can redistribute it and/or
  10 # modify it under the terms of the GNU Lesser General Public License
  11 # as published by the Free Software Foundation; either version 2.1
  12 # of the License, or (at your option) any later version.
  13 #
  14 # GROMACS is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17 # Lesser General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public
  20 # License along with GROMACS; if not, see
  21 # http://www.gnu.org/licenses, or write to the Free Software Foundation,
  22 # Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA.
  23 #
  24 # If you want to redistribute modifications to GROMACS, please
  25 # consider that scientific software is very special. Version
  26 # control is crucial - bugs must be traceable. We will be happy to
  27 # consider code for inclusion in the official distribution, but
  28 # derived work must not be called official GROMACS. Details are found
  29 # in the README & COPYING files - if they are missing, get the
  30 # official version at http://www.gromacs.org.
  31 #
  32 # To help us fund GROMACS development, we humbly ask that you cite
  33 # the research papers on the package. Check out http://www.gromacs.org.
  34
  35 # This directory provides a unified place for building all kinds of
  36 # GROMACS documentation. This includes some "static" content (Doxygen
  37 # code documentation, reference manual, install guide, old online HTML
  38 # images), and content generated from the gmx program for the various
  39 # tools (man and HTML pages). It also provides the "webpage" target,
  40 # that combines all of the above (except man pages in man format) into
  41 # a form suitable for automated deployment to the GROMACS website. It
  42 # also provides the INSTALL file for the tarball.
  43 #
  44 # The webpage is mostly built by Sphinx.  Variable values for Sphinx
  45 # substitutions are configured by CMake (for things like version numbers),
  46 # using gmx_configure_version_file().  This happens during build time instead
  47 # of configure time, because 1) some of the version variables are only
  48 # available during build time, and 2) we don't want to do all the Sphinx setup
  49 # during configuration to save some time when not building the content.
  50 # All the generated values get put into conf-vars.py (generated from
  51 # conf-vars.py.cmakein), which in turn is included by the Sphinx configuration
  52 # file conf.py.
  53
  54 set(SOURCE_MD5SUM "unknown" CACHE STRING
  55     "MD5 sum of the source tarball, normally used only for the pre-release webpage build")
  56 # REGRESSIONTEST_MD5SUM is set in cmake/gmxVersionInfo.cmake because it is used also in tests/CMakeLists.txt
  57 mark_as_advanced(SOURCE_MD5SUM)
  58
  59 set(EXPECTED_DOXYGEN_VERSION 1.8.5)
  60
  61 find_package(PythonInterp 2.7)
  62 find_package(Sphinx 1.2.3 QUIET COMPONENTS pygments)
  63
  64 # Even if we aren't going to make the full webpage, set up to put all
  65 # the documentation output in the same place, for convenience
  66 set(HTML_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/html")
  67 file(MAKE_DIRECTORY ${HTML_OUTPUT_DIR})
  68
  69 # The directory from which man pages will be installed; if it remains
  70 # empty, they will be silently skipped.
  71 set(MAN_PAGE_DIR)
  72 if (SOURCE_IS_SOURCE_DISTRIBUTION)
  73     # When building from the tarball, install the bundled man pages
  74     # (unless overridden).
  75     set(MAN_PAGE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  76 endif()
  77
  78 add_subdirectory(doxygen)
  79 add_subdirectory(manual)
  80
  81 if (SPHINX_FOUND)
  82     set(SPHINX_THEME default)
  83     if (NOT SPHINX_EXECUTABLE_VERSION VERSION_LESS 1.3)
  84         set(SPHINX_THEME classic)
  85     endif()
  86     # We need to have all the Sphinx input files in a single directory, and
  87     # since some of them are generated, we copy everything into the build tree,
  88     # to this directory.
  89     set(SPHINX_INPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/sphinx-input)
  90     set(SPHINX_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/conf.py)
  91     set(SPHINX_CONFIG_VARS_FILE ${SPHINX_INPUT_DIR}/conf-vars.py)
  92     set(SPHINX_EXTENSION_PATH ${CMAKE_CURRENT_SOURCE_DIR})
  93     if (SOURCE_MD5SUM STREQUAL "unknown")
  94         # But for testing the webpage build (e.g. from the repo) we
  95         # need a default value.
  96         set(REGRESSIONTEST_MD5SUM_STRING "unknown")
  97     else()
  98         # The real build of the webpage happens from the tarball, and
  99         # this should be set to the matching MD5 sum.
 100         set(REGRESSIONTEST_MD5SUM_STRING "${REGRESSIONTEST_MD5SUM}")
 101     endif()
 102     set(SPHINX_SOURCE_FILES
 103         index.rst
 104         download.rst
 105         dev-manual/index.rst
 106         dev-manual/build-system.rst
 107         dev-manual/doxygen.rst
 108         dev-manual/formatting.rst
 109         dev-manual/gmxtree.rst
 110         dev-manual/includestyle.rst
 111         dev-manual/jenkins.rst
 112         dev-manual/language-features.rst
 113         dev-manual/naming.rst
 114         dev-manual/overview.rst
 115         dev-manual/relocatable-binaries.rst
 116         dev-manual/style.rst
 117         dev-manual/testutils.rst
 118         dev-manual/tools.rst
 119         dev-manual/uncrustify.rst
 120         fragments/doxygen-links.rst
 121         install-guide/index.rst
 122         user-guide/index.rst
 123         user-guide/getting-started.rst
 124         user-guide/flow.rst
 125         user-guide/cutoff-schemes.rst
 126         user-guide/mdrun-features.rst
 127         user-guide/mdrun-performance.rst
 128         user-guide/mdp-options.rst
 129         user-guide/file-formats.rst
 130         user-guide/cmdline.rst
 131         user-guide/environment-variables.rst
 132         user-guide/plotje.gif
 133         user-guide/xvgr.gif
 134         conf.py
 135         links.dat
 136         )
 137
 138     # Remove other rst files from the build tree, since they confuse Sphinx.
 139     file(GLOB_RECURSE _obsolete_sources RELATIVE ${SPHINX_INPUT_DIR}
 140          ${SPHINX_INPUT_DIR}/*.rst)
 141     list(REMOVE_ITEM _obsolete_sources ${SPHINX_SOURCE_FILES})
 142     foreach(_file ${_obsolete_sources})
 143         # Skip generated files in onlinehelp/, and fragments.
 144         # The latter do not cause issues with obsolete files, as they
 145         # are not considered as Sphinx input files, but will only be
 146         # included using an explicit .. include::.
 147         if (NOT _file MATCHES "^(onlinehelp|fragments)/.*\\.rst$")
 148             message(STATUS "Removing obsolete Sphinx input ${_file}")
 149             file(REMOVE ${SPHINX_INPUT_DIR}/${_file})
 150         endif()
 151     endforeach()
 152
 153     gmx_configure_version_file(conf-vars.py.cmakein ${SPHINX_CONFIG_VARS_FILE}
 154         EXTRA_VARS
 155             SPHINX_THEME
 156             SPHINX_EXTENSION_PATH
 157             EXPECTED_DOXYGEN_VERSION
 158             GMX_CMAKE_MINIMUM_REQUIRED_VERSION REQUIRED_CUDA_VERSION
 159             REQUIRED_OPENCL_MIN_VERSION
 160             REQUIRED_CUDA_COMPUTE_CAPABILITY REGRESSIONTEST_VERSION
 161             SOURCE_MD5SUM REGRESSIONTEST_MD5SUM_STRING
 162         COMMENT "Configuring Sphinx configuration file")
 163     set(SPHINX_INPUT_FILES ${SPHINX_CONFIG_VARS_FILE})
 164     foreach(_file ${SPHINX_SOURCE_FILES})
 165         add_custom_command(
 166             OUTPUT ${SPHINX_INPUT_DIR}/${_file}
 167             COMMAND ${CMAKE_COMMAND} -E copy
 168                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 169                 ${SPHINX_INPUT_DIR}/${_file}
 170             DEPENDS
 171                 ${CMAKE_CURRENT_SOURCE_DIR}/${_file}
 172             COMMENT "Copying Sphinx input file ${_file}"
 173             VERBATIM)
 174         list(APPEND SPHINX_INPUT_FILES ${SPHINX_INPUT_DIR}/${_file})
 175     endforeach()
 176     gmx_add_custom_output_target(sphinx-input OUTPUT STAMP
 177         DEPENDS ${SPHINX_INPUT_FILES})
 178     # TODO: Make this remove obsolete .rst files.
 179     # TODO: This does not work in cross-compilation scenarios; disable up to
 180     # the necessary level.
 181     gmx_add_custom_output_target(sphinx-programs OUTPUT STAMP
 182         COMMAND ${CMAKE_COMMAND} -E make_directory onlinehelp
 183         COMMAND gmx -quiet help -export rst
 184         DEPENDS gmx
 185         WORKING_DIRECTORY ${SPHINX_INPUT_DIR}
 186         COMMENT "Generating reStructuredText help")
 187     # This dependency ensures that the directories exist before the
 188     # executable tries to write things there.
 189     add_dependencies(sphinx-programs sphinx-input)
 190
 191     # Make the INSTALL file for CPack for the tarball. This gets put
 192     # into the tarball via the CPack rules below, which requires that
 193     # the INSTALL file is in a separate directory by itself.
 194     set(TEXT_INSTALL_GUIDE_OUTPUT_DIR "install-guide/text")
 195     add_custom_target(install-guide
 196         COMMAND
 197             ${SPHINX_EXECUTABLE}
 198             -q -b text
 199             -w sphinx-install.log
 200             -d ${CMAKE_CURRENT_BINARY_DIR}/install-guide/_doctrees
 201             -c ${SPHINX_INPUT_DIR}
 202             "${SPHINX_INPUT_DIR}/install-guide"
 203             "${TEXT_INSTALL_GUIDE_OUTPUT_DIR}"
 204         COMMAND
 205             ${CMAKE_COMMAND} -E rename
 206             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/index.txt
 207             ${TEXT_INSTALL_GUIDE_OUTPUT_DIR}/INSTALL
 208         WORKING_DIRECTORY
 209             ${CMAKE_CURRENT_BINARY_DIR}
 210         COMMENT "Building INSTALL with Sphinx"
 211         VERBATIM
 212         )
 213     add_dependencies(install-guide sphinx-input)
 214     gmx_cpack_add_generated_source_directory(install-guide/text DESTINATION /)
 215
 216     # Sphinx cache with pickled ReST documents
 217     set(SPHINX_CACHE_DIR "${CMAKE_CURRENT_BINARY_DIR}/_doctrees")
 218
 219     add_custom_target(webpage-sphinx
 220         COMMAND
 221             ${CMAKE_COMMAND} -E make_directory ${SPHINX_INPUT_DIR}/_static
 222         COMMAND
 223             ${SPHINX_EXECUTABLE}
 224             -q -b html
 225             -w sphinx-html.log
 226             -d "${SPHINX_CACHE_DIR}"
 227             "${SPHINX_INPUT_DIR}"
 228             "${HTML_OUTPUT_DIR}"
 229         WORKING_DIRECTORY
 230             ${CMAKE_CURRENT_BINARY_DIR}
 231         COMMENT "Building HTML documentation with Sphinx"
 232         VERBATIM
 233         )
 234     add_dependencies(webpage-sphinx sphinx-input sphinx-programs)
 235
 236     add_custom_target(man
 237         COMMAND
 238             ${SPHINX_EXECUTABLE}
 239             -q -b man
 240             -w sphinx-man.log
 241             -d ${SPHINX_CACHE_DIR}
 242             -t do_man
 243             ${SPHINX_INPUT_DIR}
 244             ${CMAKE_CURRENT_BINARY_DIR}/man
 245         COMMENT "Building man pages with Sphinx"
 246         VERBATIM)
 247     add_dependencies(man sphinx-input sphinx-programs)
 248     if (GMX_BUILD_HELP)
 249         # If requested, install the man pages built by the 'man' target
 250         # created above.  Nothing will be installed if the user did not
 251         # manually build the target.
 252         set(MAN_PAGE_DIR ${CMAKE_CURRENT_BINARY_DIR})
 253     endif()
 254 else()
 255     add_custom_target(webpage-sphinx
 256         COMMAND ${CMAKE_COMMAND} -E echo
 257             "HTML pages cannot be built because Sphinx is not available"
 258         VERBATIM)
 259     add_custom_target(install-guide
 260         COMMAND ${CMAKE_COMMAND} -E echo
 261             "INSTALL cannot be built because Sphinx is not available"
 262         VERBATIM)
 263     add_custom_target(man
 264         COMMAND ${CMAKE_COMMAND} -E echo
 265             "man pages cannot be built because Sphinx is not available"
 266         VERBATIM)
 267 endif()
 268
 269 if (MAN_PAGE_DIR)
 270     set(MAN_PAGE_DIR ${MAN_PAGE_DIR}/man)
 271     # Trailing slash on directory is significant for
 272     # install(DIRECTORY). See CMake docs.
 273     install(DIRECTORY ${MAN_PAGE_DIR}/
 274         DESTINATION ${MAN_INSTALL_DIR}/man1
 275         COMPONENT man OPTIONAL
 276         FILES_MATCHING PATTERN "*.1")
 277 endif()
 278 gmx_cpack_add_generated_source_directory(man)
 279
 280 # Determine whether we can build all the HTML pages and content linked from
 281 # there.  If not, construct an informative message if the user tries to
 282 # build the target; most people never need to know, unless they've asked for
 283 # the webpage build.
 284 set(HTML_BUILD_IS_POSSIBLE ON)
 285 set(HTML_BUILD_NOT_POSSIBLE_REASON)
 286 set(HTML_BUILD_WARNINGS)
 287
 288 # Next, turn it off if any of the preconditions are unsatisified
 289 if (NOT PYTHON_EXECUTABLE)
 290     set(HTML_BUILD_IS_POSSIBLE OFF)
 291     set(HTML_BUILD_NOT_POSSIBLE_REASON "Python is required")
 292 elseif (NOT SPHINX_FOUND)
 293     # Hardly anything gets built if Sphinx is not available, so don't bother.
 294     set(HTML_BUILD_IS_POSSIBLE OFF)
 295     set(HTML_BUILD_NOT_POSSIBLE_REASON "Sphinx is required")
 296 endif()
 297 if (NOT MANUAL_BUILD_IS_POSSIBLE)
 298     list(APPEND HTML_BUILD_WARNINGS
 299          "Reference PDF manual was not built, so links to it do not work")
 300 endif()
 301 if (NOT DOXYGEN_EXECUTABLE)
 302     list(APPEND HTML_BUILD_WARNINGS
 303         "Doxygen was not available, so links to Doxygen do not work")
 304 endif()
 305 if (NOT DOXYGEN_DOT_EXECUTABLE)
 306     list(APPEND HTML_BUILD_WARNINGS
 307         "dot/graphviz was not found, so some graphs are missing")
 308 endif()
 309
 310 if (HTML_BUILD_IS_POSSIBLE)
 311     set(_webpage_target_properties)
 312     if (HTML_BUILD_WARNINGS)
 313         list(APPEND _webpage_target_properties
 314              COMMAND ${CMAKE_COMMAND} -E echo
 315                  "webpage was built, but with the following limitations:")
 316         foreach(_warning ${HTML_BUILD_WARNINGS})
 317         list(APPEND _webpage_target_properties
 318              COMMAND ${CMAKE_COMMAND} -E echo " - ${_warning}")
 319         endforeach()
 320     endif()
 321
 322     if (MANUAL_BUILD_IS_POSSIBLE)
 323         # Make the PDF reference guide
 324         # TODO Try to make the PDF arrive directly in ${HTML_OUTPUT_DIR}
 325         # TODO Make this depend on the output of the manual build, so that the
 326         # file actually gets copied multiple times.
 327         set(_manual_target_location ${HTML_OUTPUT_DIR}/manual-${GMX_VERSION_STRING}.pdf)
 328         add_custom_command(
 329             OUTPUT ${_manual_target_location}
 330             COMMAND ${CMAKE_COMMAND}
 331                 -E remove -f ${_manual_target_location}
 332             COMMAND ${CMAKE_COMMAND}
 333                 -E copy ${CMAKE_CURRENT_BINARY_DIR}/manual/gromacs.pdf ${_manual_target_location}
 334             DEPENDS manual
 335             VERBATIM)
 336         list(APPEND _webpage_target_properties
 337              DEPENDS ${_manual_target_location})
 338     endif()
 339
 340     # The Doxygen configuration in doxygen/Doxyfile-common.cmakein
 341     # makes all the Doxygen output directly in
 342     # ${HTML_OUTPUT_DIR}/doxygen (and makes the directory if it needs
 343     # to).
 344
 345     # Add a top-level target that builds everything related to the webpage,
 346     # for Jenkins (and possibly others) to use
 347     add_custom_target(webpage ${_webpage_target_properties}
 348         COMMENT "Building webpage"
 349         VERBATIM)
 350     add_dependencies(webpage webpage-sphinx doxygen-all)
 351 else()
 352     add_custom_target(webpage
 353         COMMAND ${CMAKE_COMMAND} -E echo
 354             "Cannot build webpage because ${HTML_BUILD_NOT_POSSIBLE_REASON}"
 355         COMMENT "Webpage build not possible"
 356         VERBATIM)
 357 endif()