src/gmxlib/CMakeLists.txt

   1 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
   2
   3
   4 # add target that generates version.c every time a make is run
   5 # only do this if we generate the version
   6 if(USE_VERSION_H)
   7     add_custom_target(gmx_version ALL
   8             COMMAND ${CMAKE_COMMAND}
   9                 -D Git_EXECUTABLE="${Git_EXECUTABLE}"
  10                 -D Git_VERSION="${Git_VERSION}"
  11                 -D PROJECT_VERSION="${PROJECT_VERSION}"
  12                 -D PROJECT_SOURCE_DIR="${PROJECT_SOURCE_DIR}"
  13                 -D VERSION_C_CMAKEIN="${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein"
  14                 -D VERSION_C_OUT="${CMAKE_CURRENT_BINARY_DIR}/version.c"
  15                 -P ${CMAKE_SOURCE_DIR}/cmake/gmxGenerateVersionInfo.cmake
  16             WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}/src/gmxlib
  17             DEPENDS ${CMAKE_SOURCE_DIR}/src/gmxlib/version.c.cmakein
  18             COMMENT "Generating version information")
  19 endif()
  20
  21 # The nonbonded directory contains subdirectories that are only
  22 # conditionally built, so we cannot use a GLOB_RECURSE here.
  23 file(GLOB GMXLIB_SOURCES *.c
  24      selection/*.c trajana/*.c
  25      statistics/*.c nonbonded/*.c nonbonded/nb_kernel_c/*.c
  26      nonbonded/nb_kernel_adress_c/*.c)
  27
  28 # This source file is generated
  29 file(GLOB VERSION_SOURCE version.c)
  30
  31 if(VERSION_SOURCE)
  32         list(REMOVE_ITEM GMXLIB_SOURCES ${VERSION_SOURCE})
  33 endif(VERSION_SOURCE)
  34
  35 # add version.c to the list of sources and tell cmake that it is generated
  36 if(USE_VERSION_H)
  37 LIST(APPEND GMXLIB_SOURCES ${CMAKE_CURRENT_BINARY_DIR}/version.c) # auto-generated
  38 set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/version.c
  39                 PROPERTIES GENERATED true)
  40 endif()
  41
  42 if(GMX_DOUBLE)
  43   set(SSETYPE sse2)
  44 else()
  45   set(SSETYPE sse)
  46 endif()
  47
  48 if(GMX_IA32_ASM)
  49   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_ia32_${SSETYPE}/*.c)
  50   if(GMX_ASM_USEASM-NASM)
  51     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*intel_syntax*.s)
  52   else()
  53     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_ia32_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_ia32_${SSETYPE}/*asm.s)
  54   endif()
  55 endif(GMX_IA32_ASM)
  56
  57 if(GMX_X86_64_ASM)
  58   file(GLOB GMX_SSEKERNEL_C_SRC   nonbonded/nb_kernel_x86_64_${SSETYPE}/*.c)
  59   if(GMX_ASM_USEASM-NASM)
  60     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*intel_syntax*.s)
  61   else()
  62     file(GLOB GMX_SSEKERNEL_ASM_SRC nonbonded/nb_kernel_x86_64_${SSETYPE}/*${SSETYPE}.s nonbonded/nb_kernel_x86_64_${SSETYPE}/*asm.s)
  63   endif()
  64 endif(GMX_X86_64_ASM)
  65
  66 if(GMX_FORTRAN)
  67   if (GMX_DOUBLE)
  68     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_double/*.[cf])
  69   else(GMX_DOUBLE)
  70     file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_f77_single/*.[cf])
  71   endif(GMX_DOUBLE)
  72 endif(GMX_FORTRAN)
  73
  74 if(GMX_POWER6)
  75   file(GLOB FORTRAN_SOURCES nonbonded/nb_kernel_power6/*.[cF])
  76 endif(GMX_POWER6)
  77
  78 if(GMX_BLUEGENE)
  79   file(GLOB GMX_BLUEGENE_C_SRC nonbonded/nb_kernel_bluegene/*.c)
  80 endif(GMX_BLUEGENE)
  81
  82 if(GMX_PPC_ALTIVEC)
  83   file(GLOB GMX_PPC_ALTIVEC_SRC nonbonded/nb_kernel_ppc_altivec/*.c)
  84 endif(GMX_PPC_ALTIVEC)
  85
  86 if(NOT GMX_EXTERNAL_BLAS)
  87   file(GLOB BLAS_SOURCES gmx_blas/*.c)
  88 endif(NOT GMX_EXTERNAL_BLAS)
  89
  90 if(NOT GMX_EXTERNAL_LAPACK)
  91   file(GLOB LAPACK_SOURCES gmx_lapack/*.c)
  92 endif(NOT GMX_EXTERNAL_LAPACK)
  93
  94 # This would be the standard way to include thread_mpi, but we want libgmx
  95 # to link the functions directly
  96 #if(GMX_THREADS)
  97 #    add_subdirectory(thread_mpi)
  98 #endif(GMX_THREADS)
  99 #target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES} ${THREAD_MPI_LIB})
 100
 101 # Files called xxx_test.c are test drivers with a main() function for module xxx.c,
 102 # so they should not be included in the library
 103 file(GLOB_RECURSE NOT_GMXLIB_SOURCES *_test.c *\#*)
 104 list(REMOVE_ITEM GMXLIB_SOURCES ${NOT_GMXLIB_SOURCES})
 105 # Selection has test_ instead of _test.  Removing here for special case, perhaps make general?
 106 if(GMX_FAHCORE)
 107     file(GLOB SELECTION_TEST selection/test*)
 108     list(REMOVE_ITEM GMXLIB_SOURCES ${SELECTION_TEST})
 109 endif(GMX_FAHCORE)
 110
 111 # only fiddle with assembly kernels if we're not doing OpenMM build
 112 if(NOT GMX_OPENMM)
 113 if(GMX_ASM_USEASM-NASM)
 114   enable_language(ASM-NASM)
 115
 116   # if NASM is used, we need a special build command for windows...
 117   FOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 118     GET_FILENAME_COMPONENT(FILE_BASE ${SRC} NAME_WE)
 119     SET(OBJ ${CMAKE_CURRENT_BINARY_DIR}/${FILE_BASE}${CMAKE_C_OUTPUT_EXTENSION})
 120
 121     ADD_CUSTOM_COMMAND(OUTPUT ${OBJ}
 122                        MAIN_DEPENDENCY ${SRC}
 123                        COMMAND ${CMAKE_ASM-NASM_COMPILER} -f ${CMAKE_ASM-NASM_OBJECT_FORMAT} -o ${OBJ} ${SRC})
 124
 125     SET(ALL_ASM_OBJS ${ALL_ASM_OBJS} ${OBJ})
 126   ENDFOREACH(SRC ${GMX_SSEKERNEL_ASM_SRC})
 127   set(GMX_SSEKERNEL_ASM_SRC ${ALL_ASM_OBJS})
 128
 129 else(GMX_ASM_USEASM-NASM)
 130
 131   enable_language(ASM-ATT)
 132   SET(CMAKE_ASM-ATT_COMPILER ${CMAKE_C_COMPILER})
 133   if(GMX_IA32_ASM)
 134     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m32")
 135   else()
 136     set_source_files_properties(${GMX_SSEKERNEL_ASM_SRC} PROPERTIES COMPILE_FLAGS "-c -m64")
 137   endif()
 138
 139 endif(GMX_ASM_USEASM-NASM)
 140 endif(NOT GMX_OPENMM)
 141
 142 add_library(gmx ${GMXLIB_SOURCES} ${BLAS_SOURCES} ${LAPACK_SOURCES} ${GMX_SSEKERNEL_C_SRC} ${GMX_SSEKERNEL_ASM_SRC} ${FORTRAN_SOURCES} ${GMX_BLUEGENE_C_SRC} ${GMX_PPC_ALTIVEC_SRC} ${THREAD_MPI_SRC})
 143 target_link_libraries(gmx ${GMX_EXTRA_LIBRARIES}  ${THREAD_LIB})
 144 if(USE_VERSION_H)
 145         add_dependencies(gmx gmx_version)
 146 endif()
 147 set_target_properties(gmx PROPERTIES OUTPUT_NAME "gmx${GMX_LIBS_SUFFIX}" SOVERSION ${SOVERSION} INSTALL_NAME_DIR "${LIB_INSTALL_DIR}")
 148
 149 install(TARGETS gmx DESTINATION ${LIB_INSTALL_DIR} COMPONENT libraries)
 150
 151 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libgmx.pc.cmakein ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc @ONLY)
 152 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libgmx.pc
 153         DESTINATION ${LIB_INSTALL_DIR}/pkgconfig
 154         RENAME "libgmx${GMX_LIBS_SUFFIX}.pc"
 155         COMPONENT development)
 156