grub-core/lib/riscv/setjmp.S

   1 /*
   2  *  GRUB  --  GRand Unified Bootloader
   3  *  Copyright (C) 2018  Free Software Foundation, Inc.
   4  *
   5  *  GRUB is free software: you can redistribute it and/or modify
   6  *  it under the terms of the GNU General Public License as published by
   7  *  the Free Software Foundation, either version 3 of the License, or
   8  *  (at your option) any later version.
   9  *
  10  *  GRUB is distributed in the hope that it will be useful,
  11  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  *  GNU General Public License for more details.
  14  *
  15  *  You should have received a copy of the GNU General Public License
  16  *  along with GRUB.  If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 #include <grub/symbol.h>
  20 #include <grub/dl.h>
  21
  22         .file   "setjmp.S"
  23
  24 GRUB_MOD_LICENSE "GPLv3+"
  25
  26         .text
  27
  28 #if __riscv_xlen == 64
  29 #define STORE_IDX(reg, idx)     sd reg, (idx*8)(a0)
  30 #define LOAD_IDX(reg, idx)      ld reg, (idx*8)(a0)
  31 #else
  32 #define STORE_IDX(reg, idx)     sw reg, (idx*4)(a0)
  33 #define LOAD_IDX(reg, idx)      lw reg, (idx*4)(a0)
  34 #endif
  35
  36 /*
  37  * int grub_setjmp (grub_jmp_buf env)
  38  */
  39 FUNCTION(grub_setjmp)
  40         /* Preserve all callee-saved registers and the SP */
  41         STORE_IDX(s0, 0)
  42         STORE_IDX(s1, 1)
  43         STORE_IDX(s2, 2)
  44         STORE_IDX(s3, 3)
  45         STORE_IDX(s4, 4)
  46         STORE_IDX(s5, 5)
  47         STORE_IDX(s6, 6)
  48         STORE_IDX(s7, 7)
  49         STORE_IDX(s8, 8)
  50         STORE_IDX(s9, 9)
  51         STORE_IDX(s10, 10)
  52         STORE_IDX(s11, 11)
  53         STORE_IDX(ra, 12)
  54         STORE_IDX(sp, 13)
  55         li  a0, 0
  56         ret
  57
  58 /*
  59  * int grub_longjmp (grub_jmp_buf env, int val)
  60  */
  61 FUNCTION(grub_longjmp)
  62         LOAD_IDX(s0, 0)
  63         LOAD_IDX(s1, 1)
  64         LOAD_IDX(s2, 2)
  65         LOAD_IDX(s3, 3)
  66         LOAD_IDX(s4, 4)
  67         LOAD_IDX(s5, 5)
  68         LOAD_IDX(s6, 6)
  69         LOAD_IDX(s7, 7)
  70         LOAD_IDX(s8, 8)
  71         LOAD_IDX(s9, 9)
  72         LOAD_IDX(s10, 10)
  73         LOAD_IDX(s11, 11)
  74         LOAD_IDX(ra, 12)
  75         LOAD_IDX(sp, 13)
  76
  77         /* Move the return value in place, but return 1 if passed 0. */
  78         beq a1, zero, longjmp_1
  79         mv a0, a1
  80         ret
  81
  82         longjmp_1:
  83         li a0, 1
  84         ret