build-aux/check-final-inputs-self-contained.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;;
  20 ;;; Check whether important binaries are available.
  21 ;;;
  22
  23 (use-modules (guix store)
  24              (guix grafts)
  25              (guix packages)
  26              (guix derivations)
  27              (guix ui)
  28              (gnu packages commencement)
  29              (ice-9 match)
  30              (srfi srfi-1)
  31              (srfi srfi-26))
  32
  33 (define (final-inputs store system)
  34   "Return the list of outputs directories of the final inputs for SYSTEM."
  35   (append-map (match-lambda
  36                 ((or (name package) (name package _))
  37                  (let ((drv (package-derivation store package system)))
  38                    ;; Libc's 'debug' output refers to gcc-cross-boot0, but it's
  39                    ;; hard to avoid, so we tolerate it.  This should be the
  40                    ;; only exception.  Likewise, 'bash:include' depends on
  41                    ;; bootstrap-binaries via its 'Makefile.inc' (FIXME).
  42                    (filter-map (match-lambda
  43                                  (("debug" . directory)
  44                                   (if (string=? "glibc" (package-name package))
  45                                       #f
  46                                       directory))
  47                                  (("include" . directory)
  48                                   (if (string=? "bash" (package-name package))
  49                                       #f
  50                                       directory))
  51                                  ((_ . directory) directory))
  52                                (derivation->output-paths drv)))))
  53               %final-inputs))
  54
  55 (define (assert-valid-substitute substitute)
  56   "Make sure SUBSTITUTE does not refer to any bootstrap inputs, and bail out
  57 if it does."
  58   (let ((references (substitutable-references substitute)))
  59     (when (any (cut string-contains <> "boot") references)
  60       (leave (G_ "'~a' refers to bootstrap inputs: ~s~%")
  61              (substitutable-path substitute) references))))
  62
  63 (define (test-final-inputs store system)
  64   "Check whether the final inputs for SYSTEM are clean---i.e., they don't
  65 refer to the bootstrap tools."
  66   (format #t "checking final inputs for '~a'...~%" system)
  67   (let* ((inputs    (final-inputs store system))
  68          (available (substitutable-path-info store inputs)))
  69     (for-each (lambda (dir)
  70                 (unless (find (lambda (substitute)
  71                                 (string=? (substitutable-path substitute)
  72                                           dir))
  73                               available)
  74                   (leave (G_ "~a (system: ~a) has no substitute~%")
  75                          dir system)))
  76               inputs)
  77
  78     (for-each assert-valid-substitute available)))
  79
  80 ;; Entry point.
  81 (with-store store
  82   (parameterize ((%graft? #f))
  83     (set-build-options store #:use-substitutes? #t)
  84
  85     (for-each (cut test-final-inputs store <>)
  86               %hydra-supported-systems)))
  87