configure.ac

   1 AC_INIT(gwm-basic, 1.0, gtw@gnu.org)
   2 AC_CONFIG_SRCDIR(gwm.c)
   3 AM_INIT_AUTOMAKE
   4 AC_CONFIG_FILES(Makefile)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 AC_DEFINE(_GNU_SOURCE,1,Enable GNU extensions on systems that have them.)
   8
   9 # Checks for programs:
  10 AC_PROG_CC
  11 PKG_PROG_PKG_CONFIG
  12
  13 # Checks for libraries:
  14 #  pkg-config packages which must be present:
  15 packages="xcb"
  16 #  pkg-config xcb- packages which can optionally be used:
  17 optional_xcb_packages="shape"
  18
  19 AC_ARG_WITH(shape,    [  --with-shape            use the X SHAPE extension.])
  20
  21 AH_TEMPLATE(USE_SHAPE,[Use the X SHAPE extension.])
  22
  23 for i in $optional_xcb_packages; do
  24   AC_MSG_CHECKING([for $i])
  25   if eval test "x\$with_$i" = xno; then
  26     AC_MSG_RESULT(disabled)
  27   else
  28     iname=`echo $i | tr 'a-z' 'A-Z'`
  29     PKG_CHECK_EXISTS( xcb-$i,
  30                       [AC_MSG_RESULT(yes)
  31                       packages="$packages xcb-$i"
  32                       AC_DEFINE_UNQUOTED(USE_$iname, 1)],
  33                       [AC_MSG_RESULT(no)])
  34   fi
  35 done
  36
  37 AC_SEARCH_LIBS(iconv, iconv)
  38
  39 # Checks for header files:
  40 AC_CHECK_HEADERS(iconv.h mcheck.h poll.h)
  41
  42 # Checks for functions:
  43 AC_CHECK_FUNCS(iconv mtrace ppoll)
  44
  45 PKG_CHECK_MODULES(XCB, $packages)
  46
  47 AC_SUBST(XCB_CFLAGS)
  48 AC_SUBST(XCB_LIBS)
  49
  50 AC_OUTPUT