CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(Gromacs)
   4 include(Dart)
   5 mark_as_advanced(DART_ROOT)
   6
   7 # PROJECT_VERSION should have the following structure:
   8 # VERSION-dev[-SUFFIX] where the VERSION should have the for: vMajor.vMinor.vPatch
   9 #
  10 # The "-dev" suffix is important to keep because it makes possible to distinguish
  11 # between a build from official release and a build from git release branch on a
  12 # machine with no git.
  13 #
  14 # NOTE: when releasing the "-dev" suffix needs to be stripped off!
  15 set(PROJECT_VERSION "4.5.4-dev")
  16 set(CUSTOM_VERSION_STRING ""
  17     CACHE STRING "Custom version string (if empty, use hard-coded default)")
  18 mark_as_advanced(CUSTOM_VERSION_STRING)
  19 if (CUSTOM_VERSION_STRING)
  20     set(PROJECT_VERSION ${CUSTOM_VERSION_STRING})
  21 endif (CUSTOM_VERSION_STRING)
  22 set(SOVERSION 6)
  23 # It is a bit irritating, but this has to be set separately for now!
  24 SET(CPACK_PACKAGE_VERSION_MAJOR "4")
  25 SET(CPACK_PACKAGE_VERSION_MINOR "5")
  26 SET(CPACK_PACKAGE_VERSION_PATCH "4")
  27
  28
  29 # Cmake modules/macros are in a subdirectory to keep this file cleaner
  30 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  31
  32 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  33 set(CMAKE_INSTALL_PREFIX "/usr/local/gromacs" CACHE STRING "Installation prefix (installation will need write permissions here)" FORCE)
  34 endif()
  35
  36 if(NOT CMAKE_BUILD_TYPE)
  37     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel." FORCE)
  38 endif(NOT CMAKE_BUILD_TYPE)
  39
  40 enable_language(C)
  41
  42 set(CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
  43 set(CPACK_PACKAGE_VENDOR "gromacs.org")
  44 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Gromacs - a toolkit for high-performance molecular simulation")
  45 set(CPACK_SET_DESTDIR "ON")
  46 set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
  47 set(CPACK_RESOURCE_FILE_WELCOME "${CMAKE_SOURCE_DIR}/admin/InstallWelcome.txt")
  48 # Its GPL/LGPL, so they do not have to agree to a license for mere usage, but some installers require this...
  49 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_SOURCE_DIR}/admin/InstallLicense.txt")
  50 set(CPACK_RESOURCE_FILE_README "${CMAKE_SOURCE_DIR}/admin/InstallInfo.txt")
  51
  52 #must come after all cpack settings!
  53 include(CPack)
  54
  55 ########################################################################
  56 # Check and warn if cache generated on a different host is being reused
  57 ########################################################################
  58 if(CMAKE_HOST_UNIX)
  59     execute_process(COMMAND hostname
  60                     OUTPUT_VARIABLE TMP_HOSTNAME
  61                     OUTPUT_STRIP_TRAILING_WHITESPACE)
  62     if(GMX_BUILD_HOSTNAME AND NOT "${GMX_BUILD_HOSTNAME}" STREQUAL "${TMP_HOSTNAME}")
  63         message(WARNING "
  64             The CMake cache, probably generated on a different host (${GMX_BUILD_HOSTNAME}),
  65             is being reused! This could lead to inconsitencies; therefore, it is
  66             recommended to regenerate the cache!")
  67     endif()
  68     set(GMX_BUILD_HOSTNAME "${TMP_HOSTNAME}" CACHE INTERNAL
  69             "Hostname of the machine where the cache was generated.")
  70 endif()
  71
  72 ########################################################################
  73 # Fix stupid flags on MSVC
  74 ########################################################################
  75 SET(SHARED_LIBS_DEFAULT ON)
  76 IF(CMAKE_GENERATOR MATCHES "Visual Studio")
  77     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE})
  78     SET(CMAKE_C_FLAGS_RELEASE ${CMAKE_C_FLAGS_RELEASE} CACHE STRING "" FORCE)
  79     STRING(REPLACE /MD /MT CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG})
  80     SET(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_DEBUG} CACHE STRING "" FORCE)
  81     SET(SHARED_LIBS_DEFAULT OFF)
  82 ENDIF(CMAKE_GENERATOR MATCHES "Visual Studio")
  83
  84 set(GMX_EXTRA_LIBRARIES)
  85
  86
  87
  88 ######################################################################
  89 # compiler tests
  90 # these need ot be done early (before further tests).
  91 #####################################################################
  92
  93 include(CheckCCompilerFlag)
  94 include(CheckCXXCompilerFlag)
  95
  96 include(gmxCFlags)
  97 gmx_c_flags()
  98
  99 ########################################################################
 100 # User input options                                                   #
 101 ########################################################################
 102 option(GMX_DOUBLE "Use double precision (much slower, use only if you really need it)" OFF)
 103 option(GMX_MPI    "Build a parallel (message-passing) version of GROMACS" OFF)
 104 option(GMX_THREADS    "Build a parallel (thread-based) version of GROMACS (cannot be combined with MPI yet)" ON)
 105 option(GMX_SOFTWARE_INVSQRT "Use GROMACS software 1/sqrt" ON)
 106 mark_as_advanced(GMX_SOFTWARE_INVSQRT)
 107 option(GMX_POWERPC_INVSQRT "Use PowerPC hardware 1/sqrt" OFF)
 108 mark_as_advanced(GMX_POWERPC_INVSQRT)
 109 option(GMX_FAHCORE "Build a library with mdrun functionality" OFF)
 110 mark_as_advanced(GMX_FAHCORE)
 111 option(GMX_OPENMM "Accelerated execution on GPUs through the OpenMM library (rerun cmake after changing to see relevant options)" OFF)
 112 set(GMX_ACCELERATION "auto"
 113     CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran")
 114
 115 set(GMX_FFT_LIBRARY "fftw3"
 116     CACHE STRING "FFT library choices: fftw3,fftw2,mkl,fftpack[built-in]")
 117 option(GMX_DISABLE_FFTW_MEASURE
 118        "Do not optimize FFTW setups (not needed with SSE)" OFF)
 119 mark_as_advanced(GMX_DISABLE_FFTW_MEASURE)
 120 set(GMX_QMMM_PROGRAM "none"
 121     CACHE STRING "QM package choices: none,gaussian,mopac,gamess,orca")
 122 option(GMX_BROKEN_CALLOC "Work around broken calloc()" OFF)
 123 mark_as_advanced(GMX_BROKEN_CALLOC)
 124 option(BUILD_SHARED_LIBS "Enable shared libraries (can be problematic with MPI, Windows)" ${SHARED_LIBS_DEFAULT})
 125 option(GMX_MPI_IN_PLACE "Enable MPI_IN_PLACE for MPIs that have it defined" ON)
 126 mark_as_advanced(GMX_MPI_IN_PLACE)
 127 option(GMX_DLOPEN "Compile with dlopen, needed to read VMD supported file formats" ON)
 128 mark_as_advanced(GMX_DLOPEN)
 129
 130
 131 option(GMX_IA32_ASM "Add SSE assembly files for IA32" OFF)
 132 mark_as_advanced(GMX_IA32_ASM)
 133 option(GMX_X86_64_ASM "Add SSE assembly files for X86_64" OFF)
 134 mark_as_advanced(GMX_X86_64_ASM)
 135
 136 option(USE_VERSION_H "Generate development version string/information" ON)
 137 mark_as_advanced(USE_VERSION_H)
 138
 139 option(GMX_DEFAULT_SUFFIX "Use default suffixes for GROMACS binaries and libs (_d for double, _mpi for MPI; rerun cmake after changing to see relevant options)" ON)
 140
 141 if(UNIX AND NOT APPLE)
 142     option(GMX_PREFER_STATIC_LIBS "When finding libraries prefer \".a\" static archives (NOTE: this is enabled only for UNIX (excluding APPLE) platforms but it might not always work!" OFF)
 143     mark_as_advanced(GMX_PREFER_STATIC_LIBS)
 144 endif()
 145
 146 ########################################################################
 147 # Set up binary and library suffixing
 148 ########################################################################
 149 set(GMX_BINARY_SUFFIX "" CACHE STRING "Suffix for GROMACS binaries (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 150 set(GMX_LIBS_SUFFIX ""
 151   CACHE STRING "Suffix for GROMACS libs (default: _d for double, _mpi for MPI, _mpi_d for MPI and double).")
 152 if (GMX_DEFAULT_SUFFIX)
 153   set(GMX_BINARY_SUFFIX "")
 154   set(GMX_LIBS_SUFFIX "")
 155   if (GMX_MPI)
 156     set(GMX_BINARY_SUFFIX "_mpi")
 157     set(GMX_LIBS_SUFFIX "_mpi")
 158   endif(GMX_MPI)
 159   if (GMX_DOUBLE)
 160     set (GMX_BINARY_SUFFIX "${GMX_BINARY_SUFFIX}_d")
 161     set (GMX_LIBS_SUFFIX "${GMX_LIBS_SUFFIX}_d")
 162   endif(GMX_DOUBLE)
 163   if (GMX_OPENMM)
 164     set (GMX_BINARY_SUFFIX "-gpu")
 165     set (GMX_LIBS_SUFFIX "_gpu")
 166   endif(GMX_OPENMM)
 167   mark_as_advanced(FORCE GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 168   message(STATUS "Using default binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 169   message(STATUS "Using default library suffix: \"${GMX_LIBS_SUFFIX}\"")
 170 else(GMX_DEFAULT_SUFFIX)
 171   mark_as_advanced(CLEAR GMX_BINARY_SUFFIX GMX_LIBS_SUFFIX)
 172   message(STATUS "Using manually set binary suffix: \"${GMX_BINARY_SUFFIX}\"")
 173   message(STATUS "Using manually set library suffix: \"${GMX_LIBS_SUFFIX}\"")
 174 endif(GMX_DEFAULT_SUFFIX)
 175
 176 set(PKG_CFLAGS "")
 177 if(GMX_DOUBLE)
 178     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_DOUBLE")
 179 endif(GMX_DOUBLE)
 180 if(GMX_SOFTWARE_INVSQRT)
 181   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_SOFTWARE_INVSQRT")
 182 endif(GMX_SOFTWARE_INVSQRT)
 183 if(GMX_POWERPC_INVSQRT)
 184   set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_POWERPC_INVSQRT")
 185 endif(GMX_POWERPC_INVSQRT)
 186
 187 ########################################################################
 188 #Process MPI settings
 189 ########################################################################
 190 include(CheckCSourceCompiles) # for gmxTestMPI_IN_PLACE
 191 if(GMX_MPI)
 192         MESSAGE(WARNING "
 193             There are known problems with some MPI implementations:
 194                      OpenMPI version < 1.4.1
 195                      MVAPICH2 version <= 1.4.1                               *")
 196     if(GMX_THREADS)
 197         #message(FATAL_ERROR "Thread-based parallelization conflicts with MPI.")
 198         set(GMX_THREADS OFF CACHE BOOL
 199             "Thread-based parallelization conflicts with MPI." FORCE)
 200     endif(GMX_THREADS)
 201     find_package(MPI)
 202     if(MPI_FOUND)
 203         set(GROMACS_C_FLAGS ${GROMACS_FLAGS} ${MPI_COMPILE_FLAGS})
 204         set(GROMACS_LINKER_FLAGS ${GROMACS_LINKER_FLAGS} ${MPI_LINK_FLAGS})
 205
 206         include_directories(${MPI_INCLUDE_PATH})
 207         list(APPEND GMX_EXTRA_LIBRARIES ${MPI_LIBRARIES})
 208         add_definitions( -DMPI ) #for FAHCORE
 209         include(gmxTestMPI_IN_PLACE)
 210         if (GMX_MPI_IN_PLACE)
 211             gmx_test_mpi_in_place(MPI_IN_PLACE_EXISTS)
 212         endif (GMX_MPI_IN_PLACE)
 213     else(MPI_FOUND)
 214         message(FATAL_ERROR "MPI support requested, but no MPI compiler found.")
 215     endif(MPI_FOUND)
 216     include(gmxTestCatamount)
 217     gmx_test_catamount(GMX_CRAY_XT3)
 218     if(GMX_CRAY_XT3)
 219         set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_CRAY_XT3")
 220         set(GMX_NO_SYSTEM 1)
 221         set(GMX_NO_NICE 1)
 222     endif(GMX_CRAY_XT3)
 223     set(GMX_LIB_MPI 1)
 224     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_LIB_MPI")
 225 endif(GMX_MPI)
 226
 227
 228 #######################################################################
 229 # Check for options incompatible with OpenMM build                    #
 230 #######################################################################
 231 if(GMX_OPENMM)
 232     cmake_minimum_required(VERSION 2.6.4)
 233     # we'll use the built-in fft to avoid unnecessary dependencies
 234     string(TOUPPER ${GMX_FFT_LIBRARY} GMX_FFT_LIBRARY)
 235     if(NOT ${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 236         message(STATUS "No external FFT libraries needed for the OpenMM build, switching to fftpack!")
 237         set(GMX_FFT_LIBRARY "fftpack" CACHE STRING
 238                 "No external FFT libraries needed for the OpenMM build, switching to  fftpack!" FORCE)
 239     endif()
 240     if(GMX_MPI)
 241         message(FATAL_ERROR "The OpenMM build is not compatible with MPI!")
 242     endif(GMX_MPI)
 243     if(GMX_THREADS)
 244         message(STATUS "Threads are  not compatible with OpenMM build, disabled!")
 245         set(GMX_THREADS OFF CACHE BOOL
 246                 "Threads are not compatible with OpenMM build, disabled!" FORCE)
 247     endif(GMX_THREADS)
 248     if(GMX_SOFTWARE_INVSQRT)
 249         set(GMX_SOFTWARE_INVSQRT OFF CACHE STRING
 250                 "The OpenMM build does not need GROMACS software 1/sqrt!" FORCE)
 251     endif(GMX_SOFTWARE_INVSQRT)
 252     string(TOUPPER ${GMX_ACCELERATION} GMX_ACCELERATION)
 253     if(NOT GMX_ACCELERATION STREQUAL "NONE")
 254         message(STATUS "Switching off CPU-based acceleration, the OpenMM build does not support/need any!")
 255         set(GMX_ACCELERATION "none" CACHE STRING
 256                 "Switching off CPU-based acceleration, the OpenMM build does not support/need any!" FORCE)
 257     endif()
 258     if(GMX_FAHCORE)
 259         message(FATAL_ERROR "The OpenMM build does not support FAH build!")
 260     endif(GMX_FAHCORE)
 261     if(GMX_DOUBLE)
 262         message(FATAL_ERROR  "The OpenMM-build does not support double precision calculations!")
 263     endif()
 264     # mark as advanced the unused variables
 265     mark_as_advanced(FORCE GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 266         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 267 else(GMX_OPENMM)
 268      mark_as_advanced(CLEAR GMX_ACCELERATION GMX_MPI GMX_FFT_LIBRARY
 269         GMX_QMMM_PROGRAM GMX_THREADS GMX_DOUBLE)
 270 endif(GMX_OPENMM)
 271
 272
 273 ########################################################################
 274 # Basic system tests (standard libraries, headers, functions, types)   #
 275 ########################################################################
 276 include(CheckIncludeFiles)
 277 check_include_files(string.h     HAVE_STRING_H)
 278 check_include_files(math.h       HAVE_MATH_H)
 279 check_include_files(limits.h     HAVE_LIMITS_H)
 280 check_include_files(memory.h     HAVE_MEMORY_H)
 281 check_include_files(unistd.h     HAVE_UNISTD_H)
 282 check_include_files(direct.h     HAVE_DIRECT_H)
 283 check_include_files(pwd.h        HAVE_PWD_H)
 284 check_include_files(stdint.h     HAVE_STDINT_H)
 285 check_include_files(stdlib.h     HAVE_STDLIB_H)
 286 check_include_files(pthread.h    HAVE_PTHREAD_H)
 287 check_include_files(dirent.h     HAVE_DIRENT_H)
 288 check_include_files(inttypes.h   HAVE_INTTYPES_H)
 289 check_include_files(regex.h      HAVE_REGEX_H)
 290 check_include_files(sys/types.h  HAVE_SYS_TYPES_H)
 291 check_include_files(sys/stat.h   HAVE_SYS_STAT_H)
 292 check_include_files(sys/time.h   HAVE_SYS_TIME_H)
 293 check_include_files(rpc/rpc.h    HAVE_RPC_RPC_H)
 294 check_include_files("rpc/rpc.h;rpc/xdr.h"    HAVE_RPC_XDR_H)
 295 # SSE support
 296 check_include_files(xmmintrin.h  HAVE_XMMINTRIN_H)
 297 check_include_files(emmintrin.h  HAVE_EMMINTRIN_H)
 298 check_include_files(pmmintrin.h  HAVE_PMMINTRIN_H)
 299 check_include_files(smmintrin.h  HAVE_SMMINTRIN_H)
 300 check_include_files(io.h                 HAVE_IO_H)
 301
 302
 303 include(CheckFunctionExists)
 304 check_function_exists(strcasecmp        HAVE_STRCASECMP)
 305 check_function_exists(strdup            HAVE_STRDUP)
 306 check_function_exists(vprintf           HAVE_VPRINTF)
 307 check_function_exists(memcmp            HAVE_MEMCMP)
 308 check_function_exists(posix_memalign    HAVE_POSIX_MEMALIGN)
 309 check_function_exists(memalign          HAVE_MEMALIGN)
 310 check_function_exists(_aligned_malloc   HAVE__ALIGNED_MALLOC)
 311 check_function_exists(gettimeofday      HAVE_GETTIMEOFDAY)
 312 check_function_exists(isnan             HAVE_ISNAN)
 313 check_function_exists(_isnan            HAVE__ISNAN)
 314 check_function_exists(isfinite          HAVE_ISFINITE)
 315 check_function_exists(_isfinite         HAVE__ISFINITE)
 316 check_function_exists(fsync             HAVE_FSYNC)
 317 check_function_exists(_fileno           HAVE__FILENO)
 318 check_function_exists(fileno            HAVE_FILENO)
 319 check_function_exists(_commit           HAVE__COMMIT)
 320
 321 include(CheckLibraryExists)
 322 check_library_exists(m sqrt "" HAVE_LIBM)
 323 check_library_exists(m cbrt "" HAVE_CBRT)
 324
 325
 326 include(CheckTypeSize)
 327
 328 check_type_size("bool"          SIZEOF_BOOL) # will also set HAVE_BOOL
 329 check_type_size("int"           SIZEOF_INT)
 330 check_type_size("long int"      SIZEOF_LONG_INT)
 331 check_type_size("long long int" SIZEOF_LONG_LONG_INT)
 332 check_type_size("off_t"         SIZEOF_OFF_T)
 333 check_type_size("void *"        SIZEOF_VOIDP)
 334
 335 if (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 336     set(GMX_64_BIT TRUE)
 337 else (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 338     set(GMX_64_BIT FALSE)
 339 endif (CMAKE_C_SIZEOF_DATA_PTR EQUAL 8)
 340
 341 # Check for some basic types that we *need*, so set these to int if they are not present
 342 check_type_size(uid_t uid_t)
 343 if(NOT uid_t)
 344   set(uid_t int)
 345 else(NOT uid_t)
 346   set(uid_t 0)
 347 endif(NOT uid_t)
 348
 349 check_type_size(gid_t gid_t)
 350 if(NOT gid_t)
 351   set(gid_t 1)
 352 else(NOT gid_t)
 353   set(gid_t 0)
 354 endif(NOT gid_t)
 355
 356 check_type_size(size_t size_t)
 357 if(NOT size_t)
 358   set(size_t int)
 359 else(NOT size_t)
 360   set(size_t 0)
 361 endif(NOT size_t)
 362
 363 check_type_size(off_t off_t)
 364 if(NOT off_t)
 365   set(off_t int)
 366 else(NOT off_t)
 367   set(off_t 0)
 368 endif(NOT off_t)
 369
 370 include(TestBigEndian)
 371 test_big_endian(GMX_INTEGER_BIG_ENDIAN)
 372
 373
 374
 375
 376 ########################################################################
 377 # Find external packages                                               #
 378 ########################################################################
 379 if(UNIX AND NOT APPLE)
 380     if(GMX_PREFER_STATIC_LIBS)
 381         SET(CMAKE_FIND_LIBRARY_SUFFIXES .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
 382         if(BUILD_SHARED_LIBS)
 383             message(WARNING "Static libraries requested, the GROMACS libraries will also be build static (BUILD_SHARED_LIBS=OFF)")
 384             set(BUILD_SHARED_LIBS OFF CACHE BOOL "Enable shared libraries (can be problematic with MPI, Windows)" FORCE)
 385         endif()
 386     endif()
 387 endif()
 388
 389 option(GMX_XML "Use libxml2 to parse xml files" ON)
 390 if (GMX_XML)
 391   find_package(LibXml2)
 392   set(PKG_XML "")
 393   if(LIBXML2_FOUND)
 394     include_directories(${LIBXML2_INCLUDE_DIR})
 395     set(PKG_XML libxml-2.0)
 396     set(XML_LIBRARIES ${LIBXML2_LIBRARIES})
 397     set(HAVE_LIBXML2 1)
 398   endif(LIBXML2_FOUND)
 399 endif(GMX_XML)
 400
 401 option(GMX_GSL "Add support for gsl" OFF)
 402 if (GMX_GSL)
 403   find_package(gsl)
 404   set(PKG_GSL "")
 405   if(GSL_FOUND)
 406     include_directories(${GSL_INCLUDE_DIR})
 407     set(PKG_GSL gsl)
 408     set(HAVE_LIBGSL 1)
 409   endif(GSL_FOUND)
 410 endif (GMX_GSL)
 411
 412 option(GMX_X11 "Use X window system" OFF)
 413 if (GMX_X11)
 414         find_package(X11)
 415         # X11 includes/libraries are only set in the ngmx subdirectory!
 416         if(X11_FOUND)
 417         set(HAVE_X11 1)
 418         endif(X11_FOUND)
 419 endif(GMX_X11)
 420
 421 if(GMX_THREADS)
 422     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_THREADS")
 423     include(ThreadMPI)
 424     set(THREAD_MPI_LIB thread_mpi)
 425     set(GMX_MPI 1)
 426     string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 427     if(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 428         message(FATAL_ERROR "FFTW2 can't be used with threads. Try fftw3 or mkl.")
 429     endif()
 430 endif(GMX_THREADS)
 431
 432 if(GMX_OPENMM)
 433     set(CUDA_BUILD_EMULATION OFF)
 434     find_package(CUDA 3.1 REQUIRED)
 435     add_definitions(-DGMX_OPENMM)
 436     if(CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 437         set(CUDA_VERBOSE_BUILD ON)
 438     endif()
 439     find_package(OpenMM)
 440 endif(GMX_OPENMM)
 441
 442 if(APPLE)
 443    find_library(ACCELERATE_FRAMEWORK Accelerate)
 444    list(APPEND GMX_EXTRA_LIBRARIES ${ACCELERATE_FRAMEWORK})
 445 endif(APPLE)
 446
 447 if(CYGWIN)
 448     set(GMX_CYGWIN 1)
 449 endif(CYGWIN)
 450
 451 # only bother with finding git and using version.h if the source is a git repo
 452 if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
 453     if(USE_VERSION_H)
 454         # We need at least git v1.5.1 be able to parse git's date output. If not
 455         # fund or the version is too small, we can't generate version information.
 456         find_package(Git 1.5.1)
 457         # this should at some point become VERSION_LESS
 458         if(NOT Git_FOUND OR Git_VERSION STRLESS "1.5.1")
 459             message("No compatible git version found, won't be able to generate proper development version information.")
 460             set(USE_VERSION_H OFF)
 461         endif()
 462     endif()
 463 else()
 464     set(USE_VERSION_H OFF)
 465 endif()
 466
 467 if (GMX_DLOPEN)
 468     list(APPEND GMX_EXTRA_LIBRARIES ${CMAKE_DL_LIBS})
 469 endif (GMX_DLOPEN)
 470
 471 ########################################################################
 472 # Generate development version info for cache
 473 ########################################################################
 474 # set(GEN_VERSION_INFO_INTERNAL "ON")
 475 # include(gmxGenerateVersionString)
 476
 477 ########################################################################
 478 # Our own GROMACS tests
 479 ########################################################################
 480
 481 add_definitions( -DHAVE_CONFIG_H )
 482 include_directories(${CMAKE_BINARY_DIR}/src)
 483 include_directories(${CMAKE_SOURCE_DIR}/include)
 484
 485 include(gmxCheckBuildUserTime)
 486 gmx_check_build_user_time(BUILD_TIME BUILD_USER BUILD_MACHINE)
 487
 488 include(gmxTestFloatFormat)
 489 gmx_test_float_format(GMX_FLOAT_FORMAT_IEEE754
 490                       GMX_IEEE754_BIG_ENDIAN_BYTE_ORDER
 491                       GMX_IEEE754_BIG_ENDIAN_WORD_ORDER)
 492
 493 include(gmxTestLargeFiles)
 494 gmx_test_large_files(GMX_LARGEFILES)
 495 check_function_exists(fseeko     HAVE_FSEEKO)
 496
 497 include(gmxTestSignal)
 498 gmx_test_retsigtype(RETSIGTYPE)
 499 gmx_test_sigusr1(HAVE_SIGUSR1)
 500
 501 include(gmxTestInline)
 502 gmx_test_inline(INLINE_KEYWORD)
 503
 504 include(gmxTestRestrict)
 505 gmx_test_inline(RESTRICT_KEYWORD)
 506
 507 include(gmxTestPipes)
 508 gmx_test_pipes(HAVE_PIPES)
 509
 510 include(gmxTestInlineASM)
 511 gmx_test_inline_asm_gcc_x86(GMX_X86_GCC_INLINE_ASM)
 512 gmx_test_inline_asm_msvc_x86(GMX_X86_MSVC_INLINE_ASM)
 513
 514 # turn on SSE if supported with reasonable defaults.
 515 if (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 516   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^(i.86|x86|x64|x86_64|AMD64|amd64)")
 517
 518     set(GMX_ACCELERATION "SSE" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 519
 520     if (GMX_64_BIT)
 521       set(GMX_X86_64_ASM ON CACHE BOOL "Add SSE assembly files for x86_64" FORCE)
 522     else (GMX_64_BIT)
 523       set(GMX_IA32_ASM ON CACHE BOOL "Add SSE assembly files for i386" FORCE)
 524     endif (GMX_64_BIT)
 525
 526     # Determine the assembler/compiler to use
 527   else()
 528     set(GMX_ACCELERATION "none" CACHE STRING "Accelerated kernels. Pick one of: auto, none, SSE, BlueGene, Power6, ia64, altivec, fortran" FORCE)
 529   endif()
 530 endif (${GMX_ACCELERATION} STREQUAL "auto" AND NOT GMX_OPENMM)
 531
 532 include(gmxTestXDR)
 533 gmx_test_xdr(GMX_SYSTEM_XDR)
 534 if(NOT GMX_SYSTEM_XDR)
 535     set(GMX_INTERNAL_XDR 1)
 536     set(PKG_CFLAGS "${PKG_CFLAGS} -DGMX_INTERNAL_XDR")
 537 endif(NOT GMX_SYSTEM_XDR)
 538
 539 # Process nonbonded accelerated kernels settings
 540 string(TOUPPER ${GMX_ACCELERATION} ${GMX_ACCELERATION})
 541 if(${GMX_ACCELERATION} STREQUAL "NONE")
 542   # nothing to do
 543 elseif(${GMX_ACCELERATION} STREQUAL "SSE")
 544
 545     if(CMAKE_GENERATOR MATCHES "Visual Studio")
 546       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" ON)
 547     else()
 548       option(GMX_ASM_USEASM-NASM "Use Nasm for assembly instead of compiler (necessary on windows)" OFF)
 549     endif()
 550         mark_as_advanced(GMX_ASM_USEASM-NASM)
 551
 552     if (NOT GMX_64_BIT)
 553         # for 32-bit compiles, we might need to turn on sse
 554         CHECK_C_COMPILER_FLAG("-msse2" XFLAGS_SSE)
 555         if (XFLAGS_SSE)
 556             set(GROMACS_C_FLAGS "-msse2 ${GROMACS_C_FLAGS}")
 557         endif (XFLAGS_SSE)
 558         CHECK_CXX_COMPILER_FLAG("-msse2" XXFLAGS_SSE)
 559         if (XXFLAGS_SSE)
 560             set(GROMACS_CXX_FLAGS "-msse2 ${GROMACS_CXX_FLAGS}")
 561         endif (XXFLAGS_SSE)
 562     endif (NOT GMX_64_BIT)
 563
 564     if(GMX_IA32_ASM)
 565       if(GMX_DOUBLE)
 566         set(GMX_IA32_SSE2 1)
 567       else()
 568        set(GMX_IA32_SSE 1)
 569       endif()
 570     elseif(GMX_X86_64_ASM)
 571       if(GMX_DOUBLE)
 572        set(GMX_X86_64_SSE2 1)
 573       else()
 574         set(GMX_X86_64_SSE 1)
 575       endif()
 576     endif()
 577
 578 #    if(HAVE_PMMINTRIN_H)
 579 #        set(GMX_SSE3 1)
 580 #    endif(HAVE_PMMINTRIN_H)
 581 #    if(HAVE_SMMINTRIN_H)
 582 #        set(GMX_SSE4_1 1)
 583 #    endif(HAVE_SMMINTRIN_H)
 584
 585 elseif(${GMX_ACCELERATION} STREQUAL "FORTRAN")
 586     set(GMX_FORTRAN 1)
 587     #these are switch on by default sometimes
 588     set(GMX_IA32_ASM 0)
 589     set(GMX_GMX_X86_64_ASM 0)
 590 elseif(${GMX_ACCELERATION} STREQUAL "BLUEGENE")
 591 # GMX_ACCELERATION=BlueGene should be set in the Toolchain-BlueGene?-???.cmake file
 592     message(STATUS "Configuring for BlueGene")
 593     set(GMX_BLUEGENE 1)
 594     if (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 595         set(SHARED_LIBS_DEFAULT OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 596         set(BUILD_SHARED_LIBS OFF CACHE BOOL "Shared libraries not compatible with BlueGene/L, disabled!" FORCE)
 597     endif (${CMAKE_SYSTEM_NAME} STREQUAL "BlueGeneL")
 598     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on BlueGene" FORCE)
 599     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on BlueGene" FORCE)
 600     set(GMX_X11 OFF CACHE BOOL "X11 not compatible with BlueGene, disabled!" FORCE)
 601     set(GMX_THREADS OFF CACHE BOOL "Threads not compatible with BlueGene, disabled!" FORCE)
 602     set(GMX_MPI ON CACHE BOOL "Use MPI on BlueGene" FORCE)
 603     set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use MASSV for BLAS on BlueGene" FORCE)
 604     set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use MASSV for LAPACK on BlueGene" FORCE)
 605     list(APPEND GMX_EXTRA_LIBRARIES massv)
 606 elseif(${GMX_ACCELERATION} STREQUAL "POWER6")
 607     set(GMX_POWER6 1)
 608     set(GMX_SOFTWARE_INVSQRT OFF CACHE BOOL "Do not use software reciprocal square root on Power6" FORCE)
 609     set(GMX_POWERPC_INVSQRT ON CACHE BOOL "Use hardware reciprocal square root on Power6" FORCE)
 610 elseif(${GMX_ACCELERATION} STREQUAL "IA64")
 611     set(GMX_IA64_ASM 1)
 612     set(DISABLE_WATERWATER_NLIST 1)
 613     set(DISABLE_WATER_NLIST 1)
 614 elseif(${GMX_ACCELERATION} STREQUAL "ALTIVEC")
 615     check_include_files(altivec.h HAVE_ALTIVEC_H)
 616     if(HAVE_ALTIVEC_H)
 617         set(GMX_PPC_ALTIVEC 1)
 618     endif(HAVE_ALTIVEC_H)
 619 else(${GMX_ACCELERATION} STREQUAL "NONE")
 620     MESSAGE(FATAL_ERROR "Unrecognized option for accelerated kernels: ${GMX_ACCELERATION}. Pick one of auto, none, SSE, Fortran, BlueGene, Power6, ia64, altivec")
 621 endif(${GMX_ACCELERATION} STREQUAL "NONE")
 622
 623 if(GMX_FORTRAN OR GMX_POWER6)
 624     if (GMX_THREADS)
 625         message(FATAL_ERROR "FORTRAN/POWER6 is incompatible with threads and only provides a speed-up on certain IBM compilers. Disable FORTRAN (or threads if you really want to use FORTRAN kernels).")
 626     endif(GMX_THREADS)
 627     enable_language(Fortran)
 628     include(FortranCInterface)
 629     discover_fortran_mangling(prefix isupper suffix extra_under_score found)
 630     if(extra_under_score)
 631         set(extrasuffix "_")
 632     endif(extra_under_score)
 633     if(prefix)
 634       set(prefix "${prefix} ##")
 635     endif(prefix)
 636
 637     if(isupper)
 638         set(F77_FUNCDEF   "${prefix} NAME ## ${suffix}")
 639         set(F77_FUNCDEF_  "${prefix} NAME ## ${suffix}${extrasuffix}")
 640     else(isupper)
 641         set(F77_FUNCDEF   "${prefix} name ## ${suffix}")
 642         set(F77_FUNCDEF_  "${prefix} name ## ${suffix}${extrasuffix}")
 643     endif(isupper)
 644 else(GMX_FORTRAN OR GMX_POWER6)
 645         set(F77_FUNCDEF   "name ## _")
 646         set(F77_FUNCDEF_  "name ## _")
 647 endif(GMX_FORTRAN OR GMX_POWER6)
 648
 649 # Process QM/MM Settings
 650 string(TOUPPER ${GMX_QMMM_PROGRAM} ${GMX_QMMM_PROGRAM})
 651 if(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 652     set(GMX_QMMM_GAUSSIAN 1)
 653 elseif(${GMX_QMMM_PROGRAM} STREQUAL "MOPAC")
 654     set(GMX_QMMM_MOPAC 1)
 655 elseif(${GMX_QMMM_PROGRAM} STREQUAL "GAMESS")
 656     set(GMX_QMMM_GAMESS 1)
 657 elseif(${GMX_QMMM_PROGRAM} STREQUAL "ORCA")
 658     set(GMX_QMMM_ORCA 1)
 659 elseif(${GMX_QMMM_PROGRAM} STREQUAL "NONE")
 660     # nothing to do
 661 else(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 662     MESSAGE(FATAL_ERROR "Invalid QM/MM program option: ${GMX_QMMM_PROGRAM}. Choose one of: Gaussian, Mopac, Gamess, Orca, None")
 663 endif(${GMX_QMMM_PROGRAM} STREQUAL "GAUSSIAN")
 664
 665 # Process FFT library settings - if not OpenMM build
 666 string(TOUPPER ${GMX_FFT_LIBRARY} ${GMX_FFT_LIBRARY})
 667 set(PKG_FFT "")
 668 set(PKG_FFT_LIBS "")
 669 if(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 670 #    MESSAGE(STATUS "Using external FFT library - fftw3")
 671     if(GMX_DOUBLE)
 672         find_package(FFTW3 REQUIRED)
 673                 include_directories(${FFTW3_INCLUDE_DIR})
 674         set(FFT_LIBRARIES ${FFTW3_LIBRARIES})
 675         set(PKG_FFT "fftw3")
 676     else(GMX_DOUBLE)
 677         find_package(FFTW3F REQUIRED)
 678         include_directories(${FFTW3F_INCLUDE_DIR})
 679         set(FFT_LIBRARIES ${FFTW3F_LIBRARIES})
 680         set(PKG_FFT "fftw3f")
 681     endif(GMX_DOUBLE)
 682
 683     if(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 684         MESSAGE(FATAL_ERROR "Cannot find fftw3 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 685     endif(NOT FFTW3_FOUND AND NOT FFTW3F_FOUND)
 686
 687     set(GMX_FFT_FFTW3 1)
 688
 689 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTW2")
 690 #    MESSAGE(STATUS "Using external FFT library - fftw2")
 691     if(GMX_DOUBLE)
 692         find_package(FFTW2 REQUIRED)
 693     else(GMX_DOUBLE)
 694         find_package(FFTW2F REQUIRED)
 695     endif(GMX_DOUBLE)
 696
 697     if(NOT FFTW2_FOUND)
 698            MESSAGE(FATAL_ERROR "Cannot find fftw2 (with correct precision). Fix it, choose another FFT library, or use the Gromacs built-in fftpack (slower)!")
 699     endif(NOT FFTW2_FOUND)
 700     include_directories(${FFTW2_INCLUDE_DIR})
 701     set(FFT_LIBRARIES ${FFTW2_LIBRARIES})
 702     set(PKG_FFT_LIBS ${FFTW2_LIBRARIES})
 703
 704     if("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 705         set(FFTW2_NAME_DFFTW 1)
 706     elseif("${FFTW2_LIBRARIES}" MATCHES "sfftw")
 707         set(FFTW2_NAME_SFFTW 1)
 708     else("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 709         set(FFTW2_NAME_FFTW 1)
 710     endif("${FFTW2_LIBRARIES}" MATCHES "dfftw")
 711
 712     set(GMX_FFT_FFTW2 1)
 713 elseif(${GMX_FFT_LIBRARY} STREQUAL "MKL")
 714 #    MESSAGE(STATUS "Using external FFT library - Intel MKL")
 715     find_package(MKL REQUIRED)
 716     include_directories(${MKL_INCLUDE_DIR})
 717     set(FFT_LIBRARIES ${MKL_LIBRARIES})
 718     set(PKG_FFT_LIBS ${MKL_LIBRARIES})
 719
 720     set(GMX_FFT_MKL 1)
 721     set(HAVE_MKL 1)
 722
 723 #elseif(${GMX_FFT_LIBRARY} STREQUAL "ACML")
 724 #    MESSAGE(STATUS "Using external FFT library - AMD core math library")
 725 #    set(GMX_FFT_ACML 1)
 726 elseif(${GMX_FFT_LIBRARY} STREQUAL "FFTPACK")
 727     MESSAGE(STATUS "Using internal FFT library - fftpack")
 728     set(GMX_FFT_FFTPACK 1)
 729 else(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 730     MESSAGE(FATAL_ERROR "Invalid FFT library setting: ${GMX_FFT_LIBRARY}. Choose one of: fftw3, fftw2, mkl, acml, fftpack")
 731 endif(${GMX_FFT_LIBRARY} STREQUAL "FFTW3")
 732
 733 # MKL has BLAS/LAPACK routines
 734 if(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 735   set(GMX_EXTERNAL_BLAS TRUE CACHE BOOL "Use external BLAS instead of built-in")
 736   set(GMX_EXTERNAL_LAPACK TRUE CACHE BOOL "Use external LAPACK instead of built-in")
 737 else(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 738   set(GMX_EXTERNAL_BLAS FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 739   set(GMX_EXTERNAL_LAPACK FALSE CACHE BOOL "Use external LAPACK instead of built-in")
 740   if(GMX_EXTERNAL_BLAS)
 741     #FindBLAS needs Fortran
 742     enable_language(Fortran)
 743     find_package(BLAS REQUIRED)
 744     list(APPEND GMX_EXTRA_LIBRARIES ${BLAS_LIBRARIES})
 745   endif(GMX_EXTERNAL_BLAS)
 746   if(GMX_EXTERNAL_LAPACK)
 747     #FindLAPACK needs Fortran
 748     enable_language(Fortran)
 749     find_package(LAPACK REQUIRED)
 750     list(APPEND GMX_EXTRA_LIBRARIES ${LAPACK_LIBRARIES})
 751   endif(GMX_EXTERNAL_LAPACK)
 752 endif(HAVE_MKL OR ACCELERATE_FRAMEWORK)
 753 mark_as_advanced(GMX_EXTERNAL_LAPACK)
 754 mark_as_advanced(GMX_EXTERNAL_BLAS)
 755
 756 # Math and thread libraries must often come after all others when linking...
 757 if(HAVE_LIBM)
 758     list(APPEND GMX_EXTRA_LIBRARIES m)
 759 endif(HAVE_LIBM)
 760
 761 if(GMX_FAHCORE)
 762   set(COREWRAP_INCLUDE_DIR "${CMAKE_SOURCE_DIR}/../corewrap" CACHE STRING
 763       "Path to swindirect.h")
 764   include_directories(${COREWRAP_INCLUDE_DIR})
 765 endif(GMX_FAHCORE)
 766
 767 # # # # # # # # # # NO MORE TESTS AFTER THIS LINE! # # # # # # # # # # #
 768 # these are set after everything else
 769 if (NOT DEFINED GROMACS_C_FLAGS_SET)
 770     set(GROMACS_C_FLAGS_SET true CACHE INTERNAL "Whether to reset the C flags"
 771         FORCE)
 772     set(CMAKE_C_FLAGS "${GROMACS_C_FLAGS} ${CMAKE_C_FLAGS}" CACHE STRING
 773         "Flags used by the compiler during all build types" FORCE)
 774     set(CMAKE_CXX_FLAGS "${GROMACS_CXX_FLAGS} ${CMAKE_CXX_FLAGS}" CACHE STRING
 775         "Flags used by the compiler during all build types" FORCE)
 776     set(CMAKE_EXE_LINKER_FLAGS
 777         "${GROMACS_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS}"
 778         CACHE STRING "Linker flags" FORCE)
 779 endif (NOT DEFINED GROMACS_C_FLAGS_SET)
 780
 781 ########################################################################
 782 # Specify install locations and which subdirectories to process        #
 783 ########################################################################
 784 if ( DEFINED LIB )
 785     set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
 786 else()
 787     set(LIB_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/lib)
 788 endif()
 789 set(BIN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/bin)
 790 set(DATA_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/share/gromacs)
 791 set(MAN_INSTALL_DIR  ${CMAKE_INSTALL_PREFIX}/share/man)
 792 set(INCL_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include)
 793
 794 set(GMXLIBDIR        ${DATA_INSTALL_DIR}/top)
 795
 796 ##################################################################
 797 # Shared library settings - Darwin uses INSTALL_NAME_DIR instead!
 798 ##################################################################
 799 if(NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 800     set(CMAKE_SKIP_BUILD_RPATH  FALSE)
 801     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
 802     set(CMAKE_INSTALL_RPATH "${LIB_INSTALL_DIR}")
 803     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 804 endif()
 805
 806 add_subdirectory(share)
 807 add_subdirectory(include)
 808 add_subdirectory(man)
 809 add_subdirectory(src)
 810 add_subdirectory(scripts)
 811
 812 #######################
 813 ## uninstall target
 814 #######################
 815     CONFIGURE_FILE(
 816                    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 817                    "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake"
 818                    IMMEDIATE @ONLY)
 819 ###########################
 820 ADD_CUSTOM_TARGET(uninstall
 821                   "${CMAKE_COMMAND}" -P
 822                   "${CMAKE_CURRENT_BINARY_DIR}/cmake/cmake_uninstall.cmake")
 823 ###########################
 824
 825
 826 ########################################################################
 827 # Tests                                                                #
 828 ########################################################################
 829
 830 include(CTest)
 831 mark_as_advanced(BUILD_TESTING)
 832 IF(BUILD_TESTING)
 833         enable_testing()
 834         add_test(TestBuildAll make)
 835         add_subdirectory(tests)
 836 ENDIF()
 837